opac/opac-memberentry.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use CGI qw ( -utf8 );
  21 use Digest::MD5 qw( md5_base64 md5_hex );
  22 use String::Random qw( random_string );
  23 use HTML::Entities;
  24
  25 use C4::Auth;
  26 use C4::Output;
  27 use C4::Members;
  28 use C4::Form::MessagingPreferences;
  29 use Koha::Patrons;
  30 use Koha::Patron::Modifications;
  31 use C4::Branch qw(GetBranchesLoop);
  32 use C4::Scrubber;
  33 use Email::Valid;
  34 use Koha::DateUtils;
  35 use Koha::Patron::Images;
  36 use Koha::Token;
  37
  38 my $cgi = new CGI;
  39 my $dbh = C4::Context->dbh;
  40
  41 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  42     {
  43         template_name   => "opac-memberentry.tt",
  44         type            => "opac",
  45         query           => $cgi,
  46         authnotrequired => 1,
  47     }
  48 );
  49
  50 unless ( C4::Context->preference('PatronSelfRegistration') || $borrowernumber )
  51 {
  52     print $cgi->redirect("/cgi-bin/koha/opac-main.pl");
  53     exit;
  54 }
  55
  56 my $action = $cgi->param('action') || q{};
  57 if ( $action eq q{} ) {
  58     if ($borrowernumber) {
  59         $action = 'edit';
  60     }
  61     else {
  62         $action = 'new';
  63     }
  64 }
  65
  66 my $mandatory = GetMandatoryFields($action);
  67
  68 $template->param(
  69     action            => $action,
  70     hidden            => GetHiddenFields( $mandatory, 'registration' ),
  71     mandatory         => $mandatory,
  72     branches          => GetBranchesLoop(),
  73     OPACPatronDetails => C4::Context->preference('OPACPatronDetails'),
  74 );
  75
  76 if ( $action eq 'create' ) {
  77
  78     my %borrower = ParseCgiForBorrower($cgi);
  79
  80     %borrower = DelEmptyFields(%borrower);
  81
  82     my @empty_mandatory_fields = CheckMandatoryFields( \%borrower, $action );
  83     my $invalidformfields = CheckForInvalidFields(\%borrower);
  84     delete $borrower{'password2'};
  85     my $cardnumber_error_code;
  86     if ( !grep { $_ eq 'cardnumber' } @empty_mandatory_fields ) {
  87         # No point in checking the cardnumber if it's missing and mandatory, it'll just generate a
  88         # spurious length warning.
  89         $cardnumber_error_code = checkcardnumber( $borrower{cardnumber}, $borrower{borrowernumber} );
  90     }
  91
  92     if ( @empty_mandatory_fields || @$invalidformfields || $cardnumber_error_code ) {
  93         if ( $cardnumber_error_code == 1 ) {
  94             $template->param( cardnumber_already_exists => 1 );
  95         } elsif ( $cardnumber_error_code == 2 ) {
  96             $template->param( cardnumber_wrong_length => 1 );
  97         }
  98
  99         $template->param(
 100             empty_mandatory_fields => \@empty_mandatory_fields,
 101             invalid_form_fields    => $invalidformfields,
 102             borrower               => \%borrower
 103         );
 104     }
 105     elsif (
 106         md5_base64( uc( $cgi->param('captcha') ) ) ne $cgi->param('captcha_digest') )
 107     {
 108         $template->param(
 109             failed_captcha => 1,
 110             borrower       => \%borrower
 111         );
 112     }
 113     else {
 114         if (
 115             C4::Context->boolean_preference(
 116                 'PatronSelfRegistrationVerifyByEmail')
 117           )
 118         {
 119             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 120                 {
 121                     template_name   => "opac-registration-email-sent.tt",
 122                     type            => "opac",
 123                     query           => $cgi,
 124                     authnotrequired => 1,
 125                 }
 126             );
 127             $template->param( 'email' => $borrower{'email'} );
 128
 129             my $verification_token = md5_hex( \%borrower );
 130             $borrower{'password'} = random_string("..........");
 131
 132             Koha::Patron::Modifications->new(
 133                 verification_token => $verification_token )
 134               ->AddModifications(\%borrower);
 135
 136             #Send verification email
 137             my $letter = C4::Letters::GetPreparedLetter(
 138                 module      => 'members',
 139                 letter_code => 'OPAC_REG_VERIFY',
 140                 tables      => {
 141                     borrower_modifications => $verification_token,
 142                 },
 143             );
 144
 145             C4::Letters::EnqueueLetter(
 146                 {
 147                     letter                 => $letter,
 148                     message_transport_type => 'email',
 149                     to_address             => $borrower{'email'},
 150                     from_address =>
 151                       C4::Context->preference('KohaAdminEmailAddress'),
 152                 }
 153             );
 154         }
 155         else {
 156             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 157                 {
 158                     template_name   => "opac-registration-confirmation.tt",
 159                     type            => "opac",
 160                     query           => $cgi,
 161                     authnotrequired => 1,
 162                 }
 163             );
 164
 165             $template->param( OpacPasswordChange =>
 166                   C4::Context->preference('OpacPasswordChange') );
 167
 168             my ( $borrowernumber, $password ) = AddMember_Opac(%borrower);
 169             C4::Form::MessagingPreferences::handle_form_action($cgi, { borrowernumber => $borrowernumber }, $template, 1, C4::Context->preference('PatronSelfRegistrationDefaultCategory') ) if $borrowernumber && C4::Context->preference('EnhancedMessagingPreferences');
 170
 171             $template->param( password_cleartext => $password );
 172             $template->param(
 173                 borrower => GetMember( borrowernumber => $borrowernumber ) );
 174             $template->param(
 175                 PatronSelfRegistrationAdditionalInstructions =>
 176                   C4::Context->preference(
 177                     'PatronSelfRegistrationAdditionalInstructions')
 178             );
 179         }
 180     }
 181 }
 182 elsif ( $action eq 'update' ) {
 183
 184     my $borrower = GetMember( borrowernumber => $borrowernumber );
 185     die "Wrong CSRF token"
 186         unless Koha::Token->new->check_csrf({
 187             id     => $borrower->{userid},
 188             secret => md5_base64( C4::Context->config('pass') ),
 189             token  => scalar $cgi->param('csrf_token'),
 190         });
 191
 192     my %borrower = ParseCgiForBorrower($cgi);
 193
 194     my %borrower_changes = DelEmptyFields(%borrower);
 195     my @empty_mandatory_fields =
 196       CheckMandatoryFields( \%borrower_changes, $action );
 197     my $invalidformfields = CheckForInvalidFields(\%borrower);
 198
 199     if (@empty_mandatory_fields || @$invalidformfields) {
 200         $template->param(
 201             empty_mandatory_fields => \@empty_mandatory_fields,
 202             invalid_form_fields    => $invalidformfields,
 203             borrower               => \%borrower,
 204             csrf_token             => Koha::Token->new->generate_csrf({
 205                 id     => $borrower->{userid},
 206                 secret => md5_base64( C4::Context->config('pass') ),
 207             }),
 208         );
 209
 210         $template->param( action => 'edit' );
 211     }
 212     else {
 213         my %borrower_changes = DelUnchangedFields( $borrowernumber, %borrower );
 214         if (%borrower_changes) {
 215             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 216                 {
 217                     template_name   => "opac-memberentry-update-submitted.tt",
 218                     type            => "opac",
 219                     query           => $cgi,
 220                     authnotrequired => 1,
 221                 }
 222             );
 223
 224             my $m =
 225               Koha::Patron::Modifications->new(
 226                 borrowernumber => $borrowernumber );
 227
 228             $m->DelModifications;
 229             $m->AddModifications(\%borrower_changes);
 230             $template->param(
 231                 borrower => GetMember( borrowernumber => $borrowernumber ),
 232             );
 233         }
 234         else {
 235             $template->param(
 236                 action => 'edit',
 237                 nochanges => 1,
 238                 borrower => GetMember( borrowernumber => $borrowernumber ),
 239                 csrf_token => Koha::Token->new->generate_csrf({
 240                     id     => $borrower->{userid},
 241                     secret => md5_base64( C4::Context->config('pass') ),
 242                 }),
 243             );
 244         }
 245     }
 246 }
 247 elsif ( $action eq 'edit' ) {    #Display logged in borrower's data
 248     my $borrower = GetMember( borrowernumber => $borrowernumber );
 249
 250     if (C4::Context->preference('ExtendedPatronAttributes')) {
 251         my $attributes = C4::Members::Attributes::GetBorrowerAttributes($borrowernumber, 'opac');
 252         if (scalar(@$attributes) > 0) {
 253             $borrower->{ExtendedPatronAttributes} = 1;
 254             $borrower->{patron_attributes} = $attributes;
 255         }
 256     }
 257
 258     $template->param(
 259         borrower  => $borrower,
 260         guarantor => scalar Koha::Patrons->find($borrowernumber)->guarantor(),
 261         hidden => GetHiddenFields( $mandatory, 'modification' ),
 262         csrf_token => Koha::Token->new->generate_csrf({
 263             id     => $borrower->{userid},
 264             secret => md5_base64( C4::Context->config('pass') ),
 265         }),
 266     );
 267
 268     if (C4::Context->preference('OPACpatronimages')) {
 269         my $patron_image = Koha::Patron::Images->find($borrower->{borrowernumber});
 270         $template->param( display_patron_image => 1 ) if $patron_image;
 271     }
 272
 273 }
 274
 275 my $captcha = random_string("CCCCC");
 276
 277 $template->param(
 278     captcha        => $captcha,
 279     captcha_digest => md5_base64($captcha)
 280 );
 281
 282 output_html_with_http_headers $cgi, $cookie, $template->output, undef, { force_no_caching => 1 };
 283
 284 sub GetHiddenFields {
 285     my ( $mandatory, $action ) = @_;
 286     my %hidden_fields;
 287
 288     my $BorrowerUnwantedField = $action eq 'modification' ?
 289       C4::Context->preference( "PatronSelfModificationBorrowerUnwantedField" ) :
 290       C4::Context->preference( "PatronSelfRegistrationBorrowerUnwantedField" );
 291
 292     my @fields = split( /\|/, $BorrowerUnwantedField || q|| );
 293     foreach (@fields) {
 294         next unless m/\w/o;
 295         #Don't hide mandatory fields
 296         next if $mandatory->{$_};
 297         $hidden_fields{$_} = 1;
 298     }
 299
 300     return \%hidden_fields;
 301 }
 302
 303 sub GetMandatoryFields {
 304     my ($action) = @_;
 305
 306     my %mandatory_fields;
 307
 308     my $BorrowerMandatoryField =
 309       C4::Context->preference("PatronSelfRegistrationBorrowerMandatoryField");
 310
 311     my @fields = split( /\|/, $BorrowerMandatoryField );
 312
 313     foreach (@fields) {
 314         $mandatory_fields{$_} = 1;
 315     }
 316
 317     if ( $action eq 'create' || $action eq 'new' ) {
 318         $mandatory_fields{'email'} = 1
 319           if C4::Context->boolean_preference(
 320             'PatronSelfRegistrationVerifyByEmail');
 321     }
 322
 323     return \%mandatory_fields;
 324 }
 325
 326 sub CheckMandatoryFields {
 327     my ( $borrower, $action ) = @_;
 328
 329     my @empty_mandatory_fields;
 330
 331     my $mandatory_fields = GetMandatoryFields($action);
 332     delete $mandatory_fields->{'cardnumber'};
 333
 334     foreach my $key ( keys %$mandatory_fields ) {
 335         push( @empty_mandatory_fields, $key )
 336           unless ( defined( $borrower->{$key} ) && $borrower->{$key} );
 337     }
 338
 339     return @empty_mandatory_fields;
 340 }
 341
 342 sub CheckForInvalidFields {
 343     my $minpw = C4::Context->preference('minPasswordLength');
 344     my $borrower = shift;
 345     my @invalidFields;
 346     if ($borrower->{'email'}) {
 347         push(@invalidFields, "email") if (!Email::Valid->address($borrower->{'email'}));
 348     }
 349     if ($borrower->{'emailpro'}) {
 350         push(@invalidFields, "emailpro") if (!Email::Valid->address($borrower->{'emailpro'}));
 351     }
 352     if ($borrower->{'B_email'}) {
 353         push(@invalidFields, "B_email") if (!Email::Valid->address($borrower->{'B_email'}));
 354     }
 355     if ( $borrower->{'password'} ne $borrower->{'password2'} ){
 356         push(@invalidFields, "password_match");
 357     }
 358     if ( $borrower->{'password'}  && $minpw && (length($borrower->{'password'}) < $minpw) ) {
 359        push(@invalidFields, "password_invalid");
 360     }
 361     if ( $borrower->{'password'} ) {
 362        push(@invalidFields, "password_spaces") if ($borrower->{'password'} =~ /^\s/ or $borrower->{'password'} =~ /\s$/);
 363     }
 364
 365     return \@invalidFields;
 366 }
 367
 368 sub ParseCgiForBorrower {
 369     my ($cgi) = @_;
 370
 371     my $scrubber = C4::Scrubber->new();
 372     my %borrower;
 373
 374     foreach ( $cgi->param ) {
 375         if ( $_ =~ '^borrower_' ) {
 376             my ($key) = substr( $_, 9 );
 377             $borrower{$key} = HTML::Entities::encode( $scrubber->scrub( $cgi->param($_) ) );
 378         }
 379     }
 380
 381     my $dob_dt;
 382     $dob_dt = eval { dt_from_string( $borrower{'dateofbirth'} ); }
 383         if ( $borrower{'dateofbirth'} );
 384
 385     if ( $dob_dt ) {
 386         $borrower{'dateofbirth'} = output_pref ( { dt => $dob_dt, dateonly => 1, dateformat => 'iso' } );
 387     }
 388     else {
 389         # Trigger validation
 390         $borrower{'dateofbirth'} = undef;
 391     }
 392
 393     return %borrower;
 394 }
 395
 396 sub DelUnchangedFields {
 397     my ( $borrowernumber, %new_data ) = @_;
 398
 399     my $current_data = GetMember( borrowernumber => $borrowernumber );
 400
 401     foreach my $key ( keys %new_data ) {
 402         if ( $current_data->{$key} eq $new_data{$key} ) {
 403             delete $new_data{$key};
 404         }
 405     }
 406
 407     return %new_data;
 408 }
 409
 410 sub DelEmptyFields {
 411     my (%borrower) = @_;
 412
 413     foreach my $key ( keys %borrower ) {
 414         delete $borrower{$key} unless $borrower{$key};
 415     }
 416
 417     return %borrower;
 418 }