opac/svc/report

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Copyright (C) 2011  Chris Cormack <chris@bigballofwax.co.nz>
   6 # Copyright (C) 2013  Mark Tompsett
   7 # Updated 2013 by Chris Cormack <chris@bigballofwax.co.nz>
   8 #
   9 # This file is part of Koha.
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it under the
  12 # terms of the GNU General Public License as published by the Free Software
  13 # Foundation; either version 3 of the License, or (at your option) any later
  14 # version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but
  17 # WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  19 # GNU General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU General Public License
  22 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  23
  24 use Modern::Perl;
  25
  26 use C4::Reports::Guided;
  27 use Koha::Reports;
  28 use JSON;
  29 use CGI qw ( -utf8 );
  30
  31 use Koha::Caches;
  32
  33 my $query       = CGI->new();
  34 my $report_id   = $query->param('id');
  35 my $report_name = $query->param('name');
  36 my $report_annotation = $query->param('annotated');
  37
  38 my $report_rec = Koha::Reports->find( $report_name ? { 'name' => $report_name } : { 'id' => $report_id } );
  39 if (!$report_rec) { die "There is no such report.\n"; }
  40
  41 die "Sorry this report is not public\n" unless $report_rec->public;
  42
  43 my @sql_params  = $query->param('sql_params');
  44
  45 my $cache = Koha::Caches->get_instance();
  46 my $cache_active = $cache->is_cache_active;
  47 my ($cache_key, $json_text);
  48 if ($cache_active) {
  49     $cache_key =
  50         "opac:report:"
  51       . ( $report_name ? "name:$report_name" : "id:$report_id" )
  52       . join( '-', @sql_params );
  53     $json_text = $cache->get_from_cache($cache_key);
  54 }
  55
  56 unless ($json_text) {
  57     my $offset = 0;
  58     my $limit = C4::Context->preference("SvcMaxReportRows") || 10;
  59     my $sql = $report_rec->savedsql;
  60
  61     # convert SQL parameters to placeholders
  62     $sql =~ s/(<<.*?>>)/\?/g;
  63
  64     my ( $sth, $errors ) =
  65       execute_query( $sql, $offset, $limit, \@sql_params, $report_id );
  66     if ($sth) {
  67         my $lines;
  68         if ($report_annotation) {
  69             $lines = $sth->fetchall_arrayref({});
  70         }
  71         else {
  72             $lines = $sth->fetchall_arrayref;
  73         }
  74         $json_text = encode_json($lines);
  75
  76         if ($cache_active) {
  77             $cache->set_in_cache( $cache_key, $json_text,
  78                 { expiry => $report_rec->cache_expiry } );
  79         }
  80     }
  81     else {
  82         $json_text = encode_json($errors);
  83     }
  84 }
  85
  86 print $query->header(
  87     -charset    => 'UTF-8',
  88     -type       => 'application/json'
  89 );
  90 print $json_text;