misc/cronjobs/reconcile_balances.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2018 Theke Solutions
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 NAME
  21
  22 reconcile_balances.pl - cron script to reconcile patron's balances
  23
  24 =head1 SYNOPSIS
  25
  26 ./reconcile_balances.pl
  27
  28 or, in crontab:
  29 0 1 * * * reconcile_balances.pl
  30
  31 =head1 DESCRIPTION
  32
  33 This script loops through patrons with outstanding credits and proceeds
  34 to reconcile their balances.
  35
  36 =head1 OPTIONS
  37
  38 =over 8
  39
  40 =item B<--help>
  41
  42 Prints a brief help message and exits.
  43
  44 =item B<--verbose>
  45
  46 Makes the process print information about the taken actions.
  47
  48 =back
  49
  50 =cut
  51
  52 use Modern::Perl;
  53
  54 use Getopt::Long;
  55 use Pod::Usage;
  56 use Try::Tiny;
  57
  58 BEGIN {
  59     # find Koha's Perl modules
  60     # test carefully before changing this
  61     use FindBin;
  62     eval { require "$FindBin::Bin/../kohalib.pl" };
  63 }
  64
  65 use Koha::Script -cron;
  66 use C4::Log;
  67
  68 use Koha::Account::Lines;
  69 use Koha::Patrons;
  70
  71 my $help    = 0;
  72 my $verbose = 0;
  73
  74 GetOptions(
  75     'help'    => \$help,
  76     'verbose' => \$verbose
  77 ) or pod2usage(2);
  78
  79 pod2usage(1) if $help;
  80 cronlogaction();
  81
  82 my @patron_ids = map { $_->borrowernumber } Koha::Account::Lines->search(
  83         {
  84             amountoutstanding => { '<' => 0 },
  85             borrowernumber => { '!=' => undef }
  86         },
  87         {
  88             columns  => [ qw/borrowernumber/ ],
  89             distinct => 1,
  90         }
  91     );
  92
  93 my $patrons = Koha::Patrons->search({ borrowernumber => { -in => \@patron_ids } });
  94
  95 while (my $patron = $patrons->next) {
  96
  97     my $account = $patron->account;
  98     my $total_outstanding_credit = $account->outstanding_credits->total_outstanding;
  99     my $total_outstanding_debit  = $account->outstanding_debits->total_outstanding;
 100
 101     if ( $total_outstanding_credit < 0
 102          and $total_outstanding_debit > 0) {
 103
 104         try {
 105
 106             $account->reconcile_balance;
 107
 108             print $patron->id . ": credit: $total_outstanding_credit " .
 109                                   "debit: $total_outstanding_debit " .
 110                                   "=> outstanding " .
 111                                   "credit: " . $account->outstanding_credits->total_outstanding .
 112                                  " debit: " .  $account->outstanding_debits->total_outstanding . "\n"
 113                 if $verbose;
 114         }
 115         catch {
 116             print "Problem with patron " . $patron->borrowernumber . ": $_";
 117         };
 118     }
 119 }
 120
 121 1;
 122
 123 __END__