opac/opac-user.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 # parts copyright 2010 BibLibre
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23
  24 use C4::Auth;
  25 use C4::Koha;
  26 use C4::Circulation;
  27 use C4::External::BakerTaylor qw( image_url link_url );
  28 use C4::Reserves;
  29 use C4::Members;
  30 use C4::Members::AttributeTypes;
  31 use C4::Members::Attributes qw/GetBorrowerAttributeValue/;
  32 use C4::Output;
  33 use C4::Biblio;
  34 use C4::Items;
  35 use C4::Letters;
  36 use Koha::Account::Lines;
  37 use Koha::Biblios;
  38 use Koha::Libraries;
  39 use Koha::DateUtils;
  40 use Koha::Holds;
  41 use Koha::Database;
  42 use Koha::ItemTypes;
  43 use Koha::Patron::Attribute::Types;
  44 use Koha::Patrons;
  45 use Koha::Patron::Messages;
  46 use Koha::Patron::Discharge;
  47 use Koha::Patrons;
  48
  49 use constant ATTRIBUTE_SHOW_BARCODE => 'SHOW_BCODE';
  50
  51 use Scalar::Util qw(looks_like_number);
  52 use Date::Calc qw(
  53   Today
  54   Add_Delta_Days
  55   Date_to_Days
  56 );
  57
  58 my $query = new CGI;
  59
  60 # CAS single logout handling
  61 # Will print header and exit
  62 C4::Context->preference('casAuthentication') and C4::Auth_with_cas::logout_if_required($query);
  63
  64 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  65     {
  66         template_name   => "opac-user.tt",
  67         query           => $query,
  68         type            => "opac",
  69         debug           => 1,
  70     }
  71 );
  72
  73 my %renewed = map { $_ => 1 } split( ':', $query->param('renewed') || '' );
  74
  75 my $show_priority;
  76 for ( C4::Context->preference("OPACShowHoldQueueDetails") ) {
  77     m/priority/ and $show_priority = 1;
  78 }
  79
  80 my $patronupdate = $query->param('patronupdate');
  81 my $canrenew = 1;
  82
  83 $template->param( shibbolethAuthentication => C4::Context->config('useshibboleth') );
  84
  85 # get borrower information ....
  86 my $patron = Koha::Patrons->find( $borrowernumber );
  87 my $borr = $patron->unblessed;
  88 # unblessed is a hash vs. object/undef. Hence the use of curly braces here.
  89 my $borcat = $borr ? $borr->{categorycode} : q{};
  90
  91 my (  $today_year,   $today_month,   $today_day) = Today();
  92 my ($warning_year, $warning_month, $warning_day) = split /-/, $borr->{'dateexpiry'};
  93
  94 my $debar = Koha::Patrons->find( $borrowernumber )->is_debarred;
  95 my $userdebarred;
  96
  97 if ($debar) {
  98     $userdebarred = 1;
  99     $template->param( 'userdebarred' => $userdebarred );
 100     if ( $debar ne "9999-12-31" ) {
 101         $borr->{'userdebarreddate'} = $debar;
 102     }
 103     # FIXME looks like $available is not needed
 104     # If a user is discharged they have a validated discharge available
 105     my $available = Koha::Patron::Discharge::count({
 106         borrowernumber => $borrowernumber,
 107         validated      => 1,
 108     });
 109     $template->param( 'discharge_available' => $available && Koha::Patron::Discharge::is_discharged({borrowernumber => $borrowernumber}) );
 110 }
 111
 112 if ( $userdebarred || $borr->{'gonenoaddress'} || $borr->{'lost'} ) {
 113     $borr->{'flagged'} = 1;
 114     $canrenew = 0;
 115 }
 116
 117 my $amountoutstanding = $patron->account->balance;
 118 my $no_renewal_amt = C4::Context->preference( 'OPACFineNoRenewals' );
 119 $no_renewal_amt = undef unless looks_like_number( $no_renewal_amt );
 120 my $amountoutstandingfornewal =
 121   C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
 122   ? $amountoutstanding
 123   : $patron->account->outstanding_debits->total_outstanding;
 124
 125 if (   C4::Context->preference('OpacRenewalAllowed')
 126     && defined($no_renewal_amt)
 127     && $amountoutstandingfornewal > $no_renewal_amt )
 128 {
 129     $borr->{'flagged'} = 1;
 130     $canrenew = 0;
 131     $template->param(
 132         renewal_blocked_fines => $no_renewal_amt,
 133         renewal_blocked_fines_amountoutstanding => $amountoutstandingfornewal,
 134     );
 135 }
 136
 137 my $maxoutstanding = C4::Context->preference('maxoutstanding');
 138 if ( $amountoutstanding && ( $amountoutstanding > $maxoutstanding ) ){
 139     $borr->{blockedonfines} = 1;
 140 }
 141
 142 # Warningdate is the date that the warning starts appearing
 143 if ( $borr->{'dateexpiry'} && C4::Context->preference('NotifyBorrowerDeparture') ) {
 144     my $days_to_expiry = Date_to_Days( $warning_year, $warning_month, $warning_day ) - Date_to_Days( $today_year, $today_month, $today_day );
 145     if ( $days_to_expiry < 0 ) {
 146         #borrower card has expired, warn the borrower
 147         $borr->{'warnexpired'} = $borr->{'dateexpiry'};
 148     } elsif ( $days_to_expiry < C4::Context->preference('NotifyBorrowerDeparture') ) {
 149         # borrower card soon to expire, warn the borrower
 150         $borr->{'warndeparture'} = $borr->{dateexpiry};
 151         if (C4::Context->preference('ReturnBeforeExpiry')){
 152             $borr->{'returnbeforeexpiry'} = 1;
 153         }
 154     }
 155 }
 156
 157 # pass on any renew errors to the template for displaying
 158 my $renew_error = $query->param('renew_error');
 159
 160 $template->param(
 161                     amountoutstanding => $amountoutstanding,
 162                     borrowernumber    => $borrowernumber,
 163                     patron_flagged    => $borr->{flagged},
 164                     OPACMySummaryHTML => (C4::Context->preference("OPACMySummaryHTML")) ? 1 : 0,
 165                     surname           => $borr->{surname},
 166                     RENEW_ERROR       => $renew_error,
 167                     borrower          => $borr,
 168                 );
 169
 170 #get issued items ....
 171
 172 my $count          = 0;
 173 my $overdues_count = 0;
 174 my @overdues;
 175 my @issuedat;
 176 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 177 my $pending_checkouts = $patron->pending_checkouts->search({}, { order_by => [ { -desc => 'date_due' }, { -asc => 'issue_id' } ] });
 178 my $are_renewable_items = 0;
 179 if ( $pending_checkouts->count ) { # Useless test
 180     while ( my $c = $pending_checkouts->next ) {
 181         my $issue = $c->unblessed_all_relateds;
 182         # check for reserves
 183         my $restype = GetReserveStatus( $issue->{'itemnumber'} );
 184         if ( $restype ) {
 185             $issue->{'reserved'} = 1;
 186         }
 187
 188         # Must be moved in a module if reused
 189         my $charges = Koha::Account::Lines->search(
 190             {
 191                 borrowernumber    => $patron->borrowernumber,
 192                 amountoutstanding => { '>' => 0 },
 193                 debit_type_code   => [ 'OVERDUE', 'LOST' ],
 194                 itemnumber        => $issue->{itemnumber}
 195             },
 196         );
 197         $issue->{charges} = $charges->total_outstanding;
 198
 199         my $rental_fines = Koha::Account::Lines->search(
 200             {
 201                 borrowernumber    => $patron->borrowernumber,
 202                 amountoutstanding => { '>' => 0 },
 203                 debit_type_code   => { 'LIKE' => 'RENT_%' },
 204                 itemnumber        => $issue->{itemnumber}
 205             }
 206         );
 207         $issue->{rentalfines} = $rental_fines->total_outstanding;
 208
 209         # check if item is renewable
 210         my ($status,$renewerror) = CanBookBeRenewed( $borrowernumber, $issue->{'itemnumber'} );
 211         ($issue->{'renewcount'},$issue->{'renewsallowed'},$issue->{'renewsleft'}) = GetRenewCount($borrowernumber, $issue->{'itemnumber'});
 212         ( $issue->{'renewalfee'}, $issue->{'renewalitemtype'} ) = GetIssuingCharges( $issue->{'itemnumber'}, $borrowernumber );
 213         $issue->{itemtype_object} = Koha::ItemTypes->find( Koha::Items->find( $issue->{itemnumber} )->effective_itemtype );
 214         if($status && C4::Context->preference("OpacRenewalAllowed")){
 215             $are_renewable_items = 1;
 216             $issue->{'status'} = $status;
 217         }
 218
 219         $issue->{'renewed'} = $renewed{ $issue->{'itemnumber'} };
 220
 221         if ($renewerror) {
 222             $issue->{'too_many'}       = 1 if $renewerror eq 'too_many';
 223             $issue->{'on_reserve'}     = 1 if $renewerror eq 'on_reserve';
 224             $issue->{'norenew_overdue'} = 1 if $renewerror eq 'overdue';
 225             $issue->{'auto_renew'}     = 1 if $renewerror eq 'auto_renew';
 226             $issue->{'auto_too_soon'}  = 1 if $renewerror eq 'auto_too_soon';
 227             $issue->{'auto_too_late'}  = 1 if $renewerror eq 'auto_too_late';
 228             $issue->{'auto_too_much_oweing'}  = 1 if $renewerror eq 'auto_too_much_oweing';
 229             $issue->{'item_denied_renewal'}  = 1 if $renewerror eq 'item_denied_renewal';
 230
 231             if ( $renewerror eq 'too_soon' ) {
 232                 $issue->{'too_soon'}         = 1;
 233                 $issue->{'soonestrenewdate'} = output_pref(
 234                     C4::Circulation::GetSoonestRenewDate(
 235                         $issue->{borrowernumber},
 236                         $issue->{itemnumber}
 237                     )
 238                 );
 239             }
 240         }
 241
 242         if ( $c->is_overdue ) {
 243             push @overdues, $issue;
 244             $overdues_count++;
 245             $issue->{'overdue'} = 1;
 246         }
 247         else {
 248             $issue->{'issued'} = 1;
 249         }
 250         # imageurl:
 251         my $itemtype = $issue->{'itemtype'};
 252         if ( $itemtype ) {
 253             $issue->{'imageurl'}    = getitemtypeimagelocation( 'opac', $itemtypes->{$itemtype}->{'imageurl'} );
 254             $issue->{'description'} = $itemtypes->{$itemtype}->{'description'};
 255         }
 256
 257         $issue->{biblio_object} = Koha::Biblios->find($issue->{biblionumber});
 258         push @issuedat, $issue;
 259         $count++;
 260
 261         my $isbn = GetNormalizedISBN($issue->{'isbn'});
 262         $issue->{normalized_isbn} = $isbn;
 263         my $marcrecord = GetMarcBiblio({
 264             biblionumber => $issue->{'biblionumber'},
 265             embed_items  => 1,
 266             opac         => 1,
 267             borcat       => $borcat });
 268         $issue->{normalized_upc} = GetNormalizedUPC( $marcrecord, C4::Context->preference('marcflavour') );
 269
 270                 # My Summary HTML
 271                 if (my $my_summary_html = C4::Context->preference('OPACMySummaryHTML')){
 272                     $issue->{author} ? $my_summary_html =~ s/{AUTHOR}/$issue->{author}/g : $my_summary_html =~ s/{AUTHOR}//g;
 273                     $issue->{title} =~ s/\/+$//; # remove trailing slash
 274                     $issue->{title} =~ s/\s+$//; # remove trailing space
 275                     $issue->{title} ? $my_summary_html =~ s/{TITLE}/$issue->{title}/g : $my_summary_html =~ s/{TITLE}//g;
 276                     $issue->{isbn} ? $my_summary_html =~ s/{ISBN}/$isbn/g : $my_summary_html =~ s/{ISBN}//g;
 277                     $issue->{biblionumber} ? $my_summary_html =~ s/{BIBLIONUMBER}/$issue->{biblionumber}/g : $my_summary_html =~ s/{BIBLIONUMBER}//g;
 278                     $issue->{MySummaryHTML} = $my_summary_html;
 279                 }
 280     }
 281 }
 282 my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
 283 $canrenew = 0 if ($overduesblockrenewing ne 'allow' and $overdues_count == $count) || !$are_renewable_items;
 284
 285 $template->param( ISSUES       => \@issuedat );
 286 $template->param( issues_count => $count );
 287 $template->param( canrenew     => $canrenew );
 288 $template->param( OVERDUES       => \@overdues );
 289 $template->param( overdues_count => $overdues_count );
 290
 291 my $show_barcode = Koha::Patron::Attribute::Types->search(
 292     { code => ATTRIBUTE_SHOW_BARCODE } )->count;
 293 if ($show_barcode) {
 294     my $patron_show_barcode = GetBorrowerAttributeValue($borrowernumber, ATTRIBUTE_SHOW_BARCODE);
 295     undef $show_barcode if defined($patron_show_barcode) && !$patron_show_barcode;
 296 }
 297 $template->param( show_barcode => 1 ) if $show_barcode;
 298
 299 # now the reserved items....
 300 my $reserves = Koha::Holds->search( { borrowernumber => $borrowernumber } );
 301
 302 $template->param(
 303     RESERVES       => $reserves,
 304     showpriority   => $show_priority,
 305 );
 306
 307 if (C4::Context->preference('BakerTaylorEnabled')) {
 308     $template->param(
 309         BakerTaylorEnabled  => 1,
 310         BakerTaylorImageURL => &image_url(),
 311         BakerTaylorLinkURL  => &link_url(),
 312         BakerTaylorBookstoreURL => C4::Context->preference('BakerTaylorBookstoreURL'),
 313     );
 314 }
 315
 316 if (C4::Context->preference("OPACAmazonCoverImages") or
 317     C4::Context->preference("GoogleJackets") or
 318     C4::Context->preference("BakerTaylorEnabled") or
 319     C4::Context->preference("SyndeticsCoverImages") or
 320     ( C4::Context->preference('OPACCustomCoverImages') and C4::Context->preference('CustomCoverImagesURL') )
 321 ) {
 322         $template->param(JacketImages=>1);
 323 }
 324
 325 $template->param(
 326     OverDriveCirculation => C4::Context->preference('OverDriveCirculation') || 0,
 327     overdrive_error      => scalar $query->param('overdrive_error') || undef,
 328     overdrive_tab        => scalar $query->param('overdrive_tab') || 0,
 329     RecordedBooksCirculation => C4::Context->preference('RecordedBooksClientSecret') && C4::Context->preference('RecordedBooksLibraryID'),
 330 );
 331
 332 my $patron_messages = Koha::Patron::Messages->search(
 333     {
 334         borrowernumber => $borrowernumber,
 335         message_type => 'B',
 336     }
 337 );
 338
 339 if (   C4::Context->preference('AllowPatronToSetCheckoutsVisibilityForGuarantor')
 340     || C4::Context->preference('AllowStaffToSetCheckoutsVisibilityForGuarantor') )
 341 {
 342     my @relatives;
 343     # Filter out guarantees that don't want guarantor to see checkouts
 344     foreach my $gr ( $patron->guarantee_relationships() ) {
 345         my $g = $gr->guarantee;
 346         push( @relatives, $g ) if $g->privacy_guarantor_checkouts;
 347     }
 348     $template->param( relatives => \@relatives );
 349 }
 350
 351 if (   C4::Context->preference('AllowPatronToSetFinesVisibilityForGuarantor')
 352     || C4::Context->preference('AllowStaffToSetFinesVisibilityForGuarantor') )
 353 {
 354     my @relatives_with_fines;
 355     # Filter out guarantees that don't want guarantor to see checkouts
 356     foreach my $gr ( $patron->guarantee_relationships() ) {
 357         my $g = $gr->guarantee;
 358         push( @relatives_with_fines, $g ) if $g->privacy_guarantor_fines;
 359     }
 360     $template->param( relatives_with_fines => \@relatives_with_fines );
 361 }
 362
 363
 364 $template->param(
 365     patron_messages          => $patron_messages,
 366     opacnote                 => $borr->{opacnote},
 367     patronupdate             => $patronupdate,
 368     OpacRenewalAllowed       => C4::Context->preference("OpacRenewalAllowed"),
 369     userview                 => 1,
 370     SuspendHoldsOpac         => C4::Context->preference('SuspendHoldsOpac'),
 371     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 372     OpacHoldNotes            => C4::Context->preference('OpacHoldNotes'),
 373     failed_holds             => scalar $query->param('failed_holds'),
 374 );
 375
 376 # if not an empty string this indicates to return
 377 # back to the opac-results page
 378 my $search_query = $query->param('has-search-query');
 379
 380 if ($search_query) {
 381
 382     print $query->redirect(
 383         -uri    => "/cgi-bin/koha/opac-search.pl?$search_query",
 384         -cookie => $cookie,
 385     );
 386 }
 387
 388 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };