opac/opac-user.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 # parts copyright 2010 BibLibre
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19
  20 use strict;
  21 #use warnings; FIXME - Bug 2505
  22
  23 use CGI qw ( -utf8 );
  24
  25 use C4::Auth;
  26 use C4::Koha;
  27 use C4::Circulation;
  28 use C4::Reserves;
  29 use C4::Members;
  30 use C4::Members::AttributeTypes;
  31 use C4::Members::Attributes qw/GetBorrowerAttributeValue/;
  32 use C4::Output;
  33 use C4::Biblio;
  34 use C4::Items;
  35 use C4::Letters;
  36 use C4::Branch; # GetBranches
  37 use Koha::DateUtils;
  38 use Koha::Patron::Debarments qw(IsDebarred);
  39 use Koha::Holds;
  40 use Koha::Database;
  41 use Koha::Patron::Messages;
  42 use Koha::Patron::Discharge;
  43
  44 use constant ATTRIBUTE_SHOW_BARCODE => 'SHOW_BCODE';
  45
  46 use Scalar::Util qw(looks_like_number);
  47 use Date::Calc qw(
  48   Today
  49   Add_Delta_Days
  50   Date_to_Days
  51 );
  52
  53 my $query = new CGI;
  54
  55 BEGIN {
  56     if (C4::Context->preference('BakerTaylorEnabled')) {
  57         require C4::External::BakerTaylor;
  58         import C4::External::BakerTaylor qw(&image_url &link_url);
  59     }
  60 }
  61
  62 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  63     {
  64         template_name   => "opac-user.tt",
  65         query           => $query,
  66         type            => "opac",
  67         authnotrequired => 0,
  68         debug           => 1,
  69     }
  70 );
  71
  72 my %renewed = map { $_ => 1 } split( ':', $query->param('renewed') );
  73
  74 my $show_priority;
  75 for ( C4::Context->preference("OPACShowHoldQueueDetails") ) {
  76     m/priority/ and $show_priority = 1;
  77 }
  78
  79 my $patronupdate = $query->param('patronupdate');
  80 my $canrenew = 1;
  81
  82 $template->param( shibbolethAuthentication => C4::Context->config('useshibboleth') );
  83
  84 if (!$borrowernumber) {
  85     $template->param( adminWarning => 1 );
  86 }
  87
  88 # get borrower information ....
  89 my ( $borr ) = GetMemberDetails( $borrowernumber );
  90
  91 my (  $today_year,   $today_month,   $today_day) = Today();
  92 my ($warning_year, $warning_month, $warning_day) = split /-/, $borr->{'dateexpiry'};
  93
  94 my $debar = IsDebarred($borrowernumber);
  95 my $userdebarred;
  96
  97 if ($debar) {
  98     $userdebarred = 1;
  99     $template->param( 'userdebarred' => $userdebarred );
 100     if ( $debar ne "9999-12-31" ) {
 101         $borr->{'userdebarreddate'} = $debar;
 102     }
 103     # FIXME looks like $available is not needed
 104     # If a patron is discharged he has a validated discharge available
 105     my $available = Koha::Patron::Discharge::count({
 106         borrowernumber => $borrowernumber,
 107         validated      => 1,
 108     });
 109     $template->param( 'discharge_available' => $available && Koha::Patron::Discharge::is_discharged({borrowernumber => $borrowernumber}) );
 110 }
 111
 112 if ( $userdebarred || $borr->{'gonenoaddress'} || $borr->{'lost'} ) {
 113     $borr->{'flagged'} = 1;
 114     $canrenew = 0;
 115 }
 116
 117 if ( $borr->{'amountoutstanding'} > 5 ) {
 118     $borr->{'amountoverfive'} = 1;
 119 }
 120 if ( 5 >= $borr->{'amountoutstanding'} && $borr->{'amountoutstanding'} > 0 ) {
 121     $borr->{'amountoverzero'} = 1;
 122 }
 123 my $no_renewal_amt = C4::Context->preference( 'OPACFineNoRenewals' );
 124 $no_renewal_amt = undef unless looks_like_number( $no_renewal_amt );
 125
 126 if (   C4::Context->preference('OpacRenewalAllowed')
 127     && defined($no_renewal_amt)
 128     && $borr->{amountoutstanding} > $no_renewal_amt )
 129 {
 130     $borr->{'flagged'} = 1;
 131     $canrenew = 0;
 132     $template->param(
 133         renewal_blocked_fines => $no_renewal_amt,
 134         renewal_blocked_fines_amountoutstanding => $borr->{amountoutstanding},
 135     );
 136 }
 137
 138 if ( $borr->{'amountoutstanding'} < 0 ) {
 139     $borr->{'amountlessthanzero'} = 1;
 140     $borr->{'amountoutstanding'} = -1 * ( $borr->{'amountoutstanding'} );
 141 }
 142
 143 # Warningdate is the date that the warning starts appearing
 144 if ( $borr->{'dateexpiry'} && C4::Context->preference('NotifyBorrowerDeparture') ) {
 145     my $days_to_expiry = Date_to_Days( $warning_year, $warning_month, $warning_day ) - Date_to_Days( $today_year, $today_month, $today_day );
 146     if ( $days_to_expiry < 0 ) {
 147         #borrower card has expired, warn the borrower
 148         $borr->{'warnexpired'} = $borr->{'dateexpiry'};
 149     } elsif ( $days_to_expiry < C4::Context->preference('NotifyBorrowerDeparture') ) {
 150         # borrower card soon to expire, warn the borrower
 151         $borr->{'warndeparture'} = $borr->{dateexpiry};
 152         if (C4::Context->preference('ReturnBeforeExpiry')){
 153             $borr->{'returnbeforeexpiry'} = 1;
 154         }
 155     }
 156 }
 157
 158 # pass on any renew errors to the template for displaying
 159 my $renew_error = $query->param('renew_error');
 160
 161 $template->param(   BORROWER_INFO     => $borr,
 162                     borrowernumber    => $borrowernumber,
 163                     patron_flagged    => $borr->{flagged},
 164                     OPACMySummaryHTML => (C4::Context->preference("OPACMySummaryHTML")) ? 1 : 0,
 165                     surname           => $borr->{surname},
 166                     RENEW_ERROR       => $renew_error,
 167                     borrower          => $borr,
 168                 );
 169
 170 #get issued items ....
 171
 172 my $count          = 0;
 173 my $overdues_count = 0;
 174 my @overdues;
 175 my @issuedat;
 176 my $itemtypes = GetItemTypes();
 177 my $issues = GetPendingIssues($borrowernumber);
 178 if ($issues){
 179     foreach my $issue ( sort { $b->{date_due}->datetime() cmp $a->{date_due}->datetime() } @{$issues} ) {
 180         # check for reserves
 181         my $restype = GetReserveStatus( $issue->{'itemnumber'} );
 182         if ( $restype ) {
 183             $issue->{'reserved'} = 1;
 184         }
 185
 186         my ( $total , $accts, $numaccts) = GetMemberAccountRecords( $borrowernumber );
 187         my $charges = 0;
 188         my $rentalfines = 0;
 189         foreach my $ac (@$accts) {
 190             if ( $ac->{'itemnumber'} == $issue->{'itemnumber'} ) {
 191                 $charges += $ac->{'amountoutstanding'}
 192                   if $ac->{'accounttype'} eq 'F';
 193                 $charges += $ac->{'amountoutstanding'}
 194                   if $ac->{'accounttype'} eq 'FU';
 195                 $charges += $ac->{'amountoutstanding'}
 196                   if $ac->{'accounttype'} eq 'L';
 197                 $rentalfines += $ac->{'amountoutstanding'}
 198                   if $ac->{'accounttype'} eq 'Rent';
 199             }
 200         }
 201         $issue->{'charges'} = $charges;
 202         $issue->{'rentalfines'} = $rentalfines;
 203         my $marcrecord = GetMarcBiblio( $issue->{'biblionumber'} );
 204         $issue->{'subtitle'} = GetRecordValue('subtitle', $marcrecord, GetFrameworkCode($issue->{'biblionumber'}));
 205         # check if item is renewable
 206         my ($status,$renewerror) = CanBookBeRenewed( $borrowernumber, $issue->{'itemnumber'} );
 207         ($issue->{'renewcount'},$issue->{'renewsallowed'},$issue->{'renewsleft'}) = GetRenewCount($borrowernumber, $issue->{'itemnumber'});
 208         if($status && C4::Context->preference("OpacRenewalAllowed")){
 209             $issue->{'status'} = $status;
 210         }
 211
 212         $issue->{'renewed'} = $renewed{ $issue->{'itemnumber'} };
 213
 214         if ($renewerror) {
 215             $issue->{'too_many'}       = 1 if $renewerror eq 'too_many';
 216             $issue->{'on_reserve'}     = 1 if $renewerror eq 'on_reserve';
 217             $issue->{'norenew_overdue'} = 1 if $renewerror eq 'overdue';
 218             $issue->{'auto_renew'}     = 1 if $renewerror eq 'auto_renew';
 219             $issue->{'auto_too_soon'}  = 1 if $renewerror eq 'auto_too_soon';
 220
 221             if ( $renewerror eq 'too_soon' ) {
 222                 $issue->{'too_soon'}         = 1;
 223                 $issue->{'soonestrenewdate'} = output_pref(
 224                     C4::Circulation::GetSoonestRenewDate(
 225                         $issue->{borrowernumber},
 226                         $issue->{itemnumber}
 227                     )
 228                 );
 229             }
 230         }
 231
 232         if ( $issue->{'overdue'} ) {
 233             push @overdues, $issue;
 234             $overdues_count++;
 235             $issue->{'overdue'} = 1;
 236         }
 237         else {
 238             $issue->{'issued'} = 1;
 239         }
 240         # imageurl:
 241         my $itemtype = $issue->{'itemtype'};
 242         if ( $itemtype ) {
 243             $issue->{'imageurl'}    = getitemtypeimagelocation( 'opac', $itemtypes->{$itemtype}->{'imageurl'} );
 244             $issue->{'description'} = $itemtypes->{$itemtype}->{'description'};
 245         }
 246         push @issuedat, $issue;
 247         $count++;
 248
 249         my $isbn = GetNormalizedISBN($issue->{'isbn'});
 250         $issue->{normalized_isbn} = $isbn;
 251         $issue->{normalized_upc} = GetNormalizedUPC( $marcrecord, C4::Context->preference('marcflavour') );
 252
 253                 # My Summary HTML
 254                 if (my $my_summary_html = C4::Context->preference('OPACMySummaryHTML')){
 255                     $issue->{author} ? $my_summary_html =~ s/{AUTHOR}/$issue->{author}/g : $my_summary_html =~ s/{AUTHOR}//g;
 256                     $issue->{title} =~ s/\/+$//; # remove trailing slash
 257                     $issue->{title} =~ s/\s+$//; # remove trailing space
 258                     $issue->{title} ? $my_summary_html =~ s/{TITLE}/$issue->{title}/g : $my_summary_html =~ s/{TITLE}//g;
 259                     $issue->{isbn} ? $my_summary_html =~ s/{ISBN}/$isbn/g : $my_summary_html =~ s/{ISBN}//g;
 260                     $issue->{biblionumber} ? $my_summary_html =~ s/{BIBLIONUMBER}/$issue->{biblionumber}/g : $my_summary_html =~ s/{BIBLIONUMBER}//g;
 261                     $issue->{MySummaryHTML} = $my_summary_html;
 262                 }
 263     }
 264 }
 265 my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
 266 $canrenew = 0 if ($overduesblockrenewing ne 'allow' and $overdues_count == $count);
 267 $template->param( ISSUES       => \@issuedat );
 268 $template->param( issues_count => $count );
 269 $template->param( canrenew     => $canrenew );
 270 $template->param( OVERDUES       => \@overdues );
 271 $template->param( overdues_count => $overdues_count );
 272
 273 my $show_barcode = C4::Members::AttributeTypes::AttributeTypeExists( ATTRIBUTE_SHOW_BARCODE );
 274 if ($show_barcode) {
 275     my $patron_show_barcode = GetBorrowerAttributeValue($borrowernumber, ATTRIBUTE_SHOW_BARCODE);
 276     undef $show_barcode if defined($patron_show_barcode) && !$patron_show_barcode;
 277 }
 278 $template->param( show_barcode => 1 ) if $show_barcode;
 279
 280 # load the branches
 281 my $branches = GetBranches();
 282 my @branch_loop;
 283 for my $branch_hash ( sort keys %{$branches} ) {
 284     my $selected;
 285     if ( C4::Context->preference('SearchMyLibraryFirst') ) {
 286         $selected =
 287           ( C4::Context->userenv
 288               && ( $branch_hash eq C4::Context->userenv->{branch} ) );
 289     }
 290     push @branch_loop,
 291       { value      => "branch: $branch_hash",
 292         branchname => $branches->{$branch_hash}->{'branchname'},
 293         selected   => $selected,
 294       };
 295 }
 296 $template->param( branchloop => \@branch_loop );
 297
 298 # now the reserved items....
 299 my $reserves = Koha::Holds->search( { borrowernumber => $borrowernumber } );
 300
 301 $template->param(
 302     RESERVES       => $reserves,
 303     showpriority   => $show_priority,
 304 );
 305
 306 # current alert subscriptions
 307 my $alerts = getalert($borrowernumber);
 308 foreach ( @$alerts ) {
 309     $_->{ $_->{type} } = 1;
 310     $_->{relatedto} = findrelatedto( $_->{type}, $_->{externalid} );
 311 }
 312
 313 if (C4::Context->preference('BakerTaylorEnabled')) {
 314     $template->param(
 315         BakerTaylorEnabled  => 1,
 316         BakerTaylorImageURL => &image_url(),
 317         BakerTaylorLinkURL  => &link_url(),
 318         BakerTaylorBookstoreURL => C4::Context->preference('BakerTaylorBookstoreURL'),
 319     );
 320 }
 321
 322 if (C4::Context->preference("OPACAmazonCoverImages") or
 323     C4::Context->preference("GoogleJackets") or
 324     C4::Context->preference("BakerTaylorEnabled") or
 325     C4::Context->preference("SyndeticsCoverImages")) {
 326         $template->param(JacketImages=>1);
 327 }
 328
 329 my $patron_messages = Koha::Patron::Messages->search(
 330     {
 331         borrowernumber => $borrowernumber,
 332         message_type => 'B',
 333     }
 334 );
 335 if ( $patron_messages->count ) {
 336     $template->param( bor_messages => 1 );
 337 }
 338
 339 if ( $borr->{'opacnote'} ) {
 340   $template->param(
 341     bor_messages => 1,
 342     opacnote => $borr->{'opacnote'},
 343   );
 344 }
 345
 346 if (   C4::Context->preference('AllowPatronToSetCheckoutsVisibilityForGuarantor')
 347     || C4::Context->preference('AllowStaffToSetCheckoutsVisibilityForGuarantor') )
 348 {
 349     my @relatives =
 350       Koha::Database->new()->schema()->resultset("Borrower")->search(
 351         {
 352             privacy_guarantor_checkouts => 1,
 353             'me.guarantorid'           => $borrowernumber
 354         },
 355         { prefetch => [ { 'issues' => { 'item' => 'biblio' } } ] }
 356       );
 357     $template->param( relatives => \@relatives );
 358 }
 359
 360 $template->param(
 361     borrower                 => $borr,
 362     patron_messages          => $patron_messages,
 363     patronupdate             => $patronupdate,
 364     OpacRenewalAllowed       => C4::Context->preference("OpacRenewalAllowed"),
 365     userview                 => 1,
 366     SuspendHoldsOpac         => C4::Context->preference('SuspendHoldsOpac'),
 367     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 368     OpacHoldNotes            => C4::Context->preference('OpacHoldNotes'),
 369     failed_holds             => scalar $query->param('failed_holds'),
 370 );
 371
 372 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };