misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl -w
   2
   3 # Copyright 2008 Liblime
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along with
  17 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  18 # Suite 330, Boston, MA  02111-1307 USA
  19
  20 use strict;
  21 use warnings;
  22
  23 BEGIN {
  24
  25     # find Koha's Perl modules
  26     # test carefully before changing this
  27     use FindBin;
  28     eval { require "$FindBin::Bin/../kohalib.pl" };
  29 }
  30
  31 use C4::Context;
  32 use C4::Dates qw/format_date/;
  33 use C4::Debug;
  34 use C4::Letters;
  35
  36 use Getopt::Long;
  37 use Pod::Usage;
  38 use Text::CSV_XS;
  39
  40 =head1 NAME
  41
  42 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  43
  44 =head1 SYNOPSIS
  45
  46 overdue_notices.pl [ -n ] [ -library <branchcode> ] [ -max <number of days> ] [ -csv [ <filename> ] ] [ -itemscontent <field list> ]
  47
  48  Options:
  49    -help                          brief help message
  50    -man                           full documentation
  51    -n                             No email will be sent
  52    -max          <days>           maximum days overdue to deal with
  53    -library      <branchname>     only deal with overdues from this library
  54    -csv          <filename>       populate CSV file
  55    -itemscontent <list of fields> item information in templates
  56
  57 =head1 OPTIONS
  58
  59 =over 8
  60
  61 =item B<-help>
  62
  63 Print a brief help message and exits.
  64
  65 =item B<-man>
  66
  67 Prints the manual page and exits.
  68
  69 =item B<-v>
  70
  71 Verbose. Without this flag set, only fatal errors are reported.
  72
  73 =item B<-n>
  74
  75 Do not send any email. Overdue notices that would have been sent to
  76 the patrons or to the admin are printed to standard out. CSV data (if
  77 the -csv flag is set) is written to standard out or to any csv
  78 filename given.
  79
  80 =item B<-max>
  81
  82 Items older than max days are assumed to be handled somewhere else,
  83 probably the F<longoverdues.pl> script. They are therefore ignored by
  84 this program. No notices are sent for them, and they are not added to
  85 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
  86
  87 =item B<-library>
  88
  89 select overdues for one specific library. Use the value in the
  90 branches.branchcode table.
  91
  92 =item B<-csv>
  93
  94 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
  95 sent to standard out or to a filename if provided. Otherwise, only
  96 overdues that could not be emailed are sent in CSV format to the admin.
  97
  98 =item B<-itemscontent>
  99
 100 comma separated list of fields that get substituted into templates in
 101 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 102 defaults to issuedate,title,barcode,author
 103
 104 Other possible values come from fields in the biblios, items, and
 105 issues tables.
 106
 107 =item B<-t> | B<--triggered>
 108
 109 This option causes a notice to be generated if and only if
 110 an item is overdue by the number of days defined in a notice trigger.
 111
 112 By default, a notice is sent each time the script runs, which is suitable for
 113 less frequent run cron script, but requires syncing notice triggers with
 114 the  cron schedule to ensure proper behavior.
 115 Add the --triggered option for daily cron, at the risk of no notice
 116 being generated if the cron fails to run on time.
 117
 118 =item B<-list-all>
 119
 120 Default items.content lists only those items that fall in the
 121 range of the currently processing notice.
 122 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 123
 124 =back
 125
 126 =head1 DESCRIPTION
 127
 128 This script is designed to alert patrons and administrators of overdue
 129 items.
 130
 131 =head2 Configuration
 132
 133 This script pays attention to the overdue notice configuration
 134 performed in the "Overdue notice/status triggers" section of the
 135 "Tools" area of the staff interface to Koha. There, you can choose
 136 which letter templates are sent out after a configurable number of
 137 days to patrons of each library. More information about the use of this
 138 section of Koha is available in the Koha manual.
 139
 140 The templates used to craft the emails are defined in the "Tools:
 141 Notices" section of the staff interface to Koha.
 142
 143 =head2 Outgoing emails
 144
 145 Typically, messages are prepared for each patron with overdue
 146 items. Messages for whom there is no email address on file are
 147 collected and sent as attachments in a single email to each library
 148 administrator, or if that is not set, then to the email address in the
 149 C<KohaAdminEmailAddress> system preference.
 150
 151 These emails are staged in the outgoing message queue, as are messages
 152 produced by other features of Koha. This message queue must be
 153 processed regularly by the
 154 F<misc/cronjobs/process_message_queue.pl> program.
 155
 156 In the event that the C<-n> flag is passed to this program, no emails
 157 are sent. Instead, messages are sent on standard output from this
 158 program. They may be redirected to a file if desired.
 159
 160 =head2 Templates
 161
 162 Templates can contain variables enclosed in double angle brackets like
 163 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 164 specific to the overdue items or relevant patron. Available variables
 165 are:
 166
 167 =over
 168
 169 =item E<lt>E<lt>bibE<gt>E<gt>
 170
 171 the name of the library
 172
 173 =item E<lt>E<lt>items.contentE<gt>E<gt>
 174
 175 one line for each item, each line containing a tab separated list of
 176 title, author, barcode, issuedate
 177
 178 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 179
 180 any field from the borrowers table
 181
 182 =item E<lt>E<lt>branches.*E<gt>E<gt>
 183
 184 any field from the branches table
 185
 186 =back
 187
 188 =head2 CSV output
 189
 190 The C<-csv> command line option lets you specify a file to which
 191 overdues data should be output in CSV format.
 192
 193 With the C<-n> flag set, data about all overdues is written to the
 194 file. Without that flag, only information about overdues that were
 195 unable to be sent directly to the patrons will be written. In other
 196 words, this CSV file replaces the data that is typically sent to the
 197 administrator email address.
 198
 199 =head1 USAGE EXAMPLES
 200
 201 C<overdue_notices.pl> - In this most basic usage, with no command line
 202 arguments, all libraries are procesed individually, and notices are
 203 prepared for all patrons with overdue items for whom we have email
 204 addresses. Messages for those patrons for whom we have no email
 205 address are sent in a single attachment to the library administrator's
 206 email address, or to the address in the KohaAdminEmailAddress system
 207 preference.
 208
 209 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 210 populates F</tmp/overdues.csv> with information about all overdue
 211 items.
 212
 213 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 214 overdues in the last 2 weeks for the MAIN library.
 215
 216 =head1 SEE ALSO
 217
 218 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 219 messages to patrons in advance of thier items becoming due, or to
 220 alert them of items that have just become due.
 221
 222 =cut
 223
 224 # These variables are set by command line options.
 225 # They are initially set to default values.
 226 my $help    = 0;
 227 my $man     = 0;
 228 my $verbose = 0;
 229 my $nomail  = 0;
 230 my $MAX     = 90;
 231 my $mybranch;
 232 my $csvfilename;
 233 my $triggered = 0;
 234 my $listall = 0;
 235 my $itemscontent = join( ',', qw( issuedate title barcode author ) );
 236
 237 GetOptions(
 238     'help|?'         => \$help,
 239     'man'            => \$man,
 240     'v'              => \$verbose,
 241     'n'              => \$nomail,
 242     'max=s'          => \$MAX,
 243     'library=s'      => \$mybranch,
 244     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 245     'itemscontent=s' => \$itemscontent,
 246     'list-all'      => \$listall,
 247     't|triggered'             => \$triggered,
 248 ) or pod2usage(2);
 249 pod2usage(1) if $help;
 250 pod2usage( -verbose => 2 ) if $man;
 251
 252 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 253     warn qq(using "$csvfilename" as filename, that seems odd);
 254 }
 255
 256 my @branches    = C4::Overdues::GetBranchcodesWithOverdueRules();
 257 my $branchcount = scalar(@branches);
 258 if ($branchcount) {
 259     my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 260     $verbose and warn "Found $branchcount $branch_word with first message enabled: " . join( ', ', map { "'$_'" } @branches ), "\n";
 261 } else {
 262     die 'No branches with active overduerules';
 263 }
 264
 265 if ($mybranch) {
 266     $verbose and warn "Branch $mybranch selected\n";
 267     if ( scalar grep { $mybranch eq $_ } @branches ) {
 268         @branches = ($mybranch);
 269     } else {
 270         $verbose and warn "No active overduerules for branch '$mybranch'\n";
 271         ( scalar grep { '' eq $_ } @branches )
 272           or die "No active overduerules for DEFAULT either!";
 273         $verbose and warn "Falling back on default rules for $mybranch\n";
 274         @branches = ('');
 275     }
 276 }
 277
 278 # these are the fields that will be substituted into <<item.content>>
 279 my @item_content_fields = split( /,/, $itemscontent );
 280
 281 my $dbh = C4::Context->dbh();
 282 binmode( STDOUT, ":utf8" );
 283
 284 our $csv;       # the Text::CSV_XS object
 285 our $csv_fh;    # the filehandle to the CSV file.
 286 if ( defined $csvfilename ) {
 287     $csv = Text::CSV_XS->new( { binary => 1 } );
 288     if ( $csvfilename eq '' ) {
 289         $csv_fh = *STDOUT;
 290     } else {
 291         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 292     }
 293     if ( $csv->combine(qw(name surname address1 address2 zipcode city email itemcount itemsinfo)) ) {
 294         print $csv_fh $csv->string, "\n";
 295     } else {
 296         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 297     }
 298 }
 299
 300 foreach my $branchcode (@branches) {
 301
 302     my $branch_details = C4::Branch::GetBranchDetail($branchcode);
 303     my $admin_email_address = $branch_details->{'branchemail'} || C4::Context->preference('KohaAdminEmailAddress');
 304     my @output_chunks;    # may be sent to mail or stdout or csv file.
 305
 306     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $admin_email_address;
 307
 308     my $sth2 = $dbh->prepare( <<'END_SQL' );
 309 SELECT biblio.*, items.*, issues.*, TO_DAYS(NOW())-TO_DAYS(date_due) AS days_overdue
 310   FROM issues,items,biblio
 311   WHERE items.itemnumber=issues.itemnumber
 312     AND biblio.biblionumber   = items.biblionumber
 313     AND issues.borrowernumber = ?
 314     AND TO_DAYS(NOW())-TO_DAYS(date_due) BETWEEN ? and ?
 315 END_SQL
 316
 317     my $rqoverduerules = $dbh->prepare("SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ");
 318     $rqoverduerules->execute($branchcode);
 319     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 320     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 321       PERIOD: foreach my $i ( 1 .. 3 ) {
 322
 323             $verbose and warn "branch '$branchcode', pass $i\n";
 324             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 325             my $maxdays = (
 326                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 327                 ? $overdue_rules->{ "delay" . ( $i + 1 ) }
 328                 : ($MAX)
 329             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 330
 331             if ( !$overdue_rules->{"letter$i"} ) {
 332                 $verbose and warn "No letter$i code for branch '$branchcode'";
 333                 next PERIOD;
 334             }
 335
 336             # $letter->{'content'} is the text of the mail that is sent.
 337             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 338             # The following fields are available :
 339             # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 340             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode>
 341
 342             my $borrower_sql = <<'END_SQL';
 343 SELECT COUNT(*), issues.borrowernumber, firstname, surname, address, address2, city, zipcode, email, MIN(date_due) as longest_issue
 344 FROM   issues,borrowers,categories
 345 WHERE  issues.borrowernumber=borrowers.borrowernumber
 346 AND    borrowers.categorycode=categories.categorycode
 347 END_SQL
 348             my @borrower_parameters;
 349             if ($branchcode) {
 350                 $borrower_sql .= ' AND issues.branchcode=? ';
 351                 push @borrower_parameters, $branchcode;
 352             }
 353             if ( $overdue_rules->{categorycode} ) {
 354                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 355                 push @borrower_parameters, $overdue_rules->{categorycode};
 356             }
 357             $borrower_sql .= '  AND categories.overduenoticerequired=1
 358                                 GROUP BY issues.borrowernumber ';
 359             if($triggered) {
 360                 $borrower_sql .= ' HAVING TO_DAYS(NOW())-TO_DAYS(longest_issue) = ?';
 361                 push @borrower_parameters, $mindays;
 362             } else {
 363                 $borrower_sql .= ' HAVING TO_DAYS(NOW())-TO_DAYS(longest_issue) BETWEEN ? and ? ' ;
 364                 push @borrower_parameters, $mindays, $maxdays;
 365             }
 366
 367             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 368                 my $sth = $dbh->prepare($borrower_sql);
 369             $sth->execute(@borrower_parameters);
 370             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays)\nreturns " . $sth->rows . " rows";
 371
 372             while( my ( $itemcount, $borrowernumber, $firstname, $lastname, $address1, $address2, $city, $postcode, $email ) = $sth->fetchrow ) {
 373                 $verbose and warn "borrower $firstname, $lastname ($borrowernumber) has $itemcount items triggering level $i.";
 374
 375                 my $letter = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"} );
 376                 unless ($letter) {
 377                     $verbose and warn "Message '$overdue_rules->{letter$i}' content not found";
 378
 379                     # might as well skip while PERIOD, no other borrowers are going to work.
 380                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 381                     next PERIOD;
 382                 }
 383
 384                 if ( $overdue_rules->{"debarred$i"} ) {
 385
 386                     #action taken is debarring
 387                     C4::Members::DebarMember($borrowernumber);
 388                     $verbose and warn "debarring $borrowernumber $firstname $lastname\n";
 389                 }
 390                 $sth2->execute( ($listall) ? ( $borrowernumber , 1 , $MAX ) : ( $borrowernumber, $mindays, $maxdays ) );
 391                 my $itemcount = 0;
 392                 my $titles = "";
 393                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 394                     my @item_info = map { $_ =~ /^date|date$/ ? format_date( $item_info->{$_} ) : $item_info->{$_} || '' } @item_content_fields;
 395                     $titles .= join("\t", @item_info) . "\n";
 396                 }
 397                 $sth2->finish;
 398
 399                 $letter = parse_letter(
 400                     {   letter         => $letter,
 401                         borrowernumber => $borrowernumber,
 402                         branchcode     => $branchcode,
 403                         substitute     => {
 404                             bib             => $branch_details->{'branchname'},
 405                             'items.content' => $titles
 406                         }
 407                     }
 408                 );
 409
 410                 my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 411                 if (@misses) {
 412                     $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 413                 }
 414                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # Now that we've warned about them, remove them.
 415                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # 2nd pass for the double nesting.
 416
 417                 if ($nomail) {
 418
 419                     push @output_chunks,
 420                       prepare_letter_for_printing(
 421                         {   letter         => $letter,
 422                             borrowernumber => $borrowernumber,
 423                             firstname      => $firstname,
 424                             lastname       => $lastname,
 425                             address1       => $address1,
 426                             address2       => $address2,
 427                             city           => $city,
 428                             postcode       => $postcode,
 429                             email          => $email,
 430                             itemcount      => $itemcount,
 431                             titles         => $titles,
 432                             outputformat   => defined $csvfilename ? 'csv' : '',
 433                         }
 434                       );
 435                 } else {
 436                     if ($email) {
 437                         C4::Letters::EnqueueLetter(
 438                             {   letter                 => $letter,
 439                                 borrowernumber         => $borrowernumber,
 440                                 message_transport_type => 'email',
 441                                 from_address           => $admin_email_address,
 442                             }
 443                         );
 444                     } else {
 445
 446                         # If we don't have an email address for this patron, send it to the admin to deal with.
 447                         push @output_chunks,
 448                           prepare_letter_for_printing(
 449                             {   letter         => $letter,
 450                                 borrowernumber => $borrowernumber,
 451                                 firstname      => $firstname,
 452                                 lastname       => $lastname,
 453                                 address1       => $address1,
 454                                 address2       => $address2,
 455                                 city           => $city,
 456                                 postcode       => $postcode,
 457                                 email          => $email,
 458                                 itemcount      => $itemcount,
 459                                 titles         => $titles,
 460                                 outputformat   => defined $csvfilename ? 'csv' : '',
 461                             }
 462                           );
 463                     }
 464                 }
 465             }
 466             $sth->finish;
 467         }
 468     }
 469
 470     if (@output_chunks) {
 471         if ($nomail) {
 472             if ( defined $csvfilename ) {
 473                 print $csv_fh @output_chunks;
 474             } else {
 475                 local $, = "\f";    # pagebreak
 476                 print @output_chunks;
 477             }
 478         } else {
 479             my $attachment = {
 480                 filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 481                 type => 'text/plain',
 482                 content => join( "\n", @output_chunks )
 483             };
 484
 485             my $letter = {
 486                 title   => 'Overdue Notices',
 487                 content => 'These messages were not sent directly to the patrons.',
 488             };
 489             C4::Letters::EnqueueLetter(
 490                 {   letter                 => $letter,
 491                     borrowernumber         => undef,
 492                     message_transport_type => 'email',
 493                     attachments            => [$attachment],
 494                     to_address             => $admin_email_address,
 495                 }
 496             );
 497         }
 498     }
 499
 500 }
 501 if ($csvfilename) {
 502
 503     # note that we're not testing on $csv_fh to prevent closing
 504     # STDOUT.
 505     close $csv_fh;
 506 }
 507
 508 =head1 INTERNAL METHODS
 509
 510 These methods are internal to the operation of overdue_notices.pl.
 511
 512 =head2 parse_letter
 513
 514 parses the letter template, replacing the placeholders with data
 515 specific to this patron, biblio, or item
 516
 517 named parameters:
 518   letter - required hashref
 519   borrowernumber - required integer
 520   substitute - optional hashref of other key/value pairs that should
 521     be substituted in the letter content
 522
 523 returns the C<letter> hashref, with the content updated to reflect the
 524 substituted keys and values.
 525
 526
 527 =cut
 528
 529 sub parse_letter {
 530     my $params = shift;
 531     foreach my $required (qw( letter borrowernumber )) {
 532         return unless exists $params->{$required};
 533     }
 534
 535     if ( $params->{'substitute'} ) {
 536         while ( my ( $key, $replacedby ) = each %{ $params->{'substitute'} } ) {
 537             my $replacefield = "<<$key>>";
 538
 539             $params->{'letter'}->{title}   =~ s/$replacefield/$replacedby/g;
 540             $params->{'letter'}->{content} =~ s/$replacefield/$replacedby/g;
 541         }
 542     }
 543
 544     C4::Letters::parseletter( $params->{'letter'}, 'borrowers', $params->{'borrowernumber'} );
 545
 546     if ( $params->{'branchcode'} ) {
 547         C4::Letters::parseletter( $params->{'letter'}, 'branches', $params->{'branchcode'} );
 548     }
 549
 550     if ( $params->{'biblionumber'} ) {
 551         C4::Letters::parseletter( $params->{'letter'}, 'biblio',      $params->{'biblionumber'} );
 552         C4::Letters::parseletter( $params->{'letter'}, 'biblioitems', $params->{'biblionumber'} );
 553     }
 554
 555     return $params->{'letter'};
 556 }
 557
 558 =head2 prepare_letter_for_printing
 559
 560 returns a string of text appropriate for printing in the event that an
 561 overdue notice will not be sent to the patron's email
 562 address. Depending on the desired output format, this may be a CSV
 563 string, or a human-readable representation of the notice.
 564
 565 required parameters:
 566   letter
 567   borrowernumber
 568
 569 optional parameters:
 570   outputformat
 571
 572 =cut
 573
 574 sub prepare_letter_for_printing {
 575     my $params = shift;
 576
 577     return unless ref $params eq 'HASH';
 578
 579     foreach my $required_parameter (qw( letter borrowernumber )) {
 580         return unless defined $params->{$required_parameter};
 581     }
 582
 583     my $return;
 584     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 585         if ($csv->combine(
 586                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 587                 $params->{'city'},      $params->{'email'},    $params->{'itemcount'}, $params->{'items.content'}
 588             )
 589           ) {
 590             return $csv->string, "\n";
 591         } else {
 592             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 593         }
 594     } else {
 595         $return .= "$params->{'letter'}->{'content'}\n";
 596
 597         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 598     }
 599     return $return;
 600 }
 601