recalls/recalls_to_pull.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2020 Aleisha Amohia <aleisha@catalyst.net.nz>
   4 #
   5 # This file is part of Koha.
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use Modern::Perl;
  20 use CGI qw ( -utf8 );
  21 use C4::Auth qw( get_template_and_user );
  22 use C4::Output qw( output_html_with_http_headers );
  23 use Koha::BiblioFrameworks;
  24
  25 my $query = CGI->new;
  26 my ( $template, $loggedinuser, $cookie, $flags ) = get_template_and_user(
  27     {
  28       template_name   => "recalls/recalls_to_pull.tt",
  29       query           => $query,
  30       type            => "intranet",
  31       flagsrequired   => { recalls => 'manage_recalls' },
  32       debug           => 1,
  33     }
  34 );
  35
  36 my $op = $query->param('op') || 'list';
  37 my $recall_id = $query->param('recall_id');
  38 if ( $op eq 'cancel' ) {
  39     my $recall = Koha::Recalls->find( $recall_id );
  40     if ( $recall->in_transit ) {
  41         C4::Items::ModItemTransfer( $recall->item->itemnumber, $recall->item->holdingbranch, $recall->item->homebranch, 'CancelRecall' );
  42     }
  43     $recall->set_cancelled;
  44     $op = 'list';
  45 }
  46
  47 if ( $op eq 'list' ) {
  48     my @recalls = Koha::Recalls->search({ status => [ 'requested','overdue','in_transit' ] })->as_list;
  49     my @pull_list;
  50     my %seen_bib;
  51     foreach my $recall ( @recalls ) {
  52         if ( $seen_bib{$recall->biblio_id} ){
  53             # we've already looked at the recalls on this biblio
  54             next;
  55         } else {
  56             # this is an unseen biblio
  57             $seen_bib{$recall->biblio_id}++;
  58
  59             # get recall data about this biblio
  60             my @this_bib_recalls = Koha::Recalls->search({ biblio_id => $recall->biblio_id, status => [ 'requested','overdue','in_transit' ] }, { order_by => { -asc => 'created_date' } })->as_list;
  61             my $recalls_count = scalar @this_bib_recalls;
  62             my @unique_patrons = do { my %seen; grep { !$seen{$_->patron_id}++ } @this_bib_recalls };
  63             my $patrons_count = scalar @unique_patrons;
  64             my $first_recall = $this_bib_recalls[0];
  65
  66             my $items_count = 0;
  67             my @callnumbers;
  68             my @copynumbers;
  69             my @enumchrons;
  70             my @itemtypes;
  71             my @locations;
  72             my @libraries;
  73
  74             my @items = Koha::Items->search({ biblio_id => $recall->biblio_id })->as_list;
  75             foreach my $item ( @items ) {
  76                 if ( $item->can_be_waiting_recall and !$item->checkout ) {
  77                     # if item can be pulled to fulfill recall, collect item data
  78                     $items_count++;
  79                     push( @callnumbers, $item->itemcallnumber ) if ( $item->itemcallnumber );
  80                     push( @copynumbers, $item->copynumber ) if ( $item->copynumber );
  81                     push( @enumchrons, $item->enumchron ) if ( $item->enumchron );
  82                     push( @itemtypes, $item->effective_itemtype ) if ( $item->effective_itemtype );
  83                     push( @locations, $item->location ) if ( $item->location );
  84                     push( @libraries, $item->holdingbranch ) if ( $item->holdingbranch );
  85                 }
  86             }
  87
  88             if ( $items_count > 0 ) {
  89             # don't push data if there are no items available for this recall
  90
  91                 # get unique values
  92                 my @unique_callnumbers = do { my %seen; grep { !$seen{$_}++ } @callnumbers };
  93                 my @unique_copynumbers = do { my %seen; grep { !$seen{$_}++ } @copynumbers };
  94                 my @unique_enumchrons = do { my %seen; grep { !$seen{$_}++ } @enumchrons };
  95                 my @unique_itemtypes = do { my %seen; grep { !$seen{$_}++ } @itemtypes };
  96                 my @unique_locations = do { my %seen; grep { !$seen{$_}++ } @locations };
  97                 my @unique_libraries = do { my %seen; grep { !$seen{$_}++ } @libraries };
  98
  99                 push( @pull_list, {
 100                     biblio => $recall->biblio,
 101                     items_count => $items_count,
 102                     recalls_count => $recalls_count,
 103                     patrons_count => $patrons_count,
 104                     pull_count => $items_count <= $recalls_count ? $items_count : $recalls_count,
 105                     first_recall => $first_recall,
 106                     callnumbers => \@unique_callnumbers,
 107                     copynumbers => \@unique_copynumbers,
 108                     enumchrons => \@unique_enumchrons,
 109                     itemtypes => \@unique_itemtypes,
 110                     locations => \@unique_locations,
 111                     libraries => \@unique_libraries,
 112                 });
 113             }
 114         }
 115     }
 116     $template->param(
 117         recalls => \@pull_list,
 118     );
 119 }
 120
 121 # Checking if there is a Fast Cataloging Framework
 122 $template->param( fast_cataloging => 1 ) if Koha::BiblioFrameworks->find( 'FA' );
 123
 124 # writing the template
 125 output_html_with_http_headers $query, $cookie, $template->output;