misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Liblime
   4 # Copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use Getopt::Long qw( GetOptions );
  24 use Pod::Usage qw( pod2usage );
  25 use Text::CSV_XS;
  26 use DateTime;
  27 use DateTime::Duration;
  28
  29 use Koha::Script -cron;
  30 use C4::Context;
  31 use C4::Letters;
  32 use C4::Overdues qw( GetOverdueMessageTransportTypes parse_overdues_letter );
  33 use C4::Log qw( cronlogaction );
  34 use Koha::Patron::Debarments qw( AddUniqueDebarment );
  35 use Koha::DateUtils qw( dt_from_string output_pref );
  36 use Koha::Calendar;
  37 use Koha::Libraries;
  38 use Koha::Acquisition::Currencies;
  39 use Koha::Patrons;
  40
  41 =head1 NAME
  42
  43 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  44
  45 =head1 SYNOPSIS
  46
  47 overdue_notices.pl
  48   [ -n ][ --library <branchcode> ][ --library <branchcode> ... ]
  49   [ --max <number of days> ][ --csv [<filename>] ][ --itemscontent <field list> ]
  50   [ --email <email_type> ... ]
  51
  52  Options:
  53    --help                          Brief help message.
  54    --man                           Full documentation.
  55    --verbose | -v                  Verbose mode.
  56    --nomail | -n                   No email will be sent.
  57    --max          <days>           Maximum days overdue to deal with.
  58    --library      <branchcode>     Only deal with overdues from this library.
  59                                    (repeatable : several libraries can be given)
  60    --csv          <filename>       Populate CSV file.
  61    --html         <directory>      Output html to a file in the given directory.
  62    --text         <directory>      Output plain text to a file in the given directory.
  63    --itemscontent <list of fields> Item information in templates.
  64    --borcat       <categorycode>   Category code that must be included.
  65    --borcatout    <categorycode>   Category code that must be excluded.
  66    --triggered | -t                Only include triggered overdues.
  67    --test                          Run in test mode. No changes will be made on the DB.
  68    --list-all                      List all overdues.
  69    --date         <yyyy-mm-dd>     Emulate overdues run for this date.
  70    --email        <email_type>     Type of email that will be used.
  71                                    Can be 'email', 'emailpro' or 'B_email'. Repeatable.
  72    --frombranch                    Organize and send overdue notices by home library (item-homebranch) or checkout library (item-issuebranch).
  73                                    This option is only used, if the OverdueNoticeFrom system preference is set to 'command-line option'.
  74                                    Defaults to item-issuebranch.
  75
  76 =head1 OPTIONS
  77
  78 =over 8
  79
  80 =item B<--help>
  81
  82 Print a brief help message and exits.
  83
  84 =item B<--man>
  85
  86 Prints the manual page and exits.
  87
  88 =item B<-v> | B<--verbose>
  89
  90 Verbose. Without this flag set, only fatal errors are reported.
  91
  92 =item B<-n> | B<--nomail>
  93
  94 Do not send any email. Overdue notices that would have been sent to
  95 the patrons or to the admin are printed to standard out. CSV data (if
  96 the --csv flag is set) is written to standard out or to any csv
  97 filename given.
  98
  99 =item B<--max>
 100
 101 Items older than max days are assumed to be handled somewhere else,
 102 probably the F<longoverdues.pl> script. They are therefore ignored by
 103 this program. No notices are sent for them, and they are not added to
 104 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
 105
 106 =item B<--library>
 107
 108 select overdues for one specific library. Use the value in the
 109 branches.branchcode table. This option can be repeated in order
 110 to select overdues for a group of libraries.
 111
 112 =item B<--csv>
 113
 114 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
 115 sent to standard out or to a filename if provided. Otherwise, only
 116 overdues that could not be emailed are sent in CSV format to the admin.
 117
 118 =item B<--html>
 119
 120 Produces html data. If patron does not have an email address or
 121 -n (no mail) flag is set, an HTML file is generated in the specified
 122 directory. This can be downloaded or further processed by library staff.
 123 The file will be called notices-YYYY-MM-DD.html and placed in the directory
 124 specified.
 125
 126 =item B<--text>
 127
 128 Produces plain text data. If patron does not have an email address or
 129 -n (no mail) flag is set, a text file is generated in the specified
 130 directory. This can be downloaded or further processed by library staff.
 131 The file will be called notices-YYYY-MM-DD.txt and placed in the directory
 132 specified.
 133
 134 =item B<--itemscontent>
 135
 136 comma separated list of fields that get substituted into templates in
 137 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 138 defaults to due date,title,barcode,author
 139
 140 Other possible values come from fields in the biblios, items and
 141 issues tables.
 142
 143 =item B<--borcat>
 144
 145 Repeatable field, that permits to select only some patron categories.
 146
 147 =item B<--borcatout>
 148
 149 Repeatable field, that permits to exclude some patron categories.
 150
 151 =item B<-t> | B<--triggered>
 152
 153 This option causes a notice to be generated if and only if
 154 an item is overdue by the number of days defined in a notice trigger.
 155
 156 By default, a notice is sent each time the script runs, which is suitable for
 157 less frequent run cron script, but requires syncing notice triggers with
 158 the  cron schedule to ensure proper behavior.
 159 Add the --triggered option for daily cron, at the risk of no notice
 160 being generated if the cron fails to run on time.
 161
 162 =item B<--test>
 163
 164 This option makes the script run in test mode.
 165
 166 In test mode, the script won't make any changes on the DB. This is useful
 167 for debugging configuration.
 168
 169 =item B<--list-all>
 170
 171 Default items.content lists only those items that fall in the
 172 range of the currently processing notice.
 173 Choose --list-all to include all overdue items in the list (limited by B<--max> setting).
 174
 175 =item B<--date>
 176
 177 use it in order to send overdues on a specific date and not Now. Format: YYYY-MM-DD.
 178
 179 =item B<--email>
 180
 181 Allows to specify which type of email will be used. Can be email, emailpro or B_email. Repeatable.
 182
 183 =item B<--frombranch>
 184
 185 Organize overdue notices either by checkout library (item-issuebranch) or item home library (item-homebranch).
 186 This option is only used, if the OverdueNoticeFrom system preference is set to use 'command-line option'.
 187 Defaults to checkout library (item-issuebranch).
 188
 189 =back
 190
 191 =head1 DESCRIPTION
 192
 193 This script is designed to alert patrons and administrators of overdue
 194 items.
 195
 196 =head2 Configuration
 197
 198 This script pays attention to the overdue notice configuration
 199 performed in the "Overdue notice/status triggers" section of the
 200 "Tools" area of the staff interface to Koha. There, you can choose
 201 which letter templates are sent out after a configurable number of
 202 days to patrons of each library. More information about the use of this
 203 section of Koha is available in the Koha manual.
 204
 205 The templates used to craft the emails are defined in the "Tools:
 206 Notices" section of the staff interface to Koha.
 207
 208 =head2 Outgoing emails
 209
 210 Typically, messages are prepared for each patron with overdue
 211 items. Messages for whom there is no email address on file are
 212 collected and sent as attachments in a single email to each library
 213 administrator, or if that is not set, then to the email address in the
 214 C<KohaAdminEmailAddress> system preference.
 215
 216 These emails are staged in the outgoing message queue, as are messages
 217 produced by other features of Koha. This message queue must be
 218 processed regularly by the
 219 F<misc/cronjobs/process_message_queue.pl> program.
 220
 221 In the event that the C<-n> flag is passed to this program, no emails
 222 are sent. Instead, messages are sent on standard output from this
 223 program. They may be redirected to a file if desired.
 224
 225 =head2 Templates
 226
 227 Templates can contain variables enclosed in double angle brackets like
 228 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 229 specific to the overdue items or relevant patron. Available variables
 230 are:
 231
 232 =over
 233
 234 =item E<lt>E<lt>bibE<gt>E<gt>
 235
 236 the name of the library
 237
 238 =item E<lt>E<lt>items.contentE<gt>E<gt>
 239
 240 one line for each item, each line containing a tab separated list of
 241 title, author, barcode, issuedate
 242
 243 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 244
 245 any field from the borrowers table
 246
 247 =item E<lt>E<lt>branches.*E<gt>E<gt>
 248
 249 any field from the branches table
 250
 251 =back
 252
 253 =head2 CSV output
 254
 255 The C<-csv> command line option lets you specify a file to which
 256 overdues data should be output in CSV format.
 257
 258 With the C<-n> flag set, data about all overdues is written to the
 259 file. Without that flag, only information about overdues that were
 260 unable to be sent directly to the patrons will be written. In other
 261 words, this CSV file replaces the data that is typically sent to the
 262 administrator email address.
 263
 264 =head1 USAGE EXAMPLES
 265
 266 C<overdue_notices.pl> - In this most basic usage, with no command line
 267 arguments, all libraries are processed individually, and notices are
 268 prepared for all patrons with overdue items for whom we have email
 269 addresses. Messages for those patrons for whom we have no email
 270 address are sent in a single attachment to the library administrator's
 271 email address, or to the address in the KohaAdminEmailAddress system
 272 preference.
 273
 274 C<overdue_notices.pl -n --csv /tmp/overdues.csv> - sends no email and
 275 populates F</tmp/overdues.csv> with information about all overdue
 276 items.
 277
 278 C<overdue_notices.pl --library MAIN max 14> - prepare notices of
 279 overdues in the last 2 weeks for the MAIN library.
 280
 281 =head1 SEE ALSO
 282
 283 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 284 messages to patrons in advance of their items becoming due, or to
 285 alert them of items that have just become due.
 286
 287 =cut
 288
 289 # These variables are set by command line options.
 290 # They are initially set to default values.
 291 my $dbh = C4::Context->dbh();
 292 my $help    = 0;
 293 my $man     = 0;
 294 my $verbose = 0;
 295 my $nomail  = 0;
 296 my $MAX     = 90;
 297 my $test_mode = 0;
 298 my $frombranch = 'item-issuebranch';
 299 my @branchcodes; # Branch(es) passed as parameter
 300 my @emails_to_use;    # Emails to use for messaging
 301 my @emails;           # Emails given in command-line parameters
 302 my $csvfilename;
 303 my $htmlfilename;
 304 my $text_filename;
 305 my $triggered = 0;
 306 my $listall = 0;
 307 my $itemscontent = join( ',', qw( date_due title barcode author itemnumber ) );
 308 my @myborcat;
 309 my @myborcatout;
 310 my ( $date_input, $today );
 311
 312 GetOptions(
 313     'help|?'         => \$help,
 314     'man'            => \$man,
 315     'v|verbose'      => \$verbose,
 316     'n|nomail'       => \$nomail,
 317     'max=s'          => \$MAX,
 318     'library=s'      => \@branchcodes,
 319     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 320     'html:s'         => \$htmlfilename,    # this optional argument gets '' if not supplied.
 321     'text:s'         => \$text_filename,    # this optional argument gets '' if not supplied.
 322     'itemscontent=s' => \$itemscontent,
 323     'list-all'       => \$listall,
 324     't|triggered'    => \$triggered,
 325     'test'           => \$test_mode,
 326     'date=s'         => \$date_input,
 327     'borcat=s'       => \@myborcat,
 328     'borcatout=s'    => \@myborcatout,
 329     'email=s'        => \@emails,
 330     'frombranch=s'   => \$frombranch,
 331 ) or pod2usage(2);
 332 pod2usage(1) if $help;
 333 pod2usage( -verbose => 2 ) if $man;
 334 cronlogaction() unless $test_mode;
 335
 336 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 337     warn qq(using "$csvfilename" as filename, that seems odd);
 338 }
 339
 340 die "--frombranch takes item-homebranch or item-issuebranch only"
 341     unless ( $frombranch eq 'item-issuebranch'
 342         || $frombranch eq 'item-homebranch' );
 343 $frombranch = C4::Context->preference('OverdueNoticeFrom') ne 'cron' ? C4::Context->preference('OverdueNoticeFrom') : $frombranch;
 344 my $owning_library = ( $frombranch eq 'item-homebranch' ) ? 1 : 0;
 345
 346 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();    # Branches with overdue rules
 347 my @branches;                                    # Branches passed as parameter with overdue rules
 348 my $branchcount = scalar(@overduebranches);
 349
 350 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 351 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 352
 353 my $PrintNoticesMaxLines = C4::Context->preference('PrintNoticesMaxLines');
 354
 355 if ($branchcount) {
 356     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 357 } else {
 358     die 'No branches with active overduerules';
 359 }
 360
 361 if (@branchcodes) {
 362     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 363
 364     # Getting libraries which have overdue rules
 365     my %seen = map { $_ => 1 } @branchcodes;
 366     @branches = grep { $seen{$_} } @overduebranches;
 367
 368
 369     if (@branches) {
 370
 371         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 372     $verbose and warn "$branch_word @branches have overdue rules\n";
 373
 374     } else {
 375
 376         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 377         ( scalar grep { '' eq $_ } @branches )
 378           or die "No active overduerules for DEFAULT either!";
 379         $verbose and warn "Falling back on default rules for @branchcodes\n";
 380         @branches = ('');
 381     }
 382 }
 383 my $date_to_run;
 384 my $date;
 385 if ( $date_input ){
 386     eval {
 387         $date_to_run = dt_from_string( $date_input, 'iso' );
 388     };
 389     die "$date_input is not a valid date, aborting! Use a date in format YYYY-MM-DD."
 390         if $@ or not $date_to_run;
 391
 392     # It's certainly useless to escape $date_input
 393     # dt_from_string should not return something if $date_input is not correctly set.
 394     $date = $dbh->quote( $date_input );
 395 }
 396 else {
 397     $date="NOW()";
 398     $date_to_run = dt_from_string();
 399 }
 400
 401 # these are the fields that will be substituted into <<item.content>>
 402 my @item_content_fields = split( /,/, $itemscontent );
 403
 404 binmode( STDOUT, ':encoding(UTF-8)' );
 405
 406
 407 our $csv;       # the Text::CSV_XS object
 408 our $csv_fh;    # the filehandle to the CSV file.
 409 if ( defined $csvfilename ) {
 410     my $sep_char = C4::Context->preference('CSVDelimiter') || ';';
 411     $sep_char = "\t" if ($sep_char eq 'tabulation');
 412     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 413     if ( $csvfilename eq '' ) {
 414         $csv_fh = *STDOUT;
 415     } else {
 416         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 417     }
 418     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email phone cardnumber itemcount itemsinfo branchname letternumber)) ) {
 419         print $csv_fh $csv->string, "\n";
 420     } else {
 421         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 422     }
 423 }
 424
 425 @branches = @overduebranches unless @branches;
 426 our $fh;
 427 if ( defined $htmlfilename ) {
 428   if ( $htmlfilename eq '' ) {
 429     $fh = *STDOUT;
 430   } else {
 431     my $today = dt_from_string();
 432     open $fh, ">:encoding(UTF-8)",File::Spec->catdir ($htmlfilename,"notices-".$today->ymd().".html");
 433   }
 434
 435   print $fh "<html>\n";
 436   print $fh "<head>\n";
 437   print $fh "<meta http-equiv=\"Content-Type\" content=\"text/html; charset=utf-8\" />\n";
 438   print $fh "<style type='text/css'>\n";
 439   print $fh "pre {page-break-after: always;}\n";
 440   print $fh "pre {white-space: pre-wrap;}\n";
 441   print $fh "pre {white-space: -moz-pre-wrap;}\n";
 442   print $fh "pre {white-space: -o-pre-wrap;}\n";
 443   print $fh "pre {word-wrap: break-work;}\n";
 444   print $fh "</style>\n";
 445   print $fh "</head>\n";
 446   print $fh "<body>\n";
 447 }
 448 elsif ( defined $text_filename ) {
 449   if ( $text_filename eq '' ) {
 450     $fh = *STDOUT;
 451   } else {
 452     my $today = dt_from_string();
 453     open $fh, ">:encoding(UTF-8)",File::Spec->catdir ($text_filename,"notices-".$today->ymd().".txt");
 454   }
 455 }
 456
 457 foreach my $branchcode (@branches) {
 458     my $calendar;
 459     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 460         $calendar = Koha::Calendar->new( branchcode => $branchcode );
 461         if ( $calendar->is_holiday($date_to_run) ) {
 462             next;
 463         }
 464     }
 465
 466     my $library             = Koha::Libraries->find($branchcode);
 467     my $admin_email_address = $library->from_email_address;
 468     my $branch_email_address = C4::Context->preference('AddressForFailedOverdueNotices')
 469       || $library->inbound_email_address;
 470     my @output_chunks;    # may be sent to mail or stdout or csv file.
 471
 472     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $branch_email_address;
 473
 474     my $sql2 = <<"END_SQL";
 475 SELECT biblio.*, items.*, issues.*, biblioitems.itemtype, branchname
 476   FROM issues,items,biblio, biblioitems, branches b
 477   WHERE items.itemnumber=issues.itemnumber
 478     AND biblio.biblionumber   = items.biblionumber
 479     AND b.branchcode = items.homebranch
 480     AND biblio.biblionumber   = biblioitems.biblionumber
 481     AND issues.borrowernumber = ?
 482     AND items.itemlost = 0
 483     AND TO_DAYS($date)-TO_DAYS(issues.date_due) >= 0
 484 END_SQL
 485
 486     if($owning_library) {
 487       $sql2 .= ' AND items.homebranch = ? ';
 488     } else {
 489       $sql2 .= ' AND issues.branchcode = ? ';
 490     }
 491     my $sth2 = $dbh->prepare($sql2);
 492
 493     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ";
 494     $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 495     $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 496
 497     my $rqoverduerules =  $dbh->prepare($query);
 498     $rqoverduerules->execute($branchcode, @myborcat, @myborcatout);
 499
 500     # We get default rules is there is no rule for this branch
 501     if($rqoverduerules->rows == 0){
 502         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ";
 503         $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 504         $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 505
 506         $rqoverduerules = $dbh->prepare($query);
 507         $rqoverduerules->execute(@myborcat, @myborcatout);
 508     }
 509
 510     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 511     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 512       PERIOD: foreach my $i ( 1 .. 3 ) {
 513
 514             $verbose and warn "branch '$branchcode', categorycode = $overdue_rules->{categorycode} pass $i\n";
 515
 516             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 517             my $maxdays = (
 518                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 519                 ? $overdue_rules->{ "delay" . ( $i + 1 ) } - 1
 520                 : ($MAX)
 521             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 522
 523             next unless defined $mindays;
 524
 525             if ( !$overdue_rules->{"letter$i"} ) {
 526                 $verbose and warn "No letter$i code for branch '$branchcode'";
 527                 next PERIOD;
 528             }
 529
 530             # $letter->{'content'} is the text of the mail that is sent.
 531             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 532             # The following fields are available :
 533         # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 534             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode> <country>
 535
 536             my $borrower_sql = <<"END_SQL";
 537 SELECT issues.borrowernumber, firstname, surname, address, address2, city, zipcode, country, email, emailpro, B_email, smsalertnumber, phone, cardnumber, date_due
 538 FROM   issues,borrowers,categories,items
 539 WHERE  issues.borrowernumber=borrowers.borrowernumber
 540 AND    borrowers.categorycode=categories.categorycode
 541 AND    issues.itemnumber = items.itemnumber
 542 AND    items.itemlost = 0
 543 AND    TO_DAYS($date)-TO_DAYS(issues.date_due) >= 0
 544 END_SQL
 545             my @borrower_parameters;
 546             if ($branchcode) {
 547         if($owning_library) {
 548             $borrower_sql .= ' AND items.homebranch=? ';
 549         } else {
 550             $borrower_sql .= ' AND issues.branchcode=? ';
 551         }
 552                 push @borrower_parameters, $branchcode;
 553             }
 554             if ( $overdue_rules->{categorycode} ) {
 555                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 556                 push @borrower_parameters, $overdue_rules->{categorycode};
 557             }
 558             $borrower_sql .= '  AND categories.overduenoticerequired=1 ORDER BY issues.borrowernumber';
 559
 560             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 561             my $sth = $dbh->prepare($borrower_sql);
 562             $sth->execute(@borrower_parameters);
 563
 564             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays, ".  $date_to_run->datetime() .")\nreturns " . $sth->rows . " rows";
 565             my $borrowernumber;
 566             while ( my $data = $sth->fetchrow_hashref ) {
 567
 568                 # check the borrower has at least one item that matches
 569                 my $days_between;
 570                 if ( C4::Context->preference('OverdueNoticeCalendar') )
 571                 {
 572                     $days_between =
 573                       $calendar->days_between( dt_from_string($data->{date_due}),
 574                         $date_to_run );
 575                 }
 576                 else {
 577                     $days_between =
 578                       $date_to_run->delta_days( dt_from_string($data->{date_due}) );
 579                 }
 580                 $days_between = $days_between->in_units('days');
 581                 if ($triggered) {
 582                     if ( $mindays != $days_between ) {
 583                         next;
 584                     }
 585                 }
 586                 else {
 587                     unless (   $days_between >= $mindays
 588                         && $days_between <= $maxdays )
 589                     {
 590                         next;
 591                     }
 592                 }
 593                 if (defined $borrowernumber && $borrowernumber eq $data->{'borrowernumber'}){
 594 # we have already dealt with this borrower
 595                     $verbose and warn "already dealt with this borrower $borrowernumber";
 596                     next;
 597                 }
 598                 $borrowernumber = $data->{'borrowernumber'};
 599                 my $borr = sprintf( "%s%s%s (%s)",
 600                     $data->{'surname'} || '',
 601                     $data->{'firstname'} && $data->{'surname'} ? ', ' : '',
 602                     $data->{'firstname'} || '',
 603                     $borrowernumber );
 604                 $verbose
 605                   and warn "borrower $borr has items triggering level $i.";
 606
 607                 my $patron = Koha::Patrons->find( $borrowernumber );
 608                 @emails_to_use = ();
 609                 my $notice_email = $patron->notice_email_address;
 610                 unless ($nomail) {
 611                     if (@emails) {
 612                         foreach (@emails) {
 613                             push @emails_to_use, $data->{$_} if ( $data->{$_} );
 614                         }
 615                     }
 616                     else {
 617                         push @emails_to_use, $notice_email if ($notice_email);
 618                     }
 619                 }
 620
 621                 my $letter = Koha::Notice::Templates->find_effective_template(
 622                     {
 623                         module     => 'circulation',
 624                         code       => $overdue_rules->{"letter$i"},
 625                         branchcode => $branchcode,
 626                         lang       => $patron->lang
 627                     }
 628                 );
 629
 630                 unless ($letter) {
 631                     $verbose and warn qq|Message '$overdue_rules->{"letter$i"}' content not found|;
 632
 633                     # might as well skip while PERIOD, no other borrowers are going to work.
 634                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 635                     next PERIOD;
 636                 }
 637
 638                 if ( $overdue_rules->{"debarred$i"} ) {
 639
 640                     #action taken is debarring
 641                     AddUniqueDebarment(
 642                         {
 643                             borrowernumber => $borrowernumber,
 644                             type           => 'OVERDUES',
 645                             comment => "OVERDUES_PROCESS " .  output_pref( dt_from_string() ),
 646                         }
 647                     ) unless $test_mode;
 648                     $verbose and warn "debarring $borr\n";
 649                 }
 650                 my @params = ($borrowernumber,$branchcode);
 651                 $verbose and warn "STH2 PARAMS: borrowernumber = $borrowernumber";
 652
 653                 $sth2->execute(@params);
 654                 my $itemcount = 0;
 655                 my $titles = "";
 656                 my @items = ();
 657
 658                 my $j = 0;
 659                 my $exceededPrintNoticesMaxLines = 0;
 660                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 661                     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 662                         $days_between =
 663                           $calendar->days_between(
 664                             dt_from_string( $item_info->{date_due} ), $date_to_run );
 665                     }
 666                     else {
 667                         $days_between =
 668                           $date_to_run->delta_days(
 669                             dt_from_string( $item_info->{date_due} ) );
 670                     }
 671                     $days_between = $days_between->in_units('days');
 672                     if ($listall){
 673                         unless ($days_between >= 1 and $days_between <= $MAX){
 674                             next;
 675                         }
 676                     }
 677                     else {
 678                         if ($triggered) {
 679                             if ( $mindays != $days_between ) {
 680                                 next;
 681                             }
 682                         }
 683                         else {
 684                             unless ( $days_between >= $mindays
 685                                 && $days_between <= $maxdays )
 686                             {
 687                                 next;
 688                             }
 689                         }
 690                     }
 691
 692                     if ( ( scalar(@emails_to_use) == 0 || $nomail ) && $PrintNoticesMaxLines && $j >= $PrintNoticesMaxLines ) {
 693                       $exceededPrintNoticesMaxLines = 1;
 694                       last;
 695                     }
 696                     $j++;
 697
 698                     $titles .= C4::Letters::get_item_content( { item => $item_info, item_content_fields => \@item_content_fields, dateonly => 1 } );
 699                     $itemcount++;
 700                     push @items, $item_info;
 701                 }
 702                 $sth2->finish;
 703
 704                 my @message_transport_types = @{ GetOverdueMessageTransportTypes( $branchcode, $overdue_rules->{categorycode}, $i) };
 705                 @message_transport_types = @{ GetOverdueMessageTransportTypes( q{}, $overdue_rules->{categorycode}, $i) }
 706                     unless @message_transport_types;
 707
 708
 709                 my $print_sent = 0; # A print notice is not yet sent for this patron
 710                 for my $mtt ( @message_transport_types ) {
 711                     my $effective_mtt = $mtt;
 712                     if ( ($mtt eq 'email' and not scalar @emails_to_use) or ($mtt eq 'sms' and not $data->{smsalertnumber}) ) {
 713                         # email or sms is requested but not exist, do a print.
 714                         $effective_mtt = 'print';
 715                     }
 716                     splice @items, $PrintNoticesMaxLines if $effective_mtt eq 'print' && $PrintNoticesMaxLines && scalar @items > $PrintNoticesMaxLines;
 717                     #catch the case where we are sending a print to someone with an email
 718
 719                     my $letter_exists = Koha::Notice::Templates->find_effective_template(
 720                         {
 721                             module     => 'circulation',
 722                             code       => $overdue_rules->{"letter$i"},
 723                             message_transport_type => $effective_mtt,
 724                             branchcode => $branchcode,
 725                             lang       => $patron->lang
 726                         }
 727                     );
 728
 729                     my $letter = parse_overdues_letter(
 730                         {   letter_code     => $overdue_rules->{"letter$i"},
 731                             borrowernumber  => $borrowernumber,
 732                             branchcode      => $branchcode,
 733                             items           => \@items,
 734                             substitute      => {    # this appears to be a hack to overcome incomplete features in this code.
 735                                                 bib             => $library->branchname, # maybe 'bib' is a typo for 'lib<rary>'?
 736                                                 'items.content' => $titles,
 737                                                 'count'         => $itemcount,
 738                                                },
 739                             # If there is no template defined for the requested letter
 740                             # Fallback on the original type
 741                             message_transport_type => $letter_exists ? $effective_mtt : $mtt,
 742                         }
 743                     );
 744                     unless ($letter && $letter->{content}) {
 745                         $verbose and warn qq|Message '$overdue_rules->{"letter$i"}' content not found|;
 746                         # this transport doesn't have a configured notice, so try another
 747                         next;
 748                     }
 749
 750                     if ( $exceededPrintNoticesMaxLines ) {
 751                       $letter->{'content'} .= "List too long for form; please check your account online for a complete list of your overdue items.";
 752                     }
 753
 754                     my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 755                     if (@misses) {
 756                         $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 757                     }
 758
 759                     if ($nomail) {
 760                         push @output_chunks,
 761                           prepare_letter_for_printing(
 762                           {   letter         => $letter,
 763                               borrowernumber => $borrowernumber,
 764                               firstname      => $data->{'firstname'},
 765                               lastname       => $data->{'surname'},
 766                               address1       => $data->{'address'},
 767                               address2       => $data->{'address2'},
 768                               city           => $data->{'city'},
 769                               phone          => $data->{'phone'},
 770                               cardnumber     => $data->{'cardnumber'},
 771                               branchname     => $library->branchname,
 772                               letternumber   => $i,
 773                               postcode       => $data->{'zipcode'},
 774                               country        => $data->{'country'},
 775                               email          => $notice_email,
 776                               itemcount      => $itemcount,
 777                               titles         => $titles,
 778                               outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 779                             }
 780                           );
 781                     } else {
 782                         if ( ($mtt eq 'email' and not scalar @emails_to_use) or ($mtt eq 'sms' and not $data->{smsalertnumber}) ) {
 783                             push @output_chunks,
 784                               prepare_letter_for_printing(
 785                               {   letter         => $letter,
 786                                   borrowernumber => $borrowernumber,
 787                                   firstname      => $data->{'firstname'},
 788                                   lastname       => $data->{'surname'},
 789                                   address1       => $data->{'address'},
 790                                   address2       => $data->{'address2'},
 791                                   city           => $data->{'city'},
 792                                   postcode       => $data->{'zipcode'},
 793                                   country        => $data->{'country'},
 794                                   email          => $notice_email,
 795                                   itemcount      => $itemcount,
 796                                   titles         => $titles,
 797                                   outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 798                                 }
 799                               );
 800                         }
 801                         unless ( $effective_mtt eq 'print' and $print_sent == 1 ) {
 802                             # Just sent a print if not already done.
 803                             C4::Letters::EnqueueLetter(
 804                                 {   letter                 => $letter,
 805                                     borrowernumber         => $borrowernumber,
 806                                     message_transport_type => $effective_mtt,
 807                                     from_address           => $admin_email_address,
 808                                     to_address             => join(',', @emails_to_use),
 809                                 }
 810                             ) unless $test_mode;
 811                             # A print notice should be sent only once per overdue level.
 812                             # Without this check, a print could be sent twice or more if the library checks sms and email and print and the patron has no email or sms number.
 813                             $print_sent = 1 if $effective_mtt eq 'print';
 814                         }
 815                     }
 816                 }
 817             }
 818             $sth->finish;
 819         }
 820     }
 821
 822     if (@output_chunks) {
 823         if ( defined $csvfilename ) {
 824             print $csv_fh @output_chunks;
 825         }
 826         elsif ( defined $htmlfilename ) {
 827             print $fh @output_chunks;
 828         }
 829         elsif ( defined $text_filename ) {
 830             print $fh @output_chunks;
 831         }
 832         elsif ($nomail){
 833                 local $, = "\f";    # pagebreak
 834                 print @output_chunks;
 835         }
 836         # Generate the content of the csv with headers
 837         my $content;
 838         if ( defined $csvfilename ) {
 839             my $delimiter = C4::Context->preference('CSVDelimiter') || ';';
 840             $content = join($delimiter, qw(title name surname address1 address2 zipcode city country email itemcount itemsinfo due_date issue_date)) . "\n";
 841         }
 842         else {
 843             $content = "";
 844         }
 845         $content .= join( "\n", @output_chunks );
 846
 847         if ( C4::Context->preference('EmailOverduesNoEmail') ) {
 848             my $attachment = {
 849                 filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 850                 type => 'text/plain',
 851                 content => $content,
 852             };
 853
 854             my $letter = {
 855                 title   => 'Overdue Notices',
 856                 content => 'These messages were not sent directly to the patrons.',
 857             };
 858
 859             C4::Letters::EnqueueLetter(
 860                 {   letter                 => $letter,
 861                     borrowernumber         => undef,
 862                     message_transport_type => 'email',
 863                     attachments            => [$attachment],
 864                     to_address             => $branch_email_address,
 865                 }
 866             ) unless $test_mode;
 867         }
 868     }
 869
 870 }
 871 if ($csvfilename) {
 872     # note that we're not testing on $csv_fh to prevent closing
 873     # STDOUT.
 874     close $csv_fh;
 875 }
 876
 877 if ( defined $htmlfilename ) {
 878   print $fh "</body>\n";
 879   print $fh "</html>\n";
 880   close $fh;
 881 } elsif ( defined $text_filename ) {
 882   close $fh;
 883 }
 884
 885 =head1 INTERNAL METHODS
 886
 887 These methods are internal to the operation of overdue_notices.pl.
 888
 889 =head2 prepare_letter_for_printing
 890
 891 returns a string of text appropriate for printing in the event that an
 892 overdue notice will not be sent to the patron's email
 893 address. Depending on the desired output format, this may be a CSV
 894 string, or a human-readable representation of the notice.
 895
 896 required parameters:
 897   letter
 898   borrowernumber
 899
 900 optional parameters:
 901   outputformat
 902
 903 =cut
 904
 905 sub prepare_letter_for_printing {
 906     my $params = shift;
 907
 908     return unless ref $params eq 'HASH';
 909
 910     foreach my $required_parameter (qw( letter borrowernumber )) {
 911         return unless defined $params->{$required_parameter};
 912     }
 913
 914     my $return;
 915     chomp $params->{titles};
 916     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 917         if ($csv->combine(
 918                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 919                 $params->{'city'}, $params->{'country'}, $params->{'email'}, $params->{'phone'}, $params->{'cardnumber'},
 920                 $params->{'itemcount'}, $params->{'titles'}, $params->{'branchname'}, $params->{'letternumber'}
 921             )
 922           ) {
 923             return $csv->string, "\n";
 924         } else {
 925             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 926         }
 927     } elsif ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'html' ) {
 928       $return = "<pre>\n";
 929       $return .= "$params->{'letter'}->{'content'}\n";
 930       $return .= "\n</pre>\n";
 931     } else {
 932         $return .= "$params->{'letter'}->{'content'}\n";
 933
 934         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 935     }
 936     return $return;
 937 }
 938