opac/sco/sco-main.pl

   1 #!/usr/bin/perl
   2 #
   3 # This code has been modified by Trendsetters (originally from opac-user.pl)
   4 # This code has been modified by rch
   5 # Parts Copyright 2010-2011, ByWater Solutions (those related to username/password auth)
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 # We're going to authenticate a self-check user.  we'll add a flag to borrowers 'selfcheck'
  23 #
  24 # We're in a controlled environment; we trust the user.
  25 # So the selfcheck station will accept a patronid and issue items to that borrower.
  26 # FIXME: NOT really a controlled environment...  We're on the internet!
  27 #
  28 # The checkout permission comes form the CGI cookie/session of a staff user.
  29 # The patron is not really logging in here in the same way as they do on the
  30 # rest of the OPAC.  So don't confuse loggedinuser with the patron user.
  31 #
  32 # FIXME: inputfocus not really used in TMPL
  33
  34 use Modern::Perl;
  35
  36 use CGI qw ( -utf8 );
  37 use Digest::MD5 qw(md5_base64);
  38
  39 use C4::Auth qw(get_template_and_user checkpw);
  40 use C4::Koha;
  41 use C4::Circulation;
  42 use C4::Reserves;
  43 use C4::Output;
  44 use C4::Members;
  45 use C4::Biblio;
  46 use C4::Items;
  47 use Koha::DateUtils qw( dt_from_string );
  48 use Koha::Acquisition::Currencies;
  49 use Koha::Patron::Images;
  50 use Koha::Patron::Messages;
  51
  52 my $query = new CGI;
  53
  54 unless (C4::Context->preference('WebBasedSelfCheck')) {
  55     # redirect to OPAC home if self-check is not enabled
  56     print $query->redirect("/cgi-bin/koha/opac-main.pl");
  57     exit;
  58 }
  59
  60 if (C4::Context->preference('AutoSelfCheckAllowed'))
  61 {
  62     my $AutoSelfCheckID = C4::Context->preference('AutoSelfCheckID');
  63     my $AutoSelfCheckPass = C4::Context->preference('AutoSelfCheckPass');
  64     $query->param(-name=>'userid',-values=>[$AutoSelfCheckID]);
  65     $query->param(-name=>'password',-values=>[$AutoSelfCheckPass]);
  66     $query->param(-name=>'koha_login_context',-values=>['sco']);
  67 }
  68 $query->param(-name=>'sco_user_login',-values=>[1]);
  69 my ($template, $loggedinuser, $cookie) = get_template_and_user({
  70     template_name   => "sco/sco-main.tt",
  71     authnotrequired => 0,
  72     flagsrequired => { circulate => "self_checkout" },
  73     query => $query,
  74     type  => "opac",
  75     debug => 1,
  76 });
  77
  78 if (C4::Context->preference('SelfCheckoutByLogin'))
  79 {
  80     $template->param(authbylogin  => 1);
  81 }
  82
  83 # Get the self checkout timeout preference, or use 120 seconds as a default
  84 my $selfchecktimeout = 120000;
  85 if (C4::Context->preference('SelfCheckTimeout')) {
  86     $selfchecktimeout = C4::Context->preference('SelfCheckTimeout') * 1000;
  87 }
  88 $template->param(SelfCheckTimeout => $selfchecktimeout);
  89
  90 # Checks policy laid out by AllowSelfCheckReturns, defaults to 'on' if preference is undefined
  91 my $allowselfcheckreturns = 1;
  92 if (defined C4::Context->preference('AllowSelfCheckReturns')) {
  93     $allowselfcheckreturns = C4::Context->preference('AllowSelfCheckReturns');
  94 }
  95 $template->param(AllowSelfCheckReturns => $allowselfcheckreturns);
  96
  97
  98 my $issuerid = $loggedinuser;
  99 my ($op, $patronid, $patronlogin, $patronpw, $barcode, $confirmed) = (
 100     $query->param("op")         || '',
 101     $query->param("patronid")   || '',
 102     $query->param("patronlogin")|| '',
 103     $query->param("patronpw")   || '',
 104     $query->param("barcode")    || '',
 105     $query->param("confirmed")  || '',
 106 );
 107
 108 my $issuenoconfirm = 1; #don't need to confirm on issue.
 109 #warn "issuerid: " . $issuerid;
 110 my $issuer   = GetMember( borrowernumber => $issuerid );
 111 my $item     = GetItem(undef,$barcode);
 112 if (C4::Context->preference('SelfCheckoutByLogin') && !$patronid) {
 113     my $dbh = C4::Context->dbh;
 114     my $resval;
 115     ($resval, $patronid) = checkpw($dbh, $patronlogin, $patronpw);
 116 }
 117 my $borrower = GetMember( cardnumber => $patronid );
 118
 119 my $currencySymbol = "";
 120 if ( my $active_currency = Koha::Acquisition::Currencies->get_active ) {
 121     $currencySymbol = $active_currency->symbol;
 122 }
 123
 124 my $branch = $issuer->{branchcode};
 125 my $confirm_required = 0;
 126 my $return_only = 0;
 127 #warn "issuer cardnumber: " .   $issuer->{cardnumber};
 128 #warn "patron cardnumber: " . $borrower->{cardnumber};
 129 if ($op eq "logout") {
 130     $query->param( patronid => undef, patronlogin => undef, patronpw => undef );
 131 }
 132 elsif ( $op eq "returnbook" && $allowselfcheckreturns ) {
 133     my ($doreturn) = AddReturn( $barcode, $branch );
 134     #warn "returnbook: " . $doreturn;
 135     $borrower = GetMember( cardnumber => $patronid );
 136 }
 137 elsif ( $op eq "checkout" ) {
 138     my $impossible  = {};
 139     my $needconfirm = {};
 140     ( $impossible, $needconfirm ) = CanBookBeIssued(
 141         $borrower,
 142         $barcode,
 143         undef,
 144         0,
 145         C4::Context->preference("AllowItemsOnHoldCheckoutSCO")
 146     );
 147     $confirm_required = scalar keys %$needconfirm;
 148
 149     #warn "confirm_required: " . $confirm_required ;
 150     if (scalar keys %$impossible) {
 151
 152         #  warn "impossible: numkeys: " . scalar (keys(%$impossible));
 153         #warn join " ", keys %$impossible;
 154         my $issue_error = (keys %$impossible)[0];
 155
 156         # FIXME  we assume only one error.
 157         $template->param(
 158             impossible                => $issue_error,
 159             "circ_error_$issue_error" => 1,
 160             title                     => $item->{title},
 161             hide_main                 => 1,
 162         );
 163         if ($issue_error eq 'DEBT') {
 164             $template->param(amount => $currencySymbol.$impossible->{DEBT});
 165         }
 166         #warn "issue_error: " . $issue_error ;
 167         if ( $issue_error eq "NO_MORE_RENEWALS" ) {
 168             $return_only = 1;
 169             $template->param(
 170                 returnitem => 1,
 171                 barcode    => $barcode,
 172             );
 173         }
 174     } elsif ( $needconfirm->{RENEW_ISSUE} ) {
 175         if ($confirmed) {
 176             #warn "renewing";
 177             AddRenewal( $borrower->{borrowernumber}, $item->{itemnumber} );
 178         } else {
 179             #warn "renew confirmation";
 180             $template->param(
 181                 renew               => 1,
 182                 barcode             => $barcode,
 183                 confirm             => 1,
 184                 confirm_renew_issue => 1,
 185                 hide_main           => 1,
 186             );
 187         }
 188     } elsif ( $confirm_required && !$confirmed ) {
 189         #warn "failed confirmation";
 190         my $issue_error = (keys %$needconfirm)[0];
 191         $template->param(
 192             impossible                => (keys %$needconfirm)[0],
 193             "circ_error_$issue_error" => 1,
 194             hide_main                 => 1,
 195         );
 196         if ($issue_error eq 'DEBT') {
 197             $template->param(amount => $currencySymbol.$needconfirm->{DEBT});
 198         }
 199     } else {
 200         if ( $confirmed || $issuenoconfirm ) {    # we'll want to call getpatroninfo again to get updated issues.
 201             my ( $hold_existed, $item );
 202             if ( C4::Context->preference('HoldFeeMode') eq 'any_time_is_collected' ) {
 203                 # There is no easy way to know if the patron has been charged for this item.
 204                 # So we check if a hold existed for this item before the check in
 205                 $item = Koha::Items->find({ barcode => $barcode });
 206                 $hold_existed = Koha::Holds->search(
 207                     {
 208                         -and => {
 209                             borrowernumber => $borrower->{borrowernumber},
 210                             -or            => {
 211                                 biblionumber => $item->biblionumber,
 212                                 itemnumber   => $item->itemnumber
 213                             }
 214                         }
 215                     }
 216                 )->count;
 217             }
 218             AddIssue( $borrower, $barcode );
 219
 220             if ( $hold_existed ) {
 221                 my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 222                 $template->param(
 223                     # If the hold existed before the check in, let's confirm that the charge line exists
 224                     # Note that this should not be needed but since we do not have proper exception handling here we do it this way
 225                     patron_has_hold_fee => Koha::Account::Lines->search(
 226                         {
 227                             borrowernumber => $borrower->{borrowernumber},
 228                             accounttype    => 'Res',
 229                             description    => 'Reserve Charge - ' . $item->biblio->title,
 230                             date           => $dtf->format_date(dt_from_string)
 231                         }
 232                       )->count,
 233                 );
 234             }
 235         } else {
 236             $confirm_required = 1;
 237             #warn "issue confirmation";
 238             $template->param(
 239                 confirm    => "Issuing title: " . $item->{title},
 240                 barcode    => $barcode,
 241                 hide_main  => 1,
 242                 inputfocus => 'confirm',
 243             );
 244         }
 245     }
 246 } # $op
 247
 248 if ($borrower->{cardnumber}) {
 249 #   warn "issuer's  branchcode: " .   $issuer->{branchcode};
 250 #   warn   "user's  branchcode: " . $borrower->{branchcode};
 251     my $borrowername = sprintf "%s %s", ($borrower->{firstname} || ''), ($borrower->{surname} || '');
 252     my @issues;
 253     my ($issueslist) = GetPendingIssues( $borrower->{'borrowernumber'} );
 254     foreach my $it (@$issueslist) {
 255         my ($can_be_renewed, $renew_error) = CanBookBeRenewed(
 256             $borrower->{borrowernumber},
 257             $it->{itemnumber},
 258         );
 259         $it->{can_be_renewed} = $can_be_renewed;
 260         $it->{renew_error} = $renew_error;
 261         $it->{date_due}  = $it->{date_due_sql};
 262         push @issues, $it;
 263     }
 264
 265     $template->param(
 266         validuser => 1,
 267         borrowername => $borrowername,
 268         issues_count => scalar(@issues),
 269         ISSUES => \@issues,
 270         patronid => $patronid,
 271         patronlogin => $patronlogin,
 272         patronpw => $patronpw,
 273         noitemlinks => 1 ,
 274         borrowernumber => $borrower->{'borrowernumber'},
 275     );
 276
 277     my $patron_messages = Koha::Patron::Messages->search(
 278         {
 279             borrowernumber => $borrower->{'borrowernumber'},
 280             message_type => 'B',
 281         }
 282     );
 283     $template->param(
 284         patron_messages => $patron_messages,
 285         opacnote => $borrower->{opacnote},
 286     );
 287
 288     my $inputfocus = ($return_only      == 1) ? 'returnbook' :
 289                      ($confirm_required == 1) ? 'confirm'    : 'barcode' ;
 290     $template->param(
 291         inputfocus => $inputfocus,
 292         nofines => 1,
 293
 294     );
 295     if (C4::Context->preference('ShowPatronImageInWebBasedSelfCheck')) {
 296         my $patron_image = Koha::Patron::Images->find($borrower->{borrowernumber});
 297         $template->param(
 298             display_patron_image => 1,
 299             cardnumber           => $borrower->{cardnumber},
 300         ) if $patron_image;
 301     }
 302 } else {
 303     $template->param(
 304         patronid   => $patronid,
 305         nouser     => $patronid,
 306     );
 307 }
 308
 309 $template->param(
 310     SCOUserJS  => C4::Context->preference('SCOUserJS'),
 311     SCOUserCSS => C4::Context->preference('SCOUserCSS'),
 312 );
 313
 314 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };