opac/opac-request-article.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright ByWater Solutions 2015
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23
  24 use C4::Auth qw( get_template_and_user );
  25 use C4::Output qw( output_html_with_http_headers );
  26
  27 use Koha::Biblios;
  28 use Koha::Logger;
  29 use Koha::Patrons;
  30
  31 use Scalar::Util qw( blessed );
  32 use Try::Tiny;
  33
  34 my $cgi = CGI->new;
  35
  36 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  37     {
  38         template_name   => "opac-request-article.tt",
  39         query           => $cgi,
  40         type            => "opac",
  41     }
  42 );
  43
  44 my $action = $cgi->param('action') || q{};
  45 my $biblionumber = $cgi->param('biblionumber');
  46 my $biblio = Koha::Biblios->find($biblionumber);
  47 if( !$biblio ) {
  48     print $cgi->redirect("/cgi-bin/koha/errors/404.pl");
  49     exit;
  50 }
  51
  52 if ( $action eq 'create' ) {
  53     my $branchcode = $cgi->param('branchcode');
  54
  55     my $itemnumber   = $cgi->param('itemnumber')   || undef;
  56     my $title        = $cgi->param('title')        || undef;
  57     my $author       = $cgi->param('author')       || undef;
  58     my $volume       = $cgi->param('volume')       || undef;
  59     my $issue        = $cgi->param('issue')        || undef;
  60     my $date         = $cgi->param('date')         || undef;
  61     my $pages        = $cgi->param('pages')        || undef;
  62     my $chapters     = $cgi->param('chapters')     || undef;
  63     my $patron_notes = $cgi->param('patron_notes') || undef;
  64     my $format       = $cgi->param('format')       || undef;
  65
  66
  67     my $success;
  68
  69     try {
  70         my $ar = Koha::ArticleRequest->new(
  71             {
  72                 borrowernumber => $borrowernumber,
  73                 biblionumber   => $biblionumber,
  74                 branchcode     => $branchcode,
  75                 itemnumber     => $itemnumber,
  76                 title          => $title,
  77                 author         => $author,
  78                 volume         => $volume,
  79                 issue          => $issue,
  80                 date           => $date,
  81                 pages          => $pages,
  82                 chapters       => $chapters,
  83                 patron_notes   => $patron_notes,
  84                 format         => $format,
  85             }
  86         )->request;
  87         $success = 1;
  88     } catch {
  89         if ( blessed $_ and $_->isa('Koha::Exceptions::ArticleRequest::LimitReached') ) {
  90             $template->param(
  91                 error_message => 'article_request_limit_reached'
  92             );
  93         }
  94         else {
  95             Koha::Logger->get->debug("Unhandled exception when placing an article request ($_)");
  96             $template->param(
  97                 error_message => 'article_request_unhandled_exception'
  98             );
  99         }
 100     };
 101
 102     if ( $success ) {
 103         print $cgi->redirect("/cgi-bin/koha/opac-user.pl#opac-user-article-requests");
 104         exit;
 105     }
 106 # Should we redirect?
 107 }
 108 elsif ( !$action && C4::Context->preference('ArticleRequestsOpacHostRedirection') ) {
 109   # Conditions: no items, host item entry (MARC21 773)
 110   my ( $host, $pageinfo ) = $biblio->get_marc_host( { no_items => 1 } );
 111   if ($host) {
 112       $template->param(
 113           pageinfo => $pageinfo,
 114           title    => $biblio->title,
 115           author   => $biblio->author
 116       );
 117       $biblio = $host;
 118   }
 119 }
 120
 121 my $patron = Koha::Patrons->find($borrowernumber);
 122
 123 if(!$patron->can_request_article) {
 124     $template->param(
 125         error_message => 'article_request_limit_reached'
 126     );
 127 }
 128
 129 $template->param(
 130     biblio => $biblio,
 131     patron => $patron,
 132     action => $action
 133 );
 134
 135 output_html_with_http_headers $cgi, $cookie, $template->output, undef, { force_no_caching => 1 };