opac/opac-user.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 # parts copyright 2010 BibLibre
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19
  20 use strict;
  21 #use warnings; FIXME - Bug 2505
  22
  23 use CGI qw ( -utf8 );
  24
  25 use C4::Auth;
  26 use C4::Koha;
  27 use C4::Circulation;
  28 use C4::Reserves;
  29 use C4::Members;
  30 use C4::Members::AttributeTypes;
  31 use C4::Members::Attributes qw/GetBorrowerAttributeValue/;
  32 use C4::Output;
  33 use C4::Biblio;
  34 use C4::Items;
  35 use C4::Letters;
  36 use C4::Branch; # GetBranches
  37 use Koha::DateUtils;
  38 use Koha::Borrower::Debarments qw(IsDebarred);
  39
  40 use constant ATTRIBUTE_SHOW_BARCODE => 'SHOW_BCODE';
  41
  42 use Date::Calc qw(
  43   Today
  44   Add_Delta_Days
  45   Date_to_Days
  46 );
  47
  48 my $query = new CGI;
  49
  50 BEGIN {
  51     if (C4::Context->preference('BakerTaylorEnabled')) {
  52         require C4::External::BakerTaylor;
  53         import C4::External::BakerTaylor qw(&image_url &link_url);
  54     }
  55 }
  56
  57 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  58     {
  59         template_name   => "opac-user.tt",
  60         query           => $query,
  61         type            => "opac",
  62         authnotrequired => 0,
  63         debug           => 1,
  64     }
  65 );
  66
  67 my %renewed = map { $_ => 1 } split( ':', $query->param('renewed') );
  68
  69 my $show_priority;
  70 for ( C4::Context->preference("OPACShowHoldQueueDetails") ) {
  71     m/priority/ and $show_priority = 1;
  72 }
  73
  74 my $patronupdate = $query->param('patronupdate');
  75 my $canrenew = 1;
  76
  77 $template->param( shibbolethAuthentication => C4::Context->config('useshibboleth') );
  78
  79 # get borrower information ....
  80 my ( $borr ) = GetMemberDetails( $borrowernumber );
  81
  82 my (  $today_year,   $today_month,   $today_day) = Today();
  83 my ($warning_year, $warning_month, $warning_day) = split /-/, $borr->{'dateexpiry'};
  84
  85 my $debar = IsDebarred($borrowernumber);
  86 my $userdebarred;
  87
  88 if ($debar) {
  89     $userdebarred = 1;
  90     $template->param( 'userdebarred' => $userdebarred );
  91     if ( $debar ne "9999-12-31" ) {
  92         $borr->{'userdebarreddate'} = $debar;
  93     }
  94 }
  95
  96 if ( $userdebarred || $borr->{'gonenoaddress'} || $borr->{'lost'} ) {
  97     $borr->{'flagged'} = 1;
  98     $canrenew = 0;
  99 }
 100
 101 if ( $borr->{'amountoutstanding'} > 5 ) {
 102     $borr->{'amountoverfive'} = 1;
 103 }
 104 if ( 5 >= $borr->{'amountoutstanding'} && $borr->{'amountoutstanding'} > 0 ) {
 105     $borr->{'amountoverzero'} = 1;
 106 }
 107 my $no_renewal_amt = C4::Context->preference( 'OPACFineNoRenewals' );
 108 $no_renewal_amt ||= 0;
 109
 110 if (  C4::Context->preference( 'OpacRenewalAllowed' ) && $borr->{amountoutstanding} > $no_renewal_amt ) {
 111     $borr->{'flagged'} = 1;
 112     $canrenew = 0;
 113     $template->param(
 114         renewal_blocked_fines => sprintf( '%.02f', $no_renewal_amt ),
 115         renewal_blocked_fines_amountoutstanding => sprintf( '%.02f', $borr->{amountoutstanding} ),
 116     );
 117 }
 118
 119 if ( $borr->{'amountoutstanding'} < 0 ) {
 120     $borr->{'amountlessthanzero'} = 1;
 121     $borr->{'amountoutstanding'} = -1 * ( $borr->{'amountoutstanding'} );
 122 }
 123
 124 $borr->{'amountoutstanding'} = sprintf "%.02f", $borr->{'amountoutstanding'};
 125
 126 my @bordat;
 127 $bordat[0] = $borr;
 128
 129 # Warningdate is the date that the warning starts appearing
 130 if ( $borr->{'dateexpiry'} && C4::Context->preference('NotifyBorrowerDeparture') ) {
 131     my $days_to_expiry = Date_to_Days( $warning_year, $warning_month, $warning_day ) - Date_to_Days( $today_year, $today_month, $today_day );
 132     if ( $days_to_expiry < 0 ) {
 133         #borrower card has expired, warn the borrower
 134         $borr->{'warnexpired'} = $borr->{'dateexpiry'};
 135     } elsif ( $days_to_expiry < C4::Context->preference('NotifyBorrowerDeparture') ) {
 136         # borrower card soon to expire, warn the borrower
 137         $borr->{'warndeparture'} = $borr->{dateexpiry};
 138         if (C4::Context->preference('ReturnBeforeExpiry')){
 139             $borr->{'returnbeforeexpiry'} = 1;
 140         }
 141     }
 142 }
 143
 144 # pass on any renew errors to the template for displaying
 145 my $renew_error = $query->param('renew_error');
 146
 147 $template->param(   BORROWER_INFO     => \@bordat,
 148                     borrowernumber    => $borrowernumber,
 149                     patron_flagged    => $borr->{flagged},
 150                     OPACMySummaryHTML => (C4::Context->preference("OPACMySummaryHTML")) ? 1 : 0,
 151                     surname           => $borr->{surname},
 152                     showname          => $borr->{showname},
 153                     RENEW_ERROR       => $renew_error,
 154                     borrower          => $borr,
 155                 );
 156
 157 #get issued items ....
 158
 159 my $count          = 0;
 160 my $overdues_count = 0;
 161 my @overdues;
 162 my @issuedat;
 163 my $itemtypes = GetItemTypes();
 164 my $issues = GetPendingIssues($borrowernumber);
 165 if ($issues){
 166     foreach my $issue ( sort { $b->{date_due}->datetime() cmp $a->{date_due}->datetime() } @{$issues} ) {
 167         # check for reserves
 168         my $restype = GetReserveStatus( $issue->{'itemnumber'} );
 169         if ( $restype ) {
 170             $issue->{'reserved'} = 1;
 171         }
 172
 173         my ( $total , $accts, $numaccts) = GetMemberAccountRecords( $borrowernumber );
 174         my $charges = 0;
 175         foreach my $ac (@$accts) {
 176             if ( $ac->{'itemnumber'} == $issue->{'itemnumber'} ) {
 177                 $charges += $ac->{'amountoutstanding'}
 178                   if $ac->{'accounttype'} eq 'F';
 179                 $charges += $ac->{'amountoutstanding'}
 180                   if $ac->{'accounttype'} eq 'FU';
 181                 $charges += $ac->{'amountoutstanding'}
 182                   if $ac->{'accounttype'} eq 'L';
 183             }
 184         }
 185         $issue->{'charges'} = $charges;
 186         $issue->{'subtitle'} = GetRecordValue('subtitle', GetMarcBiblio($issue->{'biblionumber'}), GetFrameworkCode($issue->{'biblionumber'}));
 187         # check if item is renewable
 188         my ($status,$renewerror) = CanBookBeRenewed( $borrowernumber, $issue->{'itemnumber'} );
 189         ($issue->{'renewcount'},$issue->{'renewsallowed'},$issue->{'renewsleft'}) = GetRenewCount($borrowernumber, $issue->{'itemnumber'});
 190         if($status && C4::Context->preference("OpacRenewalAllowed")){
 191             $issue->{'status'} = $status;
 192         }
 193
 194         $issue->{'renewed'} = $renewed{ $issue->{'itemnumber'} };
 195
 196         if ($renewerror) {
 197             $issue->{'too_many'}       = 1 if $renewerror eq 'too_many';
 198             $issue->{'on_reserve'}     = 1 if $renewerror eq 'on_reserve';
 199             $issue->{'auto_renew'}     = 1 if $renewerror eq 'auto_renew';
 200             $issue->{'auto_too_soon'}  = 1 if $renewerror eq 'auto_too_soon';
 201
 202             if ( $renewerror eq 'too_soon' ) {
 203                 $issue->{'too_soon'}         = 1;
 204                 $issue->{'soonestrenewdate'} = output_pref(
 205                     C4::Circulation::GetSoonestRenewDate(
 206                         $issue->{borrowernumber},
 207                         $issue->{itemnumber}
 208                     )
 209                 );
 210             }
 211         }
 212
 213         if ( $issue->{'overdue'} ) {
 214             push @overdues, $issue;
 215             $overdues_count++;
 216             $issue->{'overdue'} = 1;
 217         }
 218         else {
 219             $issue->{'issued'} = 1;
 220         }
 221         # imageurl:
 222         my $itemtype = $issue->{'itemtype'};
 223         if ( $itemtype ) {
 224             $issue->{'imageurl'}    = getitemtypeimagelocation( 'opac', $itemtypes->{$itemtype}->{'imageurl'} );
 225             $issue->{'description'} = $itemtypes->{$itemtype}->{'description'};
 226         }
 227         push @issuedat, $issue;
 228         $count++;
 229
 230         my $isbn = GetNormalizedISBN($issue->{'isbn'});
 231         $issue->{normalized_isbn} = $isbn;
 232
 233                 # My Summary HTML
 234                 if (my $my_summary_html = C4::Context->preference('OPACMySummaryHTML')){
 235                     $issue->{author} ? $my_summary_html =~ s/{AUTHOR}/$issue->{author}/g : $my_summary_html =~ s/{AUTHOR}//g;
 236                     $issue->{title} =~ s/\/+$//; # remove trailing slash
 237                     $issue->{title} =~ s/\s+$//; # remove trailing space
 238                     $issue->{title} ? $my_summary_html =~ s/{TITLE}/$issue->{title}/g : $my_summary_html =~ s/{TITLE}//g;
 239                     $issue->{isbn} ? $my_summary_html =~ s/{ISBN}/$isbn/g : $my_summary_html =~ s/{ISBN}//g;
 240                     $issue->{biblionumber} ? $my_summary_html =~ s/{BIBLIONUMBER}/$issue->{biblionumber}/g : $my_summary_html =~ s/{BIBLIONUMBER}//g;
 241                     $issue->{MySummaryHTML} = $my_summary_html;
 242                 }
 243     }
 244 }
 245 $template->param( ISSUES       => \@issuedat );
 246 $template->param( issues_count => $count );
 247 $template->param( canrenew     => $canrenew );
 248 $template->param( OVERDUES       => \@overdues );
 249 $template->param( overdues_count => $overdues_count );
 250
 251 my $show_barcode = C4::Members::AttributeTypes::AttributeTypeExists( ATTRIBUTE_SHOW_BARCODE );
 252 if ($show_barcode) {
 253     my $patron_show_barcode = GetBorrowerAttributeValue($borrowernumber, ATTRIBUTE_SHOW_BARCODE);
 254     undef $show_barcode if defined($patron_show_barcode) && !$patron_show_barcode;
 255 }
 256 $template->param( show_barcode => 1 ) if $show_barcode;
 257
 258 # load the branches
 259 my $branches = GetBranches();
 260 my @branch_loop;
 261 for my $branch_hash ( sort keys %{$branches} ) {
 262     my $selected;
 263     if ( C4::Context->preference('SearchMyLibraryFirst') ) {
 264         $selected =
 265           ( C4::Context->userenv
 266               && ( $branch_hash eq C4::Context->userenv->{branch} ) );
 267     }
 268     push @branch_loop,
 269       { value      => "branch: $branch_hash",
 270         branchname => $branches->{$branch_hash}->{'branchname'},
 271         selected   => $selected,
 272       };
 273 }
 274 $template->param( branchloop => \@branch_loop );
 275
 276 # now the reserved items....
 277 my @reserves  = GetReservesFromBorrowernumber( $borrowernumber );
 278 foreach my $res (@reserves) {
 279
 280     if ( $res->{'expirationdate'} eq '0000-00-00' ) {
 281       $res->{'expirationdate'} = '';
 282     }
 283     $res->{'subtitle'} = GetRecordValue('subtitle', GetMarcBiblio($res->{'biblionumber'}), GetFrameworkCode($res->{'biblionumber'}));
 284     $res->{'waiting'} = 1 if $res->{'found'} eq 'W';
 285     $res->{'branch'} = $branches->{ $res->{'branchcode'} }->{'branchname'};
 286     my $biblioData = GetBiblioData($res->{'biblionumber'});
 287     $res->{'reserves_title'} = $biblioData->{'title'};
 288     $res->{'author'} = $biblioData->{'author'};
 289
 290     if ($show_priority) {
 291         $res->{'priority'} ||= '';
 292     }
 293     if ( $res->{'suspend_until'} ) {
 294         $res->{'suspend_until'} = output_pref({ dt => dt_from_string( $res->{'suspend_until'} , 'iso' ), dateonly => 1 });
 295     }
 296 }
 297
 298 # use Data::Dumper;
 299 # warn Dumper(@reserves);
 300
 301 $template->param( RESERVES       => \@reserves );
 302 $template->param( reserves_count => $#reserves+1 );
 303 $template->param( showpriority=>$show_priority );
 304
 305 my @waiting;
 306 my $wcount = 0;
 307 foreach my $res (@reserves) {
 308     if ( $res->{'itemnumber'} ) {
 309         my $item = GetItem( $res->{'itemnumber'});
 310         $res->{'holdingbranch'} =
 311           $branches->{ $item->{'holdingbranch'} }->{'branchname'};
 312         $res->{'branch'} = $branches->{ $res->{'branchcode'} }->{'branchname'};
 313         $res->{'enumchron'} = $item->{'enumchron'} if $item->{'enumchron'};
 314         # get document reserve status
 315         my $biblioData = GetBiblioData($res->{'biblionumber'});
 316         $res->{'waiting_title'} = $biblioData->{'title'};
 317         if ( ( $res->{'found'} eq 'W' ) ) {
 318             my $item = $res->{'itemnumber'};
 319             $item = GetBiblioFromItemNumber($item,undef);
 320             $res->{'wait'}= 1;
 321             $res->{'holdingbranch'}=$item->{'holdingbranch'};
 322             $res->{'biblionumber'}=$item->{'biblionumber'};
 323             $res->{'barcode'} = $item->{'barcode'};
 324             $res->{'wbrcode'} = $res->{'branchcode'};
 325             $res->{'itemnumber'}    = $res->{'itemnumber'};
 326             $res->{'wbrname'} = $branches->{$res->{'branchcode'}}->{'branchname'};
 327             if($res->{'holdingbranch'} eq $res->{'wbrcode'}){
 328                 $res->{'atdestination'} = 1;
 329             }
 330             # set found to 1 if reserve is waiting for patron pickup
 331             $res->{'found'} = 1 if $res->{'found'} eq 'W';
 332         } else {
 333             my ($transfertwhen, $transfertfrom, $transfertto) = GetTransfers( $res->{'itemnumber'} );
 334             if ($transfertwhen) {
 335                 $res->{intransit} = 1;
 336                 $res->{datesent}   = $transfertwhen;
 337                 $res->{frombranch} = GetBranchName($transfertfrom);
 338             }
 339         }
 340         push @waiting, $res;
 341         $wcount++;
 342     }
 343     # can be cancelled
 344     #$res->{'cancelable'} = 1 if ($res->{'wait'} && $res->{'atdestination'} && $res->{'found'} ne "1");
 345     $res->{'cancelable'} = 1 if    ($res->{wait} and not $res->{found}) or (not $res->{wait} and not $res->{intransit});
 346
 347 }
 348
 349 $template->param( WAITING => \@waiting );
 350
 351 # current alert subscriptions
 352 my $alerts = getalert($borrowernumber);
 353 foreach ( @$alerts ) {
 354     $_->{ $_->{type} } = 1;
 355     $_->{relatedto} = findrelatedto( $_->{type}, $_->{externalid} );
 356 }
 357
 358 if (C4::Context->preference('BakerTaylorEnabled')) {
 359     $template->param(
 360         BakerTaylorEnabled  => 1,
 361         BakerTaylorImageURL => &image_url(),
 362         BakerTaylorLinkURL  => &link_url(),
 363         BakerTaylorBookstoreURL => C4::Context->preference('BakerTaylorBookstoreURL'),
 364     );
 365 }
 366
 367 if (C4::Context->preference("OPACAmazonCoverImages") or
 368     C4::Context->preference("GoogleJackets") or
 369     C4::Context->preference("BakerTaylorEnabled") or
 370     C4::Context->preference("SyndeticsCoverImages")) {
 371         $template->param(JacketImages=>1);
 372 }
 373
 374 if ( GetMessagesCount( $borrowernumber, 'B' ) ) {
 375     $template->param( bor_messages => 1 );
 376 }
 377
 378 if ( $borr->{'opacnote'} ) {
 379   $template->param(
 380     bor_messages => 1,
 381     opacnote => $borr->{'opacnote'},
 382   );
 383 }
 384
 385 $template->param(
 386     bor_messages_loop        => GetMessages( $borrowernumber, 'B', 'NONE' ),
 387     waiting_count            => $wcount,
 388     patronupdate             => $patronupdate,
 389     OpacRenewalAllowed       => C4::Context->preference("OpacRenewalAllowed"),
 390     userview                 => 1,
 391     SuspendHoldsOpac         => C4::Context->preference('SuspendHoldsOpac'),
 392     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 393     OpacHoldNotes            => C4::Context->preference('OpacHoldNotes'),
 394     failed_holds             => $query->param('failed_holds'),
 395 );
 396
 397 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };