opac/opac-downloadcart.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 BibLibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23 use Encode qw( encode );
  24
  25 use C4::Auth qw( get_template_and_user );
  26 use C4::Biblio qw( GetFrameworkCode GetISBDView );
  27 use C4::Output qw( output_html_with_http_headers );
  28 use C4::Record;
  29 use C4::Ris qw( marc2ris );
  30 use Koha::Biblios;
  31 use Koha::CsvProfiles;
  32 use Koha::RecordProcessor;
  33
  34 use utf8;
  35 my $query = CGI->new();
  36
  37 my ( $template, $borrowernumber, $cookie ) = get_template_and_user (
  38     {
  39         template_name   => "opac-downloadcart.tt",
  40         query           => $query,
  41         type            => "opac",
  42         authnotrequired => ( C4::Context->preference("OpacPublic") ? 1 : 0 ),
  43     }
  44 );
  45
  46 my $bib_list = $query->param('bib_list');
  47 my $format  = $query->param('format');
  48 my $dbh     = C4::Context->dbh;
  49
  50 if ($bib_list && $format) {
  51
  52     my $patron = Koha::Patrons->find($borrowernumber);
  53
  54     my @bibs = split( /\//, $bib_list );
  55
  56     my $marcflavour = C4::Context->preference('marcflavour');
  57     my $output;
  58     my $extension;
  59     my $type;
  60
  61     # CSV
  62     if ($format =~ /^\d+$/) {
  63
  64         my $csv_profile = Koha::CsvProfiles->find($format);
  65         if ( not $csv_profile or $csv_profile->staff_only ) {
  66             print $query->redirect('/cgi-bin/koha/errors/404.pl');
  67             exit;
  68         }
  69
  70         $output = marc2csv(\@bibs, $format);
  71
  72         # Other formats
  73     } else {
  74         my $record_processor = Koha::RecordProcessor->new({
  75             filters => 'ViewPolicy'
  76         });
  77         foreach my $biblionumber (@bibs) {
  78
  79             my $biblio = Koha::Biblios->find($biblionumber);
  80             my $record = $biblio->metadata->record(
  81                 {
  82                     embed_items => 1,
  83                     opac        => 1,
  84                     patron      => $patron,
  85                 }
  86             );
  87             my $framework = &GetFrameworkCode( $biblio );
  88             $record_processor->options({
  89                 interface => 'opac',
  90                 frameworkcode => $framework
  91             });
  92             $record_processor->process($record);
  93
  94             next unless $record;
  95
  96             if ($format eq 'iso2709') {
  97                 #NOTE: If we don't explicitly UTF-8 encode the output,
  98                 #the browser will guess the encoding, and it won't always choose UTF-8.
  99                 $output .= encode("UTF-8", $record->as_usmarc()) // q{};
 100             }
 101             elsif ($format eq 'ris') {
 102                 $output .= marc2ris($record);
 103             }
 104             elsif ($format eq 'bibtex') {
 105                 $output .= marc2bibtex($record, $biblio);
 106             }
 107             elsif ( $format eq 'isbd' ) {
 108                 my $framework = GetFrameworkCode( $biblio );
 109                 $output   .= GetISBDView({
 110                     'record'    => $record,
 111                     'template'  => 'opac',
 112                     'framework' => $framework,
 113                 });
 114                 $extension = "txt";
 115                 $type      = "text/plain";
 116             }
 117         }
 118     }
 119
 120     # If it was a CSV export we change the format after the export so the file extension is fine
 121     $format = "csv" if ($format =~ m/^\d+$/);
 122
 123     print $query->header(
 124                                -type => ($type) ? $type : 'application/octet-stream',
 125         -'Content-Transfer-Encoding' => 'binary',
 126                          -attachment => ($extension) ? "cart.$format.$extension" : "cart.$format"
 127     );
 128     print $output;
 129
 130 } else {
 131     $template->param(
 132         csv_profiles => Koha::CsvProfiles->search(
 133             {
 134                 type       => 'marc',
 135                 used_for   => 'export_records',
 136                 staff_only => 0
 137             }
 138         ),
 139         bib_list => $bib_list,
 140     );
 141     output_html_with_http_headers $query, $cookie, $template->output;
 142 }