opac/opac-user.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 # parts copyright 2010 BibLibre
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23
  24 use C4::Auth;
  25 use C4::Koha;
  26 use C4::Circulation;
  27 use C4::External::BakerTaylor qw( image_url link_url );
  28 use C4::Reserves;
  29 use C4::Members;
  30 use C4::Members::AttributeTypes;
  31 use C4::Members::Attributes qw/GetBorrowerAttributeValue/;
  32 use C4::Output;
  33 use C4::Biblio;
  34 use C4::Items;
  35 use C4::Letters;
  36 use Koha::Account::Lines;
  37 use Koha::Biblios;
  38 use Koha::Libraries;
  39 use Koha::DateUtils;
  40 use Koha::Holds;
  41 use Koha::Database;
  42 use Koha::ItemTypes;
  43 use Koha::Patron::Attribute::Types;
  44 use Koha::Patrons;
  45 use Koha::Patron::Messages;
  46 use Koha::Patron::Discharge;
  47 use Koha::Patrons;
  48
  49 use constant ATTRIBUTE_SHOW_BARCODE => 'SHOW_BCODE';
  50
  51 use Scalar::Util qw(looks_like_number);
  52 use Date::Calc qw(
  53   Today
  54   Add_Delta_Days
  55   Date_to_Days
  56 );
  57
  58 my $query = new CGI;
  59
  60 # CAS single logout handling
  61 # Will print header and exit
  62 C4::Context->preference('casAuthentication') and C4::Auth_with_cas::logout_if_required($query);
  63
  64 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  65     {
  66         template_name   => "opac-user.tt",
  67         query           => $query,
  68         type            => "opac",
  69         authnotrequired => 0,
  70         debug           => 1,
  71     }
  72 );
  73
  74 my %renewed = map { $_ => 1 } split( ':', $query->param('renewed') || '' );
  75
  76 my $show_priority;
  77 for ( C4::Context->preference("OPACShowHoldQueueDetails") ) {
  78     m/priority/ and $show_priority = 1;
  79 }
  80
  81 my $patronupdate = $query->param('patronupdate');
  82 my $canrenew = 1;
  83
  84 $template->param( shibbolethAuthentication => C4::Context->config('useshibboleth') );
  85
  86 # get borrower information ....
  87 my $patron = Koha::Patrons->find( $borrowernumber );
  88 my $borr = $patron->unblessed;
  89 # unblessed is a hash vs. object/undef. Hence the use of curly braces here.
  90 my $borcat = $borr ? $borr->{categorycode} : q{};
  91
  92 my (  $today_year,   $today_month,   $today_day) = Today();
  93 my ($warning_year, $warning_month, $warning_day) = split /-/, $borr->{'dateexpiry'};
  94
  95 my $debar = Koha::Patrons->find( $borrowernumber )->is_debarred;
  96 my $userdebarred;
  97
  98 if ($debar) {
  99     $userdebarred = 1;
 100     $template->param( 'userdebarred' => $userdebarred );
 101     if ( $debar ne "9999-12-31" ) {
 102         $borr->{'userdebarreddate'} = $debar;
 103     }
 104     # FIXME looks like $available is not needed
 105     # If a user is discharged they have a validated discharge available
 106     my $available = Koha::Patron::Discharge::count({
 107         borrowernumber => $borrowernumber,
 108         validated      => 1,
 109     });
 110     $template->param( 'discharge_available' => $available && Koha::Patron::Discharge::is_discharged({borrowernumber => $borrowernumber}) );
 111 }
 112
 113 if ( $userdebarred || $borr->{'gonenoaddress'} || $borr->{'lost'} ) {
 114     $borr->{'flagged'} = 1;
 115     $canrenew = 0;
 116 }
 117
 118 my $amountoutstanding = $patron->account->balance;
 119 my $no_renewal_amt = C4::Context->preference( 'OPACFineNoRenewals' );
 120 $no_renewal_amt = undef unless looks_like_number( $no_renewal_amt );
 121 my $amountoutstandingfornewal =
 122   C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
 123   ? $amountoutstanding
 124   : $patron->account->outstanding_debits->total_outstanding;
 125
 126 if (   C4::Context->preference('OpacRenewalAllowed')
 127     && defined($no_renewal_amt)
 128     && $amountoutstandingfornewal > $no_renewal_amt )
 129 {
 130     $borr->{'flagged'} = 1;
 131     $canrenew = 0;
 132     $template->param(
 133         renewal_blocked_fines => $no_renewal_amt,
 134         renewal_blocked_fines_amountoutstanding => $amountoutstandingfornewal,
 135     );
 136 }
 137
 138 # Warningdate is the date that the warning starts appearing
 139 if ( $borr->{'dateexpiry'} && C4::Context->preference('NotifyBorrowerDeparture') ) {
 140     my $days_to_expiry = Date_to_Days( $warning_year, $warning_month, $warning_day ) - Date_to_Days( $today_year, $today_month, $today_day );
 141     if ( $days_to_expiry < 0 ) {
 142         #borrower card has expired, warn the borrower
 143         $borr->{'warnexpired'} = $borr->{'dateexpiry'};
 144     } elsif ( $days_to_expiry < C4::Context->preference('NotifyBorrowerDeparture') ) {
 145         # borrower card soon to expire, warn the borrower
 146         $borr->{'warndeparture'} = $borr->{dateexpiry};
 147         if (C4::Context->preference('ReturnBeforeExpiry')){
 148             $borr->{'returnbeforeexpiry'} = 1;
 149         }
 150     }
 151 }
 152
 153 # pass on any renew errors to the template for displaying
 154 my $renew_error = $query->param('renew_error');
 155
 156 $template->param(
 157                     amountoutstanding => $amountoutstanding,
 158                     borrowernumber    => $borrowernumber,
 159                     patron_flagged    => $borr->{flagged},
 160                     OPACMySummaryHTML => (C4::Context->preference("OPACMySummaryHTML")) ? 1 : 0,
 161                     surname           => $borr->{surname},
 162                     RENEW_ERROR       => $renew_error,
 163                     borrower          => $borr,
 164                 );
 165
 166 #get issued items ....
 167
 168 my $count          = 0;
 169 my $overdues_count = 0;
 170 my @overdues;
 171 my @issuedat;
 172 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 173 my $pending_checkouts = $patron->pending_checkouts->search({}, { order_by => [ { -desc => 'date_due' }, { -asc => 'issue_id' } ] });
 174 if ( $pending_checkouts->count ) { # Useless test
 175     while ( my $c = $pending_checkouts->next ) {
 176         my $issue = $c->unblessed_all_relateds;
 177         # check for reserves
 178         my $restype = GetReserveStatus( $issue->{'itemnumber'} );
 179         if ( $restype ) {
 180             $issue->{'reserved'} = 1;
 181         }
 182
 183         # Must be moved in a module if reused
 184         my $charges = Koha::Account::Lines->search(
 185             {
 186                 borrowernumber    => $patron->borrowernumber,
 187                 amountoutstanding => { '>' => 0 },
 188                 debit_type_code   => [ 'OVERDUE', 'LOST' ],
 189                 itemnumber        => $issue->{itemnumber}
 190             },
 191         );
 192         $issue->{charges} = $charges->total_outstanding;
 193
 194         my $rental_fines = Koha::Account::Lines->search(
 195             {
 196                 borrowernumber    => $patron->borrowernumber,
 197                 amountoutstanding => { '>' => 0 },
 198                 debit_type_code   => { 'LIKE' => 'RENT_%' },
 199                 itemnumber        => $issue->{itemnumber}
 200             }
 201         );
 202         $issue->{rentalfines} = $rental_fines->total_outstanding;
 203
 204         # check if item is renewable
 205         my ($status,$renewerror) = CanBookBeRenewed( $borrowernumber, $issue->{'itemnumber'} );
 206         ($issue->{'renewcount'},$issue->{'renewsallowed'},$issue->{'renewsleft'}) = GetRenewCount($borrowernumber, $issue->{'itemnumber'});
 207         ( $issue->{'renewalfee'}, $issue->{'renewalitemtype'} ) = GetIssuingCharges( $issue->{'itemnumber'}, $borrowernumber );
 208         $issue->{itemtype_object} = Koha::ItemTypes->find( Koha::Items->find( $issue->{itemnumber} )->effective_itemtype );
 209         if($status && C4::Context->preference("OpacRenewalAllowed")){
 210             $issue->{'status'} = $status;
 211         }
 212
 213         $issue->{'renewed'} = $renewed{ $issue->{'itemnumber'} };
 214
 215         if ($renewerror) {
 216             $issue->{'too_many'}       = 1 if $renewerror eq 'too_many';
 217             $issue->{'on_reserve'}     = 1 if $renewerror eq 'on_reserve';
 218             $issue->{'norenew_overdue'} = 1 if $renewerror eq 'overdue';
 219             $issue->{'auto_renew'}     = 1 if $renewerror eq 'auto_renew';
 220             $issue->{'auto_too_soon'}  = 1 if $renewerror eq 'auto_too_soon';
 221             $issue->{'auto_too_late'}  = 1 if $renewerror eq 'auto_too_late';
 222             $issue->{'auto_too_much_oweing'}  = 1 if $renewerror eq 'auto_too_much_oweing';
 223             $issue->{'item_denied_renewal'}  = 1 if $renewerror eq 'item_denied_renewal';
 224
 225             if ( $renewerror eq 'too_soon' ) {
 226                 $issue->{'too_soon'}         = 1;
 227                 $issue->{'soonestrenewdate'} = output_pref(
 228                     C4::Circulation::GetSoonestRenewDate(
 229                         $issue->{borrowernumber},
 230                         $issue->{itemnumber}
 231                     )
 232                 );
 233             }
 234         }
 235
 236         if ( $c->is_overdue ) {
 237             push @overdues, $issue;
 238             $overdues_count++;
 239             $issue->{'overdue'} = 1;
 240         }
 241         else {
 242             $issue->{'issued'} = 1;
 243         }
 244         # imageurl:
 245         my $itemtype = $issue->{'itemtype'};
 246         if ( $itemtype ) {
 247             $issue->{'imageurl'}    = getitemtypeimagelocation( 'opac', $itemtypes->{$itemtype}->{'imageurl'} );
 248             $issue->{'description'} = $itemtypes->{$itemtype}->{'description'};
 249         }
 250
 251         $issue->{biblio_object} = Koha::Biblios->find($issue->{biblionumber});
 252         push @issuedat, $issue;
 253         $count++;
 254
 255         my $isbn = GetNormalizedISBN($issue->{'isbn'});
 256         $issue->{normalized_isbn} = $isbn;
 257         my $marcrecord = GetMarcBiblio({
 258             biblionumber => $issue->{'biblionumber'},
 259             embed_items  => 1,
 260             opac         => 1,
 261             borcat       => $borcat });
 262         $issue->{normalized_upc} = GetNormalizedUPC( $marcrecord, C4::Context->preference('marcflavour') );
 263
 264                 # My Summary HTML
 265                 if (my $my_summary_html = C4::Context->preference('OPACMySummaryHTML')){
 266                     $issue->{author} ? $my_summary_html =~ s/{AUTHOR}/$issue->{author}/g : $my_summary_html =~ s/{AUTHOR}//g;
 267                     $issue->{title} =~ s/\/+$//; # remove trailing slash
 268                     $issue->{title} =~ s/\s+$//; # remove trailing space
 269                     $issue->{title} ? $my_summary_html =~ s/{TITLE}/$issue->{title}/g : $my_summary_html =~ s/{TITLE}//g;
 270                     $issue->{isbn} ? $my_summary_html =~ s/{ISBN}/$isbn/g : $my_summary_html =~ s/{ISBN}//g;
 271                     $issue->{biblionumber} ? $my_summary_html =~ s/{BIBLIONUMBER}/$issue->{biblionumber}/g : $my_summary_html =~ s/{BIBLIONUMBER}//g;
 272                     $issue->{MySummaryHTML} = $my_summary_html;
 273                 }
 274     }
 275 }
 276 my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
 277 $canrenew = 0 if ($overduesblockrenewing ne 'allow' and $overdues_count == $count);
 278
 279 $template->param( ISSUES       => \@issuedat );
 280 $template->param( issues_count => $count );
 281 $template->param( canrenew     => $canrenew );
 282 $template->param( OVERDUES       => \@overdues );
 283 $template->param( overdues_count => $overdues_count );
 284
 285 my $show_barcode = Koha::Patron::Attribute::Types->search(
 286     { code => ATTRIBUTE_SHOW_BARCODE } )->count;
 287 if ($show_barcode) {
 288     my $patron_show_barcode = GetBorrowerAttributeValue($borrowernumber, ATTRIBUTE_SHOW_BARCODE);
 289     undef $show_barcode if defined($patron_show_barcode) && !$patron_show_barcode;
 290 }
 291 $template->param( show_barcode => 1 ) if $show_barcode;
 292
 293 # now the reserved items....
 294 my $reserves = Koha::Holds->search( { borrowernumber => $borrowernumber } );
 295
 296 $template->param(
 297     RESERVES       => $reserves,
 298     showpriority   => $show_priority,
 299 );
 300
 301 if (C4::Context->preference('BakerTaylorEnabled')) {
 302     $template->param(
 303         BakerTaylorEnabled  => 1,
 304         BakerTaylorImageURL => &image_url(),
 305         BakerTaylorLinkURL  => &link_url(),
 306         BakerTaylorBookstoreURL => C4::Context->preference('BakerTaylorBookstoreURL'),
 307     );
 308 }
 309
 310 if (C4::Context->preference("OPACAmazonCoverImages") or
 311     C4::Context->preference("GoogleJackets") or
 312     C4::Context->preference("BakerTaylorEnabled") or
 313     C4::Context->preference("SyndeticsCoverImages") or
 314     ( C4::Context->preference('OPACCustomCoverImages') and C4::Context->preference('CustomCoverImagesURL') )
 315 ) {
 316         $template->param(JacketImages=>1);
 317 }
 318
 319 $template->param(
 320     OverDriveCirculation => C4::Context->preference('OverDriveCirculation') || 0,
 321     overdrive_error      => scalar $query->param('overdrive_error') || undef,
 322     overdrive_tab        => scalar $query->param('overdrive_tab') || 0,
 323     RecordedBooksCirculation => C4::Context->preference('RecordedBooksClientSecret') && C4::Context->preference('RecordedBooksLibraryID'),
 324 );
 325
 326 my $patron_messages = Koha::Patron::Messages->search(
 327     {
 328         borrowernumber => $borrowernumber,
 329         message_type => 'B',
 330     }
 331 );
 332
 333 if (   C4::Context->preference('AllowPatronToSetCheckoutsVisibilityForGuarantor')
 334     || C4::Context->preference('AllowStaffToSetCheckoutsVisibilityForGuarantor') )
 335 {
 336     my @relatives;
 337     # Filter out guarantees that don't want guarantor to see checkouts
 338     foreach my $gr ( $patron->guarantee_relationships() ) {
 339         my $g = $gr->guarantee;
 340         push( @relatives, $g ) if $g->privacy_guarantor_checkouts;
 341     }
 342     $template->param( relatives => \@relatives );
 343 }
 344
 345 if (   C4::Context->preference('AllowPatronToSetFinesVisibilityForGuarantor')
 346     || C4::Context->preference('AllowStaffToSetFinesVisibilityForGuarantor') )
 347 {
 348     my @relatives_with_fines;
 349     # Filter out guarantees that don't want guarantor to see checkouts
 350     foreach my $gr ( $patron->guarantee_relationships() ) {
 351         my $g = $gr->guarantee;
 352         push( @relatives_with_fines, $g ) if $g->privacy_guarantor_fines;
 353     }
 354     $template->param( relatives_with_fines => \@relatives_with_fines );
 355 }
 356
 357
 358 $template->param(
 359     patron_messages          => $patron_messages,
 360     opacnote                 => $borr->{opacnote},
 361     patronupdate             => $patronupdate,
 362     OpacRenewalAllowed       => C4::Context->preference("OpacRenewalAllowed"),
 363     userview                 => 1,
 364     SuspendHoldsOpac         => C4::Context->preference('SuspendHoldsOpac'),
 365     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 366     OpacHoldNotes            => C4::Context->preference('OpacHoldNotes'),
 367     failed_holds             => scalar $query->param('failed_holds'),
 368 );
 369
 370 # if not an empty string this indicates to return
 371 # back to the opac-results page
 372 my $search_query = $query->param('has-search-query');
 373
 374 if ($search_query) {
 375
 376     print $query->redirect(
 377         -uri    => "/cgi-bin/koha/opac-search.pl?$search_query",
 378         -cookie => $cookie,
 379     );
 380 }
 381
 382 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };