opac/opac-passwd.pl

   1 #!/usr/bin/perl
   2 # This script lets the users change the passwords by themselves.
   3 #
   4 # (c) 2005 Universidad ORT Uruguay.
   5 #
   6 # This file is part of the extensions and enhacments made to koha by Universidad ORT Uruguay
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use CGI qw ( -utf8 );
  24
  25 use C4::Auth;    # checkauth, getborrowernumber.
  26 use C4::Context;
  27 use C4::Circulation;
  28 use C4::Members;
  29 use C4::Output;
  30 use Koha::Patrons;
  31
  32 use Try::Tiny;
  33
  34 my $query = CGI->new;
  35
  36 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  37     {
  38         template_name   => "opac-passwd.tt",
  39         query           => $query,
  40         type            => "opac",
  41         debug           => 1,
  42     }
  43 );
  44
  45 my $patron = Koha::Patrons->find( $borrowernumber );
  46 if ( $patron->category->effective_change_password ) {
  47     if (   $query->param('Oldkey')
  48         && $query->param('Newkey')
  49         && $query->param('Confirm') )
  50     {
  51         my $error;
  52         my $new_password = $query->param('Newkey');
  53         my $confirm_password = $query->param('Confirm');
  54         if ( C4::Auth::checkpw_hash( scalar $query->param('Oldkey'), $patron->password ) ) {
  55
  56             if ( $new_password ne $confirm_password ) {
  57                 $template->param( 'Ask_data'       => '1' );
  58                 $template->param( 'Error_messages' => '1' );
  59                 $template->param( 'passwords_mismatch'   => '1' );
  60             } else {
  61                 try {
  62                     $patron->set_password({ password => $new_password });
  63                     $template->param( 'password_updated' => '1' );
  64                     $template->param( 'borrowernumber'   => $borrowernumber );
  65                 }
  66                 catch {
  67                     $error = 'password_too_short'
  68                         if $_->isa('Koha::Exceptions::Password::TooShort');
  69                     $error = 'password_too_weak'
  70                         if $_->isa('Koha::Exceptions::Password::TooWeak');
  71                     $error = 'password_has_whitespaces'
  72                         if $_->isa('Koha::Exceptions::Password::WhitespaceCharacters');
  73                 };
  74             }
  75         }
  76         else {
  77             $error = 'WrongPass';
  78         }
  79         if ($error) {
  80             $template->param(
  81                 Ask_data       => 1,
  82                 Error_messages => 1,
  83                 $error         => 1,
  84             );
  85
  86         }
  87     }
  88     else {
  89
  90         # Called Empty, Ask for data.
  91         $template->param( 'Ask_data' => '1' );
  92         if (!$query->param('Oldkey') && ($query->param('Newkey') || $query->param('Confirm'))){
  93             # Old password is empty but one of the others isn't
  94             $template->param( 'Error_messages' => '1' );
  95             $template->param( 'WrongPass'      => '1' );
  96         }
  97         elsif ($query->param('Oldkey') && (!$query->param('Newkey') || !$query->param('Confirm'))){
  98             # Oldpassword is entered but one of the other fields is empty
  99             $template->param( 'Error_messages' => '1' );
 100             $template->param( 'PassMismatch'   => '1' );
 101         }
 102     }
 103 }
 104 $template->param(
 105     firstname  => $patron->firstname,
 106     surname    => $patron->surname,
 107     passwdview => 1,
 108 );
 109
 110
 111 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };