opac/sco/sco-main.pl

   1 #!/usr/bin/perl
   2 #
   3 # This code has been modified by Trendsetters (originally from opac-user.pl)
   4 # This code has been modified by rch
   5 # Parts Copyright 2010-2011, ByWater Solutions (those related to username/password auth)
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 # We're going to authenticate a self-check user.  we'll add a flag to borrowers 'selfcheck'
  23 #
  24 # We're in a controlled environment; we trust the user.
  25 # So the selfcheck station will accept a patronid and issue items to that borrower.
  26 # FIXME: NOT really a controlled environment...  We're on the internet!
  27 #
  28 # The checkout permission comes form the CGI cookie/session of a staff user.
  29 # The patron is not really logging in here in the same way as they do on the
  30 # rest of the OPAC.  So don't confuse loggedinuser with the patron user.
  31 #
  32 # FIXME: inputfocus not really used in TMPL
  33
  34 use Modern::Perl;
  35
  36 use CGI qw ( -utf8 );
  37
  38 use C4::Auth qw(get_template_and_user checkpw in_iprange);
  39 use C4::Koha;
  40 use C4::Circulation;
  41 use C4::Reserves;
  42 use C4::Output;
  43 use C4::Members;
  44 use C4::Biblio;
  45 use C4::Items;
  46 use Koha::DateUtils qw( dt_from_string );
  47 use Koha::Acquisition::Currencies;
  48 use Koha::Items;
  49 use Koha::Patrons;
  50 use Koha::Patron::Images;
  51 use Koha::Patron::Messages;
  52 use Koha::Token;
  53
  54 my $query = new CGI;
  55
  56 unless (C4::Context->preference('WebBasedSelfCheck')) {
  57     # redirect to OPAC home if self-check is not enabled
  58     print $query->redirect("/cgi-bin/koha/opac-main.pl");
  59     exit;
  60 }
  61
  62 unless ( in_iprange(C4::Context->preference('SelfCheckAllowByIPRanges')) ) {
  63     # redirect to OPAC home if self-checkout not permitted from current IP
  64     print $query->redirect("/cgi-bin/koha/opac-main.pl");
  65     exit;
  66 }
  67
  68 if (C4::Context->preference('AutoSelfCheckAllowed'))
  69 {
  70     my $AutoSelfCheckID = C4::Context->preference('AutoSelfCheckID');
  71     my $AutoSelfCheckPass = C4::Context->preference('AutoSelfCheckPass');
  72     $query->param(-name=>'userid',-values=>[$AutoSelfCheckID]);
  73     $query->param(-name=>'password',-values=>[$AutoSelfCheckPass]);
  74     $query->param(-name=>'koha_login_context',-values=>['sco']);
  75 }
  76 $query->param(-name=>'sco_user_login',-values=>[1]);
  77
  78 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  79     {
  80         template_name   => "sco/sco-main.tt",
  81         flagsrequired   => { self_check => "self_checkout_module" },
  82         query           => $query,
  83         type            => "opac",
  84         debug           => 1,
  85     }
  86 );
  87
  88 # Get the self checkout timeout preference, or use 120 seconds as a default
  89 my $selfchecktimeout = 120000;
  90 if (C4::Context->preference('SelfCheckTimeout')) {
  91     $selfchecktimeout = C4::Context->preference('SelfCheckTimeout') * 1000;
  92 }
  93 $template->param( SelfCheckTimeout => $selfchecktimeout );
  94
  95 # Checks policy laid out by SCOAllowCheckin, defaults to 'on' if preference is undefined
  96 my $allowselfcheckreturns = 1;
  97 if (defined C4::Context->preference('SCOAllowCheckin')) {
  98     $allowselfcheckreturns = C4::Context->preference('SCOAllowCheckin');
  99 }
 100
 101 my $issuerid = $loggedinuser;
 102 my ($op, $patronid, $patronlogin, $patronpw, $barcode, $confirmed, $newissues) = (
 103     $query->param("op")         || '',
 104     $query->param("patronid")   || '',
 105     $query->param("patronlogin")|| '',
 106     $query->param("patronpw")   || '',
 107     $query->param("barcode")    || '',
 108     $query->param("confirmed")  || '',
 109     $query->param("newissues")  || '',
 110 );
 111
 112 my @newissueslist = split /,/, $newissues;
 113 my $issuenoconfirm = 1; #don't need to confirm on issue.
 114 my $issuer   = Koha::Patrons->find( $issuerid )->unblessed;
 115 my $item     = Koha::Items->find({ barcode => $barcode });
 116 if (C4::Context->preference('SelfCheckoutByLogin') && !$patronid) {
 117     my $dbh = C4::Context->dbh;
 118     my $resval;
 119     ($resval, $patronid) = checkpw($dbh, $patronlogin, $patronpw);
 120 }
 121
 122 my ( $borrower, $patron );
 123 if ( $patronid ) {
 124     $patron = Koha::Patrons->find( { cardnumber => $patronid } );
 125     $borrower = $patron->unblessed if $patron;
 126 }
 127
 128 my $branch = $issuer->{branchcode};
 129 my $confirm_required = 0;
 130 my $return_only = 0;
 131 #warn "issuer cardnumber: " .   $issuer->{cardnumber};
 132 #warn "patron cardnumber: " . $borrower->{cardnumber};
 133 if ($op eq "logout") {
 134     $template->param( loggedout => 1 );
 135     $query->param( patronid => undef, patronlogin => undef, patronpw => undef );
 136 }
 137 elsif ( $op eq "returnbook" && $allowselfcheckreturns ) {
 138     my ($doreturn) = AddReturn( $barcode, $branch );
 139     $template->param( returned => $doreturn );
 140 }
 141 elsif ( $patron && ( $op eq 'checkout' ) ) {
 142     my $impossible  = {};
 143     my $needconfirm = {};
 144     ( $impossible, $needconfirm ) = CanBookBeIssued(
 145         $patron,
 146         $barcode,
 147         undef,
 148         0,
 149         C4::Context->preference("AllowItemsOnHoldCheckoutSCO")
 150     );
 151     my $issue_error;
 152     if ( $confirm_required = scalar keys %$needconfirm ) {
 153         for my $error ( qw( UNKNOWN_BARCODE max_loans_allowed ISSUED_TO_ANOTHER NO_MORE_RENEWALS NOT_FOR_LOAN DEBT WTHDRAWN RESTRICTED RESERVED ITEMNOTSAMEBRANCH EXPIRED DEBARRED CARD_LOST GNA INVALID_DATE UNKNOWN_BARCODE TOO_MANY DEBT_GUARANTEES USERBLOCKEDOVERDUE PATRON_CANT PREVISSUE NOT_FOR_LOAN_FORCING ITEM_LOST additional_materials ) ) {
 154             if ( $needconfirm->{$error} ) {
 155                 $issue_error = $error;
 156                 $confirmed = 0;
 157                 last;
 158             }
 159         }
 160     }
 161
 162     #warn "confirm_required: " . $confirm_required ;
 163     if (scalar keys %$impossible) {
 164
 165         my $issue_error = (keys %$impossible)[0]; # FIXME This is wrong, we assume only one error and keys are not ordered
 166         my $title = ( $item ) ? $item->biblio->title : '';
 167
 168         $template->param(
 169             impossible                => $issue_error,
 170             "circ_error_$issue_error" => 1,
 171             title                     => $title,
 172             hide_main                 => 1,
 173         );
 174         if ($issue_error eq 'DEBT') {
 175             $template->param(DEBT => $impossible->{DEBT});
 176         }
 177         #warn "issue_error: " . $issue_error ;
 178         if ( $issue_error eq "NO_MORE_RENEWALS" ) {
 179             $return_only = 1;
 180             $template->param(
 181                 returnitem => 1,
 182                 barcode    => $barcode,
 183             );
 184         }
 185     } elsif ( $needconfirm->{RENEW_ISSUE} ){
 186         $template->param(
 187                 renew               => 1,
 188                 barcode             => $barcode,
 189                 confirm             => 1,
 190                 confirm_renew_issue => 1,
 191                 hide_main           => 1,
 192         );
 193     } elsif ( $confirm_required && !$confirmed ) {
 194         #warn "failed confirmation";
 195         $template->param(
 196             impossible                => 1,
 197             "circ_error_$issue_error" => 1,
 198             hide_main                 => 1,
 199         );
 200         if ($issue_error eq 'DEBT') {
 201             $template->param(DEBT => $needconfirm->{DEBT});
 202         }
 203     } else {
 204         if ( $confirmed || $issuenoconfirm ) {    # we'll want to call getpatroninfo again to get updated issues.
 205             my ( $hold_existed, $item );
 206             if ( C4::Context->preference('HoldFeeMode') eq 'any_time_is_collected' ) {
 207                 # There is no easy way to know if the patron has been charged for this item.
 208                 # So we check if a hold existed for this item before the check in
 209                 $item = Koha::Items->find({ barcode => $barcode });
 210                 $hold_existed = Koha::Holds->search(
 211                     {
 212                         -and => {
 213                             borrowernumber => $borrower->{borrowernumber},
 214                             -or            => {
 215                                 biblionumber => $item->biblionumber,
 216                                 itemnumber   => $item->itemnumber
 217                             }
 218                         }
 219                     }
 220                 )->count;
 221             }
 222
 223             AddIssue( $borrower, $barcode );
 224             $template->param( issued => 1 );
 225             push @newissueslist, $barcode;
 226
 227             if ( $hold_existed ) {
 228                 my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 229                 $template->param(
 230                     # If the hold existed before the check in, let's confirm that the charge line exists
 231                     # Note that this should not be needed but since we do not have proper exception handling here we do it this way
 232                     patron_has_hold_fee => Koha::Account::Lines->search(
 233                         {
 234                             borrowernumber  => $borrower->{borrowernumber},
 235                             debit_type_code => 'RESERVE',
 236                             description     => $item->biblio->title,
 237                             date            => $dtf->format_date(dt_from_string)
 238                         }
 239                       )->count,
 240                 );
 241             }
 242         } else {
 243             $confirm_required = 1;
 244             #warn "issue confirmation";
 245             $template->param(
 246                 confirm    => "Issuing title: " . $item->biblio->title,
 247                 barcode    => $barcode,
 248                 hide_main  => 1,
 249                 inputfocus => 'confirm',
 250             );
 251         }
 252     }
 253 } # $op
 254
 255 if ( $patron && ( $op eq 'renew' ) ) {
 256     my ($status,$renewerror) = CanBookBeRenewed( $borrower->{borrowernumber}, $item->itemnumber );
 257     if ($status) {
 258         #warn "renewing";
 259         AddRenewal( $borrower->{borrowernumber}, $item->itemnumber );
 260         push @newissueslist, $barcode;
 261         $template->param( renewed => 1 );
 262     }
 263 }
 264
 265 if ($borrower) {
 266 #   warn "issuer's  branchcode: " .   $issuer->{branchcode};
 267 #   warn   "user's  branchcode: " . $borrower->{branchcode};
 268     my $borrowername = sprintf "%s %s", ($borrower->{firstname} || ''), ($borrower->{surname} || '');
 269     my $pending_checkouts = $patron->pending_checkouts;
 270     my @checkouts;
 271     while ( my $c = $pending_checkouts->next ) {
 272         my $checkout = $c->unblessed_all_relateds;
 273         my ($can_be_renewed, $renew_error) = CanBookBeRenewed(
 274             $borrower->{borrowernumber},
 275             $checkout->{itemnumber},
 276         );
 277         $checkout->{can_be_renewed} = $can_be_renewed; # In the future this will be $checkout->can_be_renewed
 278         $checkout->{renew_error} = $renew_error;
 279         $checkout->{overdue} = $c->is_overdue;
 280         push @checkouts, $checkout;
 281     }
 282
 283     my $show_priority;
 284     for ( C4::Context->preference("OPACShowHoldQueueDetails") ) {
 285         m/priority/ and $show_priority = 1;
 286     }
 287
 288     my $account = $patron->account;
 289     my $total = $account->balance;
 290     my $accountlines = $account->lines;
 291
 292     my $holds = $patron->holds;
 293     my $waiting_holds_count = 0;
 294
 295     while(my $hold = $holds->next) {
 296         $waiting_holds_count++ if $hold->is_waiting;
 297     }
 298
 299     $template->param(
 300         validuser => 1,
 301         borrowername => $borrowername,
 302         issues_count => scalar(@checkouts),
 303         ISSUES => \@checkouts,
 304         HOLDS => $holds,
 305         newissues => join(',',@newissueslist),
 306         patronid => $patronid,
 307         patronlogin => $patronlogin,
 308         patronpw => $patronpw,
 309         waiting_holds_count => $waiting_holds_count,
 310         noitemlinks => 1 ,
 311         borrowernumber => $borrower->{'borrowernumber'},
 312         SuspendHoldsOpac => C4::Context->preference('SuspendHoldsOpac'),
 313         AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 314         howpriority   => $show_priority,
 315         ACCOUNT_LINES => $accountlines,
 316         total => $total,
 317     );
 318
 319     my $patron_messages = Koha::Patron::Messages->search(
 320         {
 321             borrowernumber => $borrower->{'borrowernumber'},
 322             message_type => 'B',
 323         }
 324     );
 325     $template->param(
 326         patron_messages => $patron_messages,
 327         opacnote => $borrower->{opacnote},
 328     );
 329
 330     my $inputfocus = ($return_only      == 1) ? 'returnbook' :
 331                      ($confirm_required == 1) ? 'confirm'    : 'barcode' ;
 332     $template->param(
 333         inputfocus => $inputfocus,
 334         nofines => 1,
 335
 336     );
 337     if (C4::Context->preference('ShowPatronImageInWebBasedSelfCheck')) {
 338         my $patron_image = Koha::Patron::Images->find($borrower->{borrowernumber});
 339         $template->param(
 340             display_patron_image => 1,
 341             csrf_token           => Koha::Token->new->generate_csrf( { session_id => scalar $query->cookie('CGISESSID') . $borrower->{cardnumber}, id => $borrower->{userid}} ),
 342         ) if $patron_image;
 343     }
 344 } else {
 345     $template->param(
 346         patronid   => $patronid,
 347         nouser     => $patronid,
 348     );
 349 }
 350
 351 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };