opac/opac-user.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 # parts copyright 2010 BibLibre
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23 use URI;
  24
  25 use C4::Auth qw( get_template_and_user );
  26 use C4::Koha qw(
  27     getitemtypeimagelocation
  28     GetNormalizedISBN
  29     GetNormalizedUPC
  30 );
  31 use C4::Circulation qw( CanBookBeRenewed GetRenewCount GetIssuingCharges );
  32 use C4::External::BakerTaylor qw( image_url link_url );
  33 use C4::Reserves qw( GetReserveStatus );
  34 use C4::Members;
  35 use C4::Output qw( output_html_with_http_headers );
  36 use Koha::Account::Lines;
  37 use Koha::Biblios;
  38 use Koha::Libraries;
  39 use Koha::DateUtils qw( output_pref );
  40 use Koha::Holds;
  41 use Koha::Database;
  42 use Koha::ItemTypes;
  43 use Koha::Patron::Attribute::Types;
  44 use Koha::Patrons;
  45 use Koha::Patron::Messages;
  46 use Koha::Patron::Discharge;
  47 use Koha::Patrons;
  48 use Koha::Ratings;
  49 use Koha::Recalls;
  50 use Koha::Token;
  51
  52 use constant ATTRIBUTE_SHOW_BARCODE => 'SHOW_BCODE';
  53
  54 use Scalar::Util qw( looks_like_number );
  55 use Date::Calc qw( Date_to_Days Today );
  56
  57 my $query = CGI->new;
  58
  59 # CAS single logout handling
  60 # Will print header and exit
  61 if ( C4::Context->preference('casAuthentication') ) {
  62     require C4::Auth_with_cas;
  63     C4::Auth_with_cas::logout_if_required($query);
  64 }
  65
  66 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  67     {
  68         template_name   => "opac-user.tt",
  69         query           => $query,
  70         type            => "opac",
  71     }
  72 );
  73
  74 my %renewed = map { $_ => 1 } split( ':', $query->param('renewed') || '' );
  75
  76 my $show_priority;
  77 for ( C4::Context->preference("OPACShowHoldQueueDetails") ) {
  78     m/priority/ and $show_priority = 1;
  79 }
  80
  81 my $patronupdate = $query->param('patronupdate');
  82 my $canrenew = 1;
  83
  84 $template->param( shibbolethAuthentication => C4::Context->config('useshibboleth') );
  85
  86 # get borrower information ....
  87 my $patron = Koha::Patrons->find( $borrowernumber );
  88
  89 if( $query->param('update_arc') && C4::Context->preference("AllowPatronToControlAutorenewal") ){
  90     die "Wrong CSRF token"
  91         unless Koha::Token->new->check_csrf({
  92             session_id => scalar $query->cookie('CGISESSID'),
  93             token  => scalar $query->param('csrf_token'),
  94         });
  95
  96     my $autorenew_checkouts = $query->param('borrower_autorenew_checkouts');
  97     $patron->autorenew_checkouts( $autorenew_checkouts )->store() if defined $autorenew_checkouts;
  98 }
  99
 100 my $borr = $patron->unblessed;
 101
 102 my (  $today_year,   $today_month,   $today_day) = Today();
 103 my ($warning_year, $warning_month, $warning_day) = split /-/, $borr->{'dateexpiry'};
 104
 105 my $debar = Koha::Patrons->find( $borrowernumber )->is_debarred;
 106 my $userdebarred;
 107
 108 if ($debar) {
 109     $userdebarred = 1;
 110     $template->param( 'userdebarred' => $userdebarred );
 111     if ( $debar ne "9999-12-31" ) {
 112         $borr->{'userdebarreddate'} = $debar;
 113     }
 114     # FIXME looks like $available is not needed
 115     # If a user is discharged they have a validated discharge available
 116     my $available = Koha::Patron::Discharge::count({
 117         borrowernumber => $borrowernumber,
 118         validated      => 1,
 119     });
 120     $template->param( 'discharge_available' => $available && Koha::Patron::Discharge::is_discharged({borrowernumber => $borrowernumber}) );
 121 }
 122
 123 if ( $userdebarred || $borr->{'gonenoaddress'} || $borr->{'lost'} ) {
 124     $borr->{'flagged'} = 1;
 125     $canrenew = 0;
 126 }
 127
 128 my $amountoutstanding = $patron->account->balance;
 129 my $no_renewal_amt = C4::Context->preference( 'OPACFineNoRenewals' );
 130 $no_renewal_amt = undef unless looks_like_number( $no_renewal_amt );
 131 my $amountoutstandingfornewal =
 132   C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
 133   ? $amountoutstanding
 134   : $patron->account->outstanding_debits->total_outstanding;
 135
 136 if (   C4::Context->preference('OpacRenewalAllowed')
 137     && defined($no_renewal_amt)
 138     && $amountoutstandingfornewal > $no_renewal_amt )
 139 {
 140     $borr->{'flagged'} = 1;
 141     $canrenew = 0;
 142     $template->param(
 143         renewal_blocked_fines => $no_renewal_amt,
 144         renewal_blocked_fines_amountoutstanding => $amountoutstandingfornewal,
 145     );
 146 }
 147
 148 my $maxoutstanding = C4::Context->preference('maxoutstanding');
 149 if ( $amountoutstanding && ( $amountoutstanding > $maxoutstanding ) ){
 150     $borr->{blockedonfines} = 1;
 151 }
 152
 153 # Warningdate is the date that the warning starts appearing
 154 if ( $borr->{'dateexpiry'} && C4::Context->preference('NotifyBorrowerDeparture') ) {
 155     my $days_to_expiry = Date_to_Days( $warning_year, $warning_month, $warning_day ) - Date_to_Days( $today_year, $today_month, $today_day );
 156     if ( $days_to_expiry < 0 ) {
 157         #borrower card has expired, warn the borrower
 158         $borr->{'warnexpired'} = $borr->{'dateexpiry'};
 159     } elsif ( $days_to_expiry < C4::Context->preference('NotifyBorrowerDeparture') ) {
 160         # borrower card soon to expire, warn the borrower
 161         $borr->{'warndeparture'} = $borr->{dateexpiry};
 162         if (C4::Context->preference('ReturnBeforeExpiry')){
 163             $borr->{'returnbeforeexpiry'} = 1;
 164         }
 165     }
 166 }
 167
 168 # pass on any renew errors to the template for displaying
 169 my $renew_error = $query->param('renew_error');
 170
 171 $template->param(
 172                     amountoutstanding => $amountoutstanding,
 173                     borrowernumber    => $borrowernumber,
 174                     patron_flagged    => $borr->{flagged},
 175                     OPACMySummaryHTML => (C4::Context->preference("OPACMySummaryHTML")) ? 1 : 0,
 176                     surname           => $borr->{surname},
 177                     RENEW_ERROR       => $renew_error,
 178                     borrower          => $borr,
 179                     csrf_token             => Koha::Token->new->generate_csrf({
 180                         session_id => scalar $query->cookie('CGISESSID'),
 181                     }),
 182                 );
 183
 184 #get issued items ....
 185
 186 my $count          = 0;
 187 my $overdues_count = 0;
 188 my @overdues;
 189 my @issuedat;
 190 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 191 my $pending_checkouts = $patron->pending_checkouts->search({}, { order_by => [ { -desc => 'date_due' }, { -asc => 'issue_id' } ] });
 192 my $are_renewable_items = 0;
 193 if ( $pending_checkouts->count ) { # Useless test
 194     while ( my $c = $pending_checkouts->next ) {
 195         my $issue = $c->unblessed_all_relateds;
 196         # check for reserves
 197         my $restype = GetReserveStatus( $issue->{'itemnumber'} );
 198         if ( $restype ) {
 199             $issue->{'reserved'} = 1;
 200         }
 201
 202         # Must be moved in a module if reused
 203         my $charges = Koha::Account::Lines->search(
 204             {
 205                 borrowernumber    => $patron->borrowernumber,
 206                 amountoutstanding => { '>' => 0 },
 207                 debit_type_code   => [ 'OVERDUE', 'LOST' ],
 208                 itemnumber        => $issue->{itemnumber}
 209             },
 210         );
 211         $issue->{charges} = $charges->total_outstanding;
 212
 213         my $rental_fines = Koha::Account::Lines->search(
 214             {
 215                 borrowernumber    => $patron->borrowernumber,
 216                 amountoutstanding => { '>' => 0 },
 217                 debit_type_code   => { 'LIKE' => 'RENT_%' },
 218                 itemnumber        => $issue->{itemnumber}
 219             }
 220         );
 221         $issue->{rentalfines} = $rental_fines->total_outstanding;
 222
 223         # check if item is renewable
 224         my ($status,$renewerror,$info) = CanBookBeRenewed( $borrowernumber, $issue->{'itemnumber'} );
 225         (
 226             $issue->{'renewcount'},
 227             $issue->{'renewsallowed'},
 228             $issue->{'renewsleft'},
 229             $issue->{'unseencount'},
 230             $issue->{'unseenallowed'},
 231             $issue->{'unseenleft'}
 232         ) = GetRenewCount($borrowernumber, $issue->{'itemnumber'});
 233         ( $issue->{'renewalfee'}, $issue->{'renewalitemtype'} ) = GetIssuingCharges( $issue->{'itemnumber'}, $borrowernumber );
 234         $issue->{itemtype_object} = Koha::ItemTypes->find( Koha::Items->find( $issue->{itemnumber} )->effective_itemtype );
 235         if($status && C4::Context->preference("OpacRenewalAllowed")){
 236             $are_renewable_items = 1;
 237             $issue->{'status'} = $status;
 238         }
 239
 240         $issue->{'renewed'} = $renewed{ $issue->{'itemnumber'} };
 241
 242         if ($renewerror) {
 243             $issue->{'too_many'}       = 1 if $renewerror eq 'too_many';
 244             $issue->{'too_unseen'}     = 1 if $renewerror eq 'too_unseen';
 245             $issue->{'on_reserve'}     = 1 if $renewerror eq 'on_reserve';
 246             $issue->{'norenew_overdue'} = 1 if $renewerror eq 'overdue';
 247             $issue->{'auto_renew'}     = 1 if $renewerror eq 'auto_renew';
 248             $issue->{'auto_too_soon'}  = 1 if $renewerror eq 'auto_too_soon';
 249             $issue->{'auto_too_late'}  = 1 if $renewerror eq 'auto_too_late';
 250             $issue->{'auto_too_much_oweing'}  = 1 if $renewerror eq 'auto_too_much_oweing';
 251             $issue->{'item_denied_renewal'}  = 1 if $renewerror eq 'item_denied_renewal';
 252
 253             if ( $renewerror eq 'too_soon' ) {
 254                 $issue->{'too_soon'}         = 1;
 255                 $issue->{'soonestrenewdate'} = $info->{soonest_renew_date};
 256             }
 257         }
 258
 259         if ( $c->is_overdue ) {
 260             push @overdues, $issue;
 261             $overdues_count++;
 262             $issue->{'overdue'} = 1;
 263         }
 264         else {
 265             $issue->{'issued'} = 1;
 266         }
 267         # imageurl:
 268         my $itemtype = $issue->{'itemtype'};
 269         if ( $itemtype ) {
 270             $issue->{'imageurl'}    = getitemtypeimagelocation( 'opac', $itemtypes->{$itemtype}->{'imageurl'} );
 271             $issue->{'description'} = $itemtypes->{$itemtype}->{'description'};
 272         }
 273
 274         if ( C4::Context->preference('OpacStarRatings') eq 'all' ) {
 275             my $ratings = Koha::Ratings->search({ biblionumber => $issue->{biblionumber} });
 276             $issue->{ratings} = $ratings;
 277             $issue->{my_rating} = $borrowernumber ? $ratings->search({ borrowernumber => $borrowernumber })->next : undef;
 278         }
 279
 280         my $biblio_object = Koha::Biblios->find($issue->{biblionumber});
 281         $issue->{biblio_object} = $biblio_object;
 282         push @issuedat, $issue;
 283         $count++;
 284
 285         my $isbn = GetNormalizedISBN($issue->{'isbn'});
 286         $issue->{normalized_isbn} = $isbn;
 287         my $marcrecord = $biblio_object->metadata->record({ embed_items => 1, opac => 1, patron => $patron,});
 288         $issue->{normalized_upc} = GetNormalizedUPC( $marcrecord, C4::Context->preference('marcflavour') );
 289
 290                 # My Summary HTML
 291                 if (my $my_summary_html = C4::Context->preference('OPACMySummaryHTML')){
 292                     $issue->{author} ? $my_summary_html =~ s/{AUTHOR}/$issue->{author}/g : $my_summary_html =~ s/{AUTHOR}//g;
 293                     $issue->{title} =~ s/\/+$//; # remove trailing slash
 294                     $issue->{title} =~ s/\s+$//; # remove trailing space
 295                     $issue->{title} ? $my_summary_html =~ s/{TITLE}/$issue->{title}/g : $my_summary_html =~ s/{TITLE}//g;
 296                     $issue->{isbn} ? $my_summary_html =~ s/{ISBN}/$isbn/g : $my_summary_html =~ s/{ISBN}//g;
 297                     $issue->{biblionumber} ? $my_summary_html =~ s/{BIBLIONUMBER}/$issue->{biblionumber}/g : $my_summary_html =~ s/{BIBLIONUMBER}//g;
 298                     $issue->{MySummaryHTML} = $my_summary_html;
 299                 }
 300
 301         if ( C4::Context->preference('UseRecalls') ) {
 302             my $maybe_recalls = Koha::Recalls->search({ biblio_id => $issue->{biblionumber}, item_id => [ undef, $issue->{itemnumber} ], completed => 0 });
 303             while( my $recall = $maybe_recalls->next ) {
 304                 if ( $recall->checkout and $recall->checkout->issue_id == $issue->{issue_id} ) {
 305                     $issue->{recall} = 1;
 306                     last;
 307                 }
 308             }
 309         }
 310     }
 311 }
 312 my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
 313 $canrenew = 0 if ($overduesblockrenewing ne 'allow' and $overdues_count == $count) || !$are_renewable_items;
 314
 315 $template->param( ISSUES       => \@issuedat );
 316 $template->param( issues_count => $count );
 317 $template->param( canrenew     => $canrenew );
 318 $template->param( OVERDUES       => \@overdues );
 319 $template->param( overdues_count => $overdues_count );
 320
 321 my $show_barcode = Koha::Patron::Attribute::Types->search( # FIXME we should not need this search
 322     { code => ATTRIBUTE_SHOW_BARCODE } )->count;
 323 if ($show_barcode) {
 324     my $patron_show_barcode = $patron->get_extended_attribute(ATTRIBUTE_SHOW_BARCODE);
 325     undef $show_barcode if $patron_show_barcode and not $patron_show_barcode->attribute;
 326 }
 327 $template->param( show_barcode => 1 ) if $show_barcode;
 328
 329 # now the reserved items....
 330 my $reserves = $patron->holds->filter_out_has_cancellation_requests;
 331
 332 $template->param(
 333     RESERVES       => $reserves,
 334     showpriority   => $show_priority,
 335 );
 336
 337 if ( C4::Context->preference('UseRecalls') ) {
 338     my $recalls = Koha::Recalls->search( { patron_id => $borrowernumber, completed => 0 } );
 339     $template->param( RECALLS => $recalls );
 340 }
 341
 342 if (C4::Context->preference('BakerTaylorEnabled')) {
 343     $template->param(
 344         BakerTaylorEnabled  => 1,
 345         BakerTaylorImageURL => &image_url(),
 346         BakerTaylorLinkURL  => &link_url(),
 347         BakerTaylorBookstoreURL => C4::Context->preference('BakerTaylorBookstoreURL'),
 348     );
 349 }
 350
 351 if (C4::Context->preference("OPACAmazonCoverImages") or
 352     C4::Context->preference("GoogleJackets") or
 353     C4::Context->preference("BakerTaylorEnabled") or
 354     C4::Context->preference("SyndeticsCoverImages") or
 355     ( C4::Context->preference('OPACCustomCoverImages') and C4::Context->preference('CustomCoverImagesURL') )
 356 ) {
 357         $template->param(JacketImages=>1);
 358 }
 359
 360 $template->param(
 361     OverDriveCirculation => C4::Context->preference('OverDriveCirculation') || 0,
 362     overdrive_error      => scalar $query->param('overdrive_error') || undef,
 363     overdrive_tab        => scalar $query->param('overdrive_tab') || 0,
 364     RecordedBooksCirculation => C4::Context->preference('RecordedBooksClientSecret') && C4::Context->preference('RecordedBooksLibraryID'),
 365 );
 366
 367 my $patron_messages = Koha::Patron::Messages->search(
 368     {
 369         borrowernumber => $borrowernumber,
 370         message_type => 'B',
 371     }
 372 );
 373
 374 if (   C4::Context->preference('AllowPatronToSetCheckoutsVisibilityForGuarantor')
 375     || C4::Context->preference('AllowStaffToSetCheckoutsVisibilityForGuarantor') )
 376 {
 377     my @relatives;
 378     # Filter out guarantees that don't want guarantor to see checkouts
 379     foreach my $gr ( $patron->guarantee_relationships->as_list ) {
 380         my $g = $gr->guarantee;
 381         push( @relatives, $g ) if $g->privacy_guarantor_checkouts;
 382     }
 383     $template->param( relatives => \@relatives );
 384 }
 385
 386 if (   C4::Context->preference('AllowPatronToSetFinesVisibilityForGuarantor')
 387     || C4::Context->preference('AllowStaffToSetFinesVisibilityForGuarantor') )
 388 {
 389     my @relatives_with_fines;
 390     # Filter out guarantees that don't want guarantor to see checkouts
 391     foreach my $gr ( $patron->guarantee_relationships->as_list ) {
 392         my $g = $gr->guarantee;
 393         push( @relatives_with_fines, $g ) if $g->privacy_guarantor_fines;
 394     }
 395     $template->param( relatives_with_fines => \@relatives_with_fines );
 396 }
 397
 398 if ( C4::Context->preference("ArticleRequests") ) {
 399     $template->param(
 400         current_article_requests => [$patron->article_requests->filter_by_current->as_list],
 401     );
 402 }
 403
 404 $template->param(
 405     patron_messages          => $patron_messages,
 406     opacnote                 => $borr->{opacnote},
 407     patronupdate             => $patronupdate,
 408     OpacRenewalAllowed       => C4::Context->preference("OpacRenewalAllowed"),
 409     userview                 => 1,
 410     SuspendHoldsOpac         => C4::Context->preference('SuspendHoldsOpac'),
 411     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 412     OpacHoldNotes            => C4::Context->preference('OpacHoldNotes'),
 413     failed_holds             => scalar $query->param('failed_holds'),
 414 );
 415
 416 # if not an empty string this indicates to return
 417 # back to the opac-results page
 418 my $search_query = $query->param('has-search-query');
 419
 420 if ($search_query) {
 421
 422     print $query->redirect(
 423         -uri    => "/cgi-bin/koha/opac-search.pl?$search_query",
 424         -cookie => $cookie,
 425     );
 426 }
 427
 428 # if not an empty string this indicates to return
 429 # back to the page we triggered the login from
 430 my $return = $query->param('return');
 431 if ( $return ) {
 432     my $uri_syspref = C4::Context->preference('OPACBaseURL');
 433     if ( $uri_syspref ){
 434         my $uri = URI->new($uri_syspref);
 435         if ( $uri->isa('URI::http') && $uri->host() ){
 436             my $return_uri = URI->new($return);
 437             $return_uri->scheme( $uri->scheme() );
 438             $return_uri->authority( $uri->authority() );
 439             print $query->redirect(
 440                 -uri    => "$return_uri",
 441                 -cookie => $cookie,
 442             );
 443         }
 444     }
 445 }
 446
 447 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };