opac/opac-ISBDdetail.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # parts copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21
  22 =head1 NAME
  23
  24 opac-ISBDdetail.pl - script to show a biblio in ISBD format
  25
  26 =head1 DESCRIPTION
  27
  28 This script needs a biblionumber as parameter
  29
  30 It shows the biblio
  31
  32 The template is in <templates_dir>/catalogue/ISBDdetail.tt.
  33 this template must be divided into 11 "tabs".
  34
  35 The first 10 tabs present the biblio, the 11th one presents
  36 the items attached to the biblio
  37
  38 =head1 FUNCTIONS
  39
  40 =cut
  41
  42 use Modern::Perl;
  43
  44 use C4::Auth qw( get_template_and_user );
  45 use C4::Context;
  46 use C4::Output qw( parametrized_url output_html_with_http_headers );
  47 use CGI qw ( -utf8 );
  48 use C4::Biblio qw(
  49     CountItemsIssued
  50     GetISBDView
  51     GetMarcControlnumber
  52     GetMarcISSN
  53     TransformMarcToKoha
  54 );
  55 use C4::Reserves;
  56 use C4::Serials qw( CountSubscriptionFromBiblionumber SearchSubscriptions GetLatestSerials );
  57 use C4::Koha qw(
  58     GetNormalizedEAN
  59     GetNormalizedISBN
  60     GetNormalizedOCLCNumber
  61     GetNormalizedUPC
  62 );
  63 use Koha::CirculationRules;
  64 use Koha::ItemTypes;
  65 use Koha::Patrons;
  66 use Koha::RecordProcessor;
  67 use Koha::Biblios;
  68
  69 my $query = CGI->new();
  70 my $biblionumber = $query->param('biblionumber');
  71 my $biblio;
  72 $biblio = Koha::Biblios->find( $biblionumber, { prefetch => [ 'metadata', 'items' ] } ) if $biblionumber;
  73 if( !$biblio ) {
  74     print $query->redirect('/cgi-bin/koha/errors/404.pl');
  75     exit;
  76 }
  77
  78 #open template
  79 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  80     {
  81         template_name   => "opac-ISBDdetail.tt",
  82         query           => $query,
  83         type            => "opac",
  84         authnotrequired => ( C4::Context->preference("OpacPublic") ? 1 : 0 ),
  85     }
  86 );
  87
  88 my $patron = Koha::Patrons->find($loggedinuser);
  89
  90 my $opachiddenitems_rules = C4::Context->yaml_preference('OpacHiddenItems');
  91
  92 unless ( $patron and $patron->category->override_hidden_items ) {
  93     # only skip this check if there's a logged in user
  94     # and its category overrides OpacHiddenItems
  95     if ( $biblio->hidden_in_opac({ rules => $opachiddenitems_rules }) ) {
  96         print $query->redirect('/cgi-bin/koha/errors/404.pl'); # escape early
  97         exit;
  98     }
  99 }
 100
 101 my $record = $biblio->metadata->record;
 102 my @items  = $biblio->items->filter_by_visible_in_opac({ patron => $patron })->as_list;
 103
 104 my $record_processor = Koha::RecordProcessor->new(
 105     {   filters => [ 'EmbedItems', 'ViewPolicy' ],
 106         options => {
 107             interface     => 'opac',
 108             frameworkcode => $biblio->frameworkcode,
 109             items         => \@items
 110         }
 111     }
 112 );
 113 $record_processor->process($record);
 114
 115 # get biblionumbers stored in the cart
 116 if(my $cart_list = $query->cookie("bib_list")){
 117     my @cart_list = split(/\//, $cart_list);
 118     if ( grep {$_ eq $biblionumber} @cart_list) {
 119         $template->param( incart => 1 );
 120     }
 121 }
 122
 123 my $marcflavour = C4::Context->preference("marcflavour");
 124 # some useful variables for enhanced content;
 125 # in each case, we're grabbing the first value we find in
 126 # the record and normalizing it
 127 my $upc  = GetNormalizedUPC( $record, $marcflavour );
 128 my $ean  = GetNormalizedEAN( $record, $marcflavour );
 129 my $oclc = GetNormalizedOCLCNumber( $record, $marcflavour );
 130 my $isbn = GetNormalizedISBN( undef, $record, $marcflavour );
 131 my $content_identifier_exists;
 132 if ( $isbn or $ean or $oclc or $upc ) {
 133     $content_identifier_exists = 1;
 134 }
 135 $template->param(
 136     normalized_upc            => $upc,
 137     normalized_ean            => $ean,
 138     normalized_oclc           => $oclc,
 139     normalized_isbn           => $isbn,
 140     content_identifier_exists => $content_identifier_exists,
 141 );
 142
 143 #coping with subscriptions
 144 my $subscriptionsnumber = CountSubscriptionFromBiblionumber($biblionumber);
 145 my $dat                 = TransformMarcToKoha( $record );
 146
 147 my @subscriptions       = SearchSubscriptions({ biblionumber => $biblionumber, orderby => 'title' });
 148 my @subs;
 149 foreach my $subscription (@subscriptions) {
 150     my %cell;
 151         my $serials_to_display;
 152     $cell{subscriptionid}    = $subscription->{subscriptionid};
 153     $cell{subscriptionnotes} = $subscription->{notes};
 154     $cell{branchcode}        = $subscription->{branchcode};
 155
 156     #get the three latest serials.
 157         $serials_to_display = $subscription->{opacdisplaycount};
 158         $serials_to_display = C4::Context->preference('OPACSerialIssueDisplayCount') unless $serials_to_display;
 159         $cell{opacdisplaycount} = $serials_to_display;
 160     $cell{latestserials} =
 161       GetLatestSerials( $subscription->{subscriptionid}, $serials_to_display );
 162     push @subs, \%cell;
 163 }
 164
 165 $template->param(
 166     subscriptions       => \@subs,
 167     subscriptionsnumber => $subscriptionsnumber,
 168 );
 169
 170 my $norequests = 1;
 171 my $allow_onshelf_holds;
 172 my $res = GetISBDView({
 173     'record'    => $record,
 174     'template'  => 'opac',
 175     'framework' => $biblio->frameworkcode
 176 });
 177
 178 my $items = $biblio->items;
 179 while ( my $item = $items->next ) {
 180     $norequests = 0
 181       if $norequests
 182         && !$item->withdrawn
 183         && !$item->itemlost
 184         && ($item->notforloan < 0 || not $item->notforloan )
 185         && !Koha::ItemTypes->find($item->effective_itemtype)->notforloan
 186         && $item->itemnumber;
 187
 188     $allow_onshelf_holds = Koha::CirculationRules->get_onshelfholds_policy( { item => $item, patron => $patron } )
 189       unless $allow_onshelf_holds;
 190 }
 191
 192 if( $allow_onshelf_holds || CountItemsIssued($biblionumber) || $biblio->has_items_waiting_or_intransit ) {
 193     $template->param( ReservableItems => 1 );
 194 }
 195
 196 $template->param(
 197     RequestOnOpac       => C4::Context->preference("RequestOnOpac"),
 198     norequests   => $norequests,
 199     ISBD         => $res,
 200     biblio       => $biblio,
 201 );
 202
 203 #Search for title in links
 204 my $marccontrolnumber   = GetMarcControlnumber ($record, $marcflavour);
 205 my $marcissns = GetMarcISSN ( $record, $marcflavour );
 206 my $issn = $marcissns->[0] || '';
 207
 208 if (my $search_for_title = C4::Context->preference('OPACSearchForTitleIn')){
 209     $dat->{title} =~ s/\/+$//; # remove trailing slash
 210     $dat->{title} =~ s/\s+$//; # remove trailing space
 211     $search_for_title = parametrized_url(
 212         $search_for_title,
 213         {
 214             TITLE         => $dat->{title},
 215             AUTHOR        => $dat->{author},
 216             ISBN          => $isbn,
 217             ISSN          => $issn,
 218             CONTROLNUMBER => $marccontrolnumber,
 219             BIBLIONUMBER  => $biblionumber,
 220         }
 221     );
 222     $template->param('OPACSearchForTitleIn' => $search_for_title);
 223 }
 224
 225 if( C4::Context->preference('ArticleRequests') ) {
 226     my $itemtype = Koha::ItemTypes->find($biblio->itemtype);
 227     my $artreqpossible = $patron
 228         ? $biblio->can_article_request( $patron )
 229         : $itemtype
 230         ? $itemtype->may_article_request
 231         : q{};
 232     $template->param( artreqpossible => $artreqpossible );
 233 }
 234
 235 output_html_with_http_headers $query, $cookie, $template->output;