opac/tracklinks.pl

   1 #!/usr/bin/perl
   2
   3 # script to log clicks on links to external urls
   4
   5 # Copyright 2012 Catalyst IT
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use C4::Context;
  23 use C4::Auth qw( checkauth );
  24 use C4::Biblio;
  25 use C4::Output qw( output_error );
  26 use Koha::Biblios;
  27 use Koha::Items;
  28 use Koha::Linktracker;
  29 use CGI qw ( -utf8 );
  30 use List::MoreUtils qw( any );
  31
  32 my $cgi = CGI->new;
  33 my $uri = $cgi->param('uri') || '';
  34 my $biblionumber = $cgi->param('biblionumber');;
  35 my $itemnumber   = $cgi->param('itemnumber');
  36 $uri =~ s/^\s+|\s+$//g if $uri; # trim
  37
  38 my $tracking_method = C4::Context->preference('TrackClicks');
  39 unless ( $tracking_method ) {
  40     output_error( $cgi, '404' );
  41     exit;
  42 }
  43 my $tracker = Koha::Linktracker->new(
  44     { trackingmethod => $tracking_method } );
  45 if ($uri && ($biblionumber || $itemnumber) ) {
  46     my $borrowernumber;
  47
  48     # we have a uri and we want to track
  49     if ( $tracker->trackingmethod() eq 'track' ) {
  50         my ( $user, $cookie, $sessionID, $flags ) =
  51           checkauth( $cgi, 1, {}, 'opac' );
  52         my $userenv = C4::Context->userenv;
  53
  54         if (   defined($userenv)
  55             && ref($userenv) eq 'HASH'
  56             && $userenv->{number} )
  57         {
  58             $borrowernumber = $userenv->{number};
  59         }
  60
  61         # get borrower info
  62     }
  63
  64     my $biblio = Koha::Biblios->find($biblionumber);
  65     my $record = eval{ $biblio->metadata->record };
  66     my $marc_urls = $record ? C4::Biblio::GetMarcUrls($record, C4::Context->preference('marcflavour')) : [];
  67     my $search_crit = { uri => { -like => "%$uri%" } };
  68     if( $itemnumber ) { # itemnumber is leading over biblionumber
  69         $search_crit->{itemnumber} = $itemnumber;
  70     } elsif( $biblionumber ) {
  71         $search_crit->{biblionumber} = $biblionumber;
  72     }
  73     if ( ( any { $_ eq $uri } map { $_->{MARCURL} } @$marc_urls )
  74         || Koha::Items->search( $search_crit )->count )
  75     {
  76         $tracker->trackclick(
  77             {
  78                 uri            => $uri,
  79                 biblionumber   => $biblionumber,
  80                 borrowernumber => $borrowernumber,
  81                 itemnumber     => $itemnumber
  82             }
  83         ) if (   $tracker->trackingmethod() eq 'track' || $tracker->trackingmethod() eq 'anonymous' );
  84         print $cgi->redirect($uri);
  85         exit;
  86     }
  87 }
  88
  89 output_error( $cgi, '404' );
  90 exit;