misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl -w
   2
   3 # Copyright 2008 Liblime
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along with
  17 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  18 # Suite 330, Boston, MA  02111-1307 USA
  19
  20 use strict;
  21 use warnings;
  22 use utf8;
  23
  24 BEGIN {
  25
  26     # find Koha's Perl modules
  27     # test carefully before changing this
  28     use FindBin;
  29     eval { require "$FindBin::Bin/../kohalib.pl" };
  30 }
  31
  32 use Getopt::Long;
  33 use Pod::Usage;
  34 use Text::CSV_XS;
  35 use Locale::Currency::Format 1.28;
  36 use Encode;
  37
  38 use C4::Context;
  39 use C4::Dates qw/format_date/;
  40 use C4::Debug;
  41 use C4::Letters;
  42 use C4::Overdues qw(GetFine);
  43
  44 =head1 NAME
  45
  46 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  47
  48 =head1 SYNOPSIS
  49
  50 overdue_notices.pl [ -n ] [ -library <branchcode> ] [ -library <branchcode>...] [ -max <number of days> ] [ -csv [ <filename> ] ] [ -itemscontent <field list> ]
  51
  52  Options:
  53    -help                          brief help message
  54    -man                           full documentation
  55    -n                             No email will be sent
  56    -max          <days>           maximum days overdue to deal with
  57    -library      <branchname>     only deal with overdues from this library (repeatable : several libraries can be given)
  58    -csv          <filename>       populate CSV file
  59    -html         <filename>       Output html to file
  60    -itemscontent <list of fields> item information in templates
  61    -borcat       <categorycode>   category code that must be included
  62    -borcatout    <categorycode>   category code that must be excluded
  63
  64 =head1 OPTIONS
  65
  66 =over 8
  67
  68 =item B<-help>
  69
  70 Print a brief help message and exits.
  71
  72 =item B<-man>
  73
  74 Prints the manual page and exits.
  75
  76 =item B<-v>
  77
  78 Verbose. Without this flag set, only fatal errors are reported.
  79
  80 =item B<-n>
  81
  82 Do not send any email. Overdue notices that would have been sent to
  83 the patrons or to the admin are printed to standard out. CSV data (if
  84 the -csv flag is set) is written to standard out or to any csv
  85 filename given.
  86
  87 =item B<-max>
  88
  89 Items older than max days are assumed to be handled somewhere else,
  90 probably the F<longoverdues.pl> script. They are therefore ignored by
  91 this program. No notices are sent for them, and they are not added to
  92 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
  93
  94 =item B<-library>
  95
  96 select overdues for one specific library. Use the value in the
  97 branches.branchcode table. This option can be repeated in order
  98 to select overdues for a group of libraries.
  99
 100 =item B<-csv>
 101
 102 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
 103 sent to standard out or to a filename if provided. Otherwise, only
 104 overdues that could not be emailed are sent in CSV format to the admin.
 105
 106 =item B<-itemscontent>
 107
 108 comma separated list of fields that get substituted into templates in
 109 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 110 defaults to issuedate,title,barcode,author
 111
 112 Other possible values come from fields in the biblios, items, and
 113 issues tables.
 114
 115 =item B<-borcat>
 116
 117 Repetable field, that permit to select only few of patrons categories.
 118
 119 =item B<-borcatout>
 120
 121 Repetable field, permis to exclude some patrons categories.
 122
 123 =item B<-t> | B<--triggered>
 124
 125 This option causes a notice to be generated if and only if
 126 an item is overdue by the number of days defined in a notice trigger.
 127
 128 By default, a notice is sent each time the script runs, which is suitable for
 129 less frequent run cron script, but requires syncing notice triggers with
 130 the  cron schedule to ensure proper behavior.
 131 Add the --triggered option for daily cron, at the risk of no notice
 132 being generated if the cron fails to run on time.
 133
 134 =item B<-list-all>
 135
 136 Default items.content lists only those items that fall in the
 137 range of the currently processing notice.
 138 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 139
 140 =back
 141
 142 =head1 DESCRIPTION
 143
 144 This script is designed to alert patrons and administrators of overdue
 145 items.
 146
 147 =head2 Configuration
 148
 149 This script pays attention to the overdue notice configuration
 150 performed in the "Overdue notice/status triggers" section of the
 151 "Tools" area of the staff interface to Koha. There, you can choose
 152 which letter templates are sent out after a configurable number of
 153 days to patrons of each library. More information about the use of this
 154 section of Koha is available in the Koha manual.
 155
 156 The templates used to craft the emails are defined in the "Tools:
 157 Notices" section of the staff interface to Koha.
 158
 159 =head2 Outgoing emails
 160
 161 Typically, messages are prepared for each patron with overdue
 162 items. Messages for whom there is no email address on file are
 163 collected and sent as attachments in a single email to each library
 164 administrator, or if that is not set, then to the email address in the
 165 C<KohaAdminEmailAddress> system preference.
 166
 167 These emails are staged in the outgoing message queue, as are messages
 168 produced by other features of Koha. This message queue must be
 169 processed regularly by the
 170 F<misc/cronjobs/process_message_queue.pl> program.
 171
 172 In the event that the C<-n> flag is passed to this program, no emails
 173 are sent. Instead, messages are sent on standard output from this
 174 program. They may be redirected to a file if desired.
 175
 176 =head2 Templates
 177
 178 Templates can contain variables enclosed in double angle brackets like
 179 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 180 specific to the overdue items or relevant patron. Available variables
 181 are:
 182
 183 =over
 184
 185 =item E<lt>E<lt>bibE<gt>E<gt>
 186
 187 the name of the library
 188
 189 =item E<lt>E<lt>items.contentE<gt>E<gt>
 190
 191 one line for each item, each line containing a tab separated list of
 192 title, author, barcode, issuedate
 193
 194 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 195
 196 any field from the borrowers table
 197
 198 =item E<lt>E<lt>branches.*E<gt>E<gt>
 199
 200 any field from the branches table
 201
 202 =back
 203
 204 =head2 CSV output
 205
 206 The C<-csv> command line option lets you specify a file to which
 207 overdues data should be output in CSV format.
 208
 209 With the C<-n> flag set, data about all overdues is written to the
 210 file. Without that flag, only information about overdues that were
 211 unable to be sent directly to the patrons will be written. In other
 212 words, this CSV file replaces the data that is typically sent to the
 213 administrator email address.
 214
 215 =head1 USAGE EXAMPLES
 216
 217 C<overdue_notices.pl> - In this most basic usage, with no command line
 218 arguments, all libraries are procesed individually, and notices are
 219 prepared for all patrons with overdue items for whom we have email
 220 addresses. Messages for those patrons for whom we have no email
 221 address are sent in a single attachment to the library administrator's
 222 email address, or to the address in the KohaAdminEmailAddress system
 223 preference.
 224
 225 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 226 populates F</tmp/overdues.csv> with information about all overdue
 227 items.
 228
 229 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 230 overdues in the last 2 weeks for the MAIN library.
 231
 232 =head1 SEE ALSO
 233
 234 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 235 messages to patrons in advance of thier items becoming due, or to
 236 alert them of items that have just become due.
 237
 238 =cut
 239
 240 # These variables are set by command line options.
 241 # They are initially set to default values.
 242 my $dbh = C4::Context->dbh();
 243 my $help    = 0;
 244 my $man     = 0;
 245 my $verbose = 0;
 246 my $nomail  = 0;
 247 my $MAX     = 90;
 248 my @branchcodes; # Branch(es) passed as parameter
 249 my $csvfilename;
 250 my $htmlfilename;
 251 my $triggered = 0;
 252 my $listall = 0;
 253 my $itemscontent = join( ',', qw( issuedate title barcode author biblionumber ) );
 254 my @myborcat;
 255 my @myborcatout;
 256
 257 GetOptions(
 258     'help|?'         => \$help,
 259     'man'            => \$man,
 260     'v'              => \$verbose,
 261     'n'              => \$nomail,
 262     'max=s'          => \$MAX,
 263     'library=s'      => \@branchcodes,
 264     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 265     'html:s'          => \$htmlfilename,    # this optional argument gets '' if not supplied.
 266     'itemscontent=s' => \$itemscontent,
 267     'list-all'      => \$listall,
 268     't|triggered'             => \$triggered,
 269     'borcat=s'      => \@myborcat,
 270     'borcatout=s'   => \@myborcatout,
 271 ) or pod2usage(2);
 272 pod2usage(1) if $help;
 273 pod2usage( -verbose => 2 ) if $man;
 274
 275 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 276     warn qq(using "$csvfilename" as filename, that seems odd);
 277 }
 278
 279 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();        # Branches with overdue rules
 280 my @branches;                                                                   # Branches passed as parameter with overdue rules
 281 my $branchcount = scalar(@overduebranches);
 282
 283 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 284 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 285
 286 my $PrintNoticesMaxLines = C4::Context->preference('PrintNoticesMaxLines');
 287
 288 if ($branchcount) {
 289     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 290 } else {
 291     die 'No branches with active overduerules';
 292 }
 293
 294 if (@branchcodes) {
 295     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 296
 297     # Getting libraries which have overdue rules
 298     my %seen = map { $_ => 1 } @branchcodes;
 299     @branches = grep { $seen{$_} } @overduebranches;
 300
 301
 302     if (@overduebranches) {
 303
 304         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 305         $verbose and warn "$branch_word @branches have overdue rules\n";
 306
 307     } else {
 308
 309         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 310         ( scalar grep { '' eq $_ } @branches )
 311           or die "No active overduerules for DEFAULT either!";
 312         $verbose and warn "Falling back on default rules for @branchcodes\n";
 313         @branches = ('');
 314     }
 315 }
 316
 317 # these are the fields that will be substituted into <<item.content>>
 318 my @item_content_fields = split( /,/, $itemscontent );
 319
 320 binmode( STDOUT, ":utf8" );
 321
 322
 323 our $csv;       # the Text::CSV_XS object
 324 our $csv_fh;    # the filehandle to the CSV file.
 325 if ( defined $csvfilename ) {
 326     my $sep_char = C4::Context->preference('delimiter') || ',';
 327     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 328     if ( $csvfilename eq '' ) {
 329         $csv_fh = *STDOUT;
 330     } else {
 331         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 332     }
 333     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email itemcount itemsinfo)) ) {
 334         print $csv_fh $csv->string, "\n";
 335     } else {
 336         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 337     }
 338 }
 339
 340 @branches = @overduebranches unless @branches;
 341 our $html_fh;
 342 if ( defined $htmlfilename ) {
 343   if ( $htmlfilename eq '' ) {
 344     $html_fh = *STDOUT;
 345   } else {
 346     my $today = C4::Dates->new();
 347     open $html_fh, ">",File::Spec->catdir ($htmlfilename,"notices-".$today->output('iso').".html");
 348   }
 349
 350   print $html_fh "<html>\n";
 351   print $html_fh "<head>\n";
 352   print $html_fh "<style type='text/css'>\n";
 353   print $html_fh "pre {page-break-after: always;}\n";
 354   print $html_fh "pre {white-space: pre-wrap;}\n";
 355   print $html_fh "pre {white-space: -moz-pre-wrap;}\n";
 356   print $html_fh "pre {white-space: -o-pre-wrap;}\n";
 357   print $html_fh "pre {word-wrap: break-work;}\n";
 358   print $html_fh "</style>\n";
 359   print $html_fh "</head>\n";
 360   print $html_fh "<body>\n";
 361 }
 362
 363 foreach my $branchcode (@branches) {
 364
 365     my $branch_details = C4::Branch::GetBranchDetail($branchcode);
 366     my $admin_email_address = $branch_details->{'branchemail'} || C4::Context->preference('KohaAdminEmailAddress');
 367     my @output_chunks;    # may be sent to mail or stdout or csv file.
 368
 369     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $admin_email_address;
 370
 371     my $sth2 = $dbh->prepare( <<'END_SQL' );
 372 SELECT biblio.*, items.*, issues.*, TO_DAYS(NOW())-TO_DAYS(date_due) AS days_overdue
 373   FROM issues,items,biblio
 374   WHERE items.itemnumber=issues.itemnumber
 375     AND biblio.biblionumber   = items.biblionumber
 376     AND issues.borrowernumber = ?
 377     AND TO_DAYS(NOW())-TO_DAYS(date_due) BETWEEN ? and ?
 378 END_SQL
 379
 380     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ";
 381     $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 382     $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 383
 384     my $rqoverduerules =  $dbh->prepare($query);
 385     $rqoverduerules->execute($branchcode, @myborcat, @myborcatout);
 386
 387     # We get default rules is there is no rule for this branch
 388     if($rqoverduerules->rows == 0){
 389         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ";
 390         $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 391         $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 392
 393         $rqoverduerules = $dbh->prepare($query);
 394         $rqoverduerules->execute(@myborcat, @myborcatout);
 395     }
 396
 397     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 398     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 399       PERIOD: foreach my $i ( 1 .. 3 ) {
 400
 401             $verbose and warn "branch '$branchcode', pass $i\n";
 402             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 403             my $maxdays = (
 404                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 405                 ? $overdue_rules->{ "delay" . ( $i + 1 ) }
 406                 : ($MAX)
 407             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 408
 409             if ( !$overdue_rules->{"letter$i"} ) {
 410                 $verbose and warn "No letter$i code for branch '$branchcode'";
 411                 next PERIOD;
 412             }
 413
 414             # $letter->{'content'} is the text of the mail that is sent.
 415             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 416             # The following fields are available :
 417             # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 418             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode>
 419
 420             my $borrower_sql = <<'END_SQL';
 421 SELECT COUNT(*), issues.borrowernumber, firstname, surname, address, address2, city, zipcode, country, email, MIN(date_due) as longest_issue
 422 FROM   issues,borrowers,categories
 423 WHERE  issues.borrowernumber=borrowers.borrowernumber
 424 AND    borrowers.categorycode=categories.categorycode
 425 END_SQL
 426             my @borrower_parameters;
 427             if ($branchcode) {
 428                 $borrower_sql .= ' AND issues.branchcode=? ';
 429                 push @borrower_parameters, $branchcode;
 430             }
 431             if ( $overdue_rules->{categorycode} ) {
 432                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 433                 push @borrower_parameters, $overdue_rules->{categorycode};
 434             }
 435             $borrower_sql .= '  AND categories.overduenoticerequired=1
 436                                 GROUP BY issues.borrowernumber ';
 437             if($triggered) {
 438                 $borrower_sql .= ' HAVING TO_DAYS(NOW())-TO_DAYS(longest_issue) = ?';
 439                 push @borrower_parameters, $mindays;
 440             } else {
 441                 $borrower_sql .= ' HAVING TO_DAYS(NOW())-TO_DAYS(longest_issue) BETWEEN ? and ? ' ;
 442                 push @borrower_parameters, $mindays, $maxdays;
 443             }
 444
 445             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 446                 my $sth = $dbh->prepare($borrower_sql);
 447             $sth->execute(@borrower_parameters);
 448             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays)\nreturns " . $sth->rows . " rows";
 449
 450             while ( my ($itemcount, $borrowernumber, $firstname, $lastname,
 451                     $address1, $address2, $city, $postcode, $country, $email,
 452                     $longest_issue ) = $sth->fetchrow )
 453             {
 454                 $verbose and warn "borrower $firstname, $lastname ($borrowernumber) has $itemcount items triggering level $i.";
 455
 456                 my $letter = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"} );
 457
 458                 unless ($letter) {
 459                     $verbose and warn "Message '$overdue_rules->{letter$i}' content not found";
 460
 461                     # might as well skip while PERIOD, no other borrowers are going to work.
 462                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 463                     next PERIOD;
 464                 }
 465
 466                 if ( $overdue_rules->{"debarred$i"} ) {
 467
 468                     #action taken is debarring
 469                     C4::Members::DebarMember($borrowernumber);
 470                     $verbose and warn "debarring $borrowernumber $firstname $lastname\n";
 471                 }
 472                 my @params = ($listall ? ( $borrowernumber , 1 , $MAX ) : ( $borrowernumber, $mindays, $maxdays ));
 473                 $sth2->execute(@params);
 474                 my $itemcount = 0;
 475                 my $titles = "";
 476                 my @items = ();
 477
 478                 my $i = 0;
 479                 my $exceededPrintNoticesMaxLines = 0;
 480                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 481                     if ( ( !$email || $nomail ) && $PrintNoticesMaxLines && $i >= $PrintNoticesMaxLines ) {
 482                       $exceededPrintNoticesMaxLines = 1;
 483                       last;
 484                     }
 485                     $i++;
 486                     my @item_info = map { $_ =~ /^date|date$/ ? format_date( $item_info->{$_} ) : $item_info->{$_} || '' } @item_content_fields;
 487                     $titles .= join("\t", @item_info) . "\n";
 488                     $itemcount++;
 489                     push (@items, $item_info->{'biblionumber'});
 490                 }
 491                 $sth2->finish;
 492                 $letter = parse_letter(
 493                     {   letter          => $letter,
 494                         borrowernumber  => $borrowernumber,
 495                         branchcode      => $branchcode,
 496                         biblionumber    => \@items,
 497                         substitute      => {    # this appears to be a hack to overcome incomplete features in this code.
 498                                             bib             => $branch_details->{'branchname'}, # maybe 'bib' is a typo for 'lib<rary>'?
 499                                             'items.content' => $titles
 500                                            }
 501                     }
 502                 );
 503
 504                 if ( $exceededPrintNoticesMaxLines ) {
 505                   $letter->{'content'} .= "List too long for form; please check your account online for a complete list of your overdue items.";
 506                 }
 507
 508                 my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 509                 if (@misses) {
 510                     $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 511                 }
 512                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # Now that we've warned about them, remove them.
 513                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # 2nd pass for the double nesting.
 514
 515                 if ($nomail) {
 516
 517                     push @output_chunks,
 518                       prepare_letter_for_printing(
 519                         {   letter         => $letter,
 520                             borrowernumber => $borrowernumber,
 521                             firstname      => $firstname,
 522                             lastname       => $lastname,
 523                             address1       => $address1,
 524                             address2       => $address2,
 525                             city           => $city,
 526                             postcode       => $postcode,
 527                             email          => $email,
 528                             itemcount      => $itemcount,
 529                             titles         => $titles,
 530                             outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : '',
 531                         }
 532                       );
 533                 } else {
 534                     if ($email) {
 535                         C4::Letters::EnqueueLetter(
 536                             {   letter                 => $letter,
 537                                 borrowernumber         => $borrowernumber,
 538                                 message_transport_type => 'email',
 539                                 from_address           => $admin_email_address,
 540                             }
 541                         );
 542                     } else {
 543
 544                         # If we don't have an email address for this patron, send it to the admin to deal with.
 545                         push @output_chunks,
 546                           prepare_letter_for_printing(
 547                             {   letter         => $letter,
 548                                 borrowernumber => $borrowernumber,
 549                                 firstname      => $firstname,
 550                                 lastname       => $lastname,
 551                                 address1       => $address1,
 552                                 address2       => $address2,
 553                                 city           => $city,
 554                                 postcode       => $postcode,
 555                                 email          => $email,
 556                                 itemcount      => $itemcount,
 557                                 titles         => $titles,
 558                                 outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : '',
 559                             }
 560                           );
 561                     }
 562                 }
 563             }
 564             $sth->finish;
 565         }
 566     }
 567
 568     if (@output_chunks) {
 569         if ($nomail) {
 570             if ( defined $csvfilename ) {
 571                 print $csv_fh @output_chunks;
 572             } elsif ( defined $htmlfilename ) {
 573                 print $html_fh @output_chunks;
 574             } else {
 575                 local $, = "\f";    # pagebreak
 576                 print @output_chunks;
 577             }
 578         }
 579         elsif ( defined $htmlfilename ) {
 580             print $html_fh @output_chunks;
 581         }
 582         else {
 583             my $attachment = {
 584                 filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 585                 type => 'text/plain',
 586                 content => join( "\n", @output_chunks )
 587             };
 588
 589             my $letter = {
 590                 title   => 'Overdue Notices',
 591                 content => 'These messages were not sent directly to the patrons.',
 592             };
 593             C4::Letters::EnqueueLetter(
 594                 {   letter                 => $letter,
 595                     borrowernumber         => undef,
 596                     message_transport_type => 'email',
 597                     attachments            => [$attachment],
 598                     to_address             => $admin_email_address,
 599                 }
 600             );
 601         }
 602     }
 603
 604 }
 605 if ($csvfilename) {
 606     # note that we're not testing on $csv_fh to prevent closing
 607     # STDOUT.
 608     close $csv_fh;
 609 }
 610
 611 if ( defined $htmlfilename ) {
 612   print $html_fh "</body>\n";
 613   print $html_fh "</html>\n";
 614   close $html_fh;
 615 }
 616
 617 =head1 INTERNAL METHODS
 618
 619 These methods are internal to the operation of overdue_notices.pl.
 620
 621 =head2 parse_letter
 622
 623 parses the letter template, replacing the placeholders with data
 624 specific to this patron, biblio, or item
 625
 626 named parameters:
 627   letter - required hashref
 628   borrowernumber - required integer
 629   substitute - optional hashref of other key/value pairs that should
 630     be substituted in the letter content
 631
 632 returns the C<letter> hashref, with the content updated to reflect the
 633 substituted keys and values.
 634
 635
 636 =cut
 637
 638 sub parse_letter { # FIXME: this code should probably be moved to C4::Letters:parseletter
 639     my $params = shift;
 640     foreach my $required (qw( letter borrowernumber )) {
 641         return unless exists $params->{$required};
 642     }
 643
 644
 645     if ( $params->{'substitute'} ) {
 646         while ( my ( $key, $replacedby ) = each %{ $params->{'substitute'} } ) {
 647             my $replacefield = "<<$key>>";
 648             $params->{'letter'}->{title}   =~ s/$replacefield/$replacedby/g;
 649             $params->{'letter'}->{content} =~ s/$replacefield/$replacedby/g;
 650         }
 651     }
 652
 653     $params->{'letter'} = C4::Letters::parseletter( $params->{'letter'}, 'borrowers', $params->{'borrowernumber'} );
 654
 655     if ( $params->{'branchcode'} ) {
 656         $params->{'letter'} = C4::Letters::parseletter( $params->{'letter'}, 'branches', $params->{'branchcode'} );
 657     }
 658
 659     if ( $params->{'biblionumber'} ) {
 660         my $item_format = '';
 661         PROCESS_ITEMS:
 662         while (scalar(@{$params->{'biblionumber'}}) > 0) {
 663             my $item = shift @{$params->{'biblionumber'}};
 664             my $fine = GetFine($item, $params->{'borrowernumber'});
 665             if (!$item_format) {
 666                 $params->{'letter'}->{'content'} =~ m/(<item>.*<\/item>)/;
 667                 $item_format = $1;
 668             }
 669             if ($params->{'letter'}->{'content'} =~ m/<fine>(.*)<\/fine>/) { # process any fine tags...
 670                 no strict; # currency_format behaves badly if we quote the bareword for some reason...
 671                 my $formatted_fine = currency_format("$1", "$fine", FMT_SYMBOL);
 672                 use strict;
 673                 $formatted_fine = Encode::encode("utf8", $formatted_fine);
 674                 $params->{'letter'}->{'content'} =~ s/<fine>.*<\/fine>/$formatted_fine/;
 675             }
 676             $params->{'letter'} = C4::Letters::parseletter( $params->{'letter'}, 'biblio',      $item );
 677             $params->{'letter'} = C4::Letters::parseletter( $params->{'letter'}, 'biblioitems', $item );
 678             $params->{'letter'} = C4::Letters::parseletter( $params->{'letter'}, 'items', $item );
 679             $params->{'letter'}->{'content'} =~ s/(<item>.*<\/item>)/$1\n$item_format/ if scalar(@{$params->{'biblionumber'}} > 0);
 680
 681         }
 682     }
 683     $params->{'letter'}->{'content'} =~ s/<\/{0,1}?item>//g; # strip all remaining item tags...
 684     return $params->{'letter'};
 685 }
 686
 687 =head2 prepare_letter_for_printing
 688
 689 returns a string of text appropriate for printing in the event that an
 690 overdue notice will not be sent to the patron's email
 691 address. Depending on the desired output format, this may be a CSV
 692 string, or a human-readable representation of the notice.
 693
 694 required parameters:
 695   letter
 696   borrowernumber
 697
 698 optional parameters:
 699   outputformat
 700
 701 =cut
 702
 703 sub prepare_letter_for_printing {
 704     my $params = shift;
 705
 706     return unless ref $params eq 'HASH';
 707
 708     foreach my $required_parameter (qw( letter borrowernumber )) {
 709         return unless defined $params->{$required_parameter};
 710     }
 711
 712     my $return;
 713     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 714         if ($csv->combine(
 715                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 716                 $params->{'city'},      $params->{'email'},    $params->{'itemcount'}, $params->{'titles'}
 717             )
 718           ) {
 719             return $csv->string, "\n";
 720         } else {
 721             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 722         }
 723     } elsif ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'html' ) {
 724       $return = "<pre>\n";
 725       $return .= "$params->{'letter'}->{'content'}\n";
 726       $return .= "\n</pre>\n";
 727     } else {
 728         $return .= "$params->{'letter'}->{'content'}\n";
 729
 730         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 731     }
 732     return $return;
 733 }
 734