opac/opac-user.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 # parts copyright 2010 BibLibre
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23
  24 use C4::Auth;
  25 use C4::Koha;
  26 use C4::Circulation;
  27 use C4::External::BakerTaylor qw( image_url link_url );
  28 use C4::Reserves;
  29 use C4::Members;
  30 use C4::Output;
  31 use C4::Biblio;
  32 use C4::Items;
  33 use C4::Letters;
  34 use Koha::Account::Lines;
  35 use Koha::Biblios;
  36 use Koha::Libraries;
  37 use Koha::DateUtils;
  38 use Koha::Holds;
  39 use Koha::Database;
  40 use Koha::ItemTypes;
  41 use Koha::Patron::Attribute::Types;
  42 use Koha::Patrons;
  43 use Koha::Patron::Messages;
  44 use Koha::Patron::Discharge;
  45 use Koha::Patrons;
  46 use Koha::Ratings;
  47 use Koha::Token;
  48
  49 use constant ATTRIBUTE_SHOW_BARCODE => 'SHOW_BCODE';
  50
  51 use Scalar::Util qw(looks_like_number);
  52 use Date::Calc qw(
  53   Today
  54   Add_Delta_Days
  55   Date_to_Days
  56 );
  57
  58 my $query = CGI->new;
  59
  60 # CAS single logout handling
  61 # Will print header and exit
  62 C4::Context->preference('casAuthentication') and C4::Auth_with_cas::logout_if_required($query);
  63
  64 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  65     {
  66         template_name   => "opac-user.tt",
  67         query           => $query,
  68         type            => "opac",
  69         debug           => 1,
  70     }
  71 );
  72
  73 my %renewed = map { $_ => 1 } split( ':', $query->param('renewed') || '' );
  74
  75 my $show_priority;
  76 for ( C4::Context->preference("OPACShowHoldQueueDetails") ) {
  77     m/priority/ and $show_priority = 1;
  78 }
  79
  80 my $patronupdate = $query->param('patronupdate');
  81 my $canrenew = 1;
  82
  83 $template->param( shibbolethAuthentication => C4::Context->config('useshibboleth') );
  84
  85 # get borrower information ....
  86 my $patron = Koha::Patrons->find( $borrowernumber );
  87
  88 if( $query->param('update_arc') && C4::Context->preference("AllowPatronToControlAutorenewal") ){
  89     die "Wrong CSRF token"
  90         unless Koha::Token->new->check_csrf({
  91             session_id => scalar $query->cookie('CGISESSID'),
  92             token  => scalar $query->param('csrf_token'),
  93         });
  94
  95     my $autorenew_checkouts = $query->param('borrower_autorenew_checkouts');
  96     $patron->autorenew_checkouts( $autorenew_checkouts )->store() if defined $autorenew_checkouts;
  97 }
  98
  99 my $borr = $patron->unblessed;
 100 # unblessed is a hash vs. object/undef. Hence the use of curly braces here.
 101 my $borcat = $borr ? $borr->{categorycode} : q{};
 102
 103 my (  $today_year,   $today_month,   $today_day) = Today();
 104 my ($warning_year, $warning_month, $warning_day) = split /-/, $borr->{'dateexpiry'};
 105
 106 my $debar = Koha::Patrons->find( $borrowernumber )->is_debarred;
 107 my $userdebarred;
 108
 109 if ($debar) {
 110     $userdebarred = 1;
 111     $template->param( 'userdebarred' => $userdebarred );
 112     if ( $debar ne "9999-12-31" ) {
 113         $borr->{'userdebarreddate'} = $debar;
 114     }
 115     # FIXME looks like $available is not needed
 116     # If a user is discharged they have a validated discharge available
 117     my $available = Koha::Patron::Discharge::count({
 118         borrowernumber => $borrowernumber,
 119         validated      => 1,
 120     });
 121     $template->param( 'discharge_available' => $available && Koha::Patron::Discharge::is_discharged({borrowernumber => $borrowernumber}) );
 122 }
 123
 124 if ( $userdebarred || $borr->{'gonenoaddress'} || $borr->{'lost'} ) {
 125     $borr->{'flagged'} = 1;
 126     $canrenew = 0;
 127 }
 128
 129 my $amountoutstanding = $patron->account->balance;
 130 my $no_renewal_amt = C4::Context->preference( 'OPACFineNoRenewals' );
 131 $no_renewal_amt = undef unless looks_like_number( $no_renewal_amt );
 132 my $amountoutstandingfornewal =
 133   C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
 134   ? $amountoutstanding
 135   : $patron->account->outstanding_debits->total_outstanding;
 136
 137 if (   C4::Context->preference('OpacRenewalAllowed')
 138     && defined($no_renewal_amt)
 139     && $amountoutstandingfornewal > $no_renewal_amt )
 140 {
 141     $borr->{'flagged'} = 1;
 142     $canrenew = 0;
 143     $template->param(
 144         renewal_blocked_fines => $no_renewal_amt,
 145         renewal_blocked_fines_amountoutstanding => $amountoutstandingfornewal,
 146     );
 147 }
 148
 149 my $maxoutstanding = C4::Context->preference('maxoutstanding');
 150 if ( $amountoutstanding && ( $amountoutstanding > $maxoutstanding ) ){
 151     $borr->{blockedonfines} = 1;
 152 }
 153
 154 # Warningdate is the date that the warning starts appearing
 155 if ( $borr->{'dateexpiry'} && C4::Context->preference('NotifyBorrowerDeparture') ) {
 156     my $days_to_expiry = Date_to_Days( $warning_year, $warning_month, $warning_day ) - Date_to_Days( $today_year, $today_month, $today_day );
 157     if ( $days_to_expiry < 0 ) {
 158         #borrower card has expired, warn the borrower
 159         $borr->{'warnexpired'} = $borr->{'dateexpiry'};
 160     } elsif ( $days_to_expiry < C4::Context->preference('NotifyBorrowerDeparture') ) {
 161         # borrower card soon to expire, warn the borrower
 162         $borr->{'warndeparture'} = $borr->{dateexpiry};
 163         if (C4::Context->preference('ReturnBeforeExpiry')){
 164             $borr->{'returnbeforeexpiry'} = 1;
 165         }
 166     }
 167 }
 168
 169 # pass on any renew errors to the template for displaying
 170 my $renew_error = $query->param('renew_error');
 171
 172 $template->param(
 173                     amountoutstanding => $amountoutstanding,
 174                     borrowernumber    => $borrowernumber,
 175                     patron_flagged    => $borr->{flagged},
 176                     OPACMySummaryHTML => (C4::Context->preference("OPACMySummaryHTML")) ? 1 : 0,
 177                     surname           => $borr->{surname},
 178                     RENEW_ERROR       => $renew_error,
 179                     borrower          => $borr,
 180                     csrf_token             => Koha::Token->new->generate_csrf({
 181                         session_id => scalar $query->cookie('CGISESSID'),
 182                     }),
 183                 );
 184
 185 #get issued items ....
 186
 187 my $count          = 0;
 188 my $overdues_count = 0;
 189 my @overdues;
 190 my @issuedat;
 191 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 192 my $pending_checkouts = $patron->pending_checkouts->search({}, { order_by => [ { -desc => 'date_due' }, { -asc => 'issue_id' } ] });
 193 my $are_renewable_items = 0;
 194 if ( $pending_checkouts->count ) { # Useless test
 195     while ( my $c = $pending_checkouts->next ) {
 196         my $issue = $c->unblessed_all_relateds;
 197         # check for reserves
 198         my $restype = GetReserveStatus( $issue->{'itemnumber'} );
 199         if ( $restype ) {
 200             $issue->{'reserved'} = 1;
 201         }
 202
 203         # Must be moved in a module if reused
 204         my $charges = Koha::Account::Lines->search(
 205             {
 206                 borrowernumber    => $patron->borrowernumber,
 207                 amountoutstanding => { '>' => 0 },
 208                 debit_type_code   => [ 'OVERDUE', 'LOST' ],
 209                 itemnumber        => $issue->{itemnumber}
 210             },
 211         );
 212         $issue->{charges} = $charges->total_outstanding;
 213
 214         my $rental_fines = Koha::Account::Lines->search(
 215             {
 216                 borrowernumber    => $patron->borrowernumber,
 217                 amountoutstanding => { '>' => 0 },
 218                 debit_type_code   => { 'LIKE' => 'RENT_%' },
 219                 itemnumber        => $issue->{itemnumber}
 220             }
 221         );
 222         $issue->{rentalfines} = $rental_fines->total_outstanding;
 223
 224         # check if item is renewable
 225         my ($status,$renewerror) = CanBookBeRenewed( $borrowernumber, $issue->{'itemnumber'} );
 226         (
 227             $issue->{'renewcount'},
 228             $issue->{'renewsallowed'},
 229             $issue->{'renewsleft'},
 230             $issue->{'unseencount'},
 231             $issue->{'unseenallowed'},
 232             $issue->{'unseenleft'}
 233         ) = GetRenewCount($borrowernumber, $issue->{'itemnumber'});
 234         ( $issue->{'renewalfee'}, $issue->{'renewalitemtype'} ) = GetIssuingCharges( $issue->{'itemnumber'}, $borrowernumber );
 235         $issue->{itemtype_object} = Koha::ItemTypes->find( Koha::Items->find( $issue->{itemnumber} )->effective_itemtype );
 236         if($status && C4::Context->preference("OpacRenewalAllowed")){
 237             $are_renewable_items = 1;
 238             $issue->{'status'} = $status;
 239         }
 240
 241         $issue->{'renewed'} = $renewed{ $issue->{'itemnumber'} };
 242
 243         if ($renewerror) {
 244             $issue->{'too_many'}       = 1 if $renewerror eq 'too_many';
 245             $issue->{'too_unseen'}     = 1 if $renewerror eq 'too_unseen';
 246             $issue->{'on_reserve'}     = 1 if $renewerror eq 'on_reserve';
 247             $issue->{'norenew_overdue'} = 1 if $renewerror eq 'overdue';
 248             $issue->{'auto_renew'}     = 1 if $renewerror eq 'auto_renew';
 249             $issue->{'auto_too_soon'}  = 1 if $renewerror eq 'auto_too_soon';
 250             $issue->{'auto_too_late'}  = 1 if $renewerror eq 'auto_too_late';
 251             $issue->{'auto_too_much_oweing'}  = 1 if $renewerror eq 'auto_too_much_oweing';
 252             $issue->{'item_denied_renewal'}  = 1 if $renewerror eq 'item_denied_renewal';
 253
 254             if ( $renewerror eq 'too_soon' ) {
 255                 $issue->{'too_soon'}         = 1;
 256                 $issue->{'soonestrenewdate'} = output_pref(
 257                     C4::Circulation::GetSoonestRenewDate(
 258                         $issue->{borrowernumber},
 259                         $issue->{itemnumber}
 260                     )
 261                 );
 262             }
 263         }
 264
 265         if ( $c->is_overdue ) {
 266             push @overdues, $issue;
 267             $overdues_count++;
 268             $issue->{'overdue'} = 1;
 269         }
 270         else {
 271             $issue->{'issued'} = 1;
 272         }
 273         # imageurl:
 274         my $itemtype = $issue->{'itemtype'};
 275         if ( $itemtype ) {
 276             $issue->{'imageurl'}    = getitemtypeimagelocation( 'opac', $itemtypes->{$itemtype}->{'imageurl'} );
 277             $issue->{'description'} = $itemtypes->{$itemtype}->{'description'};
 278         }
 279
 280         if ( C4::Context->preference('OpacStarRatings') eq 'all' ) {
 281             my $ratings = Koha::Ratings->search({ biblionumber => $issue->{biblionumber} });
 282             $issue->{ratings} = $ratings;
 283             $issue->{my_rating} = $borrowernumber ? $ratings->search({ borrowernumber => $borrowernumber })->next : undef;
 284         }
 285
 286         $issue->{biblio_object} = Koha::Biblios->find($issue->{biblionumber});
 287         push @issuedat, $issue;
 288         $count++;
 289
 290         my $isbn = GetNormalizedISBN($issue->{'isbn'});
 291         $issue->{normalized_isbn} = $isbn;
 292         my $marcrecord = GetMarcBiblio({
 293             biblionumber => $issue->{'biblionumber'},
 294             embed_items  => 1,
 295             opac         => 1,
 296             borcat       => $borcat });
 297         $issue->{normalized_upc} = GetNormalizedUPC( $marcrecord, C4::Context->preference('marcflavour') );
 298
 299                 # My Summary HTML
 300                 if (my $my_summary_html = C4::Context->preference('OPACMySummaryHTML')){
 301                     $issue->{author} ? $my_summary_html =~ s/{AUTHOR}/$issue->{author}/g : $my_summary_html =~ s/{AUTHOR}//g;
 302                     $issue->{title} =~ s/\/+$//; # remove trailing slash
 303                     $issue->{title} =~ s/\s+$//; # remove trailing space
 304                     $issue->{title} ? $my_summary_html =~ s/{TITLE}/$issue->{title}/g : $my_summary_html =~ s/{TITLE}//g;
 305                     $issue->{isbn} ? $my_summary_html =~ s/{ISBN}/$isbn/g : $my_summary_html =~ s/{ISBN}//g;
 306                     $issue->{biblionumber} ? $my_summary_html =~ s/{BIBLIONUMBER}/$issue->{biblionumber}/g : $my_summary_html =~ s/{BIBLIONUMBER}//g;
 307                     $issue->{MySummaryHTML} = $my_summary_html;
 308                 }
 309     }
 310 }
 311 my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
 312 $canrenew = 0 if ($overduesblockrenewing ne 'allow' and $overdues_count == $count) || !$are_renewable_items;
 313
 314 $template->param( ISSUES       => \@issuedat );
 315 $template->param( issues_count => $count );
 316 $template->param( canrenew     => $canrenew );
 317 $template->param( OVERDUES       => \@overdues );
 318 $template->param( overdues_count => $overdues_count );
 319
 320 my $show_barcode = Koha::Patron::Attribute::Types->search( # FIXME we should not need this search
 321     { code => ATTRIBUTE_SHOW_BARCODE } )->count;
 322 if ($show_barcode) {
 323     my $patron_show_barcode = $patron->get_extended_attribute(ATTRIBUTE_SHOW_BARCODE);
 324     undef $show_barcode if $patron_show_barcode and not $patron_show_barcode->attribute;
 325 }
 326 $template->param( show_barcode => 1 ) if $show_barcode;
 327
 328 # now the reserved items....
 329 my $reserves = Koha::Holds->search( { borrowernumber => $borrowernumber } );
 330
 331 $template->param(
 332     RESERVES       => $reserves,
 333     showpriority   => $show_priority,
 334 );
 335
 336 if (C4::Context->preference('BakerTaylorEnabled')) {
 337     $template->param(
 338         BakerTaylorEnabled  => 1,
 339         BakerTaylorImageURL => &image_url(),
 340         BakerTaylorLinkURL  => &link_url(),
 341         BakerTaylorBookstoreURL => C4::Context->preference('BakerTaylorBookstoreURL'),
 342     );
 343 }
 344
 345 if (C4::Context->preference("OPACAmazonCoverImages") or
 346     C4::Context->preference("GoogleJackets") or
 347     C4::Context->preference("BakerTaylorEnabled") or
 348     C4::Context->preference("SyndeticsCoverImages") or
 349     ( C4::Context->preference('OPACCustomCoverImages') and C4::Context->preference('CustomCoverImagesURL') )
 350 ) {
 351         $template->param(JacketImages=>1);
 352 }
 353
 354 $template->param(
 355     OverDriveCirculation => C4::Context->preference('OverDriveCirculation') || 0,
 356     overdrive_error      => scalar $query->param('overdrive_error') || undef,
 357     overdrive_tab        => scalar $query->param('overdrive_tab') || 0,
 358     RecordedBooksCirculation => C4::Context->preference('RecordedBooksClientSecret') && C4::Context->preference('RecordedBooksLibraryID'),
 359 );
 360
 361 my $patron_messages = Koha::Patron::Messages->search(
 362     {
 363         borrowernumber => $borrowernumber,
 364         message_type => 'B',
 365     }
 366 );
 367
 368 if (   C4::Context->preference('AllowPatronToSetCheckoutsVisibilityForGuarantor')
 369     || C4::Context->preference('AllowStaffToSetCheckoutsVisibilityForGuarantor') )
 370 {
 371     my @relatives;
 372     # Filter out guarantees that don't want guarantor to see checkouts
 373     foreach my $gr ( $patron->guarantee_relationships() ) {
 374         my $g = $gr->guarantee;
 375         push( @relatives, $g ) if $g->privacy_guarantor_checkouts;
 376     }
 377     $template->param( relatives => \@relatives );
 378 }
 379
 380 if (   C4::Context->preference('AllowPatronToSetFinesVisibilityForGuarantor')
 381     || C4::Context->preference('AllowStaffToSetFinesVisibilityForGuarantor') )
 382 {
 383     my @relatives_with_fines;
 384     # Filter out guarantees that don't want guarantor to see checkouts
 385     foreach my $gr ( $patron->guarantee_relationships() ) {
 386         my $g = $gr->guarantee;
 387         push( @relatives_with_fines, $g ) if $g->privacy_guarantor_fines;
 388     }
 389     $template->param( relatives_with_fines => \@relatives_with_fines );
 390 }
 391
 392
 393 $template->param(
 394     patron_messages          => $patron_messages,
 395     opacnote                 => $borr->{opacnote},
 396     patronupdate             => $patronupdate,
 397     OpacRenewalAllowed       => C4::Context->preference("OpacRenewalAllowed"),
 398     userview                 => 1,
 399     SuspendHoldsOpac         => C4::Context->preference('SuspendHoldsOpac'),
 400     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 401     OpacHoldNotes            => C4::Context->preference('OpacHoldNotes'),
 402     failed_holds             => scalar $query->param('failed_holds'),
 403 );
 404
 405 # if not an empty string this indicates to return
 406 # back to the opac-results page
 407 my $search_query = $query->param('has-search-query');
 408
 409 if ($search_query) {
 410
 411     print $query->redirect(
 412         -uri    => "/cgi-bin/koha/opac-search.pl?$search_query",
 413         -cookie => $cookie,
 414     );
 415 }
 416
 417 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };