misc/cronjobs/thirdparty/TalkingTech_itiva_outbound.pl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright (C) 2011 ByWater Solutions
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use strict;
  21 use warnings;
  22
  23 BEGIN {
  24
  25     # find Koha's Perl modules
  26     # test carefully before changing this
  27     use FindBin;
  28     eval { require "$FindBin::Bin/../kohalib.pl" };
  29 }
  30
  31 use Getopt::Long;
  32 use Pod::Usage;
  33 use Date::Calc qw(Add_Delta_Days);
  34
  35 use C4::Context;
  36 use C4::Items;
  37 use C4::Letters;
  38 use C4::Overdues;
  39 use C4::Dates;
  40 use C4::Calendar;
  41
  42 sub usage {
  43     pod2usage( -verbose => 2 );
  44     exit;
  45 }
  46
  47 die
  48   "TalkingTechItivaPhoneNotification system preference not activated... dying\n"
  49   unless ( C4::Context->preference("TalkingTechItivaPhoneNotification") );
  50
  51 # Database handle
  52 my $dbh = C4::Context->dbh;
  53
  54 # Options
  55 my $verbose;
  56 my $language = "EN";
  57 my @types;
  58 my @holds_waiting_days_to_call;
  59 my $library_code;
  60 my $help;
  61 my $outfile;
  62
  63 # maps to convert I-tiva terms to Koha terms
  64 my $type_module_map = {
  65     'PREOVERDUE' => 'circulation',
  66     'OVERDUE'    => 'circulation',
  67     'RESERVE'    => 'reserves',
  68 };
  69
  70 my $type_notice_map = {
  71     'PREOVERDUE' => 'PREDUE_PHONE',
  72     'OVERDUE'    => 'OVERDUE_PHONE',
  73     'RESERVE'    => 'HOLD_PHONE',
  74 };
  75
  76 GetOptions(
  77     'o|output:s'            => \$outfile,
  78     'v'                     => \$verbose,
  79     'lang:s'                => \$language,
  80     'type:s'                => \@types,
  81     'w|waiting-hold-day:s'  => \@holds_waiting_days_to_call,
  82     'c|code|library-code:s' => \$library_code,
  83     'help|h'                => \$help,
  84 );
  85
  86 $language = uc($language);
  87 $library_code ||= '';
  88
  89 pod2usage( -verbose => 1 ) if $help;
  90
  91 # output log or STDOUT
  92 my $OUT;
  93 if ( defined $outfile ) {
  94     open( $OUT, '>', "$outfile" ) || die("Cannot open output file");
  95 }
  96 else {
  97     print "No output file defined; printing to STDOUT\n"
  98       if ( defined $verbose );
  99     open( $OUT, '>', "&STDOUT" ) || die("Couldn't duplicate STDOUT: $!");
 100 }
 101
 102 my $format = 'V';    # format for phone notifications
 103
 104 foreach my $type (@types) {
 105     $type = uc($type);    #just in case lower or mixed-case was supplied
 106     my $module =
 107       $type_module_map->{$type}; #since the module is required to get the letter
 108     my $code = $type_notice_map->{$type};    #to get the Koha name of the notice
 109
 110     my @loop;
 111     if ( $type eq 'OVERDUE' ) {
 112         @loop = GetOverdueIssues();
 113     }
 114     elsif ( $type eq 'PREOVERDUE' ) {
 115         @loop = GetPredueIssues();
 116     }
 117     elsif ( $type eq 'RESERVE' ) {
 118         @loop = GetWaitingHolds();
 119     }
 120     else {
 121         print "Unknown or unsupported message type $type; skipping...\n"
 122           if ( defined $verbose );
 123         next;
 124     }
 125
 126     foreach my $issues (@loop) {
 127         my $date = C4::Dates->new( $issues->{'date_due'}, 'iso' );
 128         my $due_date = $date->output('metric');
 129
 130         my $letter = C4::Letters::GetPreparedLetter(
 131             module      => $module,
 132             letter_code => $code,
 133             tables      => {
 134                 borrowers   => $issues->{'borrowernumber'},
 135                 biblio      => $issues->{'biblionumber'},
 136                 biblioitems => $issues->{'biblionumber'}
 137             },
 138         );
 139
 140         die "No letter found for type $type!... dying\n" unless $letter;
 141
 142         my $message_id = 0;
 143         if ($outfile) {
 144             $message_id = C4::Letters::EnqueueLetter(
 145                 {
 146                     letter                 => $letter,
 147                     borrowernumber         => $issues->{'borrowernumber'},
 148                     message_transport_type => 'phone',
 149                 }
 150             );
 151         }
 152
 153         print $OUT
 154 "\"$format\",\"$language\",\"$type\",\"$issues->{level}\",\"$issues->{cardnumber}\",\"$issues->{patron_title}\",\"$issues->{firstname}\",";
 155         print $OUT
 156 "\"$issues->{surname}\",\"$issues->{phone}\",\"$issues->{email}\",\"$library_code\",";
 157         print $OUT
 158 "\"$issues->{site}\",\"$issues->{site_name}\",\"$issues->{barcode}\",\"$due_date\",\"$issues->{title}\",\"$message_id\"\n";
 159     }
 160 }
 161
 162 =head1 NAME
 163
 164 TalkingTech_itiva_outbound.pl
 165
 166 =head1 SYNOPSIS
 167
 168   TalkingTech_itiva_outbound.pl
 169   TalkingTech_itiva_outbound.pl --type=OVERDUE -w 0 -w 2 -w 6 --output=/tmp/talkingtech/outbound.csv
 170   TalkingTech_itiva_outbound.pl --type=RESERVE --type=PREOVERDUE --lang=FR
 171
 172
 173 Script to generate Spec C outbound notifications file for Talking Tech i-tiva
 174 phone notification system.
 175
 176 =item B<--help> B<-h>
 177
 178 Prints this help
 179
 180 =item B<-v>
 181
 182 Provide verbose log information.
 183
 184 =item B<--output> B<-o>
 185
 186 Destination for outbound notifications file (CSV format).  If no value is specified,
 187 output is dumped to screen.
 188
 189 =item B<--lang>
 190
 191 Sets the language for all outbound messages.  Currently supported values are EN, FR and ES.
 192 If no value is specified, EN will be used by default.
 193
 194 =item B<--type>
 195
 196 REQUIRED. Sets which messaging types are to be used.  Can be given multiple times, to
 197 specify multiple types in a single output file.  Currently supported values are RESERVE, PREOVERDUE
 198 and OVERDUE.  If no value is given, this script will not produce any outbound notifications.
 199
 200 =item B<--waiting-hold-day> B<-w>
 201
 202 OPTIONAL for --type=RESERVE. Sets the days after a hold has been set to waiting on which to call. Use
 203 switch as many times as desired. For example, passing "-w 0 -w 2 -w 6" will cause calls to be placed
 204 on the day the hold was set to waiting, 2 days after the waiting date, and 6 days after. See example above.
 205 If this switch is not used with --type=RESERVE, calls will be placed every day until the waiting reserve
 206 is picked up or canceled.
 207
 208 =item B<--library-code> B<--code> B<-c>
 209
 210 OPTIONAL
 211 The code of the source library of the message.
 212 The library code is used to group notices together for
 213 consortium purposes and apply library specific settings, such as
 214 prompts, to those notices.
 215 This field can be blank if all messages are from a single library.
 216
 217 =cut
 218
 219 sub GetOverdueIssues {
 220     my $query =
 221 "SELECT borrowers.borrowernumber, borrowers.cardnumber, borrowers.title as patron_title, borrowers.firstname, borrowers.surname,
 222                 borrowers.phone, borrowers.email, borrowers.branchcode, biblio.biblionumber, biblio.title, items.barcode, issues.date_due,
 223                 max(overduerules.branchcode) as rulebranch, TO_DAYS(NOW())-TO_DAYS(date_due) as daysoverdue, delay1, delay2, delay3,
 224                 issues.branchcode as site, branches.branchname as site_name
 225                 FROM borrowers JOIN issues USING (borrowernumber)
 226                 JOIN items USING (itemnumber)
 227                 JOIN biblio USING (biblionumber)
 228                 JOIN branches ON (issues.branchcode = branches.branchcode)
 229                 JOIN overduerules USING (categorycode)
 230                 WHERE ( overduerules.branchcode = borrowers.branchcode or overduerules.branchcode = '')
 231                 AND ( (TO_DAYS(NOW())-TO_DAYS(date_due) ) = delay1
 232                   OR  (TO_DAYS(NOW())-TO_DAYS(date_due) ) = delay2
 233                   OR  (TO_DAYS(NOW())-TO_DAYS(date_due) ) = delay3 )
 234                 GROUP BY items.itemnumber
 235                 ";
 236     my $sth = $dbh->prepare($query);
 237     $sth->execute();
 238     my @results;
 239     while ( my $issue = $sth->fetchrow_hashref() ) {
 240         if ( $issue->{'daysoverdue'} == $issue->{'delay1'} ) {
 241             $issue->{'level'} = 1;
 242         }
 243         elsif ( $issue->{'daysoverdue'} == $issue->{'delay2'} ) {
 244             $issue->{'level'} = 2;
 245         }
 246         elsif ( $issue->{'daysoverdue'} == $issue->{'delay3'} ) {
 247             $issue->{'level'} = 3;
 248         }
 249         else {
 250
 251             # this shouldn't ever happen, based our SQL criteria
 252         }
 253         push @results, $issue;
 254     }
 255     return @results;
 256 }
 257
 258 sub GetPredueIssues {
 259     my $query =
 260 "SELECT borrowers.borrowernumber, borrowers.cardnumber, borrowers.title as patron_title, borrowers.firstname, borrowers.surname,
 261                 borrowers.phone, borrowers.email, borrowers.branchcode, biblio.biblionumber, biblio.title, items.barcode, issues.date_due,
 262                 issues.branchcode as site, branches.branchname as site_name
 263                 FROM borrowers JOIN issues USING (borrowernumber)
 264                 JOIN items USING (itemnumber)
 265                 JOIN biblio USING (biblionumber)
 266                 JOIN branches ON (issues.branchcode = branches.branchcode)
 267                 JOIN borrower_message_preferences USING (borrowernumber)
 268                 JOIN borrower_message_transport_preferences USING (borrower_message_preference_id)
 269                 JOIN message_attributes USING (message_attribute_id)
 270                 WHERE ( TO_DAYS( date_due ) - TO_DAYS( NOW() ) ) = days_in_advance
 271                 AND message_transport_type = 'phone'
 272                 AND message_name = 'Advance_Notice'
 273                 ";
 274     my $sth = $dbh->prepare($query);
 275     $sth->execute();
 276     my @results;
 277     while ( my $issue = $sth->fetchrow_hashref() ) {
 278         $issue->{'level'} = 1;    # only one level for Predue notifications
 279         push @results, $issue;
 280     }
 281     return @results;
 282 }
 283
 284 sub GetWaitingHolds {
 285     my $query =
 286 "SELECT borrowers.borrowernumber, borrowers.cardnumber, borrowers.title as patron_title, borrowers.firstname, borrowers.surname,
 287                 borrowers.phone, borrowers.email, borrowers.branchcode, biblio.biblionumber, biblio.title, items.barcode, reserves.waitingdate,
 288                 reserves.branchcode AS site, branches.branchname AS site_name,
 289                 TO_DAYS(NOW())-TO_DAYS(reserves.waitingdate) AS days_since_waiting
 290                 FROM borrowers JOIN reserves USING (borrowernumber)
 291                 JOIN items USING (itemnumber)
 292                 JOIN biblio ON (biblio.biblionumber = items.biblionumber)
 293                 JOIN branches ON (reserves.branchcode = branches.branchcode)
 294                 JOIN borrower_message_preferences USING (borrowernumber)
 295                 JOIN borrower_message_transport_preferences USING (borrower_message_preference_id)
 296                 JOIN message_attributes USING (message_attribute_id)
 297                 WHERE ( reserves.found = 'W' )
 298                 AND message_transport_type = 'phone'
 299                 AND message_name = 'Hold_Filled'
 300                 ";
 301     my $pickupdelay = C4::Context->preference("ReservesMaxPickUpDelay");
 302     my $sth         = $dbh->prepare($query);
 303     $sth->execute();
 304     my @results;
 305     while ( my $issue = $sth->fetchrow_hashref() ) {
 306         my @waitingdate = split( /-/, $issue->{'waitingdate'} );
 307         my @date_due =
 308           Add_Delta_Days( $waitingdate[0], $waitingdate[1], $waitingdate[2],
 309             $pickupdelay );
 310         $issue->{'date_due'} =
 311           sprintf( "%04d-%02d-%02d", $date_due[0], $date_due[1], $date_due[2] );
 312         $issue->{'level'} = 1;   # only one level for Hold Waiting notifications
 313
 314         my $days_to_subtract = 0;
 315         my $calendar = C4::Calendar->new( branchcode => $issue->{'site'} );
 316         while (
 317             $calendar->isHoliday(
 318                 reverse(
 319                     Add_Delta_Days(
 320                         $waitingdate[0], $waitingdate[1],
 321                         $waitingdate[2], $days_to_subtract
 322                     )
 323                 )
 324             )
 325           )
 326         {
 327             $days_to_subtract++;
 328         }
 329         $issue->{'days_since_waiting'} =
 330           $issue->{'days_since_waiting'} - $days_to_subtract;
 331
 332         if (
 333             (
 334                 grep $_ eq $issue->{'days_since_waiting'},
 335                 @holds_waiting_days_to_call
 336             )
 337             || !scalar(@holds_waiting_days_to_call)
 338           )
 339         {
 340             push @results, $issue;
 341         }
 342     }
 343     return @results;
 344
 345 }