misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Liblime
   4 # Copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 BEGIN {
  24
  25     # find Koha's Perl modules
  26     # test carefully before changing this
  27     use FindBin;
  28     eval { require "$FindBin::Bin/../kohalib.pl" };
  29 }
  30
  31 use Getopt::Long;
  32 use Pod::Usage;
  33 use Text::CSV_XS;
  34 use DateTime;
  35 use DateTime::Duration;
  36
  37 use Koha::Script -cron;
  38 use C4::Context;
  39 use C4::Letters;
  40 use C4::Overdues qw(GetFine GetOverdueMessageTransportTypes parse_overdues_letter);
  41 use C4::Log;
  42 use Koha::Patron::Debarments qw(AddUniqueDebarment);
  43 use Koha::DateUtils;
  44 use Koha::Calendar;
  45 use Koha::Libraries;
  46 use Koha::Acquisition::Currencies;
  47 use Koha::Patrons;
  48
  49 =head1 NAME
  50
  51 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  52
  53 =head1 SYNOPSIS
  54
  55 overdue_notices.pl
  56   [ -n ][ -library <branchcode> ][ -library <branchcode> ... ]
  57   [ -max <number of days> ][ -csv [<filename>] ][ -itemscontent <field list> ]
  58   [ -email <email_type> ... ]
  59
  60  Options:
  61    -help                          Brief help message.
  62    -man                           Full documentation.
  63    -v                             Verbose mode.
  64    -n                             No email will be sent.
  65    -max          <days>           Maximum days overdue to deal with.
  66    -library      <branchcode>     Only deal with overdues from this library.
  67                                   (repeatable : several libraries can be given)
  68    -csv          <filename>       Populate CSV file.
  69    -html         <directory>      Output html to a file in the given directory.
  70    -text         <directory>      Output plain text to a file in the given directory.
  71    -itemscontent <list of fields> Item information in templates.
  72    -borcat       <categorycode>   Category code that must be included.
  73    -borcatout    <categorycode>   Category code that must be excluded.
  74    -t                             Only include triggered overdues.
  75    --test                         Run in test mode. No changes will be made on the DB.
  76    -list-all                      List all overdues.
  77    -date         <yyyy-mm-dd>     Emulate overdues run for this date.
  78    -email        <email_type>     Type of email that will be used.
  79                                   Can be 'email', 'emailpro' or 'B_email'. Repeatable.
  80    --frombranch                   Set the from address for the notice to one of 'item-homebranch' or 'item-issuebranch'.
  81
  82 =head1 OPTIONS
  83
  84 =over 8
  85
  86 =item B<-help>
  87
  88 Print a brief help message and exits.
  89
  90 =item B<-man>
  91
  92 Prints the manual page and exits.
  93
  94 =item B<-v>
  95
  96 Verbose. Without this flag set, only fatal errors are reported.
  97
  98 =item B<-n>
  99
 100 Do not send any email. Overdue notices that would have been sent to
 101 the patrons or to the admin are printed to standard out. CSV data (if
 102 the -csv flag is set) is written to standard out or to any csv
 103 filename given.
 104
 105 =item B<-max>
 106
 107 Items older than max days are assumed to be handled somewhere else,
 108 probably the F<longoverdues.pl> script. They are therefore ignored by
 109 this program. No notices are sent for them, and they are not added to
 110 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
 111
 112 =item B<-library>
 113
 114 select overdues for one specific library. Use the value in the
 115 branches.branchcode table. This option can be repeated in order
 116 to select overdues for a group of libraries.
 117
 118 =item B<-csv>
 119
 120 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
 121 sent to standard out or to a filename if provided. Otherwise, only
 122 overdues that could not be emailed are sent in CSV format to the admin.
 123
 124 =item B<-html>
 125
 126 Produces html data. If patron does not have an email address or
 127 -n (no mail) flag is set, an HTML file is generated in the specified
 128 directory. This can be downloaded or further processed by library staff.
 129 The file will be called notices-YYYY-MM-DD.html and placed in the directory
 130 specified.
 131
 132 =item B<-text>
 133
 134 Produces plain text data. If patron does not have an email address or
 135 -n (no mail) flag is set, a text file is generated in the specified
 136 directory. This can be downloaded or further processed by library staff.
 137 The file will be called notices-YYYY-MM-DD.txt and placed in the directory
 138 specified.
 139
 140 =item B<-itemscontent>
 141
 142 comma separated list of fields that get substituted into templates in
 143 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 144 defaults to due date,title,barcode,author
 145
 146 Other possible values come from fields in the biblios, items and
 147 issues tables.
 148
 149 =item B<-borcat>
 150
 151 Repeatable field, that permits to select only some patron categories.
 152
 153 =item B<-borcatout>
 154
 155 Repeatable field, that permits to exclude some patron categories.
 156
 157 =item B<-t> | B<--triggered>
 158
 159 This option causes a notice to be generated if and only if
 160 an item is overdue by the number of days defined in a notice trigger.
 161
 162 By default, a notice is sent each time the script runs, which is suitable for
 163 less frequent run cron script, but requires syncing notice triggers with
 164 the  cron schedule to ensure proper behavior.
 165 Add the --triggered option for daily cron, at the risk of no notice
 166 being generated if the cron fails to run on time.
 167
 168 =item B<-test>
 169
 170 This option makes the script run in test mode.
 171
 172 In test mode, the script won't make any changes on the DB. This is useful
 173 for debugging configuration.
 174
 175 =item B<-list-all>
 176
 177 Default items.content lists only those items that fall in the
 178 range of the currently processing notice.
 179 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 180
 181 =item B<-date>
 182
 183 use it in order to send overdues on a specific date and not Now. Format: YYYY-MM-DD.
 184
 185 =item B<-email>
 186
 187 Allows to specify which type of email will be used. Can be email, emailpro or B_email. Repeatable.
 188
 189 =item B<--frombranch>
 190
 191 Use the address information from the item homebranch library instead of the issuing library.
 192
 193 Defaults to 'item-issuebranch'
 194
 195 =back
 196
 197 =head1 DESCRIPTION
 198
 199 This script is designed to alert patrons and administrators of overdue
 200 items.
 201
 202 =head2 Configuration
 203
 204 This script pays attention to the overdue notice configuration
 205 performed in the "Overdue notice/status triggers" section of the
 206 "Tools" area of the staff interface to Koha. There, you can choose
 207 which letter templates are sent out after a configurable number of
 208 days to patrons of each library. More information about the use of this
 209 section of Koha is available in the Koha manual.
 210
 211 The templates used to craft the emails are defined in the "Tools:
 212 Notices" section of the staff interface to Koha.
 213
 214 =head2 Outgoing emails
 215
 216 Typically, messages are prepared for each patron with overdue
 217 items. Messages for whom there is no email address on file are
 218 collected and sent as attachments in a single email to each library
 219 administrator, or if that is not set, then to the email address in the
 220 C<KohaAdminEmailAddress> system preference.
 221
 222 These emails are staged in the outgoing message queue, as are messages
 223 produced by other features of Koha. This message queue must be
 224 processed regularly by the
 225 F<misc/cronjobs/process_message_queue.pl> program.
 226
 227 In the event that the C<-n> flag is passed to this program, no emails
 228 are sent. Instead, messages are sent on standard output from this
 229 program. They may be redirected to a file if desired.
 230
 231 =head2 Templates
 232
 233 Templates can contain variables enclosed in double angle brackets like
 234 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 235 specific to the overdue items or relevant patron. Available variables
 236 are:
 237
 238 =over
 239
 240 =item E<lt>E<lt>bibE<gt>E<gt>
 241
 242 the name of the library
 243
 244 =item E<lt>E<lt>items.contentE<gt>E<gt>
 245
 246 one line for each item, each line containing a tab separated list of
 247 title, author, barcode, issuedate
 248
 249 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 250
 251 any field from the borrowers table
 252
 253 =item E<lt>E<lt>branches.*E<gt>E<gt>
 254
 255 any field from the branches table
 256
 257 =back
 258
 259 =head2 CSV output
 260
 261 The C<-csv> command line option lets you specify a file to which
 262 overdues data should be output in CSV format.
 263
 264 With the C<-n> flag set, data about all overdues is written to the
 265 file. Without that flag, only information about overdues that were
 266 unable to be sent directly to the patrons will be written. In other
 267 words, this CSV file replaces the data that is typically sent to the
 268 administrator email address.
 269
 270 =head1 USAGE EXAMPLES
 271
 272 C<overdue_notices.pl> - In this most basic usage, with no command line
 273 arguments, all libraries are processed individually, and notices are
 274 prepared for all patrons with overdue items for whom we have email
 275 addresses. Messages for those patrons for whom we have no email
 276 address are sent in a single attachment to the library administrator's
 277 email address, or to the address in the KohaAdminEmailAddress system
 278 preference.
 279
 280 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 281 populates F</tmp/overdues.csv> with information about all overdue
 282 items.
 283
 284 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 285 overdues in the last 2 weeks for the MAIN library.
 286
 287 =head1 SEE ALSO
 288
 289 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 290 messages to patrons in advance of their items becoming due, or to
 291 alert them of items that have just become due.
 292
 293 =cut
 294
 295 # These variables are set by command line options.
 296 # They are initially set to default values.
 297 my $dbh = C4::Context->dbh();
 298 my $help    = 0;
 299 my $man     = 0;
 300 my $verbose = 0;
 301 my $nomail  = 0;
 302 my $MAX     = 90;
 303 my $test_mode = 0;
 304 my $frombranch = 'item-issuebranch';
 305 my @branchcodes; # Branch(es) passed as parameter
 306 my @emails_to_use;    # Emails to use for messaging
 307 my @emails;           # Emails given in command-line parameters
 308 my $csvfilename;
 309 my $htmlfilename;
 310 my $text_filename;
 311 my $triggered = 0;
 312 my $listall = 0;
 313 my $itemscontent = join( ',', qw( date_due title barcode author itemnumber ) );
 314 my @myborcat;
 315 my @myborcatout;
 316 my ( $date_input, $today );
 317
 318 GetOptions(
 319     'help|?'         => \$help,
 320     'man'            => \$man,
 321     'v'              => \$verbose,
 322     'n'              => \$nomail,
 323     'max=s'          => \$MAX,
 324     'library=s'      => \@branchcodes,
 325     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 326     'html:s'         => \$htmlfilename,    # this optional argument gets '' if not supplied.
 327     'text:s'         => \$text_filename,    # this optional argument gets '' if not supplied.
 328     'itemscontent=s' => \$itemscontent,
 329     'list-all'       => \$listall,
 330     't|triggered'    => \$triggered,
 331     'test'           => \$test_mode,
 332     'date=s'         => \$date_input,
 333     'borcat=s'       => \@myborcat,
 334     'borcatout=s'    => \@myborcatout,
 335     'email=s'        => \@emails,
 336     'frombranch=s'   => \$frombranch,
 337 ) or pod2usage(2);
 338 pod2usage(1) if $help;
 339 pod2usage( -verbose => 2 ) if $man;
 340 cronlogaction() unless $test_mode;
 341
 342 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 343     warn qq(using "$csvfilename" as filename, that seems odd);
 344 }
 345
 346 die "--frombranch takes item-homebranch or item-issuebranch only"
 347     unless ( $frombranch eq 'item-issuebranch'
 348         || $frombranch eq 'item-homebranch' );
 349 my $owning_library = ( $frombranch eq 'item-homebranch' ) ? 1 : 0;
 350
 351 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();    # Branches with overdue rules
 352 my @branches;                                    # Branches passed as parameter with overdue rules
 353 my $branchcount = scalar(@overduebranches);
 354
 355 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 356 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 357
 358 my $PrintNoticesMaxLines = C4::Context->preference('PrintNoticesMaxLines');
 359
 360 if ($branchcount) {
 361     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 362 } else {
 363     die 'No branches with active overduerules';
 364 }
 365
 366 if (@branchcodes) {
 367     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 368
 369     # Getting libraries which have overdue rules
 370     my %seen = map { $_ => 1 } @branchcodes;
 371     @branches = grep { $seen{$_} } @overduebranches;
 372
 373
 374     if (@branches) {
 375
 376         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 377     $verbose and warn "$branch_word @branches have overdue rules\n";
 378
 379     } else {
 380
 381         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 382         ( scalar grep { '' eq $_ } @branches )
 383           or die "No active overduerules for DEFAULT either!";
 384         $verbose and warn "Falling back on default rules for @branchcodes\n";
 385         @branches = ('');
 386     }
 387 }
 388 my $date_to_run;
 389 my $date;
 390 if ( $date_input ){
 391     eval {
 392         $date_to_run = dt_from_string( $date_input, 'iso' );
 393     };
 394     die "$date_input is not a valid date, aborting! Use a date in format YYYY-MM-DD."
 395         if $@ or not $date_to_run;
 396
 397     # It's certainly useless to escape $date_input
 398     # dt_from_string should not return something if $date_input is not correctly set.
 399     $date = $dbh->quote( $date_input );
 400 }
 401 else {
 402     $date="NOW()";
 403     $date_to_run = dt_from_string();
 404 }
 405
 406 # these are the fields that will be substituted into <<item.content>>
 407 my @item_content_fields = split( /,/, $itemscontent );
 408
 409 binmode( STDOUT, ':encoding(UTF-8)' );
 410
 411
 412 our $csv;       # the Text::CSV_XS object
 413 our $csv_fh;    # the filehandle to the CSV file.
 414 if ( defined $csvfilename ) {
 415     my $sep_char = C4::Context->preference('CSVDelimiter') || ';';
 416     $sep_char = "\t" if ($sep_char eq 'tabulation');
 417     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 418     if ( $csvfilename eq '' ) {
 419         $csv_fh = *STDOUT;
 420     } else {
 421         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 422     }
 423     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email phone cardnumber itemcount itemsinfo branchname letternumber)) ) {
 424         print $csv_fh $csv->string, "\n";
 425     } else {
 426         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 427     }
 428 }
 429
 430 @branches = @overduebranches unless @branches;
 431 our $fh;
 432 if ( defined $htmlfilename ) {
 433   if ( $htmlfilename eq '' ) {
 434     $fh = *STDOUT;
 435   } else {
 436     my $today = dt_from_string();
 437     open $fh, ">:encoding(UTF-8)",File::Spec->catdir ($htmlfilename,"notices-".$today->ymd().".html");
 438   }
 439
 440   print $fh "<html>\n";
 441   print $fh "<head>\n";
 442   print $fh "<meta http-equiv=\"Content-Type\" content=\"text/html; charset=utf-8\" />\n";
 443   print $fh "<style type='text/css'>\n";
 444   print $fh "pre {page-break-after: always;}\n";
 445   print $fh "pre {white-space: pre-wrap;}\n";
 446   print $fh "pre {white-space: -moz-pre-wrap;}\n";
 447   print $fh "pre {white-space: -o-pre-wrap;}\n";
 448   print $fh "pre {word-wrap: break-work;}\n";
 449   print $fh "</style>\n";
 450   print $fh "</head>\n";
 451   print $fh "<body>\n";
 452 }
 453 elsif ( defined $text_filename ) {
 454   if ( $text_filename eq '' ) {
 455     $fh = *STDOUT;
 456   } else {
 457     my $today = dt_from_string();
 458     open $fh, ">:encoding(UTF-8)",File::Spec->catdir ($text_filename,"notices-".$today->ymd().".txt");
 459   }
 460 }
 461
 462 foreach my $branchcode (@branches) {
 463     my $calendar;
 464     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 465         $calendar = Koha::Calendar->new( branchcode => $branchcode );
 466         if ( $calendar->is_holiday($date_to_run) ) {
 467             next;
 468         }
 469     }
 470
 471     my $library             = Koha::Libraries->find($branchcode);
 472     my $admin_email_address = $library->from_email_address;
 473     my $branch_email_address = C4::Context->preference('AddressForFailedOverdueNotices')
 474       || $library->inbound_email_address;
 475     my @output_chunks;    # may be sent to mail or stdout or csv file.
 476
 477     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $branch_email_address;
 478
 479     my $sql2 = <<"END_SQL";
 480 SELECT biblio.*, items.*, issues.*, biblioitems.itemtype, branchname
 481   FROM issues,items,biblio, biblioitems, branches b
 482   WHERE items.itemnumber=issues.itemnumber
 483     AND biblio.biblionumber   = items.biblionumber
 484     AND b.branchcode = items.homebranch
 485     AND biblio.biblionumber   = biblioitems.biblionumber
 486     AND issues.borrowernumber = ?
 487     AND items.itemlost = 0
 488     AND TO_DAYS($date)-TO_DAYS(issues.date_due) >= 0
 489 END_SQL
 490
 491     if($owning_library) {
 492       $sql2 .= ' AND items.homebranch = ? ';
 493     } else {
 494       $sql2 .= ' AND issues.branchcode = ? ';
 495     }
 496     my $sth2 = $dbh->prepare($sql2);
 497
 498     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ";
 499     $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 500     $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 501
 502     my $rqoverduerules =  $dbh->prepare($query);
 503     $rqoverduerules->execute($branchcode, @myborcat, @myborcatout);
 504
 505     # We get default rules is there is no rule for this branch
 506     if($rqoverduerules->rows == 0){
 507         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ";
 508         $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 509         $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 510
 511         $rqoverduerules = $dbh->prepare($query);
 512         $rqoverduerules->execute(@myborcat, @myborcatout);
 513     }
 514
 515     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 516     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 517       PERIOD: foreach my $i ( 1 .. 3 ) {
 518
 519             $verbose and warn "branch '$branchcode', categorycode = $overdue_rules->{categorycode} pass $i\n";
 520
 521             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 522             my $maxdays = (
 523                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 524                 ? $overdue_rules->{ "delay" . ( $i + 1 ) } - 1
 525                 : ($MAX)
 526             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 527
 528             next unless defined $mindays;
 529
 530             if ( !$overdue_rules->{"letter$i"} ) {
 531                 $verbose and warn "No letter$i code for branch '$branchcode'";
 532                 next PERIOD;
 533             }
 534
 535             # $letter->{'content'} is the text of the mail that is sent.
 536             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 537             # The following fields are available :
 538         # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 539             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode> <country>
 540
 541             my $borrower_sql = <<"END_SQL";
 542 SELECT issues.borrowernumber, firstname, surname, address, address2, city, zipcode, country, email, emailpro, B_email, smsalertnumber, phone, cardnumber, date_due
 543 FROM   issues,borrowers,categories,items
 544 WHERE  issues.borrowernumber=borrowers.borrowernumber
 545 AND    borrowers.categorycode=categories.categorycode
 546 AND    issues.itemnumber = items.itemnumber
 547 AND    items.itemlost = 0
 548 AND    TO_DAYS($date)-TO_DAYS(issues.date_due) >= 0
 549 END_SQL
 550             my @borrower_parameters;
 551             if ($branchcode) {
 552         if($owning_library) {
 553             $borrower_sql .= ' AND items.homebranch=? ';
 554         } else {
 555             $borrower_sql .= ' AND issues.branchcode=? ';
 556         }
 557                 push @borrower_parameters, $branchcode;
 558             }
 559             if ( $overdue_rules->{categorycode} ) {
 560                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 561                 push @borrower_parameters, $overdue_rules->{categorycode};
 562             }
 563             $borrower_sql .= '  AND categories.overduenoticerequired=1 ORDER BY issues.borrowernumber';
 564
 565             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 566             my $sth = $dbh->prepare($borrower_sql);
 567             $sth->execute(@borrower_parameters);
 568
 569             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays, ".  $date_to_run->datetime() .")\nreturns " . $sth->rows . " rows";
 570             my $borrowernumber;
 571             while ( my $data = $sth->fetchrow_hashref ) {
 572
 573                 # check the borrower has at least one item that matches
 574                 my $days_between;
 575                 if ( C4::Context->preference('OverdueNoticeCalendar') )
 576                 {
 577                     $days_between =
 578                       $calendar->days_between( dt_from_string($data->{date_due}),
 579                         $date_to_run );
 580                 }
 581                 else {
 582                     $days_between =
 583                       $date_to_run->delta_days( dt_from_string($data->{date_due}) );
 584                 }
 585                 $days_between = $days_between->in_units('days');
 586                 if ($triggered) {
 587                     if ( $mindays != $days_between ) {
 588                         next;
 589                     }
 590                 }
 591                 else {
 592                     unless (   $days_between >= $mindays
 593                         && $days_between <= $maxdays )
 594                     {
 595                         next;
 596                     }
 597                 }
 598                 if (defined $borrowernumber && $borrowernumber eq $data->{'borrowernumber'}){
 599 # we have already dealt with this borrower
 600                     $verbose and warn "already dealt with this borrower $borrowernumber";
 601                     next;
 602                 }
 603                 $borrowernumber = $data->{'borrowernumber'};
 604                 my $borr = sprintf( "%s%s%s (%s)",
 605                     $data->{'surname'} || '',
 606                     $data->{'firstname'} && $data->{'surname'} ? ', ' : '',
 607                     $data->{'firstname'} || '',
 608                     $borrowernumber );
 609                 $verbose
 610                   and warn "borrower $borr has items triggering level $i.";
 611
 612                 my $patron = Koha::Patrons->find( $borrowernumber );
 613                 @emails_to_use = ();
 614                 my $notice_email = $patron->notice_email_address;
 615                 unless ($nomail) {
 616                     if (@emails) {
 617                         foreach (@emails) {
 618                             push @emails_to_use, $data->{$_} if ( $data->{$_} );
 619                         }
 620                     }
 621                     else {
 622                         push @emails_to_use, $notice_email if ($notice_email);
 623                     }
 624                 }
 625
 626                 my $letter = Koha::Notice::Templates->find_effective_template(
 627                     {
 628                         module     => 'circulation',
 629                         code       => $overdue_rules->{"letter$i"},
 630                         branchcode => $branchcode,
 631                         lang       => $patron->lang
 632                     }
 633                 );
 634
 635                 unless ($letter) {
 636                     $verbose and warn qq|Message '$overdue_rules->{"letter$i"}' content not found|;
 637
 638                     # might as well skip while PERIOD, no other borrowers are going to work.
 639                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 640                     next PERIOD;
 641                 }
 642
 643                 if ( $overdue_rules->{"debarred$i"} ) {
 644
 645                     #action taken is debarring
 646                     AddUniqueDebarment(
 647                         {
 648                             borrowernumber => $borrowernumber,
 649                             type           => 'OVERDUES',
 650                             comment => "OVERDUES_PROCESS " .  output_pref( dt_from_string() ),
 651                         }
 652                     ) unless $test_mode;
 653                     $verbose and warn "debarring $borr\n";
 654                 }
 655                 my @params = ($borrowernumber,$branchcode);
 656                 $verbose and warn "STH2 PARAMS: borrowernumber = $borrowernumber";
 657
 658                 $sth2->execute(@params);
 659                 my $itemcount = 0;
 660                 my $titles = "";
 661                 my @items = ();
 662
 663                 my $j = 0;
 664                 my $exceededPrintNoticesMaxLines = 0;
 665                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 666                     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 667                         $days_between =
 668                           $calendar->days_between(
 669                             dt_from_string( $item_info->{date_due} ), $date_to_run );
 670                     }
 671                     else {
 672                         $days_between =
 673                           $date_to_run->delta_days(
 674                             dt_from_string( $item_info->{date_due} ) );
 675                     }
 676                     $days_between = $days_between->in_units('days');
 677                     if ($listall){
 678                         unless ($days_between >= 1 and $days_between <= $MAX){
 679                             next;
 680                         }
 681                     }
 682                     else {
 683                         if ($triggered) {
 684                             if ( $mindays != $days_between ) {
 685                                 next;
 686                             }
 687                         }
 688                         else {
 689                             unless ( $days_between >= $mindays
 690                                 && $days_between <= $maxdays )
 691                             {
 692                                 next;
 693                             }
 694                         }
 695                     }
 696
 697                     if ( ( scalar(@emails_to_use) == 0 || $nomail ) && $PrintNoticesMaxLines && $j >= $PrintNoticesMaxLines ) {
 698                       $exceededPrintNoticesMaxLines = 1;
 699                       last;
 700                     }
 701                     $j++;
 702
 703                     $titles .= C4::Letters::get_item_content( { item => $item_info, item_content_fields => \@item_content_fields, dateonly => 1 } );
 704                     $itemcount++;
 705                     push @items, $item_info;
 706                 }
 707                 $sth2->finish;
 708
 709                 my @message_transport_types = @{ GetOverdueMessageTransportTypes( $branchcode, $overdue_rules->{categorycode}, $i) };
 710                 @message_transport_types = @{ GetOverdueMessageTransportTypes( q{}, $overdue_rules->{categorycode}, $i) }
 711                     unless @message_transport_types;
 712
 713
 714                 my $print_sent = 0; # A print notice is not yet sent for this patron
 715                 for my $mtt ( @message_transport_types ) {
 716                     my $effective_mtt = $mtt;
 717                     if ( ($mtt eq 'email' and not scalar @emails_to_use) or ($mtt eq 'sms' and not $data->{smsalertnumber}) ) {
 718                         # email or sms is requested but not exist, do a print.
 719                         $effective_mtt = 'print';
 720                     }
 721                     splice @items, $PrintNoticesMaxLines if $effective_mtt eq 'print' && $PrintNoticesMaxLines && scalar @items > $PrintNoticesMaxLines;
 722                     #catch the case where we are sending a print to someone with an email
 723
 724                     my $letter_exists = Koha::Notice::Templates->find_effective_template(
 725                         {
 726                             module     => 'circulation',
 727                             code       => $overdue_rules->{"letter$i"},
 728                             message_transport_type => $effective_mtt,
 729                             branchcode => $branchcode,
 730                             lang       => $patron->lang
 731                         }
 732                     );
 733
 734                     my $letter = parse_overdues_letter(
 735                         {   letter_code     => $overdue_rules->{"letter$i"},
 736                             borrowernumber  => $borrowernumber,
 737                             branchcode      => $branchcode,
 738                             items           => \@items,
 739                             substitute      => {    # this appears to be a hack to overcome incomplete features in this code.
 740                                                 bib             => $library->branchname, # maybe 'bib' is a typo for 'lib<rary>'?
 741                                                 'items.content' => $titles,
 742                                                 'count'         => $itemcount,
 743                                                },
 744                             # If there is no template defined for the requested letter
 745                             # Fallback on the original type
 746                             message_transport_type => $letter_exists ? $effective_mtt : $mtt,
 747                         }
 748                     );
 749                     unless ($letter && $letter->{content}) {
 750                         $verbose and warn qq|Message '$overdue_rules->{"letter$i"}' content not found|;
 751                         # this transport doesn't have a configured notice, so try another
 752                         next;
 753                     }
 754
 755                     if ( $exceededPrintNoticesMaxLines ) {
 756                       $letter->{'content'} .= "List too long for form; please check your account online for a complete list of your overdue items.";
 757                     }
 758
 759                     my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 760                     if (@misses) {
 761                         $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 762                     }
 763
 764                     if ($nomail) {
 765                         push @output_chunks,
 766                           prepare_letter_for_printing(
 767                           {   letter         => $letter,
 768                               borrowernumber => $borrowernumber,
 769                               firstname      => $data->{'firstname'},
 770                               lastname       => $data->{'surname'},
 771                               address1       => $data->{'address'},
 772                               address2       => $data->{'address2'},
 773                               city           => $data->{'city'},
 774                               phone          => $data->{'phone'},
 775                               cardnumber     => $data->{'cardnumber'},
 776                               branchname     => $library->branchname,
 777                               letternumber   => $i,
 778                               postcode       => $data->{'zipcode'},
 779                               country        => $data->{'country'},
 780                               email          => $notice_email,
 781                               itemcount      => $itemcount,
 782                               titles         => $titles,
 783                               outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 784                             }
 785                           );
 786                     } else {
 787                         if ( ($mtt eq 'email' and not scalar @emails_to_use) or ($mtt eq 'sms' and not $data->{smsalertnumber}) ) {
 788                             push @output_chunks,
 789                               prepare_letter_for_printing(
 790                               {   letter         => $letter,
 791                                   borrowernumber => $borrowernumber,
 792                                   firstname      => $data->{'firstname'},
 793                                   lastname       => $data->{'surname'},
 794                                   address1       => $data->{'address'},
 795                                   address2       => $data->{'address2'},
 796                                   city           => $data->{'city'},
 797                                   postcode       => $data->{'zipcode'},
 798                                   country        => $data->{'country'},
 799                                   email          => $notice_email,
 800                                   itemcount      => $itemcount,
 801                                   titles         => $titles,
 802                                   outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 803                                 }
 804                               );
 805                         }
 806                         unless ( $effective_mtt eq 'print' and $print_sent == 1 ) {
 807                             # Just sent a print if not already done.
 808                             C4::Letters::EnqueueLetter(
 809                                 {   letter                 => $letter,
 810                                     borrowernumber         => $borrowernumber,
 811                                     message_transport_type => $effective_mtt,
 812                                     from_address           => $admin_email_address,
 813                                     to_address             => join(',', @emails_to_use),
 814                                 }
 815                             ) unless $test_mode;
 816                             # A print notice should be sent only once per overdue level.
 817                             # Without this check, a print could be sent twice or more if the library checks sms and email and print and the patron has no email or sms number.
 818                             $print_sent = 1 if $effective_mtt eq 'print';
 819                         }
 820                     }
 821                 }
 822             }
 823             $sth->finish;
 824         }
 825     }
 826
 827     if (@output_chunks) {
 828         if ( defined $csvfilename ) {
 829             print $csv_fh @output_chunks;
 830         }
 831         elsif ( defined $htmlfilename ) {
 832             print $fh @output_chunks;
 833         }
 834         elsif ( defined $text_filename ) {
 835             print $fh @output_chunks;
 836         }
 837         elsif ($nomail){
 838                 local $, = "\f";    # pagebreak
 839                 print @output_chunks;
 840         }
 841         # Generate the content of the csv with headers
 842         my $content;
 843         if ( defined $csvfilename ) {
 844             my $delimiter = C4::Context->preference('CSVDelimiter') || ';';
 845             $content = join($delimiter, qw(title name surname address1 address2 zipcode city country email itemcount itemsinfo due_date issue_date)) . "\n";
 846         }
 847         else {
 848             $content = "";
 849         }
 850         $content .= join( "\n", @output_chunks );
 851
 852         my $attachment = {
 853             filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 854             type => 'text/plain',
 855             content => $content,
 856         };
 857
 858         my $letter = {
 859             title   => 'Overdue Notices',
 860             content => 'These messages were not sent directly to the patrons.',
 861         };
 862
 863         C4::Letters::EnqueueLetter(
 864             {   letter                 => $letter,
 865                 borrowernumber         => undef,
 866                 message_transport_type => 'email',
 867                 attachments            => [$attachment],
 868                 to_address             => $branch_email_address,
 869             }
 870         ) unless $test_mode;
 871     }
 872
 873 }
 874 if ($csvfilename) {
 875     # note that we're not testing on $csv_fh to prevent closing
 876     # STDOUT.
 877     close $csv_fh;
 878 }
 879
 880 if ( defined $htmlfilename ) {
 881   print $fh "</body>\n";
 882   print $fh "</html>\n";
 883   close $fh;
 884 } elsif ( defined $text_filename ) {
 885   close $fh;
 886 }
 887
 888 =head1 INTERNAL METHODS
 889
 890 These methods are internal to the operation of overdue_notices.pl.
 891
 892 =head2 prepare_letter_for_printing
 893
 894 returns a string of text appropriate for printing in the event that an
 895 overdue notice will not be sent to the patron's email
 896 address. Depending on the desired output format, this may be a CSV
 897 string, or a human-readable representation of the notice.
 898
 899 required parameters:
 900   letter
 901   borrowernumber
 902
 903 optional parameters:
 904   outputformat
 905
 906 =cut
 907
 908 sub prepare_letter_for_printing {
 909     my $params = shift;
 910
 911     return unless ref $params eq 'HASH';
 912
 913     foreach my $required_parameter (qw( letter borrowernumber )) {
 914         return unless defined $params->{$required_parameter};
 915     }
 916
 917     my $return;
 918     chomp $params->{titles};
 919     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 920         if ($csv->combine(
 921                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 922                 $params->{'city'}, $params->{'country'}, $params->{'email'}, $params->{'phone'}, $params->{'cardnumber'},
 923                 $params->{'itemcount'}, $params->{'titles'}, $params->{'branchname'}, $params->{'letternumber'}
 924             )
 925           ) {
 926             return $csv->string, "\n";
 927         } else {
 928             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 929         }
 930     } elsif ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'html' ) {
 931       $return = "<pre>\n";
 932       $return .= "$params->{'letter'}->{'content'}\n";
 933       $return .= "\n</pre>\n";
 934     } else {
 935         $return .= "$params->{'letter'}->{'content'}\n";
 936
 937         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 938     }
 939     return $return;
 940 }
 941