misc/import_patrons.pl

   1 #!/usr/bin/perl
   2
   3 # Parts copyright 2014 ByWater Solutions
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Getopt::Long qw( GetOptions );
  23 use Pod::Usage qw( pod2usage );
  24
  25 use Koha::Script;
  26 use Koha::Patrons::Import;
  27 my $Import = Koha::Patrons::Import->new();
  28
  29 my $csv_file;
  30 my $matchpoint;
  31 my $overwrite_cardnumber;
  32 my $overwrite_passwords;
  33 my $welcome_new = 0;
  34 my %defaults;
  35 my $ext_preserve = 0;
  36 my $confirm;
  37 my $verbose      = 0;
  38 my $help;
  39 my @preserve_fields;
  40 my $update_dateexpiry;
  41 my $update_dateexpiry_from_today;
  42
  43 GetOptions(
  44     'c|confirm'                      => \$confirm,
  45     'f|file=s'                       => \$csv_file,
  46     'm|matchpoint=s'                 => \$matchpoint,
  47     'd|default=s'                    => \%defaults,
  48     'o|overwrite'                    => \$overwrite_cardnumber,
  49     'op|overwrite_passwords'         => \$overwrite_passwords,
  50     'ue|update-expiration'           => \$update_dateexpiry,
  51     'et|expiration-from-today'       => \$update_dateexpiry_from_today,
  52     'en|email-new'                   => \$welcome_new,
  53     'p|preserve-extended-attributes' => \$ext_preserve,
  54     'pf|preserve-field=s'            => \@preserve_fields,
  55     'v|verbose+'                     => \$verbose,
  56     'h|help|?'                       => \$help,
  57 ) or pod2usage(2);
  58
  59 pod2usage(1) if $help;
  60 pod2usage(q|--file is required|) unless $csv_file;
  61 pod2usage(q|--matchpoint is required|) unless $matchpoint;
  62
  63 warn "Running in dry-run mode, provide --confirm to apply the changes\n" unless $confirm;
  64
  65 my $handle;
  66 open( $handle, "<", $csv_file ) or die $!;
  67
  68 my $return = $Import->import_patrons(
  69     {
  70         file                         => $handle,
  71         defaults                     => \%defaults,
  72         matchpoint                   => $matchpoint,
  73         overwrite_cardnumber         => $overwrite_cardnumber,
  74         overwrite_passwords          => $overwrite_passwords,
  75         preserve_extended_attributes => $ext_preserve,
  76         preserve_fields              => \@preserve_fields,
  77         update_dateexpiry            => $update_dateexpiry,
  78         update_dateexpiry_from_today => $update_dateexpiry_from_today,
  79         send_welcome                 => $welcome_new,
  80         dry_run                      => !$confirm,
  81     }
  82 );
  83
  84 my $feedback    = $return->{feedback};
  85 my $errors      = $return->{errors};
  86 my $imported    = $return->{imported};
  87 my $overwritten = $return->{overwritten};
  88 my $alreadyindb = $return->{already_in_db};
  89 my $invalid     = $return->{invalid};
  90
  91 if ($verbose) {
  92     my $total = $imported + $alreadyindb + $invalid + $overwritten;
  93     say q{};
  94     say "Import complete:";
  95     say "Imported:    $imported";
  96     say "Overwritten: $overwritten";
  97     say "Skipped:     $alreadyindb";
  98     say "Invalid:     $invalid";
  99     say "Total:       $total";
 100     say q{};
 101 }
 102
 103 if ($verbose > 1 ) {
 104     say "Errors:";
 105     say Data::Dumper::Dumper( $errors );
 106 }
 107
 108 if ($verbose > 2 ) {
 109     say "Feedback:";
 110     say Data::Dumper::Dumper( $feedback );
 111 }
 112
 113 =head1 NAME
 114
 115 import_patrons.pl - CLI script to import patrons data into Koha
 116
 117 =head1 SYNOPSIS
 118
 119 import_patrons.pl --file /path/to/patrons.csv --matchpoint cardnumber --confirm [--default branchcode=MPL] [--overwrite] [--preserve_field <column>] [--preserve-extended-attributes] [--update-expiration] [--expiration-from-today] [--verbose]
 120
 121 =head1 OPTIONS
 122
 123 =over 8
 124
 125 =item B<-h|--help>
 126
 127 Prints a brief help message and exits
 128
 129 =item B<-c|--confirm>
 130
 131 Confirms you really want to import these patrons, otherwise prints this help
 132
 133 =item B<-f|--file>
 134
 135 Path to the CSV file of patrons to import
 136
 137 =item B<-c|--matchpoint>
 138
 139 Field on which to match incoming patrons to existing patrons
 140
 141 =item B<-d|--default>
 142
 143 Set defaults to patron fields, repeatable e.g. --default branchcode=MPL --default categorycode=PT
 144
 145 =item B<-k|--preserve-field>
 146
 147 Prevent specified patron fields for existing patrons from being overwritten
 148
 149 =item B<-o|--overwrite>
 150
 151 Overwrite existing patrons with new data if a match is found
 152
 153 =item B<-p|--preserve-extended-attributes>
 154
 155 Retain extended patron attributes for existing patrons being overwritten
 156
 157 =item B<-en|--email-new>
 158
 159 Send the WELCOME notice email to new users
 160
 161 =item B<-ue|--update-expiration>
 162
 163 If a matching patron is found, extend the expiration date of their account using the patron's enrollment date as the base
 164
 165 =item B<-et|--expiration-from-today>
 166
 167 If a matching patron is found, extend the expiration date of their account using the patron's enrollment date as the base
 168
 169 =item B<-v|--verbose>
 170
 171 Be verbose
 172
 173 Multiple -v options increase the verbosity
 174
 175 2 repetitions or above will report lines in error
 176
 177 3 repetitions or above will report feedback
 178
 179 =back
 180
 181 =cut