misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Liblime
   4 # Copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 BEGIN {
  24
  25     # find Koha's Perl modules
  26     # test carefully before changing this
  27     use FindBin;
  28     eval { require "$FindBin::Bin/../kohalib.pl" };
  29 }
  30
  31 use Getopt::Long;
  32 use Pod::Usage;
  33 use Text::CSV_XS;
  34 use DateTime;
  35 use DateTime::Duration;
  36
  37 use Koha::Script -cron;
  38 use C4::Context;
  39 use C4::Letters;
  40 use C4::Overdues qw(GetFine GetOverdueMessageTransportTypes parse_overdues_letter);
  41 use C4::Log;
  42 use Koha::Patron::Debarments qw(AddUniqueDebarment);
  43 use Koha::DateUtils;
  44 use Koha::Calendar;
  45 use Koha::Libraries;
  46 use Koha::Acquisition::Currencies;
  47 use Koha::Patrons;
  48
  49 =head1 NAME
  50
  51 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  52
  53 =head1 SYNOPSIS
  54
  55 overdue_notices.pl
  56   [ -n ][ -library <branchcode> ][ -library <branchcode> ... ]
  57   [ -max <number of days> ][ -csv [<filename>] ][ -itemscontent <field list> ]
  58   [ -email <email_type> ... ]
  59
  60  Options:
  61    -help                          Brief help message.
  62    -man                           Full documentation.
  63    -v                             Verbose mode.
  64    -n                             No email will be sent.
  65    -max          <days>           Maximum days overdue to deal with.
  66    -library      <branchcode>     Only deal with overdues from this library.
  67                                   (repeatable : several libraries can be given)
  68    -csv          <filename>       Populate CSV file.
  69    -html         <directory>      Output html to a file in the given directory.
  70    -text         <directory>      Output plain text to a file in the given directory.
  71    -itemscontent <list of fields> Item information in templates.
  72    -borcat       <categorycode>   Category code that must be included.
  73    -borcatout    <categorycode>   Category code that must be excluded.
  74    -t                             Only include triggered overdues.
  75    --test                         Run in test mode. No changes will be made on the DB.
  76    -list-all                      List all overdues.
  77    -date         <yyyy-mm-dd>     Emulate overdues run for this date.
  78    -email        <email_type>     Type of email that will be used.
  79                                   Can be 'email', 'emailpro' or 'B_email'. Repeatable.
  80
  81 =head1 OPTIONS
  82
  83 =over 8
  84
  85 =item B<-help>
  86
  87 Print a brief help message and exits.
  88
  89 =item B<-man>
  90
  91 Prints the manual page and exits.
  92
  93 =item B<-v>
  94
  95 Verbose. Without this flag set, only fatal errors are reported.
  96
  97 =item B<-n>
  98
  99 Do not send any email. Overdue notices that would have been sent to
 100 the patrons or to the admin are printed to standard out. CSV data (if
 101 the -csv flag is set) is written to standard out or to any csv
 102 filename given.
 103
 104 =item B<-max>
 105
 106 Items older than max days are assumed to be handled somewhere else,
 107 probably the F<longoverdues.pl> script. They are therefore ignored by
 108 this program. No notices are sent for them, and they are not added to
 109 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
 110
 111 =item B<-library>
 112
 113 select overdues for one specific library. Use the value in the
 114 branches.branchcode table. This option can be repeated in order
 115 to select overdues for a group of libraries.
 116
 117 =item B<-csv>
 118
 119 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
 120 sent to standard out or to a filename if provided. Otherwise, only
 121 overdues that could not be emailed are sent in CSV format to the admin.
 122
 123 =item B<-html>
 124
 125 Produces html data. If patron does not have an email address or
 126 -n (no mail) flag is set, an HTML file is generated in the specified
 127 directory. This can be downloaded or further processed by library staff.
 128 The file will be called notices-YYYY-MM-DD.html and placed in the directory
 129 specified.
 130
 131 =item B<-text>
 132
 133 Produces plain text data. If patron does not have an email address or
 134 -n (no mail) flag is set, a text file is generated in the specified
 135 directory. This can be downloaded or further processed by library staff.
 136 The file will be called notices-YYYY-MM-DD.txt and placed in the directory
 137 specified.
 138
 139 =item B<-itemscontent>
 140
 141 comma separated list of fields that get substituted into templates in
 142 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 143 defaults to due date,title,barcode,author
 144
 145 Other possible values come from fields in the biblios, items and
 146 issues tables.
 147
 148 =item B<-borcat>
 149
 150 Repeatable field, that permits to select only some patron categories.
 151
 152 =item B<-borcatout>
 153
 154 Repeatable field, that permits to exclude some patron categories.
 155
 156 =item B<-t> | B<--triggered>
 157
 158 This option causes a notice to be generated if and only if
 159 an item is overdue by the number of days defined in a notice trigger.
 160
 161 By default, a notice is sent each time the script runs, which is suitable for
 162 less frequent run cron script, but requires syncing notice triggers with
 163 the  cron schedule to ensure proper behavior.
 164 Add the --triggered option for daily cron, at the risk of no notice
 165 being generated if the cron fails to run on time.
 166
 167 =item B<-test>
 168
 169 This option makes the script run in test mode.
 170
 171 In test mode, the script won't make any changes on the DB. This is useful
 172 for debugging configuration.
 173
 174 =item B<-list-all>
 175
 176 Default items.content lists only those items that fall in the
 177 range of the currently processing notice.
 178 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 179
 180 =item B<-date>
 181
 182 use it in order to send overdues on a specific date and not Now. Format: YYYY-MM-DD.
 183
 184 =item B<-email>
 185
 186 Allows to specify which type of email will be used. Can be email, emailpro or B_email. Repeatable.
 187
 188 =back
 189
 190 =head1 DESCRIPTION
 191
 192 This script is designed to alert patrons and administrators of overdue
 193 items.
 194
 195 =head2 Configuration
 196
 197 This script pays attention to the overdue notice configuration
 198 performed in the "Overdue notice/status triggers" section of the
 199 "Tools" area of the staff interface to Koha. There, you can choose
 200 which letter templates are sent out after a configurable number of
 201 days to patrons of each library. More information about the use of this
 202 section of Koha is available in the Koha manual.
 203
 204 The templates used to craft the emails are defined in the "Tools:
 205 Notices" section of the staff interface to Koha.
 206
 207 =head2 Outgoing emails
 208
 209 Typically, messages are prepared for each patron with overdue
 210 items. Messages for whom there is no email address on file are
 211 collected and sent as attachments in a single email to each library
 212 administrator, or if that is not set, then to the email address in the
 213 C<KohaAdminEmailAddress> system preference.
 214
 215 These emails are staged in the outgoing message queue, as are messages
 216 produced by other features of Koha. This message queue must be
 217 processed regularly by the
 218 F<misc/cronjobs/process_message_queue.pl> program.
 219
 220 In the event that the C<-n> flag is passed to this program, no emails
 221 are sent. Instead, messages are sent on standard output from this
 222 program. They may be redirected to a file if desired.
 223
 224 =head2 Templates
 225
 226 Templates can contain variables enclosed in double angle brackets like
 227 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 228 specific to the overdue items or relevant patron. Available variables
 229 are:
 230
 231 =over
 232
 233 =item E<lt>E<lt>bibE<gt>E<gt>
 234
 235 the name of the library
 236
 237 =item E<lt>E<lt>items.contentE<gt>E<gt>
 238
 239 one line for each item, each line containing a tab separated list of
 240 title, author, barcode, issuedate
 241
 242 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 243
 244 any field from the borrowers table
 245
 246 =item E<lt>E<lt>branches.*E<gt>E<gt>
 247
 248 any field from the branches table
 249
 250 =back
 251
 252 =head2 CSV output
 253
 254 The C<-csv> command line option lets you specify a file to which
 255 overdues data should be output in CSV format.
 256
 257 With the C<-n> flag set, data about all overdues is written to the
 258 file. Without that flag, only information about overdues that were
 259 unable to be sent directly to the patrons will be written. In other
 260 words, this CSV file replaces the data that is typically sent to the
 261 administrator email address.
 262
 263 =head1 USAGE EXAMPLES
 264
 265 C<overdue_notices.pl> - In this most basic usage, with no command line
 266 arguments, all libraries are processed individually, and notices are
 267 prepared for all patrons with overdue items for whom we have email
 268 addresses. Messages for those patrons for whom we have no email
 269 address are sent in a single attachment to the library administrator's
 270 email address, or to the address in the KohaAdminEmailAddress system
 271 preference.
 272
 273 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 274 populates F</tmp/overdues.csv> with information about all overdue
 275 items.
 276
 277 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 278 overdues in the last 2 weeks for the MAIN library.
 279
 280 =head1 SEE ALSO
 281
 282 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 283 messages to patrons in advance of their items becoming due, or to
 284 alert them of items that have just become due.
 285
 286 =cut
 287
 288 # These variables are set by command line options.
 289 # They are initially set to default values.
 290 my $dbh = C4::Context->dbh();
 291 my $help    = 0;
 292 my $man     = 0;
 293 my $verbose = 0;
 294 my $nomail  = 0;
 295 my $MAX     = 90;
 296 my $test_mode = 0;
 297 my @branchcodes; # Branch(es) passed as parameter
 298 my @emails_to_use;    # Emails to use for messaging
 299 my @emails;           # Emails given in command-line parameters
 300 my $csvfilename;
 301 my $htmlfilename;
 302 my $text_filename;
 303 my $triggered = 0;
 304 my $listall = 0;
 305 my $itemscontent = join( ',', qw( date_due title barcode author itemnumber ) );
 306 my @myborcat;
 307 my @myborcatout;
 308 my ( $date_input, $today );
 309
 310 GetOptions(
 311     'help|?'         => \$help,
 312     'man'            => \$man,
 313     'v'              => \$verbose,
 314     'n'              => \$nomail,
 315     'max=s'          => \$MAX,
 316     'library=s'      => \@branchcodes,
 317     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 318     'html:s'         => \$htmlfilename,    # this optional argument gets '' if not supplied.
 319     'text:s'         => \$text_filename,    # this optional argument gets '' if not supplied.
 320     'itemscontent=s' => \$itemscontent,
 321     'list-all'       => \$listall,
 322     't|triggered'    => \$triggered,
 323     'test'           => \$test_mode,
 324     'date=s'         => \$date_input,
 325     'borcat=s'       => \@myborcat,
 326     'borcatout=s'    => \@myborcatout,
 327     'email=s'        => \@emails,
 328 ) or pod2usage(2);
 329 pod2usage(1) if $help;
 330 pod2usage( -verbose => 2 ) if $man;
 331 cronlogaction() unless $test_mode;
 332
 333 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 334     warn qq(using "$csvfilename" as filename, that seems odd);
 335 }
 336
 337 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();        # Branches with overdue rules
 338 my @branches;                                                                   # Branches passed as parameter with overdue rules
 339 my $branchcount = scalar(@overduebranches);
 340
 341 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 342 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 343
 344 my $PrintNoticesMaxLines = C4::Context->preference('PrintNoticesMaxLines');
 345
 346 if ($branchcount) {
 347     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 348 } else {
 349     die 'No branches with active overduerules';
 350 }
 351
 352 if (@branchcodes) {
 353     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 354
 355     # Getting libraries which have overdue rules
 356     my %seen = map { $_ => 1 } @branchcodes;
 357     @branches = grep { $seen{$_} } @overduebranches;
 358
 359
 360     if (@branches) {
 361
 362         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 363         $verbose and warn "$branch_word @branches have overdue rules\n";
 364
 365     } else {
 366
 367         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 368         ( scalar grep { '' eq $_ } @branches )
 369           or die "No active overduerules for DEFAULT either!";
 370         $verbose and warn "Falling back on default rules for @branchcodes\n";
 371         @branches = ('');
 372     }
 373 }
 374 my $date_to_run;
 375 my $date;
 376 if ( $date_input ){
 377     eval {
 378         $date_to_run = dt_from_string( $date_input, 'iso' );
 379     };
 380     die "$date_input is not a valid date, aborting! Use a date in format YYYY-MM-DD."
 381         if $@ or not $date_to_run;
 382
 383     # It's certainly useless to escape $date_input
 384     # dt_from_string should not return something if $date_input is not correctly set.
 385     $date = $dbh->quote( $date_input );
 386 }
 387 else {
 388     $date="NOW()";
 389     $date_to_run = dt_from_string();
 390 }
 391
 392 # these are the fields that will be substituted into <<item.content>>
 393 my @item_content_fields = split( /,/, $itemscontent );
 394
 395 binmode( STDOUT, ':encoding(UTF-8)' );
 396
 397
 398 our $csv;       # the Text::CSV_XS object
 399 our $csv_fh;    # the filehandle to the CSV file.
 400 if ( defined $csvfilename ) {
 401     my $sep_char = C4::Context->preference('delimiter') || ';';
 402     $sep_char = "\t" if ($sep_char eq 'tabulation');
 403     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 404     if ( $csvfilename eq '' ) {
 405         $csv_fh = *STDOUT;
 406     } else {
 407         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 408     }
 409     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email phone cardnumber itemcount itemsinfo branchname letternumber)) ) {
 410         print $csv_fh $csv->string, "\n";
 411     } else {
 412         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 413     }
 414 }
 415
 416 @branches = @overduebranches unless @branches;
 417 our $fh;
 418 if ( defined $htmlfilename ) {
 419   if ( $htmlfilename eq '' ) {
 420     $fh = *STDOUT;
 421   } else {
 422     my $today = dt_from_string();
 423     open $fh, ">:encoding(UTF-8)",File::Spec->catdir ($htmlfilename,"notices-".$today->ymd().".html");
 424   }
 425
 426   print $fh "<html>\n";
 427   print $fh "<head>\n";
 428   print $fh "<meta http-equiv=\"Content-Type\" content=\"text/html; charset=utf-8\" />\n";
 429   print $fh "<style type='text/css'>\n";
 430   print $fh "pre {page-break-after: always;}\n";
 431   print $fh "pre {white-space: pre-wrap;}\n";
 432   print $fh "pre {white-space: -moz-pre-wrap;}\n";
 433   print $fh "pre {white-space: -o-pre-wrap;}\n";
 434   print $fh "pre {word-wrap: break-work;}\n";
 435   print $fh "</style>\n";
 436   print $fh "</head>\n";
 437   print $fh "<body>\n";
 438 }
 439 elsif ( defined $text_filename ) {
 440   if ( $text_filename eq '' ) {
 441     $fh = *STDOUT;
 442   } else {
 443     my $today = dt_from_string();
 444     open $fh, ">:encoding(UTF-8)",File::Spec->catdir ($text_filename,"notices-".$today->ymd().".txt");
 445   }
 446 }
 447
 448 foreach my $branchcode (@branches) {
 449     my $calendar;
 450     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 451         $calendar = Koha::Calendar->new( branchcode => $branchcode );
 452         if ( $calendar->is_holiday($date_to_run) ) {
 453             next;
 454         }
 455     }
 456
 457     my $library             = Koha::Libraries->find($branchcode);
 458     my $admin_email_address = $library->branchemail
 459       || C4::Context->preference('KohaAdminEmailAddress');
 460     my $branch_email_address = C4::Context->preference('AddressForFailedOverdueNotices')
 461       || $library->inbound_email_address;
 462     my @output_chunks;    # may be sent to mail or stdout or csv file.
 463
 464     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $branch_email_address;
 465
 466     my $sth2 = $dbh->prepare( <<"END_SQL" );
 467 SELECT biblio.*, items.*, issues.*, biblioitems.itemtype, branchname
 468   FROM issues,items,biblio, biblioitems, branches b
 469   WHERE items.itemnumber=issues.itemnumber
 470     AND biblio.biblionumber   = items.biblionumber
 471     AND b.branchcode = items.homebranch
 472     AND biblio.biblionumber   = biblioitems.biblionumber
 473     AND issues.borrowernumber = ?
 474     AND issues.branchcode = ?
 475     AND items.itemlost = 0
 476     AND TO_DAYS($date)-TO_DAYS(issues.date_due) >= 0
 477 END_SQL
 478
 479     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ";
 480     $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 481     $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 482
 483     my $rqoverduerules =  $dbh->prepare($query);
 484     $rqoverduerules->execute($branchcode, @myborcat, @myborcatout);
 485
 486     # We get default rules is there is no rule for this branch
 487     if($rqoverduerules->rows == 0){
 488         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ";
 489         $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 490         $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 491
 492         $rqoverduerules = $dbh->prepare($query);
 493         $rqoverduerules->execute(@myborcat, @myborcatout);
 494     }
 495
 496     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 497     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 498       PERIOD: foreach my $i ( 1 .. 3 ) {
 499
 500             $verbose and warn "branch '$branchcode', categorycode = $overdue_rules->{categorycode} pass $i\n";
 501
 502             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 503             my $maxdays = (
 504                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 505                 ? $overdue_rules->{ "delay" . ( $i + 1 ) } - 1
 506                 : ($MAX)
 507             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 508
 509             next unless defined $mindays;
 510
 511             if ( !$overdue_rules->{"letter$i"} ) {
 512                 $verbose and warn "No letter$i code for branch '$branchcode'";
 513                 next PERIOD;
 514             }
 515
 516             # $letter->{'content'} is the text of the mail that is sent.
 517             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 518             # The following fields are available :
 519             # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 520             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode> <country>
 521
 522             my $borrower_sql = <<"END_SQL";
 523 SELECT issues.borrowernumber, firstname, surname, address, address2, city, zipcode, country, email, emailpro, B_email, smsalertnumber, phone, cardnumber, date_due
 524 FROM   issues,borrowers,categories,items
 525 WHERE  issues.borrowernumber=borrowers.borrowernumber
 526 AND    borrowers.categorycode=categories.categorycode
 527 AND    issues.itemnumber = items.itemnumber
 528 AND    items.itemlost = 0
 529 AND    TO_DAYS($date)-TO_DAYS(issues.date_due) >= 0
 530 END_SQL
 531             my @borrower_parameters;
 532             if ($branchcode) {
 533                 $borrower_sql .= ' AND issues.branchcode=? ';
 534                 push @borrower_parameters, $branchcode;
 535             }
 536             if ( $overdue_rules->{categorycode} ) {
 537                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 538                 push @borrower_parameters, $overdue_rules->{categorycode};
 539             }
 540             $borrower_sql .= '  AND categories.overduenoticerequired=1 ORDER BY issues.borrowernumber';
 541
 542             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 543                 my $sth = $dbh->prepare($borrower_sql);
 544             $sth->execute(@borrower_parameters);
 545
 546             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays, ".  $date_to_run->datetime() .")\nreturns " . $sth->rows . " rows";
 547             my $borrowernumber;
 548             while ( my $data = $sth->fetchrow_hashref ) {
 549
 550                 # check the borrower has at least one item that matches
 551                 my $days_between;
 552                 if ( C4::Context->preference('OverdueNoticeCalendar') )
 553                 {
 554                     $days_between =
 555                       $calendar->days_between( dt_from_string($data->{date_due}),
 556                         $date_to_run );
 557                 }
 558                 else {
 559                     $days_between =
 560                       $date_to_run->delta_days( dt_from_string($data->{date_due}) );
 561                 }
 562                 $days_between = $days_between->in_units('days');
 563                 if ($triggered) {
 564                     if ( $mindays != $days_between ) {
 565                         next;
 566                     }
 567                 }
 568                 else {
 569                     unless (   $days_between >= $mindays
 570                         && $days_between <= $maxdays )
 571                     {
 572                         next;
 573                     }
 574                 }
 575                 if (defined $borrowernumber && $borrowernumber eq $data->{'borrowernumber'}){
 576 # we have already dealt with this borrower
 577                     $verbose and warn "already dealt with this borrower $borrowernumber";
 578                     next;
 579                 }
 580                 $borrowernumber = $data->{'borrowernumber'};
 581                 my $borr = sprintf( "%s%s%s (%s)",
 582                     $data->{'surname'} || '',
 583                     $data->{'firstname'} && $data->{'surname'} ? ', ' : '',
 584                     $data->{'firstname'} || '',
 585                     $borrowernumber );
 586                 $verbose
 587                   and warn "borrower $borr has items triggering level $i.";
 588
 589                 my $patron = Koha::Patrons->find( $borrowernumber );
 590                 @emails_to_use = ();
 591                 my $notice_email = $patron->notice_email_address;
 592                 unless ($nomail) {
 593                     if (@emails) {
 594                         foreach (@emails) {
 595                             push @emails_to_use, $data->{$_} if ( $data->{$_} );
 596                         }
 597                     }
 598                     else {
 599                         push @emails_to_use, $notice_email if ($notice_email);
 600                     }
 601                 }
 602
 603                 my $letter = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"}, $branchcode, undef, $patron->lang );
 604
 605                 unless ($letter) {
 606                     $verbose and warn qq|Message '$overdue_rules->{"letter$i"}' content not found|;
 607
 608                     # might as well skip while PERIOD, no other borrowers are going to work.
 609                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 610                     next PERIOD;
 611                 }
 612
 613                 if ( $overdue_rules->{"debarred$i"} ) {
 614
 615                     #action taken is debarring
 616                     AddUniqueDebarment(
 617                         {
 618                             borrowernumber => $borrowernumber,
 619                             type           => 'OVERDUES',
 620                             comment => "OVERDUES_PROCESS " .  output_pref( dt_from_string() ),
 621                         }
 622                     ) unless $test_mode;
 623                     $verbose and warn "debarring $borr\n";
 624                 }
 625                 my @params = ($borrowernumber,$branchcode);
 626                 $verbose and warn "STH2 PARAMS: borrowernumber = $borrowernumber";
 627
 628                 $sth2->execute(@params);
 629                 my $itemcount = 0;
 630                 my $titles = "";
 631                 my @items = ();
 632
 633                 my $j = 0;
 634                 my $exceededPrintNoticesMaxLines = 0;
 635                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 636                     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 637                         $days_between =
 638                           $calendar->days_between(
 639                             dt_from_string( $item_info->{date_due} ), $date_to_run );
 640                     }
 641                     else {
 642                         $days_between =
 643                           $date_to_run->delta_days(
 644                             dt_from_string( $item_info->{date_due} ) );
 645                     }
 646                     $days_between = $days_between->in_units('days');
 647                     if ($listall){
 648                         unless ($days_between >= 1 and $days_between <= $MAX){
 649                             next;
 650                         }
 651                     }
 652                     else {
 653                         if ($triggered) {
 654                             if ( $mindays != $days_between ) {
 655                                 next;
 656                             }
 657                         }
 658                         else {
 659                             unless ( $days_between >= $mindays
 660                                 && $days_between <= $maxdays )
 661                             {
 662                                 next;
 663                             }
 664                         }
 665                     }
 666
 667                     if ( ( scalar(@emails_to_use) == 0 || $nomail ) && $PrintNoticesMaxLines && $j >= $PrintNoticesMaxLines ) {
 668                       $exceededPrintNoticesMaxLines = 1;
 669                       last;
 670                     }
 671                     $j++;
 672
 673                     $titles .= C4::Letters::get_item_content( { item => $item_info, item_content_fields => \@item_content_fields, dateonly => 1 } );
 674                     $itemcount++;
 675                     push @items, $item_info;
 676                 }
 677                 $sth2->finish;
 678
 679                 my @message_transport_types = @{ GetOverdueMessageTransportTypes( $branchcode, $overdue_rules->{categorycode}, $i) };
 680                 @message_transport_types = @{ GetOverdueMessageTransportTypes( q{}, $overdue_rules->{categorycode}, $i) }
 681                     unless @message_transport_types;
 682
 683
 684                 my $print_sent = 0; # A print notice is not yet sent for this patron
 685                 for my $mtt ( @message_transport_types ) {
 686                     my $effective_mtt = $mtt;
 687                     if ( ($mtt eq 'email' and not scalar @emails_to_use) or ($mtt eq 'sms' and not $data->{smsalertnumber}) ) {
 688                         # email or sms is requested but not exist, do a print.
 689                         $effective_mtt = 'print';
 690                     }
 691                     splice @items, $PrintNoticesMaxLines if $effective_mtt eq 'print' && $PrintNoticesMaxLines && scalar @items > $PrintNoticesMaxLines;
 692                     #catch the case where we are sending a print to someone with an email
 693
 694                     my $letter_exists = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"}, $branchcode, $effective_mtt, $patron->lang ) ? 1 : 0;
 695                     my $letter = parse_overdues_letter(
 696                         {   letter_code     => $overdue_rules->{"letter$i"},
 697                             borrowernumber  => $borrowernumber,
 698                             branchcode      => $branchcode,
 699                             items           => \@items,
 700                             substitute      => {    # this appears to be a hack to overcome incomplete features in this code.
 701                                                 bib             => $library->branchname, # maybe 'bib' is a typo for 'lib<rary>'?
 702                                                 'items.content' => $titles,
 703                                                 'count'         => $itemcount,
 704                                                },
 705                             # If there is no template defined for the requested letter
 706                             # Fallback on the original type
 707                             message_transport_type => $letter_exists ? $effective_mtt : $mtt,
 708                         }
 709                     );
 710                     unless ($letter) {
 711                         $verbose and warn qq|Message '$overdue_rules->{"letter$i"}' content not found|;
 712                         # this transport doesn't have a configured notice, so try another
 713                         next;
 714                     }
 715
 716                     if ( $exceededPrintNoticesMaxLines ) {
 717                       $letter->{'content'} .= "List too long for form; please check your account online for a complete list of your overdue items.";
 718                     }
 719
 720                     my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 721                     if (@misses) {
 722                         $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 723                     }
 724
 725                     if ($nomail) {
 726                         push @output_chunks,
 727                           prepare_letter_for_printing(
 728                           {   letter         => $letter,
 729                               borrowernumber => $borrowernumber,
 730                               firstname      => $data->{'firstname'},
 731                               lastname       => $data->{'surname'},
 732                               address1       => $data->{'address'},
 733                               address2       => $data->{'address2'},
 734                               city           => $data->{'city'},
 735                               phone          => $data->{'phone'},
 736                               cardnumber     => $data->{'cardnumber'},
 737                               branchname     => $library->branchname,
 738                               letternumber   => $i,
 739                               postcode       => $data->{'zipcode'},
 740                               country        => $data->{'country'},
 741                               email          => $notice_email,
 742                               itemcount      => $itemcount,
 743                               titles         => $titles,
 744                               outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 745                             }
 746                           );
 747                     } else {
 748                         if ( ($mtt eq 'email' and not scalar @emails_to_use) or ($mtt eq 'sms' and not $data->{smsalertnumber}) ) {
 749                             push @output_chunks,
 750                               prepare_letter_for_printing(
 751                               {   letter         => $letter,
 752                                   borrowernumber => $borrowernumber,
 753                                   firstname      => $data->{'firstname'},
 754                                   lastname       => $data->{'surname'},
 755                                   address1       => $data->{'address'},
 756                                   address2       => $data->{'address2'},
 757                                   city           => $data->{'city'},
 758                                   postcode       => $data->{'zipcode'},
 759                                   country        => $data->{'country'},
 760                                   email          => $notice_email,
 761                                   itemcount      => $itemcount,
 762                                   titles         => $titles,
 763                                   outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 764                                 }
 765                               );
 766                         }
 767                         unless ( $effective_mtt eq 'print' and $print_sent == 1 ) {
 768                             # Just sent a print if not already done.
 769                             C4::Letters::EnqueueLetter(
 770                                 {   letter                 => $letter,
 771                                     borrowernumber         => $borrowernumber,
 772                                     message_transport_type => $effective_mtt,
 773                                     from_address           => $admin_email_address,
 774                                     to_address             => join(',', @emails_to_use),
 775                                 }
 776                             ) unless $test_mode;
 777                             # A print notice should be sent only once per overdue level.
 778                             # Without this check, a print could be sent twice or more if the library checks sms and email and print and the patron has no email or sms number.
 779                             $print_sent = 1 if $effective_mtt eq 'print';
 780                         }
 781                     }
 782                 }
 783             }
 784             $sth->finish;
 785         }
 786     }
 787
 788     if (@output_chunks) {
 789         if ( defined $csvfilename ) {
 790             print $csv_fh @output_chunks;
 791         }
 792         elsif ( defined $htmlfilename ) {
 793             print $fh @output_chunks;
 794         }
 795         elsif ( defined $text_filename ) {
 796             print $fh @output_chunks;
 797         }
 798         elsif ($nomail){
 799                 local $, = "\f";    # pagebreak
 800                 print @output_chunks;
 801         }
 802         # Generate the content of the csv with headers
 803         my $content;
 804         if ( defined $csvfilename ) {
 805             my $delimiter = C4::Context->preference('delimiter') || ';';
 806             $content = join($delimiter, qw(title name surname address1 address2 zipcode city country email itemcount itemsinfo due_date issue_date)) . "\n";
 807         }
 808         else {
 809             $content = "";
 810         }
 811         $content .= join( "\n", @output_chunks );
 812
 813         my $attachment = {
 814             filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 815             type => 'text/plain',
 816             content => $content,
 817         };
 818
 819         my $letter = {
 820             title   => 'Overdue Notices',
 821             content => 'These messages were not sent directly to the patrons.',
 822         };
 823
 824         C4::Letters::EnqueueLetter(
 825             {   letter                 => $letter,
 826                 borrowernumber         => undef,
 827                 message_transport_type => 'email',
 828                 attachments            => [$attachment],
 829                 to_address             => $branch_email_address,
 830             }
 831         ) unless $test_mode;
 832     }
 833
 834 }
 835 if ($csvfilename) {
 836     # note that we're not testing on $csv_fh to prevent closing
 837     # STDOUT.
 838     close $csv_fh;
 839 }
 840
 841 if ( defined $htmlfilename ) {
 842   print $fh "</body>\n";
 843   print $fh "</html>\n";
 844   close $fh;
 845 } elsif ( defined $text_filename ) {
 846   close $fh;
 847 }
 848
 849 =head1 INTERNAL METHODS
 850
 851 These methods are internal to the operation of overdue_notices.pl.
 852
 853 =head2 prepare_letter_for_printing
 854
 855 returns a string of text appropriate for printing in the event that an
 856 overdue notice will not be sent to the patron's email
 857 address. Depending on the desired output format, this may be a CSV
 858 string, or a human-readable representation of the notice.
 859
 860 required parameters:
 861   letter
 862   borrowernumber
 863
 864 optional parameters:
 865   outputformat
 866
 867 =cut
 868
 869 sub prepare_letter_for_printing {
 870     my $params = shift;
 871
 872     return unless ref $params eq 'HASH';
 873
 874     foreach my $required_parameter (qw( letter borrowernumber )) {
 875         return unless defined $params->{$required_parameter};
 876     }
 877
 878     my $return;
 879     chomp $params->{titles};
 880     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 881         if ($csv->combine(
 882                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 883                 $params->{'city'}, $params->{'country'}, $params->{'email'}, $params->{'phone'}, $params->{'cardnumber'},
 884                 $params->{'itemcount'}, $params->{'titles'}, $params->{'branchname'}, $params->{'letternumber'}
 885             )
 886           ) {
 887             return $csv->string, "\n";
 888         } else {
 889             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 890         }
 891     } elsif ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'html' ) {
 892       $return = "<pre>\n";
 893       $return .= "$params->{'letter'}->{'content'}\n";
 894       $return .= "\n</pre>\n";
 895     } else {
 896         $return .= "$params->{'letter'}->{'content'}\n";
 897
 898         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 899     }
 900     return $return;
 901 }
 902