misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Liblime
   4 # Copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use Getopt::Long qw( GetOptions );
  24 use Pod::Usage qw( pod2usage );
  25 use Text::CSV_XS;
  26 use DateTime;
  27 use DateTime::Duration;
  28
  29 use Koha::Script -cron;
  30 use C4::Context;
  31 use C4::Letters;
  32 use C4::Overdues qw( GetOverdueMessageTransportTypes parse_overdues_letter );
  33 use C4::Log qw( cronlogaction );
  34 use Koha::Patron::Debarments qw( AddUniqueDebarment );
  35 use Koha::DateUtils qw( dt_from_string output_pref );
  36 use Koha::Calendar;
  37 use Koha::Libraries;
  38 use Koha::Acquisition::Currencies;
  39 use Koha::Patrons;
  40
  41 =head1 NAME
  42
  43 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  44
  45 =head1 SYNOPSIS
  46
  47 overdue_notices.pl
  48   [ -n ][ --library <branchcode> ][ --library <branchcode> ... ]
  49   [ --max <number of days> ][ --csv [<filename>] ][ --itemscontent <field list> ]
  50   [ --email <email_type> ... ]
  51
  52  Options:
  53    --help                          Brief help message.
  54    --man                           Full documentation.
  55    --verbose | -v                  Verbose mode.
  56    --nomail | -n                   No email will be sent.
  57    --max          <days>           Maximum days overdue to deal with.
  58    --library      <branchcode>     Only deal with overdues from this library.
  59                                    (repeatable : several libraries can be given)
  60    --csv          <filename>       Populate CSV file.
  61    --html         <directory>      Output html to a file in the given directory.
  62    --text         <directory>      Output plain text to a file in the given directory.
  63    --itemscontent <list of fields> Item information in templates.
  64    --borcat       <categorycode>   Category code that must be included.
  65    --borcatout    <categorycode>   Category code that must be excluded.
  66    --triggered | -t                Only include triggered overdues.
  67    --test                          Run in test mode. No changes will be made on the DB.
  68    --list-all                      List all overdues.
  69    --date         <yyyy-mm-dd>     Emulate overdues run for this date.
  70    --email        <email_type>     Type of email that will be used.
  71                                    Can be 'email', 'emailpro' or 'B_email'. Repeatable.
  72    --frombranch                    Set the from address for the notice to one of 'item-homebranch' or 'item-issuebranch'.
  73
  74 =head1 OPTIONS
  75
  76 =over 8
  77
  78 =item B<--help>
  79
  80 Print a brief help message and exits.
  81
  82 =item B<--man>
  83
  84 Prints the manual page and exits.
  85
  86 =item B<-v> | B<--verbose>
  87
  88 Verbose. Without this flag set, only fatal errors are reported.
  89
  90 =item B<-n> | B<--nomail>
  91
  92 Do not send any email. Overdue notices that would have been sent to
  93 the patrons or to the admin are printed to standard out. CSV data (if
  94 the --csv flag is set) is written to standard out or to any csv
  95 filename given.
  96
  97 =item B<--max>
  98
  99 Items older than max days are assumed to be handled somewhere else,
 100 probably the F<longoverdues.pl> script. They are therefore ignored by
 101 this program. No notices are sent for them, and they are not added to
 102 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
 103
 104 =item B<--library>
 105
 106 select overdues for one specific library. Use the value in the
 107 branches.branchcode table. This option can be repeated in order
 108 to select overdues for a group of libraries.
 109
 110 =item B<--csv>
 111
 112 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
 113 sent to standard out or to a filename if provided. Otherwise, only
 114 overdues that could not be emailed are sent in CSV format to the admin.
 115
 116 =item B<--html>
 117
 118 Produces html data. If patron does not have an email address or
 119 -n (no mail) flag is set, an HTML file is generated in the specified
 120 directory. This can be downloaded or further processed by library staff.
 121 The file will be called notices-YYYY-MM-DD.html and placed in the directory
 122 specified.
 123
 124 =item B<--text>
 125
 126 Produces plain text data. If patron does not have an email address or
 127 -n (no mail) flag is set, a text file is generated in the specified
 128 directory. This can be downloaded or further processed by library staff.
 129 The file will be called notices-YYYY-MM-DD.txt and placed in the directory
 130 specified.
 131
 132 =item B<--itemscontent>
 133
 134 comma separated list of fields that get substituted into templates in
 135 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 136 defaults to due date,title,barcode,author
 137
 138 Other possible values come from fields in the biblios, items and
 139 issues tables.
 140
 141 =item B<--borcat>
 142
 143 Repeatable field, that permits to select only some patron categories.
 144
 145 =item B<--borcatout>
 146
 147 Repeatable field, that permits to exclude some patron categories.
 148
 149 =item B<-t> | B<--triggered>
 150
 151 This option causes a notice to be generated if and only if
 152 an item is overdue by the number of days defined in a notice trigger.
 153
 154 By default, a notice is sent each time the script runs, which is suitable for
 155 less frequent run cron script, but requires syncing notice triggers with
 156 the  cron schedule to ensure proper behavior.
 157 Add the --triggered option for daily cron, at the risk of no notice
 158 being generated if the cron fails to run on time.
 159
 160 =item B<--test>
 161
 162 This option makes the script run in test mode.
 163
 164 In test mode, the script won't make any changes on the DB. This is useful
 165 for debugging configuration.
 166
 167 =item B<--list-all>
 168
 169 Default items.content lists only those items that fall in the
 170 range of the currently processing notice.
 171 Choose --list-all to include all overdue items in the list (limited by B<--max> setting).
 172
 173 =item B<--date>
 174
 175 use it in order to send overdues on a specific date and not Now. Format: YYYY-MM-DD.
 176
 177 =item B<--email>
 178
 179 Allows to specify which type of email will be used. Can be email, emailpro or B_email. Repeatable.
 180
 181 =item B<--frombranch>
 182
 183 Use the address information from the item homebranch library instead of the issuing library.
 184
 185 Defaults to 'item-issuebranch'
 186
 187 =back
 188
 189 =head1 DESCRIPTION
 190
 191 This script is designed to alert patrons and administrators of overdue
 192 items.
 193
 194 =head2 Configuration
 195
 196 This script pays attention to the overdue notice configuration
 197 performed in the "Overdue notice/status triggers" section of the
 198 "Tools" area of the staff interface to Koha. There, you can choose
 199 which letter templates are sent out after a configurable number of
 200 days to patrons of each library. More information about the use of this
 201 section of Koha is available in the Koha manual.
 202
 203 The templates used to craft the emails are defined in the "Tools:
 204 Notices" section of the staff interface to Koha.
 205
 206 =head2 Outgoing emails
 207
 208 Typically, messages are prepared for each patron with overdue
 209 items. Messages for whom there is no email address on file are
 210 collected and sent as attachments in a single email to each library
 211 administrator, or if that is not set, then to the email address in the
 212 C<KohaAdminEmailAddress> system preference.
 213
 214 These emails are staged in the outgoing message queue, as are messages
 215 produced by other features of Koha. This message queue must be
 216 processed regularly by the
 217 F<misc/cronjobs/process_message_queue.pl> program.
 218
 219 In the event that the C<-n> flag is passed to this program, no emails
 220 are sent. Instead, messages are sent on standard output from this
 221 program. They may be redirected to a file if desired.
 222
 223 =head2 Templates
 224
 225 Templates can contain variables enclosed in double angle brackets like
 226 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 227 specific to the overdue items or relevant patron. Available variables
 228 are:
 229
 230 =over
 231
 232 =item E<lt>E<lt>bibE<gt>E<gt>
 233
 234 the name of the library
 235
 236 =item E<lt>E<lt>items.contentE<gt>E<gt>
 237
 238 one line for each item, each line containing a tab separated list of
 239 title, author, barcode, issuedate
 240
 241 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 242
 243 any field from the borrowers table
 244
 245 =item E<lt>E<lt>branches.*E<gt>E<gt>
 246
 247 any field from the branches table
 248
 249 =back
 250
 251 =head2 CSV output
 252
 253 The C<-csv> command line option lets you specify a file to which
 254 overdues data should be output in CSV format.
 255
 256 With the C<-n> flag set, data about all overdues is written to the
 257 file. Without that flag, only information about overdues that were
 258 unable to be sent directly to the patrons will be written. In other
 259 words, this CSV file replaces the data that is typically sent to the
 260 administrator email address.
 261
 262 =head1 USAGE EXAMPLES
 263
 264 C<overdue_notices.pl> - In this most basic usage, with no command line
 265 arguments, all libraries are processed individually, and notices are
 266 prepared for all patrons with overdue items for whom we have email
 267 addresses. Messages for those patrons for whom we have no email
 268 address are sent in a single attachment to the library administrator's
 269 email address, or to the address in the KohaAdminEmailAddress system
 270 preference.
 271
 272 C<overdue_notices.pl -n --csv /tmp/overdues.csv> - sends no email and
 273 populates F</tmp/overdues.csv> with information about all overdue
 274 items.
 275
 276 C<overdue_notices.pl --library MAIN max 14> - prepare notices of
 277 overdues in the last 2 weeks for the MAIN library.
 278
 279 =head1 SEE ALSO
 280
 281 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 282 messages to patrons in advance of their items becoming due, or to
 283 alert them of items that have just become due.
 284
 285 =cut
 286
 287 # These variables are set by command line options.
 288 # They are initially set to default values.
 289 my $dbh = C4::Context->dbh();
 290 my $help    = 0;
 291 my $man     = 0;
 292 my $verbose = 0;
 293 my $nomail  = 0;
 294 my $MAX     = 90;
 295 my $test_mode = 0;
 296 my $frombranch = 'item-issuebranch';
 297 my @branchcodes; # Branch(es) passed as parameter
 298 my @emails_to_use;    # Emails to use for messaging
 299 my @emails;           # Emails given in command-line parameters
 300 my $csvfilename;
 301 my $htmlfilename;
 302 my $text_filename;
 303 my $triggered = 0;
 304 my $listall = 0;
 305 my $itemscontent = join( ',', qw( date_due title barcode author itemnumber ) );
 306 my @myborcat;
 307 my @myborcatout;
 308 my ( $date_input, $today );
 309
 310 GetOptions(
 311     'help|?'         => \$help,
 312     'man'            => \$man,
 313     'v|verbose'      => \$verbose,
 314     'n|nomail'       => \$nomail,
 315     'max=s'          => \$MAX,
 316     'library=s'      => \@branchcodes,
 317     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 318     'html:s'         => \$htmlfilename,    # this optional argument gets '' if not supplied.
 319     'text:s'         => \$text_filename,    # this optional argument gets '' if not supplied.
 320     'itemscontent=s' => \$itemscontent,
 321     'list-all'       => \$listall,
 322     't|triggered'    => \$triggered,
 323     'test'           => \$test_mode,
 324     'date=s'         => \$date_input,
 325     'borcat=s'       => \@myborcat,
 326     'borcatout=s'    => \@myborcatout,
 327     'email=s'        => \@emails,
 328     'frombranch=s'   => \$frombranch,
 329 ) or pod2usage(2);
 330 pod2usage(1) if $help;
 331 pod2usage( -verbose => 2 ) if $man;
 332 cronlogaction() unless $test_mode;
 333
 334 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 335     warn qq(using "$csvfilename" as filename, that seems odd);
 336 }
 337
 338 die "--frombranch takes item-homebranch or item-issuebranch only"
 339     unless ( $frombranch eq 'item-issuebranch'
 340         || $frombranch eq 'item-homebranch' );
 341 $frombranch = C4::Context->preference('OverdueNoticeFrom') ne 'cron' ? C4::Context->preference('OverdueNoticeFrom') : $frombranch;
 342 my $owning_library = ( $frombranch eq 'item-homebranch' ) ? 1 : 0;
 343
 344 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();    # Branches with overdue rules
 345 my @branches;                                    # Branches passed as parameter with overdue rules
 346 my $branchcount = scalar(@overduebranches);
 347
 348 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 349 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 350
 351 my $PrintNoticesMaxLines = C4::Context->preference('PrintNoticesMaxLines');
 352
 353 if ($branchcount) {
 354     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 355 } else {
 356     die 'No branches with active overduerules';
 357 }
 358
 359 if (@branchcodes) {
 360     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 361
 362     # Getting libraries which have overdue rules
 363     my %seen = map { $_ => 1 } @branchcodes;
 364     @branches = grep { $seen{$_} } @overduebranches;
 365
 366
 367     if (@branches) {
 368
 369         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 370     $verbose and warn "$branch_word @branches have overdue rules\n";
 371
 372     } else {
 373
 374         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 375         ( scalar grep { '' eq $_ } @branches )
 376           or die "No active overduerules for DEFAULT either!";
 377         $verbose and warn "Falling back on default rules for @branchcodes\n";
 378         @branches = ('');
 379     }
 380 }
 381 my $date_to_run;
 382 my $date;
 383 if ( $date_input ){
 384     eval {
 385         $date_to_run = dt_from_string( $date_input, 'iso' );
 386     };
 387     die "$date_input is not a valid date, aborting! Use a date in format YYYY-MM-DD."
 388         if $@ or not $date_to_run;
 389
 390     # It's certainly useless to escape $date_input
 391     # dt_from_string should not return something if $date_input is not correctly set.
 392     $date = $dbh->quote( $date_input );
 393 }
 394 else {
 395     $date="NOW()";
 396     $date_to_run = dt_from_string();
 397 }
 398
 399 # these are the fields that will be substituted into <<item.content>>
 400 my @item_content_fields = split( /,/, $itemscontent );
 401
 402 binmode( STDOUT, ':encoding(UTF-8)' );
 403
 404
 405 our $csv;       # the Text::CSV_XS object
 406 our $csv_fh;    # the filehandle to the CSV file.
 407 if ( defined $csvfilename ) {
 408     my $sep_char = C4::Context->preference('CSVDelimiter') || ';';
 409     $sep_char = "\t" if ($sep_char eq 'tabulation');
 410     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 411     if ( $csvfilename eq '' ) {
 412         $csv_fh = *STDOUT;
 413     } else {
 414         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 415     }
 416     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email phone cardnumber itemcount itemsinfo branchname letternumber)) ) {
 417         print $csv_fh $csv->string, "\n";
 418     } else {
 419         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 420     }
 421 }
 422
 423 @branches = @overduebranches unless @branches;
 424 our $fh;
 425 if ( defined $htmlfilename ) {
 426   if ( $htmlfilename eq '' ) {
 427     $fh = *STDOUT;
 428   } else {
 429     my $today = dt_from_string();
 430     open $fh, ">:encoding(UTF-8)",File::Spec->catdir ($htmlfilename,"notices-".$today->ymd().".html");
 431   }
 432
 433   print $fh "<html>\n";
 434   print $fh "<head>\n";
 435   print $fh "<meta http-equiv=\"Content-Type\" content=\"text/html; charset=utf-8\" />\n";
 436   print $fh "<style type='text/css'>\n";
 437   print $fh "pre {page-break-after: always;}\n";
 438   print $fh "pre {white-space: pre-wrap;}\n";
 439   print $fh "pre {white-space: -moz-pre-wrap;}\n";
 440   print $fh "pre {white-space: -o-pre-wrap;}\n";
 441   print $fh "pre {word-wrap: break-work;}\n";
 442   print $fh "</style>\n";
 443   print $fh "</head>\n";
 444   print $fh "<body>\n";
 445 }
 446 elsif ( defined $text_filename ) {
 447   if ( $text_filename eq '' ) {
 448     $fh = *STDOUT;
 449   } else {
 450     my $today = dt_from_string();
 451     open $fh, ">:encoding(UTF-8)",File::Spec->catdir ($text_filename,"notices-".$today->ymd().".txt");
 452   }
 453 }
 454
 455 foreach my $branchcode (@branches) {
 456     my $calendar;
 457     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 458         $calendar = Koha::Calendar->new( branchcode => $branchcode );
 459         if ( $calendar->is_holiday($date_to_run) ) {
 460             next;
 461         }
 462     }
 463
 464     my $library             = Koha::Libraries->find($branchcode);
 465     my $admin_email_address = $library->from_email_address;
 466     my $branch_email_address = C4::Context->preference('AddressForFailedOverdueNotices')
 467       || $library->inbound_email_address;
 468     my @output_chunks;    # may be sent to mail or stdout or csv file.
 469
 470     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $branch_email_address;
 471
 472     my $sql2 = <<"END_SQL";
 473 SELECT biblio.*, items.*, issues.*, biblioitems.itemtype, branchname
 474   FROM issues,items,biblio, biblioitems, branches b
 475   WHERE items.itemnumber=issues.itemnumber
 476     AND biblio.biblionumber   = items.biblionumber
 477     AND b.branchcode = items.homebranch
 478     AND biblio.biblionumber   = biblioitems.biblionumber
 479     AND issues.borrowernumber = ?
 480     AND items.itemlost = 0
 481     AND TO_DAYS($date)-TO_DAYS(issues.date_due) >= 0
 482 END_SQL
 483
 484     if($owning_library) {
 485       $sql2 .= ' AND items.homebranch = ? ';
 486     } else {
 487       $sql2 .= ' AND issues.branchcode = ? ';
 488     }
 489     my $sth2 = $dbh->prepare($sql2);
 490
 491     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ";
 492     $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 493     $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 494
 495     my $rqoverduerules =  $dbh->prepare($query);
 496     $rqoverduerules->execute($branchcode, @myborcat, @myborcatout);
 497
 498     # We get default rules is there is no rule for this branch
 499     if($rqoverduerules->rows == 0){
 500         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ";
 501         $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 502         $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 503
 504         $rqoverduerules = $dbh->prepare($query);
 505         $rqoverduerules->execute(@myborcat, @myborcatout);
 506     }
 507
 508     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 509     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 510       PERIOD: foreach my $i ( 1 .. 3 ) {
 511
 512             $verbose and warn "branch '$branchcode', categorycode = $overdue_rules->{categorycode} pass $i\n";
 513
 514             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 515             my $maxdays = (
 516                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 517                 ? $overdue_rules->{ "delay" . ( $i + 1 ) } - 1
 518                 : ($MAX)
 519             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 520
 521             next unless defined $mindays;
 522
 523             if ( !$overdue_rules->{"letter$i"} ) {
 524                 $verbose and warn "No letter$i code for branch '$branchcode'";
 525                 next PERIOD;
 526             }
 527
 528             # $letter->{'content'} is the text of the mail that is sent.
 529             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 530             # The following fields are available :
 531         # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 532             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode> <country>
 533
 534             my $borrower_sql = <<"END_SQL";
 535 SELECT issues.borrowernumber, firstname, surname, address, address2, city, zipcode, country, email, emailpro, B_email, smsalertnumber, phone, cardnumber, date_due
 536 FROM   issues,borrowers,categories,items
 537 WHERE  issues.borrowernumber=borrowers.borrowernumber
 538 AND    borrowers.categorycode=categories.categorycode
 539 AND    issues.itemnumber = items.itemnumber
 540 AND    items.itemlost = 0
 541 AND    TO_DAYS($date)-TO_DAYS(issues.date_due) >= 0
 542 END_SQL
 543             my @borrower_parameters;
 544             if ($branchcode) {
 545         if($owning_library) {
 546             $borrower_sql .= ' AND items.homebranch=? ';
 547         } else {
 548             $borrower_sql .= ' AND issues.branchcode=? ';
 549         }
 550                 push @borrower_parameters, $branchcode;
 551             }
 552             if ( $overdue_rules->{categorycode} ) {
 553                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 554                 push @borrower_parameters, $overdue_rules->{categorycode};
 555             }
 556             $borrower_sql .= '  AND categories.overduenoticerequired=1 ORDER BY issues.borrowernumber';
 557
 558             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 559             my $sth = $dbh->prepare($borrower_sql);
 560             $sth->execute(@borrower_parameters);
 561
 562             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays, ".  $date_to_run->datetime() .")\nreturns " . $sth->rows . " rows";
 563             my $borrowernumber;
 564             while ( my $data = $sth->fetchrow_hashref ) {
 565
 566                 # check the borrower has at least one item that matches
 567                 my $days_between;
 568                 if ( C4::Context->preference('OverdueNoticeCalendar') )
 569                 {
 570                     $days_between =
 571                       $calendar->days_between( dt_from_string($data->{date_due}),
 572                         $date_to_run );
 573                 }
 574                 else {
 575                     $days_between =
 576                       $date_to_run->delta_days( dt_from_string($data->{date_due}) );
 577                 }
 578                 $days_between = $days_between->in_units('days');
 579                 if ($triggered) {
 580                     if ( $mindays != $days_between ) {
 581                         next;
 582                     }
 583                 }
 584                 else {
 585                     unless (   $days_between >= $mindays
 586                         && $days_between <= $maxdays )
 587                     {
 588                         next;
 589                     }
 590                 }
 591                 if (defined $borrowernumber && $borrowernumber eq $data->{'borrowernumber'}){
 592 # we have already dealt with this borrower
 593                     $verbose and warn "already dealt with this borrower $borrowernumber";
 594                     next;
 595                 }
 596                 $borrowernumber = $data->{'borrowernumber'};
 597                 my $borr = sprintf( "%s%s%s (%s)",
 598                     $data->{'surname'} || '',
 599                     $data->{'firstname'} && $data->{'surname'} ? ', ' : '',
 600                     $data->{'firstname'} || '',
 601                     $borrowernumber );
 602                 $verbose
 603                   and warn "borrower $borr has items triggering level $i.";
 604
 605                 my $patron = Koha::Patrons->find( $borrowernumber );
 606                 @emails_to_use = ();
 607                 my $notice_email = $patron->notice_email_address;
 608                 unless ($nomail) {
 609                     if (@emails) {
 610                         foreach (@emails) {
 611                             push @emails_to_use, $data->{$_} if ( $data->{$_} );
 612                         }
 613                     }
 614                     else {
 615                         push @emails_to_use, $notice_email if ($notice_email);
 616                     }
 617                 }
 618
 619                 my $letter = Koha::Notice::Templates->find_effective_template(
 620                     {
 621                         module     => 'circulation',
 622                         code       => $overdue_rules->{"letter$i"},
 623                         branchcode => $branchcode,
 624                         lang       => $patron->lang
 625                     }
 626                 );
 627
 628                 unless ($letter) {
 629                     $verbose and warn qq|Message '$overdue_rules->{"letter$i"}' content not found|;
 630
 631                     # might as well skip while PERIOD, no other borrowers are going to work.
 632                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 633                     next PERIOD;
 634                 }
 635
 636                 if ( $overdue_rules->{"debarred$i"} ) {
 637
 638                     #action taken is debarring
 639                     AddUniqueDebarment(
 640                         {
 641                             borrowernumber => $borrowernumber,
 642                             type           => 'OVERDUES',
 643                             comment => "OVERDUES_PROCESS " .  output_pref( dt_from_string() ),
 644                         }
 645                     ) unless $test_mode;
 646                     $verbose and warn "debarring $borr\n";
 647                 }
 648                 my @params = ($borrowernumber,$branchcode);
 649                 $verbose and warn "STH2 PARAMS: borrowernumber = $borrowernumber";
 650
 651                 $sth2->execute(@params);
 652                 my $itemcount = 0;
 653                 my $titles = "";
 654                 my @items = ();
 655
 656                 my $j = 0;
 657                 my $exceededPrintNoticesMaxLines = 0;
 658                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 659                     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 660                         $days_between =
 661                           $calendar->days_between(
 662                             dt_from_string( $item_info->{date_due} ), $date_to_run );
 663                     }
 664                     else {
 665                         $days_between =
 666                           $date_to_run->delta_days(
 667                             dt_from_string( $item_info->{date_due} ) );
 668                     }
 669                     $days_between = $days_between->in_units('days');
 670                     if ($listall){
 671                         unless ($days_between >= 1 and $days_between <= $MAX){
 672                             next;
 673                         }
 674                     }
 675                     else {
 676                         if ($triggered) {
 677                             if ( $mindays != $days_between ) {
 678                                 next;
 679                             }
 680                         }
 681                         else {
 682                             unless ( $days_between >= $mindays
 683                                 && $days_between <= $maxdays )
 684                             {
 685                                 next;
 686                             }
 687                         }
 688                     }
 689
 690                     if ( ( scalar(@emails_to_use) == 0 || $nomail ) && $PrintNoticesMaxLines && $j >= $PrintNoticesMaxLines ) {
 691                       $exceededPrintNoticesMaxLines = 1;
 692                       last;
 693                     }
 694                     $j++;
 695
 696                     $titles .= C4::Letters::get_item_content( { item => $item_info, item_content_fields => \@item_content_fields, dateonly => 1 } );
 697                     $itemcount++;
 698                     push @items, $item_info;
 699                 }
 700                 $sth2->finish;
 701
 702                 my @message_transport_types = @{ GetOverdueMessageTransportTypes( $branchcode, $overdue_rules->{categorycode}, $i) };
 703                 @message_transport_types = @{ GetOverdueMessageTransportTypes( q{}, $overdue_rules->{categorycode}, $i) }
 704                     unless @message_transport_types;
 705
 706
 707                 my $print_sent = 0; # A print notice is not yet sent for this patron
 708                 for my $mtt ( @message_transport_types ) {
 709                     my $effective_mtt = $mtt;
 710                     if ( ($mtt eq 'email' and not scalar @emails_to_use) or ($mtt eq 'sms' and not $data->{smsalertnumber}) ) {
 711                         # email or sms is requested but not exist, do a print.
 712                         $effective_mtt = 'print';
 713                     }
 714                     splice @items, $PrintNoticesMaxLines if $effective_mtt eq 'print' && $PrintNoticesMaxLines && scalar @items > $PrintNoticesMaxLines;
 715                     #catch the case where we are sending a print to someone with an email
 716
 717                     my $letter_exists = Koha::Notice::Templates->find_effective_template(
 718                         {
 719                             module     => 'circulation',
 720                             code       => $overdue_rules->{"letter$i"},
 721                             message_transport_type => $effective_mtt,
 722                             branchcode => $branchcode,
 723                             lang       => $patron->lang
 724                         }
 725                     );
 726
 727                     my $letter = parse_overdues_letter(
 728                         {   letter_code     => $overdue_rules->{"letter$i"},
 729                             borrowernumber  => $borrowernumber,
 730                             branchcode      => $branchcode,
 731                             items           => \@items,
 732                             substitute      => {    # this appears to be a hack to overcome incomplete features in this code.
 733                                                 bib             => $library->branchname, # maybe 'bib' is a typo for 'lib<rary>'?
 734                                                 'items.content' => $titles,
 735                                                 'count'         => $itemcount,
 736                                                },
 737                             # If there is no template defined for the requested letter
 738                             # Fallback on the original type
 739                             message_transport_type => $letter_exists ? $effective_mtt : $mtt,
 740                         }
 741                     );
 742                     unless ($letter && $letter->{content}) {
 743                         $verbose and warn qq|Message '$overdue_rules->{"letter$i"}' content not found|;
 744                         # this transport doesn't have a configured notice, so try another
 745                         next;
 746                     }
 747
 748                     if ( $exceededPrintNoticesMaxLines ) {
 749                       $letter->{'content'} .= "List too long for form; please check your account online for a complete list of your overdue items.";
 750                     }
 751
 752                     my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 753                     if (@misses) {
 754                         $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 755                     }
 756
 757                     if ($nomail) {
 758                         push @output_chunks,
 759                           prepare_letter_for_printing(
 760                           {   letter         => $letter,
 761                               borrowernumber => $borrowernumber,
 762                               firstname      => $data->{'firstname'},
 763                               lastname       => $data->{'surname'},
 764                               address1       => $data->{'address'},
 765                               address2       => $data->{'address2'},
 766                               city           => $data->{'city'},
 767                               phone          => $data->{'phone'},
 768                               cardnumber     => $data->{'cardnumber'},
 769                               branchname     => $library->branchname,
 770                               letternumber   => $i,
 771                               postcode       => $data->{'zipcode'},
 772                               country        => $data->{'country'},
 773                               email          => $notice_email,
 774                               itemcount      => $itemcount,
 775                               titles         => $titles,
 776                               outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 777                             }
 778                           );
 779                     } else {
 780                         if ( ($mtt eq 'email' and not scalar @emails_to_use) or ($mtt eq 'sms' and not $data->{smsalertnumber}) ) {
 781                             push @output_chunks,
 782                               prepare_letter_for_printing(
 783                               {   letter         => $letter,
 784                                   borrowernumber => $borrowernumber,
 785                                   firstname      => $data->{'firstname'},
 786                                   lastname       => $data->{'surname'},
 787                                   address1       => $data->{'address'},
 788                                   address2       => $data->{'address2'},
 789                                   city           => $data->{'city'},
 790                                   postcode       => $data->{'zipcode'},
 791                                   country        => $data->{'country'},
 792                                   email          => $notice_email,
 793                                   itemcount      => $itemcount,
 794                                   titles         => $titles,
 795                                   outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 796                                 }
 797                               );
 798                         }
 799                         unless ( $effective_mtt eq 'print' and $print_sent == 1 ) {
 800                             # Just sent a print if not already done.
 801                             C4::Letters::EnqueueLetter(
 802                                 {   letter                 => $letter,
 803                                     borrowernumber         => $borrowernumber,
 804                                     message_transport_type => $effective_mtt,
 805                                     from_address           => $admin_email_address,
 806                                     to_address             => join(',', @emails_to_use),
 807                                 }
 808                             ) unless $test_mode;
 809                             # A print notice should be sent only once per overdue level.
 810                             # Without this check, a print could be sent twice or more if the library checks sms and email and print and the patron has no email or sms number.
 811                             $print_sent = 1 if $effective_mtt eq 'print';
 812                         }
 813                     }
 814                 }
 815             }
 816             $sth->finish;
 817         }
 818     }
 819
 820     if (@output_chunks) {
 821         if ( defined $csvfilename ) {
 822             print $csv_fh @output_chunks;
 823         }
 824         elsif ( defined $htmlfilename ) {
 825             print $fh @output_chunks;
 826         }
 827         elsif ( defined $text_filename ) {
 828             print $fh @output_chunks;
 829         }
 830         elsif ($nomail){
 831                 local $, = "\f";    # pagebreak
 832                 print @output_chunks;
 833         }
 834         # Generate the content of the csv with headers
 835         my $content;
 836         if ( defined $csvfilename ) {
 837             my $delimiter = C4::Context->preference('CSVDelimiter') || ';';
 838             $content = join($delimiter, qw(title name surname address1 address2 zipcode city country email itemcount itemsinfo due_date issue_date)) . "\n";
 839         }
 840         else {
 841             $content = "";
 842         }
 843         $content .= join( "\n", @output_chunks );
 844
 845         if ( C4::Context->preference('EmailOverduesNoEmail') ) {
 846             my $attachment = {
 847                 filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 848                 type => 'text/plain',
 849                 content => $content,
 850             };
 851
 852             my $letter = {
 853                 title   => 'Overdue Notices',
 854                 content => 'These messages were not sent directly to the patrons.',
 855             };
 856
 857             C4::Letters::EnqueueLetter(
 858                 {   letter                 => $letter,
 859                     borrowernumber         => undef,
 860                     message_transport_type => 'email',
 861                     attachments            => [$attachment],
 862                     to_address             => $branch_email_address,
 863                 }
 864             ) unless $test_mode;
 865         }
 866     }
 867
 868 }
 869 if ($csvfilename) {
 870     # note that we're not testing on $csv_fh to prevent closing
 871     # STDOUT.
 872     close $csv_fh;
 873 }
 874
 875 if ( defined $htmlfilename ) {
 876   print $fh "</body>\n";
 877   print $fh "</html>\n";
 878   close $fh;
 879 } elsif ( defined $text_filename ) {
 880   close $fh;
 881 }
 882
 883 =head1 INTERNAL METHODS
 884
 885 These methods are internal to the operation of overdue_notices.pl.
 886
 887 =head2 prepare_letter_for_printing
 888
 889 returns a string of text appropriate for printing in the event that an
 890 overdue notice will not be sent to the patron's email
 891 address. Depending on the desired output format, this may be a CSV
 892 string, or a human-readable representation of the notice.
 893
 894 required parameters:
 895   letter
 896   borrowernumber
 897
 898 optional parameters:
 899   outputformat
 900
 901 =cut
 902
 903 sub prepare_letter_for_printing {
 904     my $params = shift;
 905
 906     return unless ref $params eq 'HASH';
 907
 908     foreach my $required_parameter (qw( letter borrowernumber )) {
 909         return unless defined $params->{$required_parameter};
 910     }
 911
 912     my $return;
 913     chomp $params->{titles};
 914     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 915         if ($csv->combine(
 916                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 917                 $params->{'city'}, $params->{'country'}, $params->{'email'}, $params->{'phone'}, $params->{'cardnumber'},
 918                 $params->{'itemcount'}, $params->{'titles'}, $params->{'branchname'}, $params->{'letternumber'}
 919             )
 920           ) {
 921             return $csv->string, "\n";
 922         } else {
 923             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 924         }
 925     } elsif ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'html' ) {
 926       $return = "<pre>\n";
 927       $return .= "$params->{'letter'}->{'content'}\n";
 928       $return .= "\n</pre>\n";
 929     } else {
 930         $return .= "$params->{'letter'}->{'content'}\n";
 931
 932         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 933     }
 934     return $return;
 935 }
 936