misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Liblime
   4 # Copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 2 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21 use strict;
  22 use warnings;
  23
  24 BEGIN {
  25
  26     # find Koha's Perl modules
  27     # test carefully before changing this
  28     use FindBin;
  29     eval { require "$FindBin::Bin/../kohalib.pl" };
  30 }
  31
  32 use Getopt::Long;
  33 use Pod::Usage;
  34 use Text::CSV_XS;
  35 use Locale::Currency::Format 1.28;
  36 use Encode;
  37
  38 use C4::Context;
  39 use C4::Dates qw/format_date/;
  40 use C4::Debug;
  41 use C4::Letters;
  42 use C4::Overdues qw(GetFine);
  43 use C4::Budgets qw(GetCurrency);
  44
  45 use Koha::Borrower::Debarments qw(AddUniqueDebarment);
  46 use Koha::DateUtils;
  47
  48 =head1 NAME
  49
  50 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  51
  52 =head1 SYNOPSIS
  53
  54 overdue_notices.pl
  55   [ -n ][ -library <branchcode> ][ -library <branchcode> ... ]
  56   [ -max <number of days> ][ -csv [<filename>] ][ -itemscontent <field list> ]
  57   [ -email <email_type> ... ]
  58
  59  Options:
  60    -help                          brief help message
  61    -man                           full documentation
  62    -n                             No email will be sent
  63    -max          <days>           maximum days overdue to deal with
  64    -library      <branchname>     only deal with overdues from this library (repeatable : several libraries can be given)
  65    -csv          <filename>       populate CSV file
  66    -html         <directory>      Output html to a file in the given directory
  67    -text         <directory>      Output plain text to a file in the given directory
  68    -itemscontent <list of fields> item information in templates
  69    -borcat       <categorycode>   category code that must be included
  70    -borcatout    <categorycode>   category code that must be excluded
  71    -email        <email_type>     type of email that will be used. Can be 'email', 'emailpro' or 'B_email'. Repeatable.
  72
  73 =head1 OPTIONS
  74
  75 =over 8
  76
  77 =item B<-help>
  78
  79 Print a brief help message and exits.
  80
  81 =item B<-man>
  82
  83 Prints the manual page and exits.
  84
  85 =item B<-v>
  86
  87 Verbose. Without this flag set, only fatal errors are reported.
  88
  89 =item B<-n>
  90
  91 Do not send any email. Overdue notices that would have been sent to
  92 the patrons or to the admin are printed to standard out. CSV data (if
  93 the -csv flag is set) is written to standard out or to any csv
  94 filename given.
  95
  96 =item B<-max>
  97
  98 Items older than max days are assumed to be handled somewhere else,
  99 probably the F<longoverdues.pl> script. They are therefore ignored by
 100 this program. No notices are sent for them, and they are not added to
 101 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
 102
 103 =item B<-library>
 104
 105 select overdues for one specific library. Use the value in the
 106 branches.branchcode table. This option can be repeated in order
 107 to select overdues for a group of libraries.
 108
 109 =item B<-csv>
 110
 111 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
 112 sent to standard out or to a filename if provided. Otherwise, only
 113 overdues that could not be emailed are sent in CSV format to the admin.
 114
 115 =item B<-html>
 116
 117 Produces html data. if patron does not have a mail address or
 118 -n (no mail) flag is set, an html file is generated in the specified
 119 directory. This can be downloaded or futher processed by library staff.
 120 The file will be called notices-YYYY-MM-DD.html and placed in the directory
 121 specified.
 122
 123 =item B<-text>
 124
 125 Produces plain text data. if patron does not have a mail address or
 126 -n (no mail) flag is set, a text file is generated in the specified
 127 directory. This can be downloaded or futher processed by library staff.
 128 The file will be called notices-YYYY-MM-DD.txt and placed in the directory
 129 specified.
 130
 131 =item B<-itemscontent>
 132
 133 comma separated list of fields that get substituted into templates in
 134 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 135 defaults to due date,title,barcode,author
 136
 137 Other possible values come from fields in the biblios, items and
 138 issues tables.
 139
 140 =item B<-borcat>
 141
 142 Repetable field, that permit to select only few of patrons categories.
 143
 144 =item B<-borcatout>
 145
 146 Repetable field, permis to exclude some patrons categories.
 147
 148 =item B<-t> | B<--triggered>
 149
 150 This option causes a notice to be generated if and only if
 151 an item is overdue by the number of days defined in a notice trigger.
 152
 153 By default, a notice is sent each time the script runs, which is suitable for
 154 less frequent run cron script, but requires syncing notice triggers with
 155 the  cron schedule to ensure proper behavior.
 156 Add the --triggered option for daily cron, at the risk of no notice
 157 being generated if the cron fails to run on time.
 158
 159 =item B<-list-all>
 160
 161 Default items.content lists only those items that fall in the
 162 range of the currently processing notice.
 163 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 164
 165 =item B<-date>
 166
 167 use it in order to send overdues on a specific date and not Now.
 168
 169 =item B<-email>
 170
 171 Allows to specify which type of email will be used. Can be email, emailpro or B_email. Repeatable.
 172
 173 =back
 174
 175 =head1 DESCRIPTION
 176
 177 This script is designed to alert patrons and administrators of overdue
 178 items.
 179
 180 =head2 Configuration
 181
 182 This script pays attention to the overdue notice configuration
 183 performed in the "Overdue notice/status triggers" section of the
 184 "Tools" area of the staff interface to Koha. There, you can choose
 185 which letter templates are sent out after a configurable number of
 186 days to patrons of each library. More information about the use of this
 187 section of Koha is available in the Koha manual.
 188
 189 The templates used to craft the emails are defined in the "Tools:
 190 Notices" section of the staff interface to Koha.
 191
 192 =head2 Outgoing emails
 193
 194 Typically, messages are prepared for each patron with overdue
 195 items. Messages for whom there is no email address on file are
 196 collected and sent as attachments in a single email to each library
 197 administrator, or if that is not set, then to the email address in the
 198 C<KohaAdminEmailAddress> system preference.
 199
 200 These emails are staged in the outgoing message queue, as are messages
 201 produced by other features of Koha. This message queue must be
 202 processed regularly by the
 203 F<misc/cronjobs/process_message_queue.pl> program.
 204
 205 In the event that the C<-n> flag is passed to this program, no emails
 206 are sent. Instead, messages are sent on standard output from this
 207 program. They may be redirected to a file if desired.
 208
 209 =head2 Templates
 210
 211 Templates can contain variables enclosed in double angle brackets like
 212 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 213 specific to the overdue items or relevant patron. Available variables
 214 are:
 215
 216 =over
 217
 218 =item E<lt>E<lt>bibE<gt>E<gt>
 219
 220 the name of the library
 221
 222 =item E<lt>E<lt>items.contentE<gt>E<gt>
 223
 224 one line for each item, each line containing a tab separated list of
 225 title, author, barcode, issuedate
 226
 227 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 228
 229 any field from the borrowers table
 230
 231 =item E<lt>E<lt>branches.*E<gt>E<gt>
 232
 233 any field from the branches table
 234
 235 =back
 236
 237 =head2 CSV output
 238
 239 The C<-csv> command line option lets you specify a file to which
 240 overdues data should be output in CSV format.
 241
 242 With the C<-n> flag set, data about all overdues is written to the
 243 file. Without that flag, only information about overdues that were
 244 unable to be sent directly to the patrons will be written. In other
 245 words, this CSV file replaces the data that is typically sent to the
 246 administrator email address.
 247
 248 =head1 USAGE EXAMPLES
 249
 250 C<overdue_notices.pl> - In this most basic usage, with no command line
 251 arguments, all libraries are procesed individually, and notices are
 252 prepared for all patrons with overdue items for whom we have email
 253 addresses. Messages for those patrons for whom we have no email
 254 address are sent in a single attachment to the library administrator's
 255 email address, or to the address in the KohaAdminEmailAddress system
 256 preference.
 257
 258 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 259 populates F</tmp/overdues.csv> with information about all overdue
 260 items.
 261
 262 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 263 overdues in the last 2 weeks for the MAIN library.
 264
 265 =head1 SEE ALSO
 266
 267 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 268 messages to patrons in advance of thier items becoming due, or to
 269 alert them of items that have just become due.
 270
 271 =cut
 272
 273 # These variables are set by command line options.
 274 # They are initially set to default values.
 275 my $dbh = C4::Context->dbh();
 276 my $help    = 0;
 277 my $man     = 0;
 278 my $verbose = 0;
 279 my $nomail  = 0;
 280 my $MAX     = 90;
 281 my @branchcodes; # Branch(es) passed as parameter
 282 my @emails_to_use;    # Emails to use for messaging
 283 my @emails;           # Emails given in command-line parameters
 284 my $csvfilename;
 285 my $htmlfilename;
 286 my $text_filename;
 287 my $triggered = 0;
 288 my $listall = 0;
 289 my $itemscontent = join( ',', qw( date_due title barcode author itemnumber ) );
 290 my @myborcat;
 291 my @myborcatout;
 292 my $date;
 293
 294 GetOptions(
 295     'help|?'         => \$help,
 296     'man'            => \$man,
 297     'v'              => \$verbose,
 298     'n'              => \$nomail,
 299     'max=s'          => \$MAX,
 300     'library=s'      => \@branchcodes,
 301     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 302     'html:s'         => \$htmlfilename,    # this optional argument gets '' if not supplied.
 303     'text:s'         => \$text_filename,    # this optional argument gets '' if not supplied.
 304     'itemscontent=s' => \$itemscontent,
 305     'list-all'       => \$listall,
 306     't|triggered'    => \$triggered,
 307     'date'           => \$date,
 308     'borcat=s'       => \@myborcat,
 309     'borcatout=s'    => \@myborcatout,
 310     'email=s'        => \@emails,
 311 ) or pod2usage(2);
 312 pod2usage(1) if $help;
 313 pod2usage( -verbose => 2 ) if $man;
 314
 315 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 316     warn qq(using "$csvfilename" as filename, that seems odd);
 317 }
 318
 319 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();        # Branches with overdue rules
 320 my @branches;                                                                   # Branches passed as parameter with overdue rules
 321 my $branchcount = scalar(@overduebranches);
 322
 323 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 324 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 325
 326 my $PrintNoticesMaxLines = C4::Context->preference('PrintNoticesMaxLines');
 327
 328 if ($branchcount) {
 329     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 330 } else {
 331     die 'No branches with active overduerules';
 332 }
 333
 334 if (@branchcodes) {
 335     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 336
 337     # Getting libraries which have overdue rules
 338     my %seen = map { $_ => 1 } @branchcodes;
 339     @branches = grep { $seen{$_} } @overduebranches;
 340
 341
 342     if (@branches) {
 343
 344         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 345         $verbose and warn "$branch_word @branches have overdue rules\n";
 346
 347     } else {
 348
 349         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 350         ( scalar grep { '' eq $_ } @branches )
 351           or die "No active overduerules for DEFAULT either!";
 352         $verbose and warn "Falling back on default rules for @branchcodes\n";
 353         @branches = ('');
 354     }
 355 }
 356
 357 if ($date){
 358     $date=$dbh->quote($date);
 359 }
 360 else {
 361     $date="NOW()";
 362 }
 363
 364 # these are the fields that will be substituted into <<item.content>>
 365 my @item_content_fields = split( /,/, $itemscontent );
 366
 367 binmode( STDOUT, ':encoding(UTF-8)' );
 368
 369
 370 our $csv;       # the Text::CSV_XS object
 371 our $csv_fh;    # the filehandle to the CSV file.
 372 if ( defined $csvfilename ) {
 373     my $sep_char = C4::Context->preference('delimiter') || ';';
 374     $sep_char = "\t" if ($sep_char eq 'tabulation');
 375     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 376     if ( $csvfilename eq '' ) {
 377         $csv_fh = *STDOUT;
 378     } else {
 379         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 380     }
 381     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email itemcount itemsinfo)) ) {
 382         print $csv_fh $csv->string, "\n";
 383     } else {
 384         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 385     }
 386 }
 387
 388 @branches = @overduebranches unless @branches;
 389 our $fh;
 390 if ( defined $htmlfilename ) {
 391   if ( $htmlfilename eq '' ) {
 392     $fh = *STDOUT;
 393   } else {
 394     my $today = DateTime->now(time_zone => C4::Context->tz );
 395     open $fh, ">",File::Spec->catdir ($htmlfilename,"notices-".$today->ymd().".html");
 396   }
 397
 398   print $fh "<html>\n";
 399   print $fh "<head>\n";
 400   print $fh "<style type='text/css'>\n";
 401   print $fh "pre {page-break-after: always;}\n";
 402   print $fh "pre {white-space: pre-wrap;}\n";
 403   print $fh "pre {white-space: -moz-pre-wrap;}\n";
 404   print $fh "pre {white-space: -o-pre-wrap;}\n";
 405   print $fh "pre {word-wrap: break-work;}\n";
 406   print $fh "</style>\n";
 407   print $fh "</head>\n";
 408   print $fh "<body>\n";
 409 }
 410 elsif ( defined $text_filename ) {
 411   if ( $text_filename eq '' ) {
 412     $fh = *STDOUT;
 413   } else {
 414     my $today = DateTime->now(time_zone => C4::Context->tz );
 415     open $fh, ">",File::Spec->catdir ($text_filename,"notices-".$today->ymd().".txt");
 416   }
 417 }
 418
 419 foreach my $branchcode (@branches) {
 420
 421     my $branch_details = C4::Branch::GetBranchDetail($branchcode);
 422     my $admin_email_address = $branch_details->{'branchemail'} || C4::Context->preference('KohaAdminEmailAddress');
 423     my @output_chunks;    # may be sent to mail or stdout or csv file.
 424
 425     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $admin_email_address;
 426
 427     my $sth2 = $dbh->prepare( <<"END_SQL" );
 428 SELECT biblio.*, items.*, issues.*, biblioitems.itemtype, TO_DAYS($date)-TO_DAYS(date_due) AS days_overdue
 429   FROM issues,items,biblio, biblioitems
 430   WHERE items.itemnumber=issues.itemnumber
 431     AND biblio.biblionumber   = items.biblionumber
 432     AND biblio.biblionumber   = biblioitems.biblionumber
 433     AND issues.borrowernumber = ?
 434     AND TO_DAYS($date)-TO_DAYS(date_due) BETWEEN ? and ?
 435 END_SQL
 436
 437     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ";
 438     $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 439     $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 440
 441     my $rqoverduerules =  $dbh->prepare($query);
 442     $rqoverduerules->execute($branchcode, @myborcat, @myborcatout);
 443
 444     # We get default rules is there is no rule for this branch
 445     if($rqoverduerules->rows == 0){
 446         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ";
 447         $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 448         $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 449
 450         $rqoverduerules = $dbh->prepare($query);
 451         $rqoverduerules->execute(@myborcat, @myborcatout);
 452     }
 453
 454     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 455     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 456       PERIOD: foreach my $i ( 1 .. 3 ) {
 457
 458             $verbose and warn "branch '$branchcode', pass $i\n";
 459             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 460             my $maxdays = (
 461                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 462                 ? $overdue_rules->{ "delay" . ( $i + 1 ) } - 1
 463                 : ($MAX)
 464             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 465
 466             if ( !$overdue_rules->{"letter$i"} ) {
 467                 $verbose and warn "No letter$i code for branch '$branchcode'";
 468                 next PERIOD;
 469             }
 470
 471             # $letter->{'content'} is the text of the mail that is sent.
 472             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 473             # The following fields are available :
 474             # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 475             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode> <country>
 476
 477             my $borrower_sql = <<'END_SQL';
 478 SELECT distinct(issues.borrowernumber), firstname, surname, address, address2, city, zipcode, country, email, emailpro, B_email
 479 FROM   issues,borrowers,categories
 480 WHERE  issues.borrowernumber=borrowers.borrowernumber
 481 AND    borrowers.categorycode=categories.categorycode
 482 END_SQL
 483             my @borrower_parameters;
 484             if ($branchcode) {
 485                 $borrower_sql .= ' AND issues.branchcode=? ';
 486                 push @borrower_parameters, $branchcode;
 487             }
 488             if ( $overdue_rules->{categorycode} ) {
 489                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 490                 push @borrower_parameters, $overdue_rules->{categorycode};
 491             }
 492             $borrower_sql .= '  AND categories.overduenoticerequired=1 ';
 493             if($triggered) {
 494                 $borrower_sql .= " AND TO_DAYS($date)-TO_DAYS(date_due) = ?";
 495                 push @borrower_parameters, $mindays;
 496             } else {
 497                 $borrower_sql .= " AND TO_DAYS($date)-TO_DAYS(date_due) BETWEEN ? and ? " ;
 498                 push @borrower_parameters, $mindays, $maxdays;
 499             }
 500
 501             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 502                 my $sth = $dbh->prepare($borrower_sql);
 503             $sth->execute(@borrower_parameters);
 504             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays)\nreturns " . $sth->rows . " rows";
 505
 506             while ( my $data = $sth->fetchrow_hashref ) {
 507                 my $borrowernumber = $data->{'borrowernumber'};
 508                 my $borr =
 509                     $data->{'firstname'} . ', '
 510                   . $data->{'surname'} . ' ('
 511                   . $borrowernumber . ')';
 512                 $verbose
 513                   and warn "borrower $borr has items triggering level $i.";
 514
 515                 @emails_to_use = ();
 516                 my $notice_email =
 517                     C4::Members::GetNoticeEmailAddress($borrowernumber);
 518                 unless ($nomail) {
 519                     if (@emails) {
 520                         foreach (@emails) {
 521                             push @emails_to_use, $data->{$_} if ( $data->{$_} );
 522                         }
 523                     }
 524                     else {
 525                         push @emails_to_use, $notice_email if ($notice_email);
 526                     }
 527                 }
 528
 529                 my $letter = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"}, $branchcode );
 530
 531                 unless ($letter) {
 532                     $verbose and warn "Message '$overdue_rules->{letter$i}' content not found";
 533
 534                     # might as well skip while PERIOD, no other borrowers are going to work.
 535                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 536                     next PERIOD;
 537                 }
 538
 539                 if ( $overdue_rules->{"debarred$i"} ) {
 540
 541                     #action taken is debarring
 542                     AddUniqueDebarment(
 543                         {
 544                             borrowernumber => $borrowernumber,
 545                             type           => 'OVERDUES',
 546                             comment => "Restriction added by overdues process "
 547                               . output_pref( dt_from_string() ),
 548                         }
 549                     );
 550                     $verbose and warn "debarring $borr\n";
 551                 }
 552                 my @params = ($listall ? ( $borrowernumber , 1 , $MAX ) : ( $borrowernumber, $mindays, $maxdays ));
 553                 $verbose and warn "STH2 PARAMS: borrowernumber = $borrowernumber, mindays = $mindays, maxdays = $maxdays";
 554                 $sth2->execute(@params);
 555                 my $itemcount = 0;
 556                 my $titles = "";
 557                 my @items = ();
 558
 559                 my $j = 0;
 560                 my $exceededPrintNoticesMaxLines = 0;
 561                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 562                     if ( ( scalar(@emails_to_use) == 0 || $nomail ) && $PrintNoticesMaxLines && $j >= $PrintNoticesMaxLines ) {
 563                       $exceededPrintNoticesMaxLines = 1;
 564                       last;
 565                     }
 566                     $j++;
 567                     my @item_info = map { $_ =~ /^date|date$/ ? format_date( $item_info->{$_} ) : $item_info->{$_} || '' } @item_content_fields;
 568                     $titles .= join("\t", @item_info) . "\n";
 569                     $itemcount++;
 570                     push @items, $item_info;
 571                 }
 572                 $sth2->finish;
 573
 574                 $letter = parse_letter(
 575                     {   letter_code     => $overdue_rules->{"letter$i"},
 576                         borrowernumber  => $borrowernumber,
 577                         branchcode      => $branchcode,
 578                         items           => \@items,
 579                         substitute      => {    # this appears to be a hack to overcome incomplete features in this code.
 580                                             bib             => $branch_details->{'branchname'}, # maybe 'bib' is a typo for 'lib<rary>'?
 581                                             'items.content' => $titles,
 582                                             'count'         => $itemcount,
 583                                            }
 584                     }
 585                 );
 586                 unless ($letter) {
 587                     $verbose and warn "Message '$overdue_rules->{letter$i}' content not found";
 588
 589                     # might as well skip while PERIOD, no other borrowers are going to work.
 590                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 591                     next PERIOD;
 592                 }
 593
 594                 if ( $exceededPrintNoticesMaxLines ) {
 595                   $letter->{'content'} .= "List too long for form; please check your account online for a complete list of your overdue items.";
 596                 }
 597
 598                 my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 599                 if (@misses) {
 600                     $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 601                 }
 602
 603                 if ( !$nomail && scalar @emails_to_use ) {
 604                     C4::Letters::EnqueueLetter(
 605                         {   letter                 => $letter,
 606                             borrowernumber         => $borrowernumber,
 607                             message_transport_type => 'email',
 608                             from_address           => $admin_email_address,
 609                             to_address             => join(',', @emails_to_use),
 610                         }
 611                     );
 612                 } else {
 613                     # if not sent by email then print
 614                     push @output_chunks,
 615                       prepare_letter_for_printing(
 616                         {   letter         => $letter,
 617                             borrowernumber => $borrowernumber,
 618                             firstname      => $data->{'firstname'},
 619                             lastname       => $data->{'surname'},
 620                             address1       => $data->{'address'},
 621                             address2       => $data->{'address2'},
 622                             city           => $data->{'city'},
 623                             postcode       => $data->{'zipcode'},
 624                             country        => $data->{'country'},
 625                             email          => $notice_email,
 626                             itemcount      => $itemcount,
 627                             titles         => $titles,
 628                             outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 629                         }
 630                       );
 631                 }
 632             }
 633             $sth->finish;
 634         }
 635     }
 636
 637     if (@output_chunks) {
 638         if ( defined $csvfilename ) {
 639             print $csv_fh @output_chunks;
 640         }
 641         elsif ( defined $htmlfilename ) {
 642             print $fh @output_chunks;
 643         }
 644         elsif ( defined $text_filename ) {
 645             print $fh @output_chunks;
 646         }
 647         elsif ($nomail){
 648                 local $, = "\f";    # pagebreak
 649                 print @output_chunks;
 650         }
 651         # Generate the content of the csv with headers
 652         my $content;
 653         if ( defined $csvfilename ) {
 654             my $delimiter = C4::Context->preference('delimiter') || ';';
 655             $content = join($delimiter, qw(title name surname address1 address2 zipcode city country email itemcount itemsinfo due_date issue_date)) . "\n";
 656         }
 657         else {
 658             $content = "";
 659         }
 660         $content .= join( "\n", @output_chunks );
 661
 662         my $attachment = {
 663             filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 664             type => 'text/plain',
 665             content => $content,
 666         };
 667
 668         my $letter = {
 669             title   => 'Overdue Notices',
 670             content => 'These messages were not sent directly to the patrons.',
 671         };
 672         C4::Letters::EnqueueLetter(
 673             {   letter                 => $letter,
 674                 borrowernumber         => undef,
 675                 message_transport_type => 'email',
 676                 attachments            => [$attachment],
 677                 to_address             => $admin_email_address,
 678             }
 679         );
 680     }
 681
 682 }
 683 if ($csvfilename) {
 684     # note that we're not testing on $csv_fh to prevent closing
 685     # STDOUT.
 686     close $csv_fh;
 687 }
 688
 689 if ( defined $htmlfilename ) {
 690   print $fh "</body>\n";
 691   print $fh "</html>\n";
 692   close $fh;
 693 } elsif ( defined $text_filename ) {
 694   close $fh;
 695 }
 696
 697 =head1 INTERNAL METHODS
 698
 699 These methods are internal to the operation of overdue_notices.pl.
 700
 701 =head2 parse_letter
 702
 703 parses the letter template, replacing the placeholders with data
 704 specific to this patron, biblio, or item
 705
 706 named parameters:
 707   letter - required hashref
 708   borrowernumber - required integer
 709   substitute - optional hashref of other key/value pairs that should
 710     be substituted in the letter content
 711
 712 returns the C<letter> hashref, with the content updated to reflect the
 713 substituted keys and values.
 714
 715
 716 =cut
 717
 718 sub parse_letter {
 719     my $params = shift;
 720     foreach my $required (qw( letter_code borrowernumber )) {
 721         return unless ( exists $params->{$required} && $params->{$required} );
 722     }
 723
 724     my $substitute = $params->{'substitute'} || {};
 725     $substitute->{today} ||= C4::Dates->new()->output("syspref");
 726
 727     my %tables = ( 'borrowers' => $params->{'borrowernumber'} );
 728     if ( my $p = $params->{'branchcode'} ) {
 729         $tables{'branches'} = $p;
 730     }
 731
 732     my $currencies = GetCurrency();
 733     my $currency_format;
 734     $currency_format = $currencies->{currency} if defined($currencies);
 735
 736     my @item_tables;
 737     if ( my $i = $params->{'items'} ) {
 738         my $item_format = '';
 739         foreach my $item (@$i) {
 740             my $fine = GetFine($item->{'itemnumber'}, $params->{'borrowernumber'});
 741             if ( !$item_format and defined $params->{'letter'}->{'content'} ) {
 742                 $params->{'letter'}->{'content'} =~ m/(<item>.*<\/item>)/;
 743                 $item_format = $1;
 744             }
 745
 746             $item->{'fine'} = currency_format($currency_format, "$fine", FMT_SYMBOL);
 747             # if active currency isn't correct ISO code fallback to sprintf
 748             $item->{'fine'} = sprintf('%.2f', $fine) unless $item->{'fine'};
 749
 750             push @item_tables, {
 751                 'biblio' => $item->{'biblionumber'},
 752                 'biblioitems' => $item->{'biblionumber'},
 753                 'items' => $item,
 754                 'issues' => $item->{'itemnumber'},
 755             };
 756         }
 757     }
 758
 759     return C4::Letters::GetPreparedLetter (
 760         module => 'circulation',
 761         letter_code => $params->{'letter_code'},
 762         branchcode => $params->{'branchcode'},
 763         tables => \%tables,
 764         substitute => $substitute,
 765         repeat => { item => \@item_tables },
 766     );
 767 }
 768
 769 =head2 prepare_letter_for_printing
 770
 771 returns a string of text appropriate for printing in the event that an
 772 overdue notice will not be sent to the patron's email
 773 address. Depending on the desired output format, this may be a CSV
 774 string, or a human-readable representation of the notice.
 775
 776 required parameters:
 777   letter
 778   borrowernumber
 779
 780 optional parameters:
 781   outputformat
 782
 783 =cut
 784
 785 sub prepare_letter_for_printing {
 786     my $params = shift;
 787
 788     return unless ref $params eq 'HASH';
 789
 790     foreach my $required_parameter (qw( letter borrowernumber )) {
 791         return unless defined $params->{$required_parameter};
 792     }
 793
 794     my $return;
 795     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 796         if ($csv->combine(
 797                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 798                 $params->{'city'}, $params->{'country'}, $params->{'email'}, $params->{'itemcount'}, $params->{'titles'}
 799             )
 800           ) {
 801             return $csv->string, "\n";
 802         } else {
 803             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 804         }
 805     } elsif ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'html' ) {
 806       $return = "<pre>\n";
 807       my $content = $params->{'letter'}->{'content'};
 808       $content =~ s/\n/<br \/>/g;
 809       $content =~ s/\r//g;
 810       $return .= "$content\n";
 811       $return .= "\n</pre>\n";
 812     } else {
 813         $return .= "$params->{'letter'}->{'content'}\n";
 814
 815         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 816     }
 817     return $return;
 818 }
 819