opac/opac-memberentry.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use CGI qw ( -utf8 );
  21 use Digest::MD5 qw( md5_base64 md5_hex );
  22 use JSON;
  23 use List::MoreUtils qw( any each_array uniq );
  24 use String::Random qw( random_string );
  25
  26 use C4::Auth;
  27 use C4::Output;
  28 use C4::Members;
  29 use C4::Members::Attributes qw( GetBorrowerAttributes );
  30 use C4::Form::MessagingPreferences;
  31 use Koha::AuthUtils;
  32 use Koha::Patrons;
  33 use Koha::Patron::Consent;
  34 use Koha::Patron::Modification;
  35 use Koha::Patron::Modifications;
  36 use C4::Scrubber;
  37 use Email::Valid;
  38 use Koha::DateUtils;
  39 use Koha::Libraries;
  40 use Koha::Patron::Attribute::Types;
  41 use Koha::Patron::Attributes;
  42 use Koha::Patron::Images;
  43 use Koha::Patron::Modification;
  44 use Koha::Patron::Modifications;
  45 use Koha::Patrons;
  46 use Koha::Token;
  47
  48 my $cgi = new CGI;
  49 my $dbh = C4::Context->dbh;
  50
  51 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  52     {
  53         template_name   => "opac-memberentry.tt",
  54         type            => "opac",
  55         query           => $cgi,
  56         authnotrequired => 1,
  57     }
  58 );
  59
  60 unless ( C4::Context->preference('PatronSelfRegistration') || $borrowernumber )
  61 {
  62     print $cgi->redirect("/cgi-bin/koha/opac-main.pl");
  63     exit;
  64 }
  65
  66 my $action = $cgi->param('action') || q{};
  67 if ( $action eq q{} ) {
  68     if ($borrowernumber) {
  69         $action = 'edit';
  70     }
  71     else {
  72         $action = 'new';
  73     }
  74 }
  75
  76 my $mandatory = GetMandatoryFields($action);
  77
  78 my @libraries = Koha::Libraries->search;
  79 if ( my @libraries_to_display = split '\|', C4::Context->preference('PatronSelfRegistrationLibraryList') ) {
  80     @libraries = map { my $b = $_; my $branchcode = $_->branchcode; grep( /^$branchcode$/, @libraries_to_display ) ? $b : () } @libraries;
  81 }
  82 my ( $min, $max ) = C4::Members::get_cardnumber_length();
  83 if ( defined $min ) {
  84      $template->param(
  85          minlength_cardnumber => $min,
  86          maxlength_cardnumber => $max
  87      );
  88  }
  89
  90 $template->param(
  91     action            => $action,
  92     hidden            => GetHiddenFields( $mandatory, $action ),
  93     mandatory         => $mandatory,
  94     libraries         => \@libraries,
  95     OPACPatronDetails => C4::Context->preference('OPACPatronDetails'),
  96 );
  97
  98 my $attributes = ParsePatronAttributes($borrowernumber,$cgi);
  99 my $conflicting_attribute = 0;
 100
 101 foreach my $attr (@$attributes) {
 102     unless ( C4::Members::Attributes::CheckUniqueness($attr->{code}, $attr->{value}, $borrowernumber) ) {
 103         my $attr_info = C4::Members::AttributeTypes->fetch($attr->{code});
 104         $template->param(
 105             extended_unique_id_failed_code => $attr->{code},
 106             extended_unique_id_failed_value => $attr->{value},
 107             extended_unique_id_failed_description => $attr_info->description()
 108         );
 109         $conflicting_attribute = 1;
 110     }
 111 }
 112
 113 if ( $action eq 'create' ) {
 114
 115     my %borrower = ParseCgiForBorrower($cgi);
 116
 117     %borrower = DelEmptyFields(%borrower);
 118
 119     my @empty_mandatory_fields = CheckMandatoryFields( \%borrower, $action );
 120     my $invalidformfields = CheckForInvalidFields(\%borrower);
 121     delete $borrower{'password2'};
 122     my $cardnumber_error_code;
 123     if ( !grep { $_ eq 'cardnumber' } @empty_mandatory_fields ) {
 124         # No point in checking the cardnumber if it's missing and mandatory, it'll just generate a
 125         # spurious length warning.
 126         $cardnumber_error_code = checkcardnumber( $borrower{cardnumber}, $borrower{borrowernumber} );
 127     }
 128
 129     if ( @empty_mandatory_fields || @$invalidformfields || $cardnumber_error_code || $conflicting_attribute ) {
 130         if ( $cardnumber_error_code == 1 ) {
 131             $template->param( cardnumber_already_exists => 1 );
 132         } elsif ( $cardnumber_error_code == 2 ) {
 133             $template->param( cardnumber_wrong_length => 1 );
 134         }
 135
 136         $template->param(
 137             empty_mandatory_fields => \@empty_mandatory_fields,
 138             invalid_form_fields    => $invalidformfields,
 139             borrower               => \%borrower
 140         );
 141         $template->param( patron_attribute_classes => GeneratePatronAttributesForm( undef, $attributes ) );
 142     }
 143     elsif (
 144         md5_base64( uc( $cgi->param('captcha') ) ) ne $cgi->param('captcha_digest') )
 145     {
 146         $template->param(
 147             failed_captcha => 1,
 148             borrower       => \%borrower
 149         );
 150         $template->param( patron_attribute_classes => GeneratePatronAttributesForm( undef, $attributes ) );
 151     }
 152     else {
 153         if (
 154             C4::Context->boolean_preference(
 155                 'PatronSelfRegistrationVerifyByEmail')
 156           )
 157         {
 158             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 159                 {
 160                     template_name   => "opac-registration-email-sent.tt",
 161                     type            => "opac",
 162                     query           => $cgi,
 163                     authnotrequired => 1,
 164                 }
 165             );
 166             $template->param( 'email' => $borrower{'email'} );
 167
 168             my $verification_token = md5_hex( time().{}.rand().{}.$$ );
 169             while ( Koha::Patron::Modifications->search( { verification_token => $verification_token } )->count() ) {
 170                 $verification_token = md5_hex( time().{}.rand().{}.$$ );
 171             }
 172
 173             $borrower{password}          = Koha::AuthUtils::generate_password unless $borrower{password};
 174             $borrower{verification_token} = $verification_token;
 175
 176             Koha::Patron::Modification->new( \%borrower )->store();
 177
 178             #Send verification email
 179             my $letter = C4::Letters::GetPreparedLetter(
 180                 module      => 'members',
 181                 letter_code => 'OPAC_REG_VERIFY',
 182                 lang        => 'default', # Patron does not have a preferred language defined yet
 183                 tables      => {
 184                     borrower_modifications => $verification_token,
 185                 },
 186             );
 187
 188             C4::Letters::EnqueueLetter(
 189                 {
 190                     letter                 => $letter,
 191                     message_transport_type => 'email',
 192                     to_address             => $borrower{'email'},
 193                     from_address =>
 194                       C4::Context->preference('KohaAdminEmailAddress'),
 195                 }
 196             );
 197         }
 198         else {
 199             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 200                 {
 201                     template_name   => "opac-registration-confirmation.tt",
 202                     type            => "opac",
 203                     query           => $cgi,
 204                     authnotrequired => 1,
 205                 }
 206             );
 207
 208             $borrower{categorycode}     ||= C4::Context->preference('PatronSelfRegistrationDefaultCategory');
 209             $borrower{password}         ||= Koha::AuthUtils::generate_password;
 210             my $consent_dt = delete $borrower{gdpr_proc_consent};
 211             my $patron = Koha::Patron->new( \%borrower )->store;
 212             Koha::Patron::Consent->new({ borrowernumber => $patron->borrowernumber, type => 'GDPR_PROCESSING', given_on => $consent_dt })->store if $consent_dt;
 213             if ( $patron ) {
 214                 C4::Members::Attributes::SetBorrowerAttributes( $patron->borrowernumber, $attributes );
 215                 if ( C4::Context->preference('EnhancedMessagingPreferences') ) {
 216                     C4::Form::MessagingPreferences::handle_form_action(
 217                         $cgi,
 218                         { borrowernumber => $patron->borrowernumber },
 219                         $template,
 220                         1,
 221                         C4::Context->preference('PatronSelfRegistrationDefaultCategory')
 222                     );
 223                 }
 224
 225                 $template->param( password_cleartext => $patron->plain_text_password );
 226                 $template->param( borrower => $patron->unblessed );
 227             } else {
 228                 # FIXME Handle possible errors here
 229             }
 230             $template->param(
 231                 PatronSelfRegistrationAdditionalInstructions =>
 232                   C4::Context->preference(
 233                     'PatronSelfRegistrationAdditionalInstructions')
 234             );
 235         }
 236     }
 237 }
 238 elsif ( $action eq 'update' ) {
 239
 240     my $borrower = Koha::Patrons->find( $borrowernumber )->unblessed;
 241     die "Wrong CSRF token"
 242         unless Koha::Token->new->check_csrf({
 243             session_id => scalar $cgi->cookie('CGISESSID'),
 244             token  => scalar $cgi->param('csrf_token'),
 245         });
 246
 247     my %borrower = ParseCgiForBorrower($cgi);
 248     $borrower{borrowernumber} = $borrowernumber;
 249
 250     my @empty_mandatory_fields =
 251       CheckMandatoryFields( \%borrower, $action );
 252     my $invalidformfields = CheckForInvalidFields(\%borrower);
 253
 254     # Send back the data to the template
 255     %borrower = ( %$borrower, %borrower );
 256
 257     if (@empty_mandatory_fields || @$invalidformfields) {
 258         $template->param(
 259             empty_mandatory_fields => \@empty_mandatory_fields,
 260             invalid_form_fields    => $invalidformfields,
 261             borrower               => \%borrower,
 262             csrf_token             => Koha::Token->new->generate_csrf({
 263                 session_id => scalar $cgi->cookie('CGISESSID'),
 264             }),
 265         );
 266         $template->param( patron_attribute_classes => GeneratePatronAttributesForm( $borrowernumber, $attributes ) );
 267
 268         $template->param( action => 'edit' );
 269     }
 270     else {
 271         my %borrower_changes = DelUnchangedFields( $borrowernumber, %borrower );
 272         $borrower_changes{'changed_fields'} = join ',', keys %borrower_changes;
 273         my $extended_attributes_changes = FilterUnchangedAttributes( $borrowernumber, $attributes );
 274
 275         if ( %borrower_changes || scalar @{$extended_attributes_changes} > 0 ) {
 276             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 277                 {
 278                     template_name   => "opac-memberentry-update-submitted.tt",
 279                     type            => "opac",
 280                     query           => $cgi,
 281                     authnotrequired => 1,
 282                 }
 283             );
 284
 285             $borrower_changes{borrowernumber} = $borrowernumber;
 286             $borrower_changes{extended_attributes} = to_json($extended_attributes_changes);
 287
 288             Koha::Patron::Modifications->search({ borrowernumber => $borrowernumber })->delete;
 289
 290             my $m = Koha::Patron::Modification->new( \%borrower_changes )->store();
 291
 292             my $patron = Koha::Patrons->find( $borrowernumber );
 293             $template->param( borrower => $patron->unblessed );
 294         }
 295         else {
 296             my $patron = Koha::Patrons->find( $borrowernumber );
 297             $template->param(
 298                 action => 'edit',
 299                 nochanges => 1,
 300                 borrower => $patron->unblessed,
 301                 patron_attribute_classes => GeneratePatronAttributesForm( $borrowernumber, $attributes ),
 302                 csrf_token => Koha::Token->new->generate_csrf({
 303                     session_id => scalar $cgi->cookie('CGISESSID'),
 304                 }),
 305             );
 306         }
 307     }
 308 }
 309 elsif ( $action eq 'edit' ) {    #Display logged in borrower's data
 310     my $patron = Koha::Patrons->find( $borrowernumber );
 311     my $borrower = $patron->unblessed;
 312
 313     $template->param(
 314         borrower  => $borrower,
 315         hidden => GetHiddenFields( $mandatory, 'edit' ),
 316         csrf_token => Koha::Token->new->generate_csrf({
 317             session_id => scalar $cgi->cookie('CGISESSID'),
 318         }),
 319     );
 320
 321     if (C4::Context->preference('OPACpatronimages')) {
 322         $template->param( display_patron_image => 1 ) if $patron->image;
 323     }
 324
 325     $template->param( patron_attribute_classes => GeneratePatronAttributesForm( $borrowernumber ) );
 326 } else {
 327     # Render self-registration page
 328     $template->param( patron_attribute_classes => GeneratePatronAttributesForm() );
 329 }
 330
 331 my $captcha = random_string("CCCCC");
 332 my $patron_param = scalar Koha::Patrons->find( $borrowernumber );
 333
 334 $template->param(
 335     captcha        => $captcha,
 336     captcha_digest => md5_base64($captcha),
 337     patron         => $patron_param,
 338     has_guarantor_flag => $patron_param->guarantor_relationships->guarantors->_resultset->count
 339 );
 340
 341 output_html_with_http_headers $cgi, $cookie, $template->output, undef, { force_no_caching => 1 };
 342
 343 sub GetHiddenFields {
 344     my ( $mandatory, $action ) = @_;
 345     my %hidden_fields;
 346
 347     my $BorrowerUnwantedField = $action eq 'edit' || $action eq 'update' ?
 348       C4::Context->preference( "PatronSelfModificationBorrowerUnwantedField" ) :
 349       C4::Context->preference( "PatronSelfRegistrationBorrowerUnwantedField" );
 350
 351     my @fields = split( /\|/, $BorrowerUnwantedField || q|| );
 352     foreach (@fields) {
 353         next unless m/\w/o;
 354         #Don't hide mandatory fields
 355         next if $mandatory->{$_};
 356         $hidden_fields{$_} = 1;
 357     }
 358
 359     return \%hidden_fields;
 360 }
 361
 362 sub GetMandatoryFields {
 363     my ($action) = @_;
 364
 365     my %mandatory_fields;
 366
 367     my $BorrowerMandatoryField =
 368       C4::Context->preference("PatronSelfRegistrationBorrowerMandatoryField");
 369
 370     my @fields = split( /\|/, $BorrowerMandatoryField );
 371     push @fields, 'gdpr_proc_consent' if C4::Context->preference('GDPR_Policy') && $action eq 'create';
 372
 373     foreach (@fields) {
 374         $mandatory_fields{$_} = 1;
 375     }
 376
 377     if ( $action eq 'create' || $action eq 'new' ) {
 378         $mandatory_fields{'email'} = 1
 379           if C4::Context->boolean_preference(
 380             'PatronSelfRegistrationVerifyByEmail');
 381     }
 382
 383     return \%mandatory_fields;
 384 }
 385
 386 sub CheckMandatoryFields {
 387     my ( $borrower, $action ) = @_;
 388
 389     my @empty_mandatory_fields;
 390
 391     my $mandatory_fields = GetMandatoryFields($action);
 392     delete $mandatory_fields->{'cardnumber'};
 393
 394     foreach my $key ( keys %$mandatory_fields ) {
 395         push( @empty_mandatory_fields, $key )
 396           unless ( defined( $borrower->{$key} ) && $borrower->{$key} );
 397     }
 398
 399     return @empty_mandatory_fields;
 400 }
 401
 402 sub CheckForInvalidFields {
 403     my $borrower = shift;
 404     my @invalidFields;
 405     if ($borrower->{'email'}) {
 406         unless ( Email::Valid->address($borrower->{'email'}) ) {
 407             push(@invalidFields, "email");
 408         } elsif ( C4::Context->preference("PatronSelfRegistrationEmailMustBeUnique") ) {
 409             my $patrons_with_same_email = Koha::Patrons->search( # FIXME Should be search_limited?
 410                 {
 411                     email => $borrower->{email},
 412                     (
 413                         exists $borrower->{borrowernumber}
 414                         ? ( borrowernumber =>
 415                               { '!=' => $borrower->{borrowernumber} } )
 416                         : ()
 417                     )
 418                 }
 419             )->count;
 420             if ( $patrons_with_same_email ) {
 421                 push @invalidFields, "duplicate_email";
 422             }
 423         }
 424     }
 425     if ($borrower->{'emailpro'}) {
 426         push(@invalidFields, "emailpro") if (!Email::Valid->address($borrower->{'emailpro'}));
 427     }
 428     if ($borrower->{'B_email'}) {
 429         push(@invalidFields, "B_email") if (!Email::Valid->address($borrower->{'B_email'}));
 430     }
 431     if ( defined $borrower->{'password'}
 432         and $borrower->{'password'} ne $borrower->{'password2'} )
 433     {
 434         push( @invalidFields, "password_match" );
 435     }
 436     if ( $borrower->{'password'} ) {
 437         my ( $is_valid, $error ) = Koha::AuthUtils::is_password_valid( $borrower->{password} );
 438           unless ( $is_valid ) {
 439               push @invalidFields, 'password_too_short' if $error eq 'too_short';
 440               push @invalidFields, 'password_too_weak' if $error eq 'too_weak';
 441               push @invalidFields, 'password_has_whitespaces' if $error eq 'has_whitespaces';
 442           }
 443     }
 444
 445     return \@invalidFields;
 446 }
 447
 448 sub ParseCgiForBorrower {
 449     my ($cgi) = @_;
 450
 451     my $scrubber = C4::Scrubber->new();
 452     my %borrower;
 453
 454     foreach my $field ( $cgi->param ) {
 455         if ( $field =~ '^borrower_' ) {
 456             my ($key) = substr( $field, 9 );
 457             if ( $field !~ '^borrower_password' ) {
 458                 $borrower{$key} = $scrubber->scrub( scalar $cgi->param($field) );
 459             } else {
 460                 # Allow html characters for passwords
 461                 $borrower{$key} = $cgi->param($field);
 462             }
 463         }
 464     }
 465
 466     my $dob_dt;
 467     $dob_dt = eval { dt_from_string( $borrower{'dateofbirth'} ); }
 468         if ( $borrower{'dateofbirth'} );
 469
 470     if ( $dob_dt ) {
 471         $borrower{'dateofbirth'} = output_pref ( { dt => $dob_dt, dateonly => 1, dateformat => 'iso' } );
 472     }
 473     else {
 474         # Trigger validation
 475         $borrower{'dateofbirth'} = undef;
 476     }
 477
 478     # Replace checkbox 'agreed' by datetime in gdpr_proc_consent
 479     $borrower{gdpr_proc_consent} = dt_from_string if  $borrower{gdpr_proc_consent} && $borrower{gdpr_proc_consent} eq 'agreed';
 480
 481     return %borrower;
 482 }
 483
 484 sub DelUnchangedFields {
 485     my ( $borrowernumber, %new_data ) = @_;
 486     # get the mandatory fields so we can get the hidden fields
 487     my $mandatory = GetMandatoryFields('edit');
 488     my $patron = Koha::Patrons->find( $borrowernumber );
 489     my $current_data = $patron->unblessed;
 490     # get the hidden fields so we don't obliterate them should they have data patrons aren't allowed to modify
 491     my $hidden_fields = GetHiddenFields($mandatory, 'edit');
 492
 493
 494     foreach my $key ( keys %new_data ) {
 495         if ( ($current_data->{$key} eq $new_data{$key}) || $hidden_fields->{$key} ) {
 496            delete $new_data{$key};
 497         }
 498     }
 499
 500     return %new_data;
 501 }
 502
 503 sub DelEmptyFields {
 504     my (%borrower) = @_;
 505
 506     foreach my $key ( keys %borrower ) {
 507         delete $borrower{$key} unless $borrower{$key};
 508     }
 509
 510     return %borrower;
 511 }
 512
 513 sub FilterUnchangedAttributes {
 514     my ( $borrowernumber, $entered_attributes ) = @_;
 515
 516     my @patron_attributes = grep {$_->opac_editable} Koha::Patron::Attributes->search({ borrowernumber => $borrowernumber })->as_list;
 517
 518     my $patron_attribute_types;
 519     foreach my $attr (@patron_attributes) {
 520         $patron_attribute_types->{ $attr->code } += 1;
 521     }
 522
 523     my $passed_attribute_types;
 524     foreach my $attr (@{ $entered_attributes }) {
 525         $passed_attribute_types->{ $attr->{ code } } += 1;
 526     }
 527
 528     my @changed_attributes;
 529
 530     # Loop through the current patron attributes
 531     foreach my $attribute_type ( keys %{ $patron_attribute_types } ) {
 532         if ( $patron_attribute_types->{ $attribute_type } !=  $passed_attribute_types->{ $attribute_type } ) {
 533             # count differs, overwrite all attributes for given type
 534             foreach my $attr (@{ $entered_attributes }) {
 535                 push @changed_attributes, $attr
 536                     if $attr->{ code } eq $attribute_type;
 537             }
 538         } else {
 539             # count matches, check values
 540             my $changes = 0;
 541             foreach my $attr (grep { $_->code eq $attribute_type } @patron_attributes) {
 542                 $changes = 1
 543                     unless any { $_->{ value } eq $attr->attribute } @{ $entered_attributes };
 544                 last if $changes;
 545             }
 546
 547             if ( $changes ) {
 548                 foreach my $attr (@{ $entered_attributes }) {
 549                     push @changed_attributes, $attr
 550                         if $attr->{ code } eq $attribute_type;
 551                 }
 552             }
 553         }
 554     }
 555
 556     # Loop through passed attributes, looking for new ones
 557     foreach my $attribute_type ( keys %{ $passed_attribute_types } ) {
 558         if ( !defined $patron_attribute_types->{ $attribute_type } ) {
 559             # YAY, new stuff
 560             foreach my $attr (grep { $_->{code} eq $attribute_type } @{ $entered_attributes }) {
 561                 push @changed_attributes, $attr;
 562             }
 563         }
 564     }
 565
 566     return \@changed_attributes;
 567 }
 568
 569 sub GeneratePatronAttributesForm {
 570     my ( $borrowernumber, $entered_attributes ) = @_;
 571
 572     # Get all attribute types and the values for this patron (if applicable)
 573     my @types = grep { $_->opac_editable() or $_->opac_display }
 574         Koha::Patron::Attribute::Types->search()->as_list();
 575     if ( scalar(@types) == 0 ) {
 576         return [];
 577     }
 578
 579     my @displayable_attributes = grep { $_->opac_display }
 580         Koha::Patron::Attributes->search({ borrowernumber => $borrowernumber })->as_list;
 581
 582     my %attr_values = ();
 583
 584     # Build the attribute values list either from the passed values
 585     # or taken from the patron itself
 586     if ( defined $entered_attributes ) {
 587         foreach my $attr (@$entered_attributes) {
 588             push @{ $attr_values{ $attr->{code} } }, $attr->{value};
 589         }
 590     }
 591     elsif ( defined $borrowernumber ) {
 592         my @editable_attributes = grep { $_->opac_editable } @displayable_attributes;
 593         foreach my $attr (@editable_attributes) {
 594             push @{ $attr_values{ $attr->code } }, $attr->attribute;
 595         }
 596     }
 597
 598     # Add the non-editable attributes (that don't come from the form)
 599     foreach my $attr ( grep { !$_->opac_editable } @displayable_attributes ) {
 600         push @{ $attr_values{ $attr->code } }, $attr->attribute;
 601     }
 602
 603     # Find all existing classes
 604     my @classes = sort( uniq( map { $_->class } @types ) );
 605     my %items_by_class;
 606
 607     foreach my $attr_type (@types) {
 608         push @{ $items_by_class{ $attr_type->class() } }, {
 609             type => $attr_type,
 610             # If editable, make sure there's at least one empty entry,
 611             # to make the template's job easier
 612             values => $attr_values{ $attr_type->code() } || ['']
 613         }
 614             unless !defined $attr_values{ $attr_type->code() }
 615                     and !$attr_type->opac_editable;
 616     }
 617
 618     # Finally, build a list of containing classes
 619     my @class_loop;
 620     foreach my $class (@classes) {
 621         next unless ( $items_by_class{$class} );
 622
 623         my $av = Koha::AuthorisedValues->search(
 624             { category => 'PA_CLASS', authorised_value => $class } );
 625
 626         my $lib = $av->count ? $av->next->opac_description : $class;
 627
 628         push @class_loop,
 629             {
 630             class => $class,
 631             items => $items_by_class{$class},
 632             lib   => $lib,
 633             };
 634     }
 635
 636     return \@class_loop;
 637 }
 638
 639 sub ParsePatronAttributes {
 640     my ( $borrowernumber, $cgi ) = @_;
 641
 642     my @codes  = $cgi->multi_param('patron_attribute_code');
 643     my @values = $cgi->multi_param('patron_attribute_value');
 644
 645     my @editable_attribute_types
 646         = map { $_->code } Koha::Patron::Attribute::Types->search({ opac_editable => 1 });
 647
 648     my $ea = each_array( @codes, @values );
 649     my @attributes;
 650
 651     my $delete_candidates = {};
 652
 653     while ( my ( $code, $value ) = $ea->() ) {
 654         if ( any { $_ eq $code } @editable_attribute_types ) {
 655             # It is an editable attribute
 656             if ( !defined($value) or $value eq '' ) {
 657                 $delete_candidates->{$code} = 1
 658                     unless $delete_candidates->{$code};
 659             }
 660             else {
 661                 # we've got a value
 662                 push @attributes, { code => $code, value => $value };
 663
 664                 # 'code' is no longer a delete candidate
 665                 delete $delete_candidates->{$code}
 666                     if defined $delete_candidates->{$code};
 667             }
 668         }
 669     }
 670
 671     foreach my $code ( keys %{$delete_candidates} ) {
 672         if ( Koha::Patron::Attributes->search({
 673                 borrowernumber => $borrowernumber, code => $code })->count > 0 )
 674         {
 675             push @attributes, { code => $code, value => '' }
 676                 unless any { $_->{code} eq $code } @attributes;
 677         }
 678     }
 679
 680     return \@attributes;
 681 }
 682
 683
 684 1;