misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Liblime
   4 # Copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 BEGIN {
  24
  25     # find Koha's Perl modules
  26     # test carefully before changing this
  27     use FindBin;
  28     eval { require "$FindBin::Bin/../kohalib.pl" };
  29 }
  30
  31 use Getopt::Long;
  32 use Pod::Usage;
  33 use Text::CSV_XS;
  34 use DateTime;
  35 use DateTime::Duration;
  36
  37 use Koha::Script -cron;
  38 use C4::Context;
  39 use C4::Letters;
  40 use C4::Overdues qw(GetFine GetOverdueMessageTransportTypes parse_overdues_letter);
  41 use C4::Log;
  42 use Koha::Patron::Debarments qw(AddUniqueDebarment);
  43 use Koha::DateUtils;
  44 use Koha::Calendar;
  45 use Koha::Libraries;
  46 use Koha::Acquisition::Currencies;
  47 use Koha::Patrons;
  48
  49 =head1 NAME
  50
  51 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  52
  53 =head1 SYNOPSIS
  54
  55 overdue_notices.pl
  56   [ -n ][ -library <branchcode> ][ -library <branchcode> ... ]
  57   [ -max <number of days> ][ -csv [<filename>] ][ -itemscontent <field list> ]
  58   [ -email <email_type> ... ]
  59
  60  Options:
  61    -help                          brief help message
  62    -man                           full documentation
  63    -v                             verbose
  64    -n                             No email will be sent
  65    -max          <days>           maximum days overdue to deal with
  66    -library      <branchname>     only deal with overdues from this library (repeatable : several libraries can be given)
  67    -csv          <filename>       populate CSV file
  68    -html         <directory>      Output html to a file in the given directory
  69    -text         <directory>      Output plain text to a file in the given directory
  70    -itemscontent <list of fields> item information in templates
  71    -borcat       <categorycode>   category code that must be included
  72    -borcatout    <categorycode>   category code that must be excluded
  73    -t                             only include triggered overdues
  74    --test                         Run in test mode. No changes will be made on the DB.
  75    -list-all                      list all overdues
  76    -date         <yyyy-mm-dd>     emulate overdues run for this date
  77    -email        <email_type>     type of email that will be used. Can be 'email', 'emailpro' or 'B_email'. Repeatable.
  78
  79 =head1 OPTIONS
  80
  81 =over 8
  82
  83 =item B<-help>
  84
  85 Print a brief help message and exits.
  86
  87 =item B<-man>
  88
  89 Prints the manual page and exits.
  90
  91 =item B<-v>
  92
  93 Verbose. Without this flag set, only fatal errors are reported.
  94
  95 =item B<-n>
  96
  97 Do not send any email. Overdue notices that would have been sent to
  98 the patrons or to the admin are printed to standard out. CSV data (if
  99 the -csv flag is set) is written to standard out or to any csv
 100 filename given.
 101
 102 =item B<-max>
 103
 104 Items older than max days are assumed to be handled somewhere else,
 105 probably the F<longoverdues.pl> script. They are therefore ignored by
 106 this program. No notices are sent for them, and they are not added to
 107 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
 108
 109 =item B<-library>
 110
 111 select overdues for one specific library. Use the value in the
 112 branches.branchcode table. This option can be repeated in order
 113 to select overdues for a group of libraries.
 114
 115 =item B<-csv>
 116
 117 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
 118 sent to standard out or to a filename if provided. Otherwise, only
 119 overdues that could not be emailed are sent in CSV format to the admin.
 120
 121 =item B<-html>
 122
 123 Produces html data. If patron does not have an email address or
 124 -n (no mail) flag is set, an HTML file is generated in the specified
 125 directory. This can be downloaded or further processed by library staff.
 126 The file will be called notices-YYYY-MM-DD.html and placed in the directory
 127 specified.
 128
 129 =item B<-text>
 130
 131 Produces plain text data. If patron does not have an email address or
 132 -n (no mail) flag is set, a text file is generated in the specified
 133 directory. This can be downloaded or further processed by library staff.
 134 The file will be called notices-YYYY-MM-DD.txt and placed in the directory
 135 specified.
 136
 137 =item B<-itemscontent>
 138
 139 comma separated list of fields that get substituted into templates in
 140 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 141 defaults to due date,title,barcode,author
 142
 143 Other possible values come from fields in the biblios, items and
 144 issues tables.
 145
 146 =item B<-borcat>
 147
 148 Repeatable field, that permits to select only some patron categories.
 149
 150 =item B<-borcatout>
 151
 152 Repeatable field, that permits to exclude some patron categories.
 153
 154 =item B<-t> | B<--triggered>
 155
 156 This option causes a notice to be generated if and only if
 157 an item is overdue by the number of days defined in a notice trigger.
 158
 159 By default, a notice is sent each time the script runs, which is suitable for
 160 less frequent run cron script, but requires syncing notice triggers with
 161 the  cron schedule to ensure proper behavior.
 162 Add the --triggered option for daily cron, at the risk of no notice
 163 being generated if the cron fails to run on time.
 164
 165 =item B<-test>
 166
 167 This option makes the script run in test mode.
 168
 169 In test mode, the script won't make any changes on the DB. This is useful
 170 for debugging configuration.
 171
 172 =item B<-list-all>
 173
 174 Default items.content lists only those items that fall in the
 175 range of the currently processing notice.
 176 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 177
 178 =item B<-date>
 179
 180 use it in order to send overdues on a specific date and not Now. Format: YYYY-MM-DD.
 181
 182 =item B<-email>
 183
 184 Allows to specify which type of email will be used. Can be email, emailpro or B_email. Repeatable.
 185
 186 =back
 187
 188 =head1 DESCRIPTION
 189
 190 This script is designed to alert patrons and administrators of overdue
 191 items.
 192
 193 =head2 Configuration
 194
 195 This script pays attention to the overdue notice configuration
 196 performed in the "Overdue notice/status triggers" section of the
 197 "Tools" area of the staff interface to Koha. There, you can choose
 198 which letter templates are sent out after a configurable number of
 199 days to patrons of each library. More information about the use of this
 200 section of Koha is available in the Koha manual.
 201
 202 The templates used to craft the emails are defined in the "Tools:
 203 Notices" section of the staff interface to Koha.
 204
 205 =head2 Outgoing emails
 206
 207 Typically, messages are prepared for each patron with overdue
 208 items. Messages for whom there is no email address on file are
 209 collected and sent as attachments in a single email to each library
 210 administrator, or if that is not set, then to the email address in the
 211 C<KohaAdminEmailAddress> system preference.
 212
 213 These emails are staged in the outgoing message queue, as are messages
 214 produced by other features of Koha. This message queue must be
 215 processed regularly by the
 216 F<misc/cronjobs/process_message_queue.pl> program.
 217
 218 In the event that the C<-n> flag is passed to this program, no emails
 219 are sent. Instead, messages are sent on standard output from this
 220 program. They may be redirected to a file if desired.
 221
 222 =head2 Templates
 223
 224 Templates can contain variables enclosed in double angle brackets like
 225 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 226 specific to the overdue items or relevant patron. Available variables
 227 are:
 228
 229 =over
 230
 231 =item E<lt>E<lt>bibE<gt>E<gt>
 232
 233 the name of the library
 234
 235 =item E<lt>E<lt>items.contentE<gt>E<gt>
 236
 237 one line for each item, each line containing a tab separated list of
 238 title, author, barcode, issuedate
 239
 240 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 241
 242 any field from the borrowers table
 243
 244 =item E<lt>E<lt>branches.*E<gt>E<gt>
 245
 246 any field from the branches table
 247
 248 =back
 249
 250 =head2 CSV output
 251
 252 The C<-csv> command line option lets you specify a file to which
 253 overdues data should be output in CSV format.
 254
 255 With the C<-n> flag set, data about all overdues is written to the
 256 file. Without that flag, only information about overdues that were
 257 unable to be sent directly to the patrons will be written. In other
 258 words, this CSV file replaces the data that is typically sent to the
 259 administrator email address.
 260
 261 =head1 USAGE EXAMPLES
 262
 263 C<overdue_notices.pl> - In this most basic usage, with no command line
 264 arguments, all libraries are processed individually, and notices are
 265 prepared for all patrons with overdue items for whom we have email
 266 addresses. Messages for those patrons for whom we have no email
 267 address are sent in a single attachment to the library administrator's
 268 email address, or to the address in the KohaAdminEmailAddress system
 269 preference.
 270
 271 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 272 populates F</tmp/overdues.csv> with information about all overdue
 273 items.
 274
 275 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 276 overdues in the last 2 weeks for the MAIN library.
 277
 278 =head1 SEE ALSO
 279
 280 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 281 messages to patrons in advance of their items becoming due, or to
 282 alert them of items that have just become due.
 283
 284 =cut
 285
 286 # These variables are set by command line options.
 287 # They are initially set to default values.
 288 my $dbh = C4::Context->dbh();
 289 my $help    = 0;
 290 my $man     = 0;
 291 my $verbose = 0;
 292 my $nomail  = 0;
 293 my $MAX     = 90;
 294 my $test_mode = 0;
 295 my @branchcodes; # Branch(es) passed as parameter
 296 my @emails_to_use;    # Emails to use for messaging
 297 my @emails;           # Emails given in command-line parameters
 298 my $csvfilename;
 299 my $htmlfilename;
 300 my $text_filename;
 301 my $triggered = 0;
 302 my $listall = 0;
 303 my $itemscontent = join( ',', qw( date_due title barcode author itemnumber ) );
 304 my @myborcat;
 305 my @myborcatout;
 306 my ( $date_input, $today );
 307
 308 GetOptions(
 309     'help|?'         => \$help,
 310     'man'            => \$man,
 311     'v'              => \$verbose,
 312     'n'              => \$nomail,
 313     'max=s'          => \$MAX,
 314     'library=s'      => \@branchcodes,
 315     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 316     'html:s'         => \$htmlfilename,    # this optional argument gets '' if not supplied.
 317     'text:s'         => \$text_filename,    # this optional argument gets '' if not supplied.
 318     'itemscontent=s' => \$itemscontent,
 319     'list-all'       => \$listall,
 320     't|triggered'    => \$triggered,
 321     'test'           => \$test_mode,
 322     'date=s'         => \$date_input,
 323     'borcat=s'       => \@myborcat,
 324     'borcatout=s'    => \@myborcatout,
 325     'email=s'        => \@emails,
 326 ) or pod2usage(2);
 327 pod2usage(1) if $help;
 328 pod2usage( -verbose => 2 ) if $man;
 329 cronlogaction() unless $test_mode;
 330
 331 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 332     warn qq(using "$csvfilename" as filename, that seems odd);
 333 }
 334
 335 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();        # Branches with overdue rules
 336 my @branches;                                                                   # Branches passed as parameter with overdue rules
 337 my $branchcount = scalar(@overduebranches);
 338
 339 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 340 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 341
 342 my $PrintNoticesMaxLines = C4::Context->preference('PrintNoticesMaxLines');
 343
 344 if ($branchcount) {
 345     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 346 } else {
 347     die 'No branches with active overduerules';
 348 }
 349
 350 if (@branchcodes) {
 351     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 352
 353     # Getting libraries which have overdue rules
 354     my %seen = map { $_ => 1 } @branchcodes;
 355     @branches = grep { $seen{$_} } @overduebranches;
 356
 357
 358     if (@branches) {
 359
 360         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 361         $verbose and warn "$branch_word @branches have overdue rules\n";
 362
 363     } else {
 364
 365         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 366         ( scalar grep { '' eq $_ } @branches )
 367           or die "No active overduerules for DEFAULT either!";
 368         $verbose and warn "Falling back on default rules for @branchcodes\n";
 369         @branches = ('');
 370     }
 371 }
 372 my $date_to_run;
 373 my $date;
 374 if ( $date_input ){
 375     eval {
 376         $date_to_run = dt_from_string( $date_input, 'iso' );
 377     };
 378     die "$date_input is not a valid date, aborting! Use a date in format YYYY-MM-DD."
 379         if $@ or not $date_to_run;
 380
 381     # It's certainly useless to escape $date_input
 382     # dt_from_string should not return something if $date_input is not correctly set.
 383     $date = $dbh->quote( $date_input );
 384 }
 385 else {
 386     $date="NOW()";
 387     $date_to_run = dt_from_string();
 388 }
 389
 390 # these are the fields that will be substituted into <<item.content>>
 391 my @item_content_fields = split( /,/, $itemscontent );
 392
 393 binmode( STDOUT, ':encoding(UTF-8)' );
 394
 395
 396 our $csv;       # the Text::CSV_XS object
 397 our $csv_fh;    # the filehandle to the CSV file.
 398 if ( defined $csvfilename ) {
 399     my $sep_char = C4::Context->preference('delimiter') || ';';
 400     $sep_char = "\t" if ($sep_char eq 'tabulation');
 401     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 402     if ( $csvfilename eq '' ) {
 403         $csv_fh = *STDOUT;
 404     } else {
 405         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 406     }
 407     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email phone cardnumber itemcount itemsinfo branchname letternumber)) ) {
 408         print $csv_fh $csv->string, "\n";
 409     } else {
 410         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 411     }
 412 }
 413
 414 @branches = @overduebranches unless @branches;
 415 our $fh;
 416 if ( defined $htmlfilename ) {
 417   if ( $htmlfilename eq '' ) {
 418     $fh = *STDOUT;
 419   } else {
 420     my $today = dt_from_string();
 421     open $fh, ">:encoding(UTF-8)",File::Spec->catdir ($htmlfilename,"notices-".$today->ymd().".html");
 422   }
 423
 424   print $fh "<html>\n";
 425   print $fh "<head>\n";
 426   print $fh "<meta http-equiv=\"Content-Type\" content=\"text/html; charset=utf-8\" />\n";
 427   print $fh "<style type='text/css'>\n";
 428   print $fh "pre {page-break-after: always;}\n";
 429   print $fh "pre {white-space: pre-wrap;}\n";
 430   print $fh "pre {white-space: -moz-pre-wrap;}\n";
 431   print $fh "pre {white-space: -o-pre-wrap;}\n";
 432   print $fh "pre {word-wrap: break-work;}\n";
 433   print $fh "</style>\n";
 434   print $fh "</head>\n";
 435   print $fh "<body>\n";
 436 }
 437 elsif ( defined $text_filename ) {
 438   if ( $text_filename eq '' ) {
 439     $fh = *STDOUT;
 440   } else {
 441     my $today = dt_from_string();
 442     open $fh, ">:encoding(UTF-8)",File::Spec->catdir ($text_filename,"notices-".$today->ymd().".txt");
 443   }
 444 }
 445
 446 foreach my $branchcode (@branches) {
 447     my $calendar;
 448     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 449         $calendar = Koha::Calendar->new( branchcode => $branchcode );
 450         if ( $calendar->is_holiday($date_to_run) ) {
 451             next;
 452         }
 453     }
 454
 455     my $library             = Koha::Libraries->find($branchcode);
 456     my $admin_email_address = $library->branchemail
 457       || C4::Context->preference('KohaAdminEmailAddress');
 458     my $branch_email_address = C4::Context->preference('AddressForFailedOverdueNotices')
 459       || $library->inbound_email_address;
 460     my @output_chunks;    # may be sent to mail or stdout or csv file.
 461
 462     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $branch_email_address;
 463
 464     my $sth2 = $dbh->prepare( <<"END_SQL" );
 465 SELECT biblio.*, items.*, issues.*, biblioitems.itemtype, branchname
 466   FROM issues,items,biblio, biblioitems, branches b
 467   WHERE items.itemnumber=issues.itemnumber
 468     AND biblio.biblionumber   = items.biblionumber
 469     AND b.branchcode = items.homebranch
 470     AND biblio.biblionumber   = biblioitems.biblionumber
 471     AND issues.borrowernumber = ?
 472     AND issues.branchcode = ?
 473     AND items.itemlost = 0
 474     AND TO_DAYS($date)-TO_DAYS(issues.date_due) >= 0
 475 END_SQL
 476
 477     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ";
 478     $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 479     $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 480
 481     my $rqoverduerules =  $dbh->prepare($query);
 482     $rqoverduerules->execute($branchcode, @myborcat, @myborcatout);
 483
 484     # We get default rules is there is no rule for this branch
 485     if($rqoverduerules->rows == 0){
 486         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ";
 487         $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 488         $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 489
 490         $rqoverduerules = $dbh->prepare($query);
 491         $rqoverduerules->execute(@myborcat, @myborcatout);
 492     }
 493
 494     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 495     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 496       PERIOD: foreach my $i ( 1 .. 3 ) {
 497
 498             $verbose and warn "branch '$branchcode', categorycode = $overdue_rules->{categorycode} pass $i\n";
 499
 500             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 501             my $maxdays = (
 502                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 503                 ? $overdue_rules->{ "delay" . ( $i + 1 ) } - 1
 504                 : ($MAX)
 505             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 506
 507             next unless defined $mindays;
 508
 509             if ( !$overdue_rules->{"letter$i"} ) {
 510                 $verbose and warn "No letter$i code for branch '$branchcode'";
 511                 next PERIOD;
 512             }
 513
 514             # $letter->{'content'} is the text of the mail that is sent.
 515             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 516             # The following fields are available :
 517             # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 518             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode> <country>
 519
 520             my $borrower_sql = <<"END_SQL";
 521 SELECT issues.borrowernumber, firstname, surname, address, address2, city, zipcode, country, email, emailpro, B_email, smsalertnumber, phone, cardnumber, date_due
 522 FROM   issues,borrowers,categories,items
 523 WHERE  issues.borrowernumber=borrowers.borrowernumber
 524 AND    borrowers.categorycode=categories.categorycode
 525 AND    issues.itemnumber = items.itemnumber
 526 AND    items.itemlost = 0
 527 AND    TO_DAYS($date)-TO_DAYS(issues.date_due) >= 0
 528 END_SQL
 529             my @borrower_parameters;
 530             if ($branchcode) {
 531                 $borrower_sql .= ' AND issues.branchcode=? ';
 532                 push @borrower_parameters, $branchcode;
 533             }
 534             if ( $overdue_rules->{categorycode} ) {
 535                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 536                 push @borrower_parameters, $overdue_rules->{categorycode};
 537             }
 538             $borrower_sql .= '  AND categories.overduenoticerequired=1 ORDER BY issues.borrowernumber';
 539
 540             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 541                 my $sth = $dbh->prepare($borrower_sql);
 542             $sth->execute(@borrower_parameters);
 543
 544             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays, ".  $date_to_run->datetime() .")\nreturns " . $sth->rows . " rows";
 545             my $borrowernumber;
 546             while ( my $data = $sth->fetchrow_hashref ) {
 547
 548                 # check the borrower has at least one item that matches
 549                 my $days_between;
 550                 if ( C4::Context->preference('OverdueNoticeCalendar') )
 551                 {
 552                     $days_between =
 553                       $calendar->days_between( dt_from_string($data->{date_due}),
 554                         $date_to_run );
 555                 }
 556                 else {
 557                     $days_between =
 558                       $date_to_run->delta_days( dt_from_string($data->{date_due}) );
 559                 }
 560                 $days_between = $days_between->in_units('days');
 561                 if ($triggered) {
 562                     if ( $mindays != $days_between ) {
 563                         next;
 564                     }
 565                 }
 566                 else {
 567                     unless (   $days_between >= $mindays
 568                         && $days_between <= $maxdays )
 569                     {
 570                         next;
 571                     }
 572                 }
 573                 if (defined $borrowernumber && $borrowernumber eq $data->{'borrowernumber'}){
 574 # we have already dealt with this borrower
 575                     $verbose and warn "already dealt with this borrower $borrowernumber";
 576                     next;
 577                 }
 578                 $borrowernumber = $data->{'borrowernumber'};
 579                 my $borr = sprintf( "%s%s%s (%s)",
 580                     $data->{'surname'} || '',
 581                     $data->{'firstname'} && $data->{'surname'} ? ', ' : '',
 582                     $data->{'firstname'} || '',
 583                     $borrowernumber );
 584                 $verbose
 585                   and warn "borrower $borr has items triggering level $i.";
 586
 587                 my $patron = Koha::Patrons->find( $borrowernumber );
 588                 @emails_to_use = ();
 589                 my $notice_email = $patron->notice_email_address;
 590                 unless ($nomail) {
 591                     if (@emails) {
 592                         foreach (@emails) {
 593                             push @emails_to_use, $data->{$_} if ( $data->{$_} );
 594                         }
 595                     }
 596                     else {
 597                         push @emails_to_use, $notice_email if ($notice_email);
 598                     }
 599                 }
 600
 601                 my $letter = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"}, $branchcode, undef, $patron->lang );
 602
 603                 unless ($letter) {
 604                     $verbose and warn qq|Message '$overdue_rules->{"letter$i"}' content not found|;
 605
 606                     # might as well skip while PERIOD, no other borrowers are going to work.
 607                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 608                     next PERIOD;
 609                 }
 610
 611                 if ( $overdue_rules->{"debarred$i"} ) {
 612
 613                     #action taken is debarring
 614                     AddUniqueDebarment(
 615                         {
 616                             borrowernumber => $borrowernumber,
 617                             type           => 'OVERDUES',
 618                             comment => "OVERDUES_PROCESS " .  output_pref( dt_from_string() ),
 619                         }
 620                     ) unless $test_mode;
 621                     $verbose and warn "debarring $borr\n";
 622                 }
 623                 my @params = ($borrowernumber,$branchcode);
 624                 $verbose and warn "STH2 PARAMS: borrowernumber = $borrowernumber";
 625
 626                 $sth2->execute(@params);
 627                 my $itemcount = 0;
 628                 my $titles = "";
 629                 my @items = ();
 630
 631                 my $j = 0;
 632                 my $exceededPrintNoticesMaxLines = 0;
 633                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 634                     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 635                         $days_between =
 636                           $calendar->days_between(
 637                             dt_from_string( $item_info->{date_due} ), $date_to_run );
 638                     }
 639                     else {
 640                         $days_between =
 641                           $date_to_run->delta_days(
 642                             dt_from_string( $item_info->{date_due} ) );
 643                     }
 644                     $days_between = $days_between->in_units('days');
 645                     if ($listall){
 646                         unless ($days_between >= 1 and $days_between <= $MAX){
 647                             next;
 648                         }
 649                     }
 650                     else {
 651                         if ($triggered) {
 652                             if ( $mindays != $days_between ) {
 653                                 next;
 654                             }
 655                         }
 656                         else {
 657                             unless ( $days_between >= $mindays
 658                                 && $days_between <= $maxdays )
 659                             {
 660                                 next;
 661                             }
 662                         }
 663                     }
 664
 665                     if ( ( scalar(@emails_to_use) == 0 || $nomail ) && $PrintNoticesMaxLines && $j >= $PrintNoticesMaxLines ) {
 666                       $exceededPrintNoticesMaxLines = 1;
 667                       last;
 668                     }
 669                     $j++;
 670
 671                     $titles .= C4::Letters::get_item_content( { item => $item_info, item_content_fields => \@item_content_fields, dateonly => 1 } );
 672                     $itemcount++;
 673                     push @items, $item_info;
 674                 }
 675                 $sth2->finish;
 676
 677                 my @message_transport_types = @{ GetOverdueMessageTransportTypes( $branchcode, $overdue_rules->{categorycode}, $i) };
 678                 @message_transport_types = @{ GetOverdueMessageTransportTypes( q{}, $overdue_rules->{categorycode}, $i) }
 679                     unless @message_transport_types;
 680
 681
 682                 my $print_sent = 0; # A print notice is not yet sent for this patron
 683                 for my $mtt ( @message_transport_types ) {
 684                     my $effective_mtt = $mtt;
 685                     if ( ($mtt eq 'email' and not scalar @emails_to_use) or ($mtt eq 'sms' and not $data->{smsalertnumber}) ) {
 686                         # email or sms is requested but not exist, do a print.
 687                         $effective_mtt = 'print';
 688                     }
 689                     splice @items, $PrintNoticesMaxLines if $effective_mtt eq 'print' && $PrintNoticesMaxLines && scalar @items > $PrintNoticesMaxLines;
 690                     #catch the case where we are sending a print to someone with an email
 691
 692                     my $letter_exists = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"}, $branchcode, $effective_mtt, $patron->lang ) ? 1 : 0;
 693                     my $letter = parse_overdues_letter(
 694                         {   letter_code     => $overdue_rules->{"letter$i"},
 695                             borrowernumber  => $borrowernumber,
 696                             branchcode      => $branchcode,
 697                             items           => \@items,
 698                             substitute      => {    # this appears to be a hack to overcome incomplete features in this code.
 699                                                 bib             => $library->branchname, # maybe 'bib' is a typo for 'lib<rary>'?
 700                                                 'items.content' => $titles,
 701                                                 'count'         => $itemcount,
 702                                                },
 703                             # If there is no template defined for the requested letter
 704                             # Fallback on the original type
 705                             message_transport_type => $letter_exists ? $effective_mtt : $mtt,
 706                         }
 707                     );
 708                     unless ($letter) {
 709                         $verbose and warn qq|Message '$overdue_rules->{"letter$i"}' content not found|;
 710                         # this transport doesn't have a configured notice, so try another
 711                         next;
 712                     }
 713
 714                     if ( $exceededPrintNoticesMaxLines ) {
 715                       $letter->{'content'} .= "List too long for form; please check your account online for a complete list of your overdue items.";
 716                     }
 717
 718                     my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 719                     if (@misses) {
 720                         $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 721                     }
 722
 723                     if ($nomail) {
 724                         push @output_chunks,
 725                           prepare_letter_for_printing(
 726                           {   letter         => $letter,
 727                               borrowernumber => $borrowernumber,
 728                               firstname      => $data->{'firstname'},
 729                               lastname       => $data->{'surname'},
 730                               address1       => $data->{'address'},
 731                               address2       => $data->{'address2'},
 732                               city           => $data->{'city'},
 733                               phone          => $data->{'phone'},
 734                               cardnumber     => $data->{'cardnumber'},
 735                               branchname     => $library->branchname,
 736                               letternumber   => $i,
 737                               postcode       => $data->{'zipcode'},
 738                               country        => $data->{'country'},
 739                               email          => $notice_email,
 740                               itemcount      => $itemcount,
 741                               titles         => $titles,
 742                               outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 743                             }
 744                           );
 745                     } else {
 746                         if ( ($mtt eq 'email' and not scalar @emails_to_use) or ($mtt eq 'sms' and not $data->{smsalertnumber}) ) {
 747                             push @output_chunks,
 748                               prepare_letter_for_printing(
 749                               {   letter         => $letter,
 750                                   borrowernumber => $borrowernumber,
 751                                   firstname      => $data->{'firstname'},
 752                                   lastname       => $data->{'surname'},
 753                                   address1       => $data->{'address'},
 754                                   address2       => $data->{'address2'},
 755                                   city           => $data->{'city'},
 756                                   postcode       => $data->{'zipcode'},
 757                                   country        => $data->{'country'},
 758                                   email          => $notice_email,
 759                                   itemcount      => $itemcount,
 760                                   titles         => $titles,
 761                                   outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 762                                 }
 763                               );
 764                         }
 765                         unless ( $effective_mtt eq 'print' and $print_sent == 1 ) {
 766                             # Just sent a print if not already done.
 767                             C4::Letters::EnqueueLetter(
 768                                 {   letter                 => $letter,
 769                                     borrowernumber         => $borrowernumber,
 770                                     message_transport_type => $effective_mtt,
 771                                     from_address           => $admin_email_address,
 772                                     to_address             => join(',', @emails_to_use),
 773                                 }
 774                             ) unless $test_mode;
 775                             # A print notice should be sent only once per overdue level.
 776                             # Without this check, a print could be sent twice or more if the library checks sms and email and print and the patron has no email or sms number.
 777                             $print_sent = 1 if $effective_mtt eq 'print';
 778                         }
 779                     }
 780                 }
 781             }
 782             $sth->finish;
 783         }
 784     }
 785
 786     if (@output_chunks) {
 787         if ( defined $csvfilename ) {
 788             print $csv_fh @output_chunks;
 789         }
 790         elsif ( defined $htmlfilename ) {
 791             print $fh @output_chunks;
 792         }
 793         elsif ( defined $text_filename ) {
 794             print $fh @output_chunks;
 795         }
 796         elsif ($nomail){
 797                 local $, = "\f";    # pagebreak
 798                 print @output_chunks;
 799         }
 800         # Generate the content of the csv with headers
 801         my $content;
 802         if ( defined $csvfilename ) {
 803             my $delimiter = C4::Context->preference('delimiter') || ';';
 804             $content = join($delimiter, qw(title name surname address1 address2 zipcode city country email itemcount itemsinfo due_date issue_date)) . "\n";
 805         }
 806         else {
 807             $content = "";
 808         }
 809         $content .= join( "\n", @output_chunks );
 810
 811         my $attachment = {
 812             filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 813             type => 'text/plain',
 814             content => $content,
 815         };
 816
 817         my $letter = {
 818             title   => 'Overdue Notices',
 819             content => 'These messages were not sent directly to the patrons.',
 820         };
 821
 822         C4::Letters::EnqueueLetter(
 823             {   letter                 => $letter,
 824                 borrowernumber         => undef,
 825                 message_transport_type => 'email',
 826                 attachments            => [$attachment],
 827                 to_address             => $branch_email_address,
 828             }
 829         ) unless $test_mode;
 830     }
 831
 832 }
 833 if ($csvfilename) {
 834     # note that we're not testing on $csv_fh to prevent closing
 835     # STDOUT.
 836     close $csv_fh;
 837 }
 838
 839 if ( defined $htmlfilename ) {
 840   print $fh "</body>\n";
 841   print $fh "</html>\n";
 842   close $fh;
 843 } elsif ( defined $text_filename ) {
 844   close $fh;
 845 }
 846
 847 =head1 INTERNAL METHODS
 848
 849 These methods are internal to the operation of overdue_notices.pl.
 850
 851 =head2 prepare_letter_for_printing
 852
 853 returns a string of text appropriate for printing in the event that an
 854 overdue notice will not be sent to the patron's email
 855 address. Depending on the desired output format, this may be a CSV
 856 string, or a human-readable representation of the notice.
 857
 858 required parameters:
 859   letter
 860   borrowernumber
 861
 862 optional parameters:
 863   outputformat
 864
 865 =cut
 866
 867 sub prepare_letter_for_printing {
 868     my $params = shift;
 869
 870     return unless ref $params eq 'HASH';
 871
 872     foreach my $required_parameter (qw( letter borrowernumber )) {
 873         return unless defined $params->{$required_parameter};
 874     }
 875
 876     my $return;
 877     chomp $params->{titles};
 878     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 879         if ($csv->combine(
 880                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 881                 $params->{'city'}, $params->{'country'}, $params->{'email'}, $params->{'phone'}, $params->{'cardnumber'},
 882                 $params->{'itemcount'}, $params->{'titles'}, $params->{'branchname'}, $params->{'letternumber'}
 883             )
 884           ) {
 885             return $csv->string, "\n";
 886         } else {
 887             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 888         }
 889     } elsif ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'html' ) {
 890       $return = "<pre>\n";
 891       $return .= "$params->{'letter'}->{'content'}\n";
 892       $return .= "\n</pre>\n";
 893     } else {
 894         $return .= "$params->{'letter'}->{'content'}\n";
 895
 896         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 897     }
 898     return $return;
 899 }
 900