misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Liblime
   4 # Copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use strict;
  22 use warnings;
  23
  24 BEGIN {
  25
  26     # find Koha's Perl modules
  27     # test carefully before changing this
  28     use FindBin;
  29     eval { require "$FindBin::Bin/../kohalib.pl" };
  30 }
  31
  32 use Getopt::Long;
  33 use Pod::Usage;
  34 use Text::CSV_XS;
  35 use Locale::Currency::Format 1.28;
  36 use Encode;
  37 use DateTime;
  38 use DateTime::Duration;
  39
  40 use C4::Context;
  41 use C4::Debug;
  42 use C4::Letters;
  43 use C4::Overdues qw(GetFine GetOverdueMessageTransportTypes);
  44 use C4::Budgets qw(GetCurrency);
  45 use C4::Log;
  46 use Koha::Borrower::Debarments qw(AddUniqueDebarment);
  47 use Koha::DateUtils;
  48 use Koha::Calendar;
  49
  50 =head1 NAME
  51
  52 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  53
  54 =head1 SYNOPSIS
  55
  56 overdue_notices.pl
  57   [ -n ][ -library <branchcode> ][ -library <branchcode> ... ]
  58   [ -max <number of days> ][ -csv [<filename>] ][ -itemscontent <field list> ]
  59   [ -email <email_type> ... ]
  60
  61  Options:
  62    -help                          brief help message
  63    -man                           full documentation
  64    -n                             No email will be sent
  65    -max          <days>           maximum days overdue to deal with
  66    -library      <branchname>     only deal with overdues from this library (repeatable : several libraries can be given)
  67    -csv          <filename>       populate CSV file
  68    -html         <directory>      Output html to a file in the given directory
  69    -text         <directory>      Output plain text to a file in the given directory
  70    -itemscontent <list of fields> item information in templates
  71    -borcat       <categorycode>   category code that must be included
  72    -borcatout    <categorycode>   category code that must be excluded
  73    -email        <email_type>     type of email that will be used. Can be 'email', 'emailpro' or 'B_email'. Repeatable.
  74
  75 =head1 OPTIONS
  76
  77 =over 8
  78
  79 =item B<-help>
  80
  81 Print a brief help message and exits.
  82
  83 =item B<-man>
  84
  85 Prints the manual page and exits.
  86
  87 =item B<-v>
  88
  89 Verbose. Without this flag set, only fatal errors are reported.
  90
  91 =item B<-n>
  92
  93 Do not send any email. Overdue notices that would have been sent to
  94 the patrons or to the admin are printed to standard out. CSV data (if
  95 the -csv flag is set) is written to standard out or to any csv
  96 filename given.
  97
  98 =item B<-max>
  99
 100 Items older than max days are assumed to be handled somewhere else,
 101 probably the F<longoverdues.pl> script. They are therefore ignored by
 102 this program. No notices are sent for them, and they are not added to
 103 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
 104
 105 =item B<-library>
 106
 107 select overdues for one specific library. Use the value in the
 108 branches.branchcode table. This option can be repeated in order
 109 to select overdues for a group of libraries.
 110
 111 =item B<-csv>
 112
 113 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
 114 sent to standard out or to a filename if provided. Otherwise, only
 115 overdues that could not be emailed are sent in CSV format to the admin.
 116
 117 =item B<-html>
 118
 119 Produces html data. If patron does not have an email address or
 120 -n (no mail) flag is set, an HTML file is generated in the specified
 121 directory. This can be downloaded or further processed by library staff.
 122 The file will be called notices-YYYY-MM-DD.html and placed in the directory
 123 specified.
 124
 125 =item B<-text>
 126
 127 Produces plain text data. If patron does not have an email address or
 128 -n (no mail) flag is set, a text file is generated in the specified
 129 directory. This can be downloaded or further processed by library staff.
 130 The file will be called notices-YYYY-MM-DD.txt and placed in the directory
 131 specified.
 132
 133 =item B<-itemscontent>
 134
 135 comma separated list of fields that get substituted into templates in
 136 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 137 defaults to due date,title,barcode,author
 138
 139 Other possible values come from fields in the biblios, items and
 140 issues tables.
 141
 142 =item B<-borcat>
 143
 144 Repetable field, that permit to select only few of patrons categories.
 145
 146 =item B<-borcatout>
 147
 148 Repetable field, permis to exclude some patrons categories.
 149
 150 =item B<-t> | B<--triggered>
 151
 152 This option causes a notice to be generated if and only if
 153 an item is overdue by the number of days defined in a notice trigger.
 154
 155 By default, a notice is sent each time the script runs, which is suitable for
 156 less frequent run cron script, but requires syncing notice triggers with
 157 the  cron schedule to ensure proper behavior.
 158 Add the --triggered option for daily cron, at the risk of no notice
 159 being generated if the cron fails to run on time.
 160
 161 =item B<-list-all>
 162
 163 Default items.content lists only those items that fall in the
 164 range of the currently processing notice.
 165 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 166
 167 =item B<-date>
 168
 169 use it in order to send overdues on a specific date and not Now. Format: YYYY-MM-DD.
 170
 171 =item B<-email>
 172
 173 Allows to specify which type of email will be used. Can be email, emailpro or B_email. Repeatable.
 174
 175 =back
 176
 177 =head1 DESCRIPTION
 178
 179 This script is designed to alert patrons and administrators of overdue
 180 items.
 181
 182 =head2 Configuration
 183
 184 This script pays attention to the overdue notice configuration
 185 performed in the "Overdue notice/status triggers" section of the
 186 "Tools" area of the staff interface to Koha. There, you can choose
 187 which letter templates are sent out after a configurable number of
 188 days to patrons of each library. More information about the use of this
 189 section of Koha is available in the Koha manual.
 190
 191 The templates used to craft the emails are defined in the "Tools:
 192 Notices" section of the staff interface to Koha.
 193
 194 =head2 Outgoing emails
 195
 196 Typically, messages are prepared for each patron with overdue
 197 items. Messages for whom there is no email address on file are
 198 collected and sent as attachments in a single email to each library
 199 administrator, or if that is not set, then to the email address in the
 200 C<KohaAdminEmailAddress> system preference.
 201
 202 These emails are staged in the outgoing message queue, as are messages
 203 produced by other features of Koha. This message queue must be
 204 processed regularly by the
 205 F<misc/cronjobs/process_message_queue.pl> program.
 206
 207 In the event that the C<-n> flag is passed to this program, no emails
 208 are sent. Instead, messages are sent on standard output from this
 209 program. They may be redirected to a file if desired.
 210
 211 =head2 Templates
 212
 213 Templates can contain variables enclosed in double angle brackets like
 214 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 215 specific to the overdue items or relevant patron. Available variables
 216 are:
 217
 218 =over
 219
 220 =item E<lt>E<lt>bibE<gt>E<gt>
 221
 222 the name of the library
 223
 224 =item E<lt>E<lt>items.contentE<gt>E<gt>
 225
 226 one line for each item, each line containing a tab separated list of
 227 title, author, barcode, issuedate
 228
 229 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 230
 231 any field from the borrowers table
 232
 233 =item E<lt>E<lt>branches.*E<gt>E<gt>
 234
 235 any field from the branches table
 236
 237 =back
 238
 239 =head2 CSV output
 240
 241 The C<-csv> command line option lets you specify a file to which
 242 overdues data should be output in CSV format.
 243
 244 With the C<-n> flag set, data about all overdues is written to the
 245 file. Without that flag, only information about overdues that were
 246 unable to be sent directly to the patrons will be written. In other
 247 words, this CSV file replaces the data that is typically sent to the
 248 administrator email address.
 249
 250 =head1 USAGE EXAMPLES
 251
 252 C<overdue_notices.pl> - In this most basic usage, with no command line
 253 arguments, all libraries are procesed individually, and notices are
 254 prepared for all patrons with overdue items for whom we have email
 255 addresses. Messages for those patrons for whom we have no email
 256 address are sent in a single attachment to the library administrator's
 257 email address, or to the address in the KohaAdminEmailAddress system
 258 preference.
 259
 260 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 261 populates F</tmp/overdues.csv> with information about all overdue
 262 items.
 263
 264 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 265 overdues in the last 2 weeks for the MAIN library.
 266
 267 =head1 SEE ALSO
 268
 269 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 270 messages to patrons in advance of their items becoming due, or to
 271 alert them of items that have just become due.
 272
 273 =cut
 274
 275 # These variables are set by command line options.
 276 # They are initially set to default values.
 277 my $dbh = C4::Context->dbh();
 278 my $help    = 0;
 279 my $man     = 0;
 280 my $verbose = 0;
 281 my $nomail  = 0;
 282 my $MAX     = 90;
 283 my @branchcodes; # Branch(es) passed as parameter
 284 my @emails_to_use;    # Emails to use for messaging
 285 my @emails;           # Emails given in command-line parameters
 286 my $csvfilename;
 287 my $htmlfilename;
 288 my $text_filename;
 289 my $triggered = 0;
 290 my $listall = 0;
 291 my $itemscontent = join( ',', qw( date_due title barcode author itemnumber ) );
 292 my @myborcat;
 293 my @myborcatout;
 294 my ( $date_input, $today );
 295
 296 GetOptions(
 297     'help|?'         => \$help,
 298     'man'            => \$man,
 299     'v'              => \$verbose,
 300     'n'              => \$nomail,
 301     'max=s'          => \$MAX,
 302     'library=s'      => \@branchcodes,
 303     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 304     'html:s'         => \$htmlfilename,    # this optional argument gets '' if not supplied.
 305     'text:s'         => \$text_filename,    # this optional argument gets '' if not supplied.
 306     'itemscontent=s' => \$itemscontent,
 307     'list-all'       => \$listall,
 308     't|triggered'    => \$triggered,
 309     'date=s'         => \$date_input,
 310     'borcat=s'       => \@myborcat,
 311     'borcatout=s'    => \@myborcatout,
 312     'email=s'        => \@emails,
 313 ) or pod2usage(2);
 314 pod2usage(1) if $help;
 315 pod2usage( -verbose => 2 ) if $man;
 316
 317 cronlogaction();
 318
 319 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 320     warn qq(using "$csvfilename" as filename, that seems odd);
 321 }
 322
 323 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();        # Branches with overdue rules
 324 my @branches;                                                                   # Branches passed as parameter with overdue rules
 325 my $branchcount = scalar(@overduebranches);
 326
 327 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 328 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 329
 330 my $PrintNoticesMaxLines = C4::Context->preference('PrintNoticesMaxLines');
 331
 332 if ($branchcount) {
 333     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 334 } else {
 335     die 'No branches with active overduerules';
 336 }
 337
 338 if (@branchcodes) {
 339     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 340
 341     # Getting libraries which have overdue rules
 342     my %seen = map { $_ => 1 } @branchcodes;
 343     @branches = grep { $seen{$_} } @overduebranches;
 344
 345
 346     if (@branches) {
 347
 348         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 349         $verbose and warn "$branch_word @branches have overdue rules\n";
 350
 351     } else {
 352
 353         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 354         ( scalar grep { '' eq $_ } @branches )
 355           or die "No active overduerules for DEFAULT either!";
 356         $verbose and warn "Falling back on default rules for @branchcodes\n";
 357         @branches = ('');
 358     }
 359 }
 360 my $date_to_run;
 361 my $date;
 362 if ( $date_input ){
 363     eval {
 364         $date_to_run = dt_from_string( $date_input, 'iso' );
 365     };
 366     die "$date_input is not a valid date, aborting! Use a date in format YYYY-MM-DD."
 367         if $@ or not $date_to_run;
 368
 369     # It's certainly useless to escape $date_input
 370     # dt_from_string should not return something if $date_input is not correctly set.
 371     $date = $dbh->quote( $date_input );
 372 }
 373 else {
 374     $date="NOW()";
 375     $date_to_run = dt_from_string();
 376 }
 377
 378 # these are the fields that will be substituted into <<item.content>>
 379 my @item_content_fields = split( /,/, $itemscontent );
 380
 381 binmode( STDOUT, ':encoding(UTF-8)' );
 382
 383
 384 our $csv;       # the Text::CSV_XS object
 385 our $csv_fh;    # the filehandle to the CSV file.
 386 if ( defined $csvfilename ) {
 387     my $sep_char = C4::Context->preference('delimiter') || ';';
 388     $sep_char = "\t" if ($sep_char eq 'tabulation');
 389     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 390     if ( $csvfilename eq '' ) {
 391         $csv_fh = *STDOUT;
 392     } else {
 393         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 394     }
 395     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email phone cardnumber itemcount itemsinfo branchname letternumber)) ) {
 396         print $csv_fh $csv->string, "\n";
 397     } else {
 398         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 399     }
 400 }
 401
 402 @branches = @overduebranches unless @branches;
 403 our $fh;
 404 if ( defined $htmlfilename ) {
 405   if ( $htmlfilename eq '' ) {
 406     $fh = *STDOUT;
 407   } else {
 408     my $today = DateTime->now(time_zone => C4::Context->tz );
 409     open $fh, ">:encoding(UTF-8)",File::Spec->catdir ($htmlfilename,"notices-".$today->ymd().".html");
 410   }
 411
 412   print $fh "<html>\n";
 413   print $fh "<head>\n";
 414   print $fh "<meta http-equiv=\"Content-Type\" content=\"text/html; charset=utf-8\" />\n";
 415   print $fh "<style type='text/css'>\n";
 416   print $fh "pre {page-break-after: always;}\n";
 417   print $fh "pre {white-space: pre-wrap;}\n";
 418   print $fh "pre {white-space: -moz-pre-wrap;}\n";
 419   print $fh "pre {white-space: -o-pre-wrap;}\n";
 420   print $fh "pre {word-wrap: break-work;}\n";
 421   print $fh "</style>\n";
 422   print $fh "</head>\n";
 423   print $fh "<body>\n";
 424 }
 425 elsif ( defined $text_filename ) {
 426   if ( $text_filename eq '' ) {
 427     $fh = *STDOUT;
 428   } else {
 429     my $today = DateTime->now(time_zone => C4::Context->tz );
 430     open $fh, ">",File::Spec->catdir ($text_filename,"notices-".$today->ymd().".txt");
 431   }
 432 }
 433
 434 foreach my $branchcode (@branches) {
 435     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 436         my $calendar = Koha::Calendar->new( branchcode => $branchcode );
 437         if ( $calendar->is_holiday($date_to_run) ) {
 438             next;
 439         }
 440     }
 441
 442     my $branch_details      = C4::Branch::GetBranchDetail($branchcode);
 443     my $admin_email_address = $branch_details->{'branchemail'}
 444       || C4::Context->preference('KohaAdminEmailAddress');
 445     my @output_chunks;    # may be sent to mail or stdout or csv file.
 446
 447     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $admin_email_address;
 448
 449     my $sth2 = $dbh->prepare( <<"END_SQL" );
 450 SELECT biblio.*, items.*, issues.*, biblioitems.itemtype, TO_DAYS($date)-TO_DAYS(date_due) AS days_overdue, branchname
 451   FROM issues,items,biblio, biblioitems, branches b
 452   WHERE items.itemnumber=issues.itemnumber
 453     AND biblio.biblionumber   = items.biblionumber
 454     AND b.branchcode = items.homebranch
 455     AND biblio.biblionumber   = biblioitems.biblionumber
 456     AND issues.borrowernumber = ?
 457 END_SQL
 458
 459     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ";
 460     $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 461     $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 462
 463     my $rqoverduerules =  $dbh->prepare($query);
 464     $rqoverduerules->execute($branchcode, @myborcat, @myborcatout);
 465
 466     # We get default rules is there is no rule for this branch
 467     if($rqoverduerules->rows == 0){
 468         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ";
 469         $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 470         $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 471
 472         $rqoverduerules = $dbh->prepare($query);
 473         $rqoverduerules->execute(@myborcat, @myborcatout);
 474     }
 475
 476     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 477     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 478       PERIOD: foreach my $i ( 1 .. 3 ) {
 479
 480             $verbose and warn "branch '$branchcode', categorycode = $overdue_rules->{categorycode} pass $i\n";
 481
 482             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 483             my $maxdays = (
 484                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 485                 ? $overdue_rules->{ "delay" . ( $i + 1 ) } - 1
 486                 : ($MAX)
 487             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 488
 489             next unless defined $mindays;
 490
 491             if ( !$overdue_rules->{"letter$i"} ) {
 492                 $verbose and warn "No letter$i code for branch '$branchcode'";
 493                 next PERIOD;
 494             }
 495
 496             # $letter->{'content'} is the text of the mail that is sent.
 497             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 498             # The following fields are available :
 499             # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 500             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode> <country>
 501
 502             my $borrower_sql = <<'END_SQL';
 503 SELECT issues.borrowernumber, firstname, surname, address, address2, city, zipcode, country, email, emailpro, B_email, smsalertnumber, phone, cardnumber,
 504 TO_DAYS(?)-TO_DAYS(date_due) as difference, date_due
 505 FROM   issues,borrowers,categories
 506 WHERE  issues.borrowernumber=borrowers.borrowernumber
 507 AND    borrowers.categorycode=categories.categorycode
 508 END_SQL
 509             my @borrower_parameters;
 510             push @borrower_parameters, $date_to_run->datetime();
 511             if ($branchcode) {
 512                 $borrower_sql .= ' AND issues.branchcode=? ';
 513                 push @borrower_parameters, $branchcode;
 514             }
 515             if ( $overdue_rules->{categorycode} ) {
 516                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 517                 push @borrower_parameters, $overdue_rules->{categorycode};
 518             }
 519             $borrower_sql .= '  AND categories.overduenoticerequired=1 ORDER BY issues.borrowernumber';
 520
 521             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 522                 my $sth = $dbh->prepare($borrower_sql);
 523             $sth->execute(@borrower_parameters);
 524
 525             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays, ".  $date_to_run->datetime() .")\nreturns " . $sth->rows . " rows";
 526             my $borrowernumber;
 527             while ( my $data = $sth->fetchrow_hashref ) {
 528
 529                 next unless ( DateTime->compare( $date_to_run, dt_from_string($data->{date_due})) ) == 1;
 530
 531                 # check the borrower has at least one item that matches
 532                 my $days_between;
 533                 if ( C4::Context->preference('OverdueNoticeCalendar') )
 534                 {
 535                     my $calendar =
 536                       Koha::Calendar->new( branchcode => $branchcode );
 537                     $days_between =
 538                       $calendar->days_between( dt_from_string($data->{date_due}),
 539                         $date_to_run );
 540                 }
 541                 else {
 542                     $days_between =
 543                       $date_to_run->delta_days( dt_from_string($data->{date_due}) );
 544                 }
 545                 $days_between = $days_between->in_units('days');
 546                 if ($triggered) {
 547                     if ( $mindays != $days_between ) {
 548                         next;
 549                     }
 550                 }
 551                 else {
 552                     unless (   $days_between >= $mindays
 553                         && $days_between <= $maxdays )
 554                     {
 555                         next;
 556                     }
 557                 }
 558                 if (defined $borrowernumber && $borrowernumber eq $data->{'borrowernumber'}){
 559 # we have already dealt with this borrower
 560                     $verbose and warn "already dealt with this borrower $borrowernumber";
 561                     next;
 562                 }
 563                 $borrowernumber = $data->{'borrowernumber'};
 564                 my $borr =
 565                     $data->{'firstname'} . ', '
 566                   . $data->{'surname'} . ' ('
 567                   . $borrowernumber . ')';
 568                 $verbose
 569                   and warn "borrower $borr has items triggering level $i.";
 570
 571                 @emails_to_use = ();
 572                 my $notice_email =
 573                     C4::Members::GetNoticeEmailAddress($borrowernumber);
 574                 unless ($nomail) {
 575                     if (@emails) {
 576                         foreach (@emails) {
 577                             push @emails_to_use, $data->{$_} if ( $data->{$_} );
 578                         }
 579                     }
 580                     else {
 581                         push @emails_to_use, $notice_email if ($notice_email);
 582                     }
 583                 }
 584
 585                 my $letter = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"}, $branchcode );
 586
 587                 unless ($letter) {
 588                     $verbose and warn qq|Message '$overdue_rules->{"letter$i"}' content not found|;
 589
 590                     # might as well skip while PERIOD, no other borrowers are going to work.
 591                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 592                     next PERIOD;
 593                 }
 594
 595                 if ( $overdue_rules->{"debarred$i"} ) {
 596
 597                     #action taken is debarring
 598                     AddUniqueDebarment(
 599                         {
 600                             borrowernumber => $borrowernumber,
 601                             type           => 'OVERDUES',
 602                             comment => "Restriction added by overdues process "
 603                               . output_pref( dt_from_string() ),
 604                         }
 605                     );
 606                     $verbose and warn "debarring $borr\n";
 607                 }
 608                 my @params = ($borrowernumber);
 609                 $verbose and warn "STH2 PARAMS: borrowernumber = $borrowernumber";
 610
 611                 $sth2->execute(@params);
 612                 my $itemcount = 0;
 613                 my $titles = "";
 614                 my @items = ();
 615
 616                 my $j = 0;
 617                 my $exceededPrintNoticesMaxLines = 0;
 618                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 619                     next unless ( DateTime->compare( $date_to_run,  dt_from_string($item_info->{date_due})) ) == 1;
 620
 621                     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 622                         my $calendar =
 623                           Koha::Calendar->new( branchcode => $branchcode );
 624                         $days_between =
 625                           $calendar->days_between(
 626                             dt_from_string( $item_info->{date_due} ), $date_to_run );
 627                     }
 628                     else {
 629                         $days_between =
 630                           $date_to_run->delta_days(
 631                             dt_from_string( $item_info->{date_due} ) );
 632                     }
 633                     $days_between = $days_between->in_units('days');
 634                     if ($listall){
 635                         unless ($days_between >= 1 and $days_between <= $MAX){
 636                             next;
 637                         }
 638                     }
 639                     else {
 640                         if ($triggered) {
 641                             if ( $mindays != $days_between ) {
 642                                 next;
 643                             }
 644                         }
 645                         else {
 646                             unless ( $days_between >= $mindays
 647                                 && $days_between <= $maxdays )
 648                             {
 649                                 next;
 650                             }
 651                         }
 652                     }
 653
 654                     if ( ( scalar(@emails_to_use) == 0 || $nomail ) && $PrintNoticesMaxLines && $j >= $PrintNoticesMaxLines ) {
 655                       $exceededPrintNoticesMaxLines = 1;
 656                       last;
 657                     }
 658                     $j++;
 659                     my @item_info = map { $_ =~ /^date|date$/ ?
 660                                            eval { output_pref( { dt => dt_from_string( $item_info->{$_} ), dateonly => 1 } ); }
 661                                            :
 662                                            $item_info->{$_} || '' } @item_content_fields;
 663                     $titles .= join("\t", @item_info) . "\n";
 664                     $itemcount++;
 665                     push @items, $item_info;
 666                 }
 667                 $sth2->finish;
 668
 669                 my @message_transport_types = @{ GetOverdueMessageTransportTypes( $branchcode, $overdue_rules->{categorycode}, $i) };
 670                 @message_transport_types = @{ GetOverdueMessageTransportTypes( q{}, $overdue_rules->{categorycode}, $i) }
 671                     unless @message_transport_types;
 672
 673
 674                 my $print_sent = 0; # A print notice is not yet sent for this patron
 675                 for my $mtt ( @message_transport_types ) {
 676
 677                     my $letter = parse_overdues_letter(
 678                         {   letter_code     => $overdue_rules->{"letter$i"},
 679                             borrowernumber  => $borrowernumber,
 680                             branchcode      => $branchcode,
 681                             items           => \@items,
 682                             substitute      => {    # this appears to be a hack to overcome incomplete features in this code.
 683                                                 bib             => $branch_details->{'branchname'}, # maybe 'bib' is a typo for 'lib<rary>'?
 684                                                 'items.content' => $titles,
 685                                                 'count'         => $itemcount,
 686                                                },
 687                             message_transport_type => $mtt,
 688                         }
 689                     );
 690                     unless ($letter) {
 691                         $verbose and warn qq|Message '$overdue_rules->{"letter$i"}' content not found|;
 692                         # this transport doesn't have a configured notice, so try another
 693                         next;
 694                     }
 695
 696                     if ( $exceededPrintNoticesMaxLines ) {
 697                       $letter->{'content'} .= "List too long for form; please check your account online for a complete list of your overdue items.";
 698                     }
 699
 700                     my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 701                     if (@misses) {
 702                         $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 703                     }
 704
 705                     if ($nomail) {
 706                         push @output_chunks,
 707                           prepare_letter_for_printing(
 708                           {   letter         => $letter,
 709                               borrowernumber => $borrowernumber,
 710                               firstname      => $data->{'firstname'},
 711                               lastname       => $data->{'surname'},
 712                               address1       => $data->{'address'},
 713                               address2       => $data->{'address2'},
 714                               city           => $data->{'city'},
 715                               phone          => $data->{'phone'},
 716                               cardnumber     => $data->{'cardnumber'},
 717                               branchname     => $branch_details->{'branchname'},
 718                               letternumber   => $i,
 719                               postcode       => $data->{'zipcode'},
 720                               country        => $data->{'country'},
 721                               email          => $notice_email,
 722                               itemcount      => $itemcount,
 723                               titles         => $titles,
 724                               outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 725                             }
 726                           );
 727                     } else {
 728                         if ( ($mtt eq 'email' and not scalar @emails_to_use) or ($mtt eq 'sms' and not $data->{smsalertnumber}) ) {
 729                             # email or sms is requested but not exist, do a print.
 730                             $mtt = 'print';
 731                             push @output_chunks,
 732                               prepare_letter_for_printing(
 733                               {   letter         => $letter,
 734                                   borrowernumber => $borrowernumber,
 735                                   firstname      => $data->{'firstname'},
 736                                   lastname       => $data->{'surname'},
 737                                   address1       => $data->{'address'},
 738                                   address2       => $data->{'address2'},
 739                                   city           => $data->{'city'},
 740                                   postcode       => $data->{'zipcode'},
 741                                   country        => $data->{'country'},
 742                                   email          => $notice_email,
 743                                   itemcount      => $itemcount,
 744                                   titles         => $titles,
 745                                   outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 746                                 }
 747                               );
 748                         }
 749                         unless ( $mtt eq 'print' and $print_sent == 1 ) {
 750                             # Just sent a print if not already done.
 751                             C4::Letters::EnqueueLetter(
 752                                 {   letter                 => $letter,
 753                                     borrowernumber         => $borrowernumber,
 754                                     message_transport_type => $mtt,
 755                                     from_address           => $admin_email_address,
 756                                     to_address             => join(',', @emails_to_use),
 757                                 }
 758                             );
 759                             # A print notice should be sent only once per overdue level.
 760                             # Without this check, a print could be sent twice or more if the library checks sms and email and print and the patron has no email or sms number.
 761                             $print_sent = 1 if $mtt eq 'print';
 762                         }
 763                     }
 764                 }
 765             }
 766             $sth->finish;
 767         }
 768     }
 769
 770     if (@output_chunks) {
 771         if ( defined $csvfilename ) {
 772             print $csv_fh @output_chunks;
 773         }
 774         elsif ( defined $htmlfilename ) {
 775             print $fh @output_chunks;
 776         }
 777         elsif ( defined $text_filename ) {
 778             print $fh @output_chunks;
 779         }
 780         elsif ($nomail){
 781                 local $, = "\f";    # pagebreak
 782                 print @output_chunks;
 783         }
 784         # Generate the content of the csv with headers
 785         my $content;
 786         if ( defined $csvfilename ) {
 787             my $delimiter = C4::Context->preference('delimiter') || ';';
 788             $content = join($delimiter, qw(title name surname address1 address2 zipcode city country email itemcount itemsinfo due_date issue_date)) . "\n";
 789         }
 790         else {
 791             $content = "";
 792         }
 793         $content .= join( "\n", @output_chunks );
 794
 795         my $attachment = {
 796             filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 797             type => 'text/plain',
 798             content => $content,
 799         };
 800
 801         my $letter = {
 802             title   => 'Overdue Notices',
 803             content => 'These messages were not sent directly to the patrons.',
 804         };
 805         C4::Letters::EnqueueLetter(
 806             {   letter                 => $letter,
 807                 borrowernumber         => undef,
 808                 message_transport_type => 'email',
 809                 attachments            => [$attachment],
 810                 to_address             => $admin_email_address,
 811             }
 812         );
 813     }
 814
 815 }
 816 if ($csvfilename) {
 817     # note that we're not testing on $csv_fh to prevent closing
 818     # STDOUT.
 819     close $csv_fh;
 820 }
 821
 822 if ( defined $htmlfilename ) {
 823   print $fh "</body>\n";
 824   print $fh "</html>\n";
 825   close $fh;
 826 } elsif ( defined $text_filename ) {
 827   close $fh;
 828 }
 829
 830 =head1 INTERNAL METHODS
 831
 832 These methods are internal to the operation of overdue_notices.pl.
 833
 834 =head2 prepare_letter_for_printing
 835
 836 returns a string of text appropriate for printing in the event that an
 837 overdue notice will not be sent to the patron's email
 838 address. Depending on the desired output format, this may be a CSV
 839 string, or a human-readable representation of the notice.
 840
 841 required parameters:
 842   letter
 843   borrowernumber
 844
 845 optional parameters:
 846   outputformat
 847
 848 =cut
 849
 850 sub prepare_letter_for_printing {
 851     my $params = shift;
 852
 853     return unless ref $params eq 'HASH';
 854
 855     foreach my $required_parameter (qw( letter borrowernumber )) {
 856         return unless defined $params->{$required_parameter};
 857     }
 858
 859     my $return;
 860     chomp $params->{titles};
 861     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 862         if ($csv->combine(
 863                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 864                 $params->{'city'}, $params->{'country'}, $params->{'email'}, $params->{'phone'}, $params->{'cardnumber'},
 865                 $params->{'itemcount'}, $params->{'titles'}, $params->{'branchname'}, $params->{'letternumber'}
 866             )
 867           ) {
 868             return $csv->string, "\n";
 869         } else {
 870             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 871         }
 872     } elsif ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'html' ) {
 873       $return = "<pre>\n";
 874       $return .= "$params->{'letter'}->{'content'}\n";
 875       $return .= "\n</pre>\n";
 876     } else {
 877         $return .= "$params->{'letter'}->{'content'}\n";
 878
 879         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 880     }
 881     return $return;
 882 }
 883