misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Liblime
   4 # Copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 BEGIN {
  24
  25     # find Koha's Perl modules
  26     # test carefully before changing this
  27     use FindBin;
  28     eval { require "$FindBin::Bin/../kohalib.pl" };
  29 }
  30
  31 use Getopt::Long;
  32 use Pod::Usage;
  33 use Text::CSV_XS;
  34 use DateTime;
  35 use DateTime::Duration;
  36
  37 use C4::Context;
  38 use C4::Letters;
  39 use C4::Overdues qw(GetFine GetOverdueMessageTransportTypes parse_overdues_letter);
  40 use C4::Log;
  41 use Koha::Borrower::Debarments qw(AddUniqueDebarment);
  42 use Koha::DateUtils;
  43 use Koha::Calendar;
  44
  45 =head1 NAME
  46
  47 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  48
  49 =head1 SYNOPSIS
  50
  51 overdue_notices.pl
  52   [ -n ][ -library <branchcode> ][ -library <branchcode> ... ]
  53   [ -max <number of days> ][ -csv [<filename>] ][ -itemscontent <field list> ]
  54   [ -email <email_type> ... ]
  55
  56  Options:
  57    -help                          brief help message
  58    -man                           full documentation
  59    -v                             verbose
  60    -n                             No email will be sent
  61    -max          <days>           maximum days overdue to deal with
  62    -library      <branchname>     only deal with overdues from this library (repeatable : several libraries can be given)
  63    -csv          <filename>       populate CSV file
  64    -html         <directory>      Output html to a file in the given directory
  65    -text         <directory>      Output plain text to a file in the given directory
  66    -itemscontent <list of fields> item information in templates
  67    -borcat       <categorycode>   category code that must be included
  68    -borcatout    <categorycode>   category code that must be excluded
  69    -t                             only include triggered overdues
  70    -list-all                      list all overdues
  71    -date         <yyyy-mm-dd>     emulate overdues run for this date
  72    -email        <email_type>     type of email that will be used. Can be 'email', 'emailpro' or 'B_email'. Repeatable.
  73
  74 =head1 OPTIONS
  75
  76 =over 8
  77
  78 =item B<-help>
  79
  80 Print a brief help message and exits.
  81
  82 =item B<-man>
  83
  84 Prints the manual page and exits.
  85
  86 =item B<-v>
  87
  88 Verbose. Without this flag set, only fatal errors are reported.
  89
  90 =item B<-n>
  91
  92 Do not send any email. Overdue notices that would have been sent to
  93 the patrons or to the admin are printed to standard out. CSV data (if
  94 the -csv flag is set) is written to standard out or to any csv
  95 filename given.
  96
  97 =item B<-max>
  98
  99 Items older than max days are assumed to be handled somewhere else,
 100 probably the F<longoverdues.pl> script. They are therefore ignored by
 101 this program. No notices are sent for them, and they are not added to
 102 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
 103
 104 =item B<-library>
 105
 106 select overdues for one specific library. Use the value in the
 107 branches.branchcode table. This option can be repeated in order
 108 to select overdues for a group of libraries.
 109
 110 =item B<-csv>
 111
 112 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
 113 sent to standard out or to a filename if provided. Otherwise, only
 114 overdues that could not be emailed are sent in CSV format to the admin.
 115
 116 =item B<-html>
 117
 118 Produces html data. If patron does not have an email address or
 119 -n (no mail) flag is set, an HTML file is generated in the specified
 120 directory. This can be downloaded or further processed by library staff.
 121 The file will be called notices-YYYY-MM-DD.html and placed in the directory
 122 specified.
 123
 124 =item B<-text>
 125
 126 Produces plain text data. If patron does not have an email address or
 127 -n (no mail) flag is set, a text file is generated in the specified
 128 directory. This can be downloaded or further processed by library staff.
 129 The file will be called notices-YYYY-MM-DD.txt and placed in the directory
 130 specified.
 131
 132 =item B<-itemscontent>
 133
 134 comma separated list of fields that get substituted into templates in
 135 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 136 defaults to due date,title,barcode,author
 137
 138 Other possible values come from fields in the biblios, items and
 139 issues tables.
 140
 141 =item B<-borcat>
 142
 143 Repeatable field, that permits to select only some patron categories.
 144
 145 =item B<-borcatout>
 146
 147 Repeatable field, that permits to exclude some patron categories.
 148
 149 =item B<-t> | B<--triggered>
 150
 151 This option causes a notice to be generated if and only if
 152 an item is overdue by the number of days defined in a notice trigger.
 153
 154 By default, a notice is sent each time the script runs, which is suitable for
 155 less frequent run cron script, but requires syncing notice triggers with
 156 the  cron schedule to ensure proper behavior.
 157 Add the --triggered option for daily cron, at the risk of no notice
 158 being generated if the cron fails to run on time.
 159
 160 =item B<-list-all>
 161
 162 Default items.content lists only those items that fall in the
 163 range of the currently processing notice.
 164 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 165
 166 =item B<-date>
 167
 168 use it in order to send overdues on a specific date and not Now. Format: YYYY-MM-DD.
 169
 170 =item B<-email>
 171
 172 Allows to specify which type of email will be used. Can be email, emailpro or B_email. Repeatable.
 173
 174 =back
 175
 176 =head1 DESCRIPTION
 177
 178 This script is designed to alert patrons and administrators of overdue
 179 items.
 180
 181 =head2 Configuration
 182
 183 This script pays attention to the overdue notice configuration
 184 performed in the "Overdue notice/status triggers" section of the
 185 "Tools" area of the staff interface to Koha. There, you can choose
 186 which letter templates are sent out after a configurable number of
 187 days to patrons of each library. More information about the use of this
 188 section of Koha is available in the Koha manual.
 189
 190 The templates used to craft the emails are defined in the "Tools:
 191 Notices" section of the staff interface to Koha.
 192
 193 =head2 Outgoing emails
 194
 195 Typically, messages are prepared for each patron with overdue
 196 items. Messages for whom there is no email address on file are
 197 collected and sent as attachments in a single email to each library
 198 administrator, or if that is not set, then to the email address in the
 199 C<KohaAdminEmailAddress> system preference.
 200
 201 These emails are staged in the outgoing message queue, as are messages
 202 produced by other features of Koha. This message queue must be
 203 processed regularly by the
 204 F<misc/cronjobs/process_message_queue.pl> program.
 205
 206 In the event that the C<-n> flag is passed to this program, no emails
 207 are sent. Instead, messages are sent on standard output from this
 208 program. They may be redirected to a file if desired.
 209
 210 =head2 Templates
 211
 212 Templates can contain variables enclosed in double angle brackets like
 213 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 214 specific to the overdue items or relevant patron. Available variables
 215 are:
 216
 217 =over
 218
 219 =item E<lt>E<lt>bibE<gt>E<gt>
 220
 221 the name of the library
 222
 223 =item E<lt>E<lt>items.contentE<gt>E<gt>
 224
 225 one line for each item, each line containing a tab separated list of
 226 title, author, barcode, issuedate
 227
 228 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 229
 230 any field from the borrowers table
 231
 232 =item E<lt>E<lt>branches.*E<gt>E<gt>
 233
 234 any field from the branches table
 235
 236 =back
 237
 238 =head2 CSV output
 239
 240 The C<-csv> command line option lets you specify a file to which
 241 overdues data should be output in CSV format.
 242
 243 With the C<-n> flag set, data about all overdues is written to the
 244 file. Without that flag, only information about overdues that were
 245 unable to be sent directly to the patrons will be written. In other
 246 words, this CSV file replaces the data that is typically sent to the
 247 administrator email address.
 248
 249 =head1 USAGE EXAMPLES
 250
 251 C<overdue_notices.pl> - In this most basic usage, with no command line
 252 arguments, all libraries are processed individually, and notices are
 253 prepared for all patrons with overdue items for whom we have email
 254 addresses. Messages for those patrons for whom we have no email
 255 address are sent in a single attachment to the library administrator's
 256 email address, or to the address in the KohaAdminEmailAddress system
 257 preference.
 258
 259 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 260 populates F</tmp/overdues.csv> with information about all overdue
 261 items.
 262
 263 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 264 overdues in the last 2 weeks for the MAIN library.
 265
 266 =head1 SEE ALSO
 267
 268 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 269 messages to patrons in advance of their items becoming due, or to
 270 alert them of items that have just become due.
 271
 272 =cut
 273
 274 # These variables are set by command line options.
 275 # They are initially set to default values.
 276 my $dbh = C4::Context->dbh();
 277 my $help    = 0;
 278 my $man     = 0;
 279 my $verbose = 0;
 280 my $nomail  = 0;
 281 my $MAX     = 90;
 282 my @branchcodes; # Branch(es) passed as parameter
 283 my @emails_to_use;    # Emails to use for messaging
 284 my @emails;           # Emails given in command-line parameters
 285 my $csvfilename;
 286 my $htmlfilename;
 287 my $text_filename;
 288 my $triggered = 0;
 289 my $listall = 0;
 290 my $itemscontent = join( ',', qw( date_due title barcode author itemnumber ) );
 291 my @myborcat;
 292 my @myborcatout;
 293 my ( $date_input, $today );
 294
 295 GetOptions(
 296     'help|?'         => \$help,
 297     'man'            => \$man,
 298     'v'              => \$verbose,
 299     'n'              => \$nomail,
 300     'max=s'          => \$MAX,
 301     'library=s'      => \@branchcodes,
 302     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 303     'html:s'         => \$htmlfilename,    # this optional argument gets '' if not supplied.
 304     'text:s'         => \$text_filename,    # this optional argument gets '' if not supplied.
 305     'itemscontent=s' => \$itemscontent,
 306     'list-all'       => \$listall,
 307     't|triggered'    => \$triggered,
 308     'date=s'         => \$date_input,
 309     'borcat=s'       => \@myborcat,
 310     'borcatout=s'    => \@myborcatout,
 311     'email=s'        => \@emails,
 312 ) or pod2usage(2);
 313 pod2usage(1) if $help;
 314 pod2usage( -verbose => 2 ) if $man;
 315
 316 cronlogaction();
 317
 318 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 319     warn qq(using "$csvfilename" as filename, that seems odd);
 320 }
 321
 322 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();        # Branches with overdue rules
 323 my @branches;                                                                   # Branches passed as parameter with overdue rules
 324 my $branchcount = scalar(@overduebranches);
 325
 326 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 327 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 328
 329 my $PrintNoticesMaxLines = C4::Context->preference('PrintNoticesMaxLines');
 330
 331 if ($branchcount) {
 332     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 333 } else {
 334     die 'No branches with active overduerules';
 335 }
 336
 337 if (@branchcodes) {
 338     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 339
 340     # Getting libraries which have overdue rules
 341     my %seen = map { $_ => 1 } @branchcodes;
 342     @branches = grep { $seen{$_} } @overduebranches;
 343
 344
 345     if (@branches) {
 346
 347         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 348         $verbose and warn "$branch_word @branches have overdue rules\n";
 349
 350     } else {
 351
 352         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 353         ( scalar grep { '' eq $_ } @branches )
 354           or die "No active overduerules for DEFAULT either!";
 355         $verbose and warn "Falling back on default rules for @branchcodes\n";
 356         @branches = ('');
 357     }
 358 }
 359 my $date_to_run;
 360 my $date;
 361 if ( $date_input ){
 362     eval {
 363         $date_to_run = dt_from_string( $date_input, 'iso' );
 364     };
 365     die "$date_input is not a valid date, aborting! Use a date in format YYYY-MM-DD."
 366         if $@ or not $date_to_run;
 367
 368     # It's certainly useless to escape $date_input
 369     # dt_from_string should not return something if $date_input is not correctly set.
 370     $date = $dbh->quote( $date_input );
 371 }
 372 else {
 373     $date="NOW()";
 374     $date_to_run = dt_from_string();
 375 }
 376
 377 # these are the fields that will be substituted into <<item.content>>
 378 my @item_content_fields = split( /,/, $itemscontent );
 379
 380 binmode( STDOUT, ':encoding(UTF-8)' );
 381
 382
 383 our $csv;       # the Text::CSV_XS object
 384 our $csv_fh;    # the filehandle to the CSV file.
 385 if ( defined $csvfilename ) {
 386     my $sep_char = C4::Context->preference('delimiter') || ';';
 387     $sep_char = "\t" if ($sep_char eq 'tabulation');
 388     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 389     if ( $csvfilename eq '' ) {
 390         $csv_fh = *STDOUT;
 391     } else {
 392         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 393     }
 394     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email phone cardnumber itemcount itemsinfo branchname letternumber)) ) {
 395         print $csv_fh $csv->string, "\n";
 396     } else {
 397         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 398     }
 399 }
 400
 401 @branches = @overduebranches unless @branches;
 402 our $fh;
 403 if ( defined $htmlfilename ) {
 404   if ( $htmlfilename eq '' ) {
 405     $fh = *STDOUT;
 406   } else {
 407     my $today = DateTime->now(time_zone => C4::Context->tz );
 408     open $fh, ">:encoding(UTF-8)",File::Spec->catdir ($htmlfilename,"notices-".$today->ymd().".html");
 409   }
 410
 411   print $fh "<html>\n";
 412   print $fh "<head>\n";
 413   print $fh "<meta http-equiv=\"Content-Type\" content=\"text/html; charset=utf-8\" />\n";
 414   print $fh "<style type='text/css'>\n";
 415   print $fh "pre {page-break-after: always;}\n";
 416   print $fh "pre {white-space: pre-wrap;}\n";
 417   print $fh "pre {white-space: -moz-pre-wrap;}\n";
 418   print $fh "pre {white-space: -o-pre-wrap;}\n";
 419   print $fh "pre {word-wrap: break-work;}\n";
 420   print $fh "</style>\n";
 421   print $fh "</head>\n";
 422   print $fh "<body>\n";
 423 }
 424 elsif ( defined $text_filename ) {
 425   if ( $text_filename eq '' ) {
 426     $fh = *STDOUT;
 427   } else {
 428     my $today = DateTime->now(time_zone => C4::Context->tz );
 429     open $fh, ">",File::Spec->catdir ($text_filename,"notices-".$today->ymd().".txt");
 430   }
 431 }
 432
 433 foreach my $branchcode (@branches) {
 434     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 435         my $calendar = Koha::Calendar->new( branchcode => $branchcode );
 436         if ( $calendar->is_holiday($date_to_run) ) {
 437             next;
 438         }
 439     }
 440
 441     my $branch_details      = C4::Branch::GetBranchDetail($branchcode);
 442     my $admin_email_address = $branch_details->{'branchemail'}
 443       || C4::Context->preference('KohaAdminEmailAddress');
 444     my @output_chunks;    # may be sent to mail or stdout or csv file.
 445
 446     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $admin_email_address;
 447
 448     my $sth2 = $dbh->prepare( <<"END_SQL" );
 449 SELECT biblio.*, items.*, issues.*, biblioitems.itemtype, branchname
 450   FROM issues,items,biblio, biblioitems, branches b
 451   WHERE items.itemnumber=issues.itemnumber
 452     AND biblio.biblionumber   = items.biblionumber
 453     AND b.branchcode = items.homebranch
 454     AND biblio.biblionumber   = biblioitems.biblionumber
 455     AND issues.borrowernumber = ?
 456     AND TO_DAYS($date)-TO_DAYS(issues.date_due) >= 0
 457 END_SQL
 458
 459     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ";
 460     $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 461     $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 462
 463     my $rqoverduerules =  $dbh->prepare($query);
 464     $rqoverduerules->execute($branchcode, @myborcat, @myborcatout);
 465
 466     # We get default rules is there is no rule for this branch
 467     if($rqoverduerules->rows == 0){
 468         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ";
 469         $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 470         $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 471
 472         $rqoverduerules = $dbh->prepare($query);
 473         $rqoverduerules->execute(@myborcat, @myborcatout);
 474     }
 475
 476     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 477     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 478       PERIOD: foreach my $i ( 1 .. 3 ) {
 479
 480             $verbose and warn "branch '$branchcode', categorycode = $overdue_rules->{categorycode} pass $i\n";
 481
 482             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 483             my $maxdays = (
 484                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 485                 ? $overdue_rules->{ "delay" . ( $i + 1 ) } - 1
 486                 : ($MAX)
 487             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 488
 489             next unless defined $mindays;
 490
 491             if ( !$overdue_rules->{"letter$i"} ) {
 492                 $verbose and warn "No letter$i code for branch '$branchcode'";
 493                 next PERIOD;
 494             }
 495
 496             # $letter->{'content'} is the text of the mail that is sent.
 497             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 498             # The following fields are available :
 499             # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 500             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode> <country>
 501
 502             my $borrower_sql = <<"END_SQL";
 503 SELECT issues.borrowernumber, firstname, surname, address, address2, city, zipcode, country, email, emailpro, B_email, smsalertnumber, phone, cardnumber, date_due
 504 FROM   issues,borrowers,categories
 505 WHERE  issues.borrowernumber=borrowers.borrowernumber
 506 AND    borrowers.categorycode=categories.categorycode
 507 AND    TO_DAYS($date)-TO_DAYS(issues.date_due) >= 0
 508 END_SQL
 509             my @borrower_parameters;
 510             if ($branchcode) {
 511                 $borrower_sql .= ' AND issues.branchcode=? ';
 512                 push @borrower_parameters, $branchcode;
 513             }
 514             if ( $overdue_rules->{categorycode} ) {
 515                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 516                 push @borrower_parameters, $overdue_rules->{categorycode};
 517             }
 518             $borrower_sql .= '  AND categories.overduenoticerequired=1 ORDER BY issues.borrowernumber';
 519
 520             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 521                 my $sth = $dbh->prepare($borrower_sql);
 522             $sth->execute(@borrower_parameters);
 523
 524             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays, ".  $date_to_run->datetime() .")\nreturns " . $sth->rows . " rows";
 525             my $borrowernumber;
 526             while ( my $data = $sth->fetchrow_hashref ) {
 527
 528                 # check the borrower has at least one item that matches
 529                 my $days_between;
 530                 if ( C4::Context->preference('OverdueNoticeCalendar') )
 531                 {
 532                     my $calendar =
 533                       Koha::Calendar->new( branchcode => $branchcode );
 534                     $days_between =
 535                       $calendar->days_between( dt_from_string($data->{date_due}),
 536                         $date_to_run );
 537                 }
 538                 else {
 539                     $days_between =
 540                       $date_to_run->delta_days( dt_from_string($data->{date_due}) );
 541                 }
 542                 $days_between = $days_between->in_units('days');
 543                 if ($triggered) {
 544                     if ( $mindays != $days_between ) {
 545                         next;
 546                     }
 547                 }
 548                 else {
 549                     unless (   $days_between >= $mindays
 550                         && $days_between <= $maxdays )
 551                     {
 552                         next;
 553                     }
 554                 }
 555                 if (defined $borrowernumber && $borrowernumber eq $data->{'borrowernumber'}){
 556 # we have already dealt with this borrower
 557                     $verbose and warn "already dealt with this borrower $borrowernumber";
 558                     next;
 559                 }
 560                 $borrowernumber = $data->{'borrowernumber'};
 561                 my $borr =
 562                     $data->{'firstname'} . ', '
 563                   . $data->{'surname'} . ' ('
 564                   . $borrowernumber . ')';
 565                 $verbose
 566                   and warn "borrower $borr has items triggering level $i.";
 567
 568                 @emails_to_use = ();
 569                 my $notice_email =
 570                     C4::Members::GetNoticeEmailAddress($borrowernumber);
 571                 unless ($nomail) {
 572                     if (@emails) {
 573                         foreach (@emails) {
 574                             push @emails_to_use, $data->{$_} if ( $data->{$_} );
 575                         }
 576                     }
 577                     else {
 578                         push @emails_to_use, $notice_email if ($notice_email);
 579                     }
 580                 }
 581
 582                 my $letter = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"}, $branchcode );
 583
 584                 unless ($letter) {
 585                     $verbose and warn qq|Message '$overdue_rules->{"letter$i"}' content not found|;
 586
 587                     # might as well skip while PERIOD, no other borrowers are going to work.
 588                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 589                     next PERIOD;
 590                 }
 591
 592                 if ( $overdue_rules->{"debarred$i"} ) {
 593
 594                     #action taken is debarring
 595                     AddUniqueDebarment(
 596                         {
 597                             borrowernumber => $borrowernumber,
 598                             type           => 'OVERDUES',
 599                             comment => "Restriction added by overdues process "
 600                               . output_pref( dt_from_string() ),
 601                         }
 602                     );
 603                     $verbose and warn "debarring $borr\n";
 604                 }
 605                 my @params = ($borrowernumber);
 606                 $verbose and warn "STH2 PARAMS: borrowernumber = $borrowernumber";
 607
 608                 $sth2->execute(@params);
 609                 my $itemcount = 0;
 610                 my $titles = "";
 611                 my @items = ();
 612
 613                 my $j = 0;
 614                 my $exceededPrintNoticesMaxLines = 0;
 615                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 616                     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 617                         my $calendar =
 618                           Koha::Calendar->new( branchcode => $branchcode );
 619                         $days_between =
 620                           $calendar->days_between(
 621                             dt_from_string( $item_info->{date_due} ), $date_to_run );
 622                     }
 623                     else {
 624                         $days_between =
 625                           $date_to_run->delta_days(
 626                             dt_from_string( $item_info->{date_due} ) );
 627                     }
 628                     $days_between = $days_between->in_units('days');
 629                     if ($listall){
 630                         unless ($days_between >= 1 and $days_between <= $MAX){
 631                             next;
 632                         }
 633                     }
 634                     else {
 635                         if ($triggered) {
 636                             if ( $mindays != $days_between ) {
 637                                 next;
 638                             }
 639                         }
 640                         else {
 641                             unless ( $days_between >= $mindays
 642                                 && $days_between <= $maxdays )
 643                             {
 644                                 next;
 645                             }
 646                         }
 647                     }
 648
 649                     if ( ( scalar(@emails_to_use) == 0 || $nomail ) && $PrintNoticesMaxLines && $j >= $PrintNoticesMaxLines ) {
 650                       $exceededPrintNoticesMaxLines = 1;
 651                       last;
 652                     }
 653                     $j++;
 654                     my @item_info = map { $_ =~ /^date|date$/ ?
 655                                            eval { output_pref( { dt => dt_from_string( $item_info->{$_} ), dateonly => 1 } ); }
 656                                            :
 657                                            $item_info->{$_} || '' } @item_content_fields;
 658                     $titles .= join("\t", @item_info) . "\n";
 659                     $itemcount++;
 660                     push @items, $item_info;
 661                 }
 662                 $sth2->finish;
 663
 664                 my @message_transport_types = @{ GetOverdueMessageTransportTypes( $branchcode, $overdue_rules->{categorycode}, $i) };
 665                 @message_transport_types = @{ GetOverdueMessageTransportTypes( q{}, $overdue_rules->{categorycode}, $i) }
 666                     unless @message_transport_types;
 667
 668
 669                 my $print_sent = 0; # A print notice is not yet sent for this patron
 670                 for my $mtt ( @message_transport_types ) {
 671
 672                     if ( ($mtt eq 'email' and not scalar @emails_to_use) or ($mtt eq 'sms' and not $data->{smsalertnumber}) ) {
 673                         # email or sms is requested but not exist, do a print.
 674                         $mtt = 'print';
 675                     }
 676                     my $letter = parse_overdues_letter(
 677                         {   letter_code     => $overdue_rules->{"letter$i"},
 678                             borrowernumber  => $borrowernumber,
 679                             branchcode      => $branchcode,
 680                             items           => \@items,
 681                             substitute      => {    # this appears to be a hack to overcome incomplete features in this code.
 682                                                 bib             => $branch_details->{'branchname'}, # maybe 'bib' is a typo for 'lib<rary>'?
 683                                                 'items.content' => $titles,
 684                                                 'count'         => $itemcount,
 685                                                },
 686                             message_transport_type => $mtt,
 687                         }
 688                     );
 689                     unless ($letter) {
 690                         $verbose and warn qq|Message '$overdue_rules->{"letter$i"}' content not found|;
 691                         # this transport doesn't have a configured notice, so try another
 692                         next;
 693                     }
 694
 695                     if ( $exceededPrintNoticesMaxLines ) {
 696                       $letter->{'content'} .= "List too long for form; please check your account online for a complete list of your overdue items.";
 697                     }
 698
 699                     my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 700                     if (@misses) {
 701                         $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 702                     }
 703
 704                     if ($nomail) {
 705                         push @output_chunks,
 706                           prepare_letter_for_printing(
 707                           {   letter         => $letter,
 708                               borrowernumber => $borrowernumber,
 709                               firstname      => $data->{'firstname'},
 710                               lastname       => $data->{'surname'},
 711                               address1       => $data->{'address'},
 712                               address2       => $data->{'address2'},
 713                               city           => $data->{'city'},
 714                               phone          => $data->{'phone'},
 715                               cardnumber     => $data->{'cardnumber'},
 716                               branchname     => $branch_details->{'branchname'},
 717                               letternumber   => $i,
 718                               postcode       => $data->{'zipcode'},
 719                               country        => $data->{'country'},
 720                               email          => $notice_email,
 721                               itemcount      => $itemcount,
 722                               titles         => $titles,
 723                               outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 724                             }
 725                           );
 726                     } else {
 727                         if ( ($mtt eq 'email' and not scalar @emails_to_use) or ($mtt eq 'sms' and not $data->{smsalertnumber}) ) {
 728                             push @output_chunks,
 729                               prepare_letter_for_printing(
 730                               {   letter         => $letter,
 731                                   borrowernumber => $borrowernumber,
 732                                   firstname      => $data->{'firstname'},
 733                                   lastname       => $data->{'surname'},
 734                                   address1       => $data->{'address'},
 735                                   address2       => $data->{'address2'},
 736                                   city           => $data->{'city'},
 737                                   postcode       => $data->{'zipcode'},
 738                                   country        => $data->{'country'},
 739                                   email          => $notice_email,
 740                                   itemcount      => $itemcount,
 741                                   titles         => $titles,
 742                                   outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 743                                 }
 744                               );
 745                         }
 746                         unless ( $mtt eq 'print' and $print_sent == 1 ) {
 747                             # Just sent a print if not already done.
 748                             C4::Letters::EnqueueLetter(
 749                                 {   letter                 => $letter,
 750                                     borrowernumber         => $borrowernumber,
 751                                     message_transport_type => $mtt,
 752                                     from_address           => $admin_email_address,
 753                                     to_address             => join(',', @emails_to_use),
 754                                 }
 755                             );
 756                             # A print notice should be sent only once per overdue level.
 757                             # Without this check, a print could be sent twice or more if the library checks sms and email and print and the patron has no email or sms number.
 758                             $print_sent = 1 if $mtt eq 'print';
 759                         }
 760                     }
 761                 }
 762             }
 763             $sth->finish;
 764         }
 765     }
 766
 767     if (@output_chunks) {
 768         if ( defined $csvfilename ) {
 769             print $csv_fh @output_chunks;
 770         }
 771         elsif ( defined $htmlfilename ) {
 772             print $fh @output_chunks;
 773         }
 774         elsif ( defined $text_filename ) {
 775             print $fh @output_chunks;
 776         }
 777         elsif ($nomail){
 778                 local $, = "\f";    # pagebreak
 779                 print @output_chunks;
 780         }
 781         # Generate the content of the csv with headers
 782         my $content;
 783         if ( defined $csvfilename ) {
 784             my $delimiter = C4::Context->preference('delimiter') || ';';
 785             $content = join($delimiter, qw(title name surname address1 address2 zipcode city country email itemcount itemsinfo due_date issue_date)) . "\n";
 786         }
 787         else {
 788             $content = "";
 789         }
 790         $content .= join( "\n", @output_chunks );
 791
 792         my $attachment = {
 793             filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 794             type => 'text/plain',
 795             content => $content,
 796         };
 797
 798         my $letter = {
 799             title   => 'Overdue Notices',
 800             content => 'These messages were not sent directly to the patrons.',
 801         };
 802         C4::Letters::EnqueueLetter(
 803             {   letter                 => $letter,
 804                 borrowernumber         => undef,
 805                 message_transport_type => 'email',
 806                 attachments            => [$attachment],
 807                 to_address             => $admin_email_address,
 808             }
 809         );
 810     }
 811
 812 }
 813 if ($csvfilename) {
 814     # note that we're not testing on $csv_fh to prevent closing
 815     # STDOUT.
 816     close $csv_fh;
 817 }
 818
 819 if ( defined $htmlfilename ) {
 820   print $fh "</body>\n";
 821   print $fh "</html>\n";
 822   close $fh;
 823 } elsif ( defined $text_filename ) {
 824   close $fh;
 825 }
 826
 827 =head1 INTERNAL METHODS
 828
 829 These methods are internal to the operation of overdue_notices.pl.
 830
 831 =head2 prepare_letter_for_printing
 832
 833 returns a string of text appropriate for printing in the event that an
 834 overdue notice will not be sent to the patron's email
 835 address. Depending on the desired output format, this may be a CSV
 836 string, or a human-readable representation of the notice.
 837
 838 required parameters:
 839   letter
 840   borrowernumber
 841
 842 optional parameters:
 843   outputformat
 844
 845 =cut
 846
 847 sub prepare_letter_for_printing {
 848     my $params = shift;
 849
 850     return unless ref $params eq 'HASH';
 851
 852     foreach my $required_parameter (qw( letter borrowernumber )) {
 853         return unless defined $params->{$required_parameter};
 854     }
 855
 856     my $return;
 857     chomp $params->{titles};
 858     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 859         if ($csv->combine(
 860                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 861                 $params->{'city'}, $params->{'country'}, $params->{'email'}, $params->{'phone'}, $params->{'cardnumber'},
 862                 $params->{'itemcount'}, $params->{'titles'}, $params->{'branchname'}, $params->{'letternumber'}
 863             )
 864           ) {
 865             return $csv->string, "\n";
 866         } else {
 867             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 868         }
 869     } elsif ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'html' ) {
 870       $return = "<pre>\n";
 871       $return .= "$params->{'letter'}->{'content'}\n";
 872       $return .= "\n</pre>\n";
 873     } else {
 874         $return .= "$params->{'letter'}->{'content'}\n";
 875
 876         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 877     }
 878     return $return;
 879 }
 880