opac/opac-user.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 # parts copyright 2010 BibLibre
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19
  20 use strict;
  21 #use warnings; FIXME - Bug 2505
  22
  23 use CGI qw ( -utf8 );
  24
  25 use C4::Auth;
  26 use C4::Koha;
  27 use C4::Circulation;
  28 use C4::Reserves;
  29 use C4::Members;
  30 use C4::Members::AttributeTypes;
  31 use C4::Members::Attributes qw/GetBorrowerAttributeValue/;
  32 use C4::Output;
  33 use C4::Biblio;
  34 use C4::Items;
  35 use C4::Letters;
  36 use Koha::Account::Lines;
  37 use Koha::Libraries;
  38 use Koha::DateUtils;
  39 use Koha::Holds;
  40 use Koha::Database;
  41 use Koha::ItemTypes;
  42 use Koha::Patron::Attribute::Types;
  43 use Koha::Patron::Messages;
  44 use Koha::Patron::Discharge;
  45 use Koha::Patrons;
  46
  47 use constant ATTRIBUTE_SHOW_BARCODE => 'SHOW_BCODE';
  48
  49 use Scalar::Util qw(looks_like_number);
  50 use Date::Calc qw(
  51   Today
  52   Add_Delta_Days
  53   Date_to_Days
  54 );
  55
  56 my $query = new CGI;
  57
  58 BEGIN {
  59     if (C4::Context->preference('BakerTaylorEnabled')) {
  60         require C4::External::BakerTaylor;
  61         import C4::External::BakerTaylor qw(&image_url &link_url);
  62     }
  63 }
  64 my $logout='';
  65 # CAS Single Sign Out
  66 if (C4::Context->preference('casAuthentication')){
  67     # Check we havent been hit by a logout call
  68     my $xml = $query->param('logoutRequest');
  69     if ($xml) {
  70         my $dom = XML::LibXML->load_xml(string => $xml);
  71         my $ticket;
  72         foreach my $node ($dom->findnodes('/samlp:LogoutRequest')){
  73             $ticket = $node->findvalue('./samlp:SessionIndex');
  74         }
  75         $query->param(-name =>'logout.x', -value => 1);
  76         $query->param(-name =>'cas_ticket', -value => $ticket);
  77         $logout=1;
  78     }
  79 }
  80
  81 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  82     {
  83         template_name   => "opac-user.tt",
  84         query           => $query,
  85         type            => "opac",
  86         authnotrequired => 0,
  87         debug           => 1,
  88     }
  89 );
  90
  91 if ($logout){
  92     print $query->header;
  93     exit;
  94 }
  95
  96
  97 my %renewed = map { $_ => 1 } split( ':', $query->param('renewed') );
  98
  99 my $show_priority;
 100 for ( C4::Context->preference("OPACShowHoldQueueDetails") ) {
 101     m/priority/ and $show_priority = 1;
 102 }
 103
 104 my $patronupdate = $query->param('patronupdate');
 105 my $canrenew = 1;
 106
 107 $template->param( shibbolethAuthentication => C4::Context->config('useshibboleth') );
 108
 109 if (!$borrowernumber) {
 110     $template->param( adminWarning => 1 );
 111 }
 112
 113 # get borrower information ....
 114 my $patron = Koha::Patrons->find( $borrowernumber );
 115 my $borr = $patron->unblessed;
 116
 117 my (  $today_year,   $today_month,   $today_day) = Today();
 118 my ($warning_year, $warning_month, $warning_day) = split /-/, $borr->{'dateexpiry'};
 119
 120 my $debar = Koha::Patrons->find( $borrowernumber )->is_debarred;
 121 my $userdebarred;
 122
 123 if ($debar) {
 124     $userdebarred = 1;
 125     $template->param( 'userdebarred' => $userdebarred );
 126     if ( $debar ne "9999-12-31" ) {
 127         $borr->{'userdebarreddate'} = $debar;
 128     }
 129     # FIXME looks like $available is not needed
 130     # If a user is discharged they have a validated discharge available
 131     my $available = Koha::Patron::Discharge::count({
 132         borrowernumber => $borrowernumber,
 133         validated      => 1,
 134     });
 135     $template->param( 'discharge_available' => $available && Koha::Patron::Discharge::is_discharged({borrowernumber => $borrowernumber}) );
 136 }
 137
 138 if ( $userdebarred || $borr->{'gonenoaddress'} || $borr->{'lost'} ) {
 139     $borr->{'flagged'} = 1;
 140     $canrenew = 0;
 141 }
 142
 143 my $amountoutstanding = $patron->account->balance;
 144 if ( $amountoutstanding > 5 ) {
 145     $borr->{'amountoverfive'} = 1;
 146 }
 147 if ( 5 >= $amountoutstanding && $amountoutstanding > 0 ) {
 148     $borr->{'amountoverzero'} = 1;
 149 }
 150 my $no_renewal_amt = C4::Context->preference( 'OPACFineNoRenewals' );
 151 $no_renewal_amt = undef unless looks_like_number( $no_renewal_amt );
 152
 153 if (   C4::Context->preference('OpacRenewalAllowed')
 154     && defined($no_renewal_amt)
 155     && $amountoutstanding > $no_renewal_amt )
 156 {
 157     $borr->{'flagged'} = 1;
 158     $canrenew = 0;
 159     $template->param(
 160         renewal_blocked_fines => $no_renewal_amt,
 161         renewal_blocked_fines_amountoutstanding => $amountoutstanding,
 162     );
 163 }
 164
 165 if ( $amountoutstanding < 0 ) {
 166     $borr->{'amountlessthanzero'} = 1;
 167     $amountoutstanding = -1 * ( $amountoutstanding );
 168 }
 169
 170 # Warningdate is the date that the warning starts appearing
 171 if ( $borr->{'dateexpiry'} && C4::Context->preference('NotifyBorrowerDeparture') ) {
 172     my $days_to_expiry = Date_to_Days( $warning_year, $warning_month, $warning_day ) - Date_to_Days( $today_year, $today_month, $today_day );
 173     if ( $days_to_expiry < 0 ) {
 174         #borrower card has expired, warn the borrower
 175         $borr->{'warnexpired'} = $borr->{'dateexpiry'};
 176     } elsif ( $days_to_expiry < C4::Context->preference('NotifyBorrowerDeparture') ) {
 177         # borrower card soon to expire, warn the borrower
 178         $borr->{'warndeparture'} = $borr->{dateexpiry};
 179         if (C4::Context->preference('ReturnBeforeExpiry')){
 180             $borr->{'returnbeforeexpiry'} = 1;
 181         }
 182     }
 183 }
 184
 185 # pass on any renew errors to the template for displaying
 186 my $renew_error = $query->param('renew_error');
 187
 188 $template->param(   BORROWER_INFO     => $borr,
 189                     amountoutstanding => $amountoutstanding,
 190                     borrowernumber    => $borrowernumber,
 191                     patron_flagged    => $borr->{flagged},
 192                     OPACMySummaryHTML => (C4::Context->preference("OPACMySummaryHTML")) ? 1 : 0,
 193                     surname           => $borr->{surname},
 194                     RENEW_ERROR       => $renew_error,
 195                     borrower          => $borr,
 196                 );
 197
 198 #get issued items ....
 199
 200 my $count          = 0;
 201 my $overdues_count = 0;
 202 my @overdues;
 203 my @issuedat;
 204 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 205 my $issues = GetPendingIssues($borrowernumber);
 206 if ($issues){
 207     foreach my $issue ( sort { $b->{date_due}->datetime() cmp $a->{date_due}->datetime() } @{$issues} ) {
 208         # check for reserves
 209         my $restype = GetReserveStatus( $issue->{'itemnumber'} );
 210         if ( $restype ) {
 211             $issue->{'reserved'} = 1;
 212         }
 213
 214         # Must be moved in a module if reused
 215         my $charges = Koha::Account::Lines->search(
 216             {
 217                 borrowernumber    => $patron->borrowernumber,
 218                 amountoutstanding => { '>' => 0 },
 219                 accounttype       => [ 'F', 'FU', 'L' ],
 220                 itemnumber        => $issue->{itemnumber}
 221             },
 222             { select => [ { sum => 'amountoutstanding' } ], as => ['charges'] }
 223         );
 224         $issue->{charges} = $charges->count ? $charges->next->get_column('charges') : 0;
 225
 226         my $rental_fines = Koha::Account::Lines->search(
 227             {
 228                 borrowernumber    => $patron->borrowernumber,
 229                 amountoutstanding => { '>' => 0 },
 230                 accounttype       => 'Rent',
 231                 itemnumber        => $issue->{itemnumber}
 232             },
 233             {
 234                 select => [ { sum => 'amountoutstanding' } ],
 235                 as     => ['rental_fines']
 236             }
 237         );
 238         $issue->{rentalfines} = $charges->count ? $charges->next->get_column('rental_fines') : 0;
 239
 240         my $marcrecord = GetMarcBiblio({ biblionumber => $issue->{'biblionumber'} });
 241         $issue->{'subtitle'} = GetRecordValue('subtitle', $marcrecord, GetFrameworkCode($issue->{'biblionumber'}));
 242         # check if item is renewable
 243         my ($status,$renewerror) = CanBookBeRenewed( $borrowernumber, $issue->{'itemnumber'} );
 244         ($issue->{'renewcount'},$issue->{'renewsallowed'},$issue->{'renewsleft'}) = GetRenewCount($borrowernumber, $issue->{'itemnumber'});
 245         ( $issue->{'renewalfee'}, $issue->{'renewalitemtype'} ) = GetIssuingCharges( $issue->{'itemnumber'}, $borrowernumber );
 246         if($status && C4::Context->preference("OpacRenewalAllowed")){
 247             $issue->{'status'} = $status;
 248         }
 249
 250         $issue->{'renewed'} = $renewed{ $issue->{'itemnumber'} };
 251
 252         if ($renewerror) {
 253             $issue->{'too_many'}       = 1 if $renewerror eq 'too_many';
 254             $issue->{'on_reserve'}     = 1 if $renewerror eq 'on_reserve';
 255             $issue->{'norenew_overdue'} = 1 if $renewerror eq 'overdue';
 256             $issue->{'auto_renew'}     = 1 if $renewerror eq 'auto_renew';
 257             $issue->{'auto_too_soon'}  = 1 if $renewerror eq 'auto_too_soon';
 258             $issue->{'auto_too_late'}  = 1 if $renewerror eq 'auto_too_late';
 259             $issue->{'auto_too_much_oweing'}  = 1 if $renewerror eq 'auto_too_much_oweing';
 260
 261             if ( $renewerror eq 'too_soon' ) {
 262                 $issue->{'too_soon'}         = 1;
 263                 $issue->{'soonestrenewdate'} = output_pref(
 264                     C4::Circulation::GetSoonestRenewDate(
 265                         $issue->{borrowernumber},
 266                         $issue->{itemnumber}
 267                     )
 268                 );
 269             }
 270         }
 271
 272         if ( $issue->{'overdue'} ) {
 273             push @overdues, $issue;
 274             $overdues_count++;
 275             $issue->{'overdue'} = 1;
 276         }
 277         else {
 278             $issue->{'issued'} = 1;
 279         }
 280         # imageurl:
 281         my $itemtype = $issue->{'itemtype'};
 282         if ( $itemtype ) {
 283             $issue->{'imageurl'}    = getitemtypeimagelocation( 'opac', $itemtypes->{$itemtype}->{'imageurl'} );
 284             $issue->{'description'} = $itemtypes->{$itemtype}->{'description'};
 285         }
 286         push @issuedat, $issue;
 287         $count++;
 288
 289         my $isbn = GetNormalizedISBN($issue->{'isbn'});
 290         $issue->{normalized_isbn} = $isbn;
 291         $issue->{normalized_upc} = GetNormalizedUPC( $marcrecord, C4::Context->preference('marcflavour') );
 292
 293                 # My Summary HTML
 294                 if (my $my_summary_html = C4::Context->preference('OPACMySummaryHTML')){
 295                     $issue->{author} ? $my_summary_html =~ s/{AUTHOR}/$issue->{author}/g : $my_summary_html =~ s/{AUTHOR}//g;
 296                     $issue->{title} =~ s/\/+$//; # remove trailing slash
 297                     $issue->{title} =~ s/\s+$//; # remove trailing space
 298                     $issue->{title} ? $my_summary_html =~ s/{TITLE}/$issue->{title}/g : $my_summary_html =~ s/{TITLE}//g;
 299                     $issue->{isbn} ? $my_summary_html =~ s/{ISBN}/$isbn/g : $my_summary_html =~ s/{ISBN}//g;
 300                     $issue->{biblionumber} ? $my_summary_html =~ s/{BIBLIONUMBER}/$issue->{biblionumber}/g : $my_summary_html =~ s/{BIBLIONUMBER}//g;
 301                     $issue->{MySummaryHTML} = $my_summary_html;
 302                 }
 303     }
 304 }
 305 my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
 306 $canrenew = 0 if ($overduesblockrenewing ne 'allow' and $overdues_count == $count);
 307
 308 $template->param( ISSUES       => \@issuedat );
 309 $template->param( issues_count => $count );
 310 $template->param( canrenew     => $canrenew );
 311 $template->param( OVERDUES       => \@overdues );
 312 $template->param( overdues_count => $overdues_count );
 313
 314 my $show_barcode = Koha::Patron::Attribute::Types->search(
 315     { code => ATTRIBUTE_SHOW_BARCODE } )->count;
 316 if ($show_barcode) {
 317     my $patron_show_barcode = GetBorrowerAttributeValue($borrowernumber, ATTRIBUTE_SHOW_BARCODE);
 318     undef $show_barcode if defined($patron_show_barcode) && !$patron_show_barcode;
 319 }
 320 $template->param( show_barcode => 1 ) if $show_barcode;
 321
 322 # now the reserved items....
 323 my $reserves = Koha::Holds->search( { borrowernumber => $borrowernumber } );
 324
 325 $template->param(
 326     RESERVES       => $reserves,
 327     showpriority   => $show_priority,
 328 );
 329
 330 # current alert subscriptions
 331 my $alerts = getalert($borrowernumber);
 332 foreach ( @$alerts ) {
 333     $_->{ $_->{type} } = 1;
 334     $_->{relatedto} = findrelatedto( $_->{type}, $_->{externalid} );
 335 }
 336
 337 if (C4::Context->preference('BakerTaylorEnabled')) {
 338     $template->param(
 339         BakerTaylorEnabled  => 1,
 340         BakerTaylorImageURL => &image_url(),
 341         BakerTaylorLinkURL  => &link_url(),
 342         BakerTaylorBookstoreURL => C4::Context->preference('BakerTaylorBookstoreURL'),
 343     );
 344 }
 345
 346 if (C4::Context->preference("OPACAmazonCoverImages") or
 347     C4::Context->preference("GoogleJackets") or
 348     C4::Context->preference("BakerTaylorEnabled") or
 349     C4::Context->preference("SyndeticsCoverImages")) {
 350         $template->param(JacketImages=>1);
 351 }
 352
 353 $template->param(
 354     OverDriveCirculation => C4::Context->preference('OverDriveCirculation') || 0,
 355     overdrive_error      => scalar $query->param('overdrive_error') || undef,
 356     overdrive_tab        => scalar $query->param('overdrive_tab') || 0,
 357 );
 358
 359 my $patron_messages = Koha::Patron::Messages->search(
 360     {
 361         borrowernumber => $borrowernumber,
 362         message_type => 'B',
 363     }
 364 );
 365
 366 if (   C4::Context->preference('AllowPatronToSetCheckoutsVisibilityForGuarantor')
 367     || C4::Context->preference('AllowStaffToSetCheckoutsVisibilityForGuarantor') )
 368 {
 369     my @relatives =
 370       Koha::Database->new()->schema()->resultset("Borrower")->search(
 371         {
 372             privacy_guarantor_checkouts => 1,
 373             'me.guarantorid'           => $borrowernumber
 374         },
 375         { prefetch => [ { 'issues' => { 'item' => 'biblio' } } ] }
 376       );
 377     $template->param( relatives => \@relatives );
 378 }
 379
 380 $template->param(
 381     borrower                 => scalar Koha::Patrons->find($borrowernumber),
 382     patron_messages          => $patron_messages,
 383     opacnote                 => $borr->{opacnote},
 384     patronupdate             => $patronupdate,
 385     OpacRenewalAllowed       => C4::Context->preference("OpacRenewalAllowed"),
 386     userview                 => 1,
 387     SuspendHoldsOpac         => C4::Context->preference('SuspendHoldsOpac'),
 388     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 389     OpacHoldNotes            => C4::Context->preference('OpacHoldNotes'),
 390     failed_holds             => scalar $query->param('failed_holds'),
 391 );
 392
 393 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };