reserve/request.pl

   1 #!/usr/bin/perl
   2
   3
   4 #written 2/1/00 by chris@katipo.oc.nz
   5 # Copyright 2000-2002 Katipo Communications
   6 # Parts Copyright 2011 Catalyst IT
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 request.pl
  24
  25 script to place reserves/requests
  26
  27 =cut
  28
  29 use Modern::Perl;
  30
  31 use CGI qw ( -utf8 );
  32 use List::MoreUtils qw/uniq/;
  33 use Date::Calc qw/Date_to_Days/;
  34 use C4::Output;
  35 use C4::Auth;
  36 use C4::Reserves;
  37 use C4::Biblio;
  38 use C4::Items;
  39 use C4::Koha;
  40 use C4::Serials;
  41 use C4::Circulation;
  42 use Koha::DateUtils;
  43 use C4::Utils::DataTables::Members;
  44 use C4::Members;
  45 use C4::Search;         # enabled_staff_search_views
  46
  47 use Koha::Biblios;
  48 use Koha::DateUtils;
  49 use Koha::Checkouts;
  50 use Koha::Holds;
  51 use Koha::CirculationRules;
  52 use Koha::Items;
  53 use Koha::ItemTypes;
  54 use Koha::Libraries;
  55 use Koha::Patrons;
  56 use Koha::Clubs;
  57
  58 my $dbh = C4::Context->dbh;
  59 my $input = CGI->new;
  60 my ( $template, $borrowernumber, $cookie, $flags ) = get_template_and_user(
  61     {
  62         template_name   => "reserve/request.tt",
  63         query           => $input,
  64         type            => "intranet",
  65         flagsrequired   => { reserveforothers => 'place_holds' },
  66     }
  67 );
  68
  69 my $showallitems = $input->param('showallitems');
  70 my $pickup = $input->param('pickup');
  71
  72 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
  73
  74 # Select borrowers infos
  75 my $findborrower = $input->param('findborrower');
  76 $findborrower = '' unless defined $findborrower;
  77 $findborrower =~ s|,| |g;
  78 my $findclub = $input->param('findclub');
  79 $findclub = '' unless defined $findclub && !$findborrower;
  80 my $borrowernumber_hold = $input->param('borrowernumber') || '';
  81 my $club_hold = $input->param('club')||'';
  82 my $messageborrower;
  83 my $messageclub;
  84 my $warnings;
  85 my $messages;
  86 my $exceeded_maxreserves;
  87 my $exceeded_holds_per_record;
  88
  89 my $date = output_pref({ dt => dt_from_string, dateformat => 'iso', dateonly => 1 });
  90 my $action = $input->param('action');
  91 $action ||= q{};
  92
  93 if ( $action eq 'move' ) {
  94   my $where           = $input->param('where');
  95   my $reserve_id      = $input->param('reserve_id');
  96   my $prev_priority   = $input->param('prev_priority');
  97   my $next_priority   = $input->param('next_priority');
  98   my $first_priority  = $input->param('first_priority');
  99   my $last_priority   = $input->param('last_priority');
 100   my $hold_itemnumber = $input->param('itemnumber');
 101   if ( $prev_priority == 0 && $next_priority == 1 ){
 102       C4::Reserves::RevertWaitingStatus({ itemnumber => $hold_itemnumber });
 103   } else {
 104       AlterPriority( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority );
 105   }
 106 } elsif ( $action eq 'cancel' ) {
 107   my $reserve_id = $input->param('reserve_id');
 108   my $cancellation_reason = $input->param("cancellation-reason");
 109   my $hold = Koha::Holds->find( $reserve_id );
 110   $hold->cancel({ cancellation_reason => $cancellation_reason }) if $hold;
 111 } elsif ( $action eq 'setLowestPriority' ) {
 112   my $reserve_id = $input->param('reserve_id');
 113   ToggleLowestPriority( $reserve_id );
 114 } elsif ( $action eq 'toggleSuspend' ) {
 115   my $reserve_id = $input->param('reserve_id');
 116   my $suspend_until  = $input->param('suspend_until');
 117   ToggleSuspend( $reserve_id, $suspend_until );
 118 }
 119
 120 if ($findborrower) {
 121     my $patron = Koha::Patrons->find( { cardnumber => $findborrower } );
 122     if ( $patron ) {
 123         $borrowernumber_hold = $patron->borrowernumber;
 124     } else {
 125         my $dt_params = { iDisplayLength => -1 };
 126         my $results = C4::Utils::DataTables::Members::search(
 127             {
 128                 searchmember => $findborrower,
 129                 dt_params => $dt_params,
 130             }
 131         );
 132         my $borrowers = $results->{patrons};
 133         if ( scalar @$borrowers == 1 ) {
 134             $borrowernumber_hold = $borrowers->[0]->{borrowernumber};
 135         } elsif ( @$borrowers ) {
 136             $template->param( borrowers => $borrowers );
 137         } else {
 138             $messageborrower = "'$findborrower'";
 139         }
 140     }
 141 }
 142
 143 if($findclub) {
 144     my $club = Koha::Clubs->find( { name => $findclub } );
 145     if( $club ) {
 146         $club_hold = $club->id;
 147     } else {
 148         my @clubs = Koha::Clubs->search( [
 149             { name => { like => '%'.$findclub.'%' } },
 150             { description => { like => '%'.$findclub.'%' } }
 151         ] );
 152         if( scalar @clubs == 1 ) {
 153             $club_hold = $clubs[0]->id;
 154         } elsif ( @clubs ) {
 155             $template->param( clubs => \@clubs );
 156         } else {
 157             $messageclub = "'$findclub'";
 158         }
 159     }
 160 }
 161
 162 my @biblionumbers = ();
 163 my $biblionumber = $input->param('biblionumber');
 164 my $biblionumbers = $input->param('biblionumbers');
 165 if ( $biblionumbers ) {
 166     @biblionumbers = split '/', $biblionumbers;
 167 } else {
 168     push @biblionumbers, $input->multi_param('biblionumber');
 169 }
 170
 171 my $multi_hold = @biblionumbers > 1;
 172 $template->param(
 173     multi_hold => $multi_hold,
 174 );
 175
 176 # If we have the borrowernumber because we've performed an action, then we
 177 # don't want to try to place another reserve.
 178 if ($borrowernumber_hold && !$action) {
 179     my $patron = Koha::Patrons->find( $borrowernumber_hold );
 180     my $diffbranch;
 181
 182     # we check the reserves of the user, and if they can reserve a document
 183     # FIXME At this time we have a simple count of reservs, but, later, we could improve the infos "title" ...
 184
 185     my $reserves_count = $patron->holds->count;
 186
 187     my $new_reserves_count = scalar( @biblionumbers );
 188
 189     my $maxreserves = C4::Context->preference('maxreserves');
 190     $template->param( maxreserves => $maxreserves );
 191
 192     if ( $maxreserves
 193         && ( $reserves_count + $new_reserves_count > $maxreserves ) )
 194     {
 195         my $new_reserves_allowed =
 196             $maxreserves - $reserves_count > 0
 197           ? $maxreserves - $reserves_count
 198           : 0;
 199         $warnings             = 1;
 200         $exceeded_maxreserves = 1;
 201         $template->param(
 202             new_reserves_allowed => $new_reserves_allowed,
 203             new_reserves_count   => $new_reserves_count,
 204             reserves_count       => $reserves_count,
 205             maxreserves          => $maxreserves,
 206         );
 207     }
 208
 209     # we check the date expiry of the borrower (only if there is an expiry date, otherwise, set to 1 (warn)
 210     my $expiry_date = $patron->dateexpiry;
 211     my $expiry = 0; # flag set if patron account has expired
 212     if ($expiry_date and
 213         Date_to_Days(split /-/,$date) > Date_to_Days(split /-/,$expiry_date)) {
 214         $expiry = 1;
 215     }
 216
 217     # check if the borrower make the reserv in a different branch
 218     if ( $patron->branchcode ne C4::Context->userenv->{'branch'} ) {
 219         $diffbranch = 1;
 220     }
 221
 222     my $amount_outstanding = $patron->account->balance;
 223     $template->param(
 224                 patron              => $patron,
 225                 expiry              => $expiry,
 226                 diffbranch          => $diffbranch,
 227                 messages            => $messages,
 228                 warnings            => $warnings,
 229                 amount_outstanding  => $amount_outstanding,
 230     );
 231 }
 232
 233 if ($club_hold && !$borrowernumber_hold && !$action) {
 234     my $club = Koha::Clubs->find($club_hold);
 235
 236     my $enrollments = $club->club_enrollments;
 237
 238     my $maxreserves = C4::Context->preference('maxreserves');
 239     my $new_reserves_count = scalar( @biblionumbers );
 240
 241     my @members;
 242
 243     while(my $enrollment = $enrollments->next) {
 244         next if $enrollment->is_canceled;
 245         my $member = { patron => $enrollment->patron };
 246         my $reserves_count = $enrollment->patron->holds->count;
 247         if ( $maxreserves
 248             && ( $reserves_count + $new_reserves_count > $maxreserves ) )
 249         {
 250             $member->{new_reserves_allowed} = $maxreserves - $reserves_count > 0
 251                 ? $maxreserves - $reserves_count
 252                 : 0;
 253             $member->{exceeded_maxreserves} = 1;
 254         }
 255         $member->{amount_outstanding} = $enrollment->patron->account->balance;
 256         if ( $enrollment->patron->branchcode ne C4::Context->userenv->{'branch'} ) {
 257             $member->{diffbranch} = 1;
 258         }
 259
 260         push @members, $member;
 261     }
 262
 263     $template->param(
 264         club                => $club,
 265         members             => \@members,
 266         maxreserves         => $maxreserves,
 267         new_reserves_count  => $new_reserves_count
 268     );
 269 }
 270
 271 unless ( $club_hold or $borrowernumber_hold ) {
 272     $template->param( clubcount => Koha::Clubs->search->count );
 273 }
 274
 275 $template->param(
 276     messageborrower => $messageborrower,
 277     messageclub     => $messageclub
 278 );
 279
 280 # FIXME launch another time GetMember perhaps until (Joubu: Why?)
 281 my $patron = Koha::Patrons->find( $borrowernumber_hold );
 282
 283 if ( $patron && $multi_hold ) {
 284     my @multi_pickup_locations =
 285       Koha::Biblios->search( { biblionumber => \@biblionumbers } )
 286       ->pickup_locations( { patron => $patron } );
 287     $template->param( multi_pickup_locations => \@multi_pickup_locations );
 288 }
 289
 290 my $logged_in_patron = Koha::Patrons->find( $borrowernumber );
 291
 292 my $wants_check;
 293 if ($patron) {
 294     $wants_check = $patron->wants_check_for_previous_checkout;
 295 }
 296 my $itemdata_enumchron = 0;
 297 my $itemdata_ccode = 0;
 298 my @biblioloop = ();
 299 my $no_reserves_allowed = 0;
 300 foreach my $biblionumber (@biblionumbers) {
 301     next unless $biblionumber =~ m|^\d+$|;
 302
 303     my %biblioloopiter = ();
 304
 305     my $biblio = Koha::Biblios->find( $biblionumber );
 306     unless ($biblio) {
 307         $biblioloopiter{noitems} = 1;
 308         $template->param('nobiblio' => 1);
 309         last;
 310     }
 311
 312     my $force_hold_level;
 313     if ( $patron ) {
 314         { # CanBookBeReserved
 315             my $canReserve = CanBookBeReserved( $patron->borrowernumber, $biblionumber );
 316             if ( $canReserve->{status} eq 'OK' ) {
 317
 318                 #All is OK and we can continue
 319             }
 320             elsif ( $canReserve->{status} eq 'noReservesAllowed' || $canReserve->{status} eq 'notReservable' ) {
 321                 $no_reserves_allowed = 1;
 322             }
 323             elsif ( $canReserve->{status} eq 'tooManyReserves' ) {
 324                 $exceeded_maxreserves = 1;
 325                 $template->param( maxreserves => $canReserve->{limit} );
 326             }
 327             elsif ( $canReserve->{status} eq 'tooManyHoldsForThisRecord' ) {
 328                 $exceeded_holds_per_record = 1;
 329                 $biblioloopiter{ $canReserve->{status} } = 1;
 330             }
 331             elsif ( $canReserve->{status} eq 'ageRestricted' ) {
 332                 $template->param( $canReserve->{status} => 1 );
 333                 $biblioloopiter{ $canReserve->{status} } = 1;
 334             }
 335             elsif ( $canReserve->{status} eq 'alreadypossession' ) {
 336                 $template->param( $canReserve->{status} => 1);
 337                 $biblioloopiter{ $canReserve->{status} } = 1;
 338             }
 339             else {
 340                 $biblioloopiter{ $canReserve->{status} } = 1;
 341             }
 342         }
 343
 344         # For multiple holds per record, if a patron has previously placed a hold,
 345         # the patron can only place more holds of the same type. That is, if the
 346         # patron placed a record level hold, all the holds the patron places must
 347         # be record level. If the patron placed an item level hold, all holds
 348         # the patron places must be item level
 349         my $holds = Koha::Holds->search(
 350             {
 351                 borrowernumber => $patron->borrowernumber,
 352                 biblionumber   => $biblionumber,
 353                 found          => undef,
 354             }
 355         );
 356         $force_hold_level = $holds->forced_hold_level();
 357         $biblioloopiter{force_hold_level} = $force_hold_level;
 358         $template->param( force_hold_level => $force_hold_level );
 359
 360         # For a librarian to be able to place multiple record holds for a patron for a record,
 361         # we must find out what the maximum number of holds they can place for the patron is
 362         my $max_holds_for_record = GetMaxPatronHoldsForRecord( $patron->borrowernumber, $biblionumber );
 363         my $remaining_holds_for_record = $max_holds_for_record - $holds->count();
 364         $biblioloopiter{remaining_holds_for_record} = $max_holds_for_record;
 365         $template->param( max_holds_for_record => $max_holds_for_record );
 366         $template->param( remaining_holds_for_record => $remaining_holds_for_record );
 367     }
 368
 369
 370     my $count = Koha::Holds->search( { biblionumber => $biblionumber } )->count();
 371     my $totalcount = $count;
 372
 373     # adding a fixed value for priority options
 374     my $fixedRank = $count+1;
 375
 376     my %itemnumbers_of_biblioitem;
 377
 378     my @hostitems = get_hostitemnumbers_of($biblionumber);
 379     my @itemnumbers;
 380     if (@hostitems){
 381         $template->param('hostitemsflag' => 1);
 382         push(@itemnumbers, @hostitems);
 383     }
 384
 385     my $items = Koha::Items->search({ -or => { biblionumber => $biblionumber, itemnumber => { in => \@itemnumbers } } });
 386
 387     unless ( $items->count ) {
 388         # FIXME Then why do we continue?
 389         $template->param('noitems' => 1) unless ( $multi_hold );
 390         $biblioloopiter{noitems} = 1;
 391     }
 392
 393     ## Here we go backwards again to create hash of biblioitemnumber to itemnumbers
 394     ## this is important when we have analytic items which may be on another record
 395     my ( $iteminfos_of );
 396     while ( my $item = $items->next ) {
 397         $item = $item->unblessed;
 398         my $biblioitemnumber = $item->{biblioitemnumber};
 399         my $itemnumber = $item->{itemnumber};
 400         push( @{ $itemnumbers_of_biblioitem{$biblioitemnumber} }, $itemnumber );
 401         $iteminfos_of->{$itemnumber} = $item;
 402     }
 403
 404     my @biblioitemnumbers = keys %itemnumbers_of_biblioitem;
 405
 406     my $biblioiteminfos_of = {
 407         map {
 408             my $biblioitem = $_;
 409             ( $biblioitem->{biblioitemnumber} => $biblioitem )
 410           } @{ Koha::Biblioitems->search(
 411                 { biblioitemnumber => { -in => \@biblioitemnumbers } },
 412                 { select => ['biblionumber', 'biblioitemnumber', 'publicationyear', 'itemtype']}
 413             )->unblessed
 414           }
 415     };
 416
 417     my @bibitemloop;
 418
 419     my @available_itemtypes;
 420     foreach my $biblioitemnumber (@biblioitemnumbers) {
 421         my $biblioitem = $biblioiteminfos_of->{$biblioitemnumber};
 422         my $num_available = 0;
 423         my $num_override  = 0;
 424         my $hiddencount   = 0;
 425         my $num_alreadyheld = 0;
 426
 427         $biblioitem->{force_hold_level} = $force_hold_level;
 428
 429         if ( $biblioitem->{biblioitemnumber} ne $biblionumber ) {
 430             $biblioitem->{hostitemsflag} = 1;
 431         }
 432
 433         $biblioloopiter{description} = $biblioitem->{description};
 434         $biblioloopiter{itypename}   = $biblioitem->{description};
 435         if ( $biblioitem->{itemtype} ) {
 436
 437             $biblioitem->{description} =
 438               $itemtypes->{ $biblioitem->{itemtype} }{description};
 439
 440             $biblioloopiter{imageurl} =
 441               getitemtypeimagelocation( 'intranet',
 442                 $itemtypes->{ $biblioitem->{itemtype} }{imageurl} );
 443         }
 444
 445         # iterating through all items first to check if any of them available
 446         # to pass this value further inside down to IsAvailableForItemLevelRequest to
 447         # it's complicated logic to analyse.
 448         # (before this loop was inside that sub loop so it was O(n^2) )
 449         my $items_any_available;
 450         $items_any_available = ItemsAnyAvailableAndNotRestricted( { biblionumber => $biblioitem->{biblionumber}, patron => $patron })
 451             if $patron;
 452
 453         foreach my $itemnumber ( @{ $itemnumbers_of_biblioitem{$biblioitemnumber} } )    {
 454             my $item = $iteminfos_of->{$itemnumber};
 455             my $do_check;
 456             if ( $patron ) {
 457                 $do_check = $patron->do_check_for_previous_checkout($item) if $wants_check;
 458                 if ( $do_check && $wants_check ) {
 459                     $item->{checked_previously} = $do_check;
 460                     if ( $multi_hold ) {
 461                         $biblioloopiter{checked_previously} = $do_check;
 462                     } else {
 463                         $template->param( checked_previously => $do_check );
 464                     }
 465                 }
 466             }
 467             $item->{force_hold_level} = $force_hold_level;
 468
 469             unless (C4::Context->preference('item-level_itypes')) {
 470                 $item->{itype} = $biblioitem->{itemtype};
 471             }
 472
 473             $item->{itypename} = $itemtypes->{ $item->{itype} }{description};
 474             $item->{imageurl} = getitemtypeimagelocation( 'intranet', $itemtypes->{ $item->{itype} }{imageurl} );
 475             $item->{homebranch} = $item->{homebranch};
 476
 477             # if the holdingbranch is different than the homebranch, we show the
 478             # holdingbranch of the document too
 479             if ( $item->{homebranch} ne $item->{holdingbranch} ) {
 480                 $item->{holdingbranch} = $item->{holdingbranch};
 481             }
 482
 483             if($item->{biblionumber} ne $biblionumber){
 484                 $item->{hostitemsflag} = 1;
 485                 $item->{hosttitle} = Koha::Biblios->find( $item->{biblionumber} )->title;
 486             }
 487
 488             # if the item is currently on loan, we display its return date and
 489             # change the background color
 490             my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } );
 491             if ( $issue ) {
 492                 $item->{date_due} = $issue->date_due;
 493                 $item->{backgroundcolor} = 'onloan';
 494             }
 495
 496             # checking reserve
 497             my $item_object = Koha::Items->find( $itemnumber );
 498             my $holds = $item_object->current_holds;
 499             if ( my $first_hold = $holds->next ) {
 500                 my $p = Koha::Patrons->find( $first_hold->borrowernumber );
 501
 502                 $item->{backgroundcolor} = 'reserved';
 503                 $item->{reservedate}     = output_pref({ dt => dt_from_string( $first_hold->reservedate ), dateonly => 1 }); # FIXME Should be formatted in the template
 504                 $item->{ReservedFor}     = $p;
 505                 $item->{ExpectedAtLibrary}     = $first_hold->branchcode;
 506                 $item->{waitingdate} = $first_hold->waitingdate;
 507             }
 508
 509             # Management of the notforloan document
 510             if ( $item->{notforloan} ) {
 511                 $item->{backgroundcolor} = 'other';
 512             }
 513
 514             # Management of lost or long overdue items
 515             if ( $item->{itemlost} ) {
 516                 $item->{backgroundcolor} = 'other';
 517                 if ($logged_in_patron->category->hidelostitems && !$showallitems) {
 518                     $item->{hide} = 1;
 519                     $hiddencount++;
 520                 }
 521             }
 522
 523             # Check the transit status
 524             my ( $transfertwhen, $transfertfrom, $transfertto ) =
 525               GetTransfers($itemnumber);
 526
 527             if ( defined $transfertwhen && $transfertwhen ne '' ) {
 528                 $item->{transfertwhen} = output_pref({ dt => dt_from_string( $transfertwhen ), dateonly => 1 });
 529                 $item->{transfertfrom} = $transfertfrom;
 530                 $item->{transfertto} = $transfertto;
 531                 $item->{nocancel} = 1;
 532             }
 533
 534             # If there is no loan, return and transfer, we show a checkbox.
 535             $item->{notforloan} ||= 0;
 536
 537             # if independent branches is on we need to check if the person can reserve
 538             # for branches they arent logged in to
 539             if ( C4::Context->preference("IndependentBranches") ) {
 540                 if (! C4::Context->preference("canreservefromotherbranches")){
 541                     # can't reserve items so need to check if item homebranch and userenv branch match if not we can't reserve
 542                     my $userenv = C4::Context->userenv;
 543                     unless ( C4::Context->IsSuperLibrarian ) {
 544                         $item->{cantreserve} = 1 if ( $item->{homebranch} ne $userenv->{branch} );
 545                     }
 546                 }
 547             }
 548
 549             if ( $patron ) {
 550                 my $patron_unblessed = $patron->unblessed;
 551                 my $branch = C4::Circulation::_GetCircControlBranch($item, $patron_unblessed);
 552
 553                 my $branchitemrule = GetBranchItemRule( $branch, $item->{'itype'} );
 554
 555                 $item->{'holdallowed'} = $branchitemrule->{'holdallowed'};
 556
 557                 my $can_item_be_reserved = CanItemBeReserved( $patron->borrowernumber, $itemnumber )->{status};
 558                 $item->{not_holdable} = $can_item_be_reserved unless ( $can_item_be_reserved eq 'OK' );
 559
 560                 $item->{item_level_holds} = Koha::CirculationRules->get_opacitemholds_policy( { item => $item_object, patron => $patron } );
 561
 562                 if (
 563                        !$item->{cantreserve}
 564                     && !$exceeded_maxreserves
 565                     && $can_item_be_reserved eq 'OK'
 566                     # items_any_available defined outside of the current loop,
 567                     # so we avoiding loop inside IsAvailableForItemLevelRequest:
 568                     && IsAvailableForItemLevelRequest($item_object, $patron, undef, $items_any_available)
 569                   )
 570                 {
 571                     # Send the pickup locations count to the UI, the pickup locations will be pulled using the API
 572                     my @pickup_locations = $item_object->pickup_locations({ patron => $patron })->as_list;
 573                     $item->{pickup_locations_count} = scalar @pickup_locations;
 574
 575                     if ( @pickup_locations ) {
 576                         $num_available++;
 577                         $item->{available} = 1;
 578
 579                         my $default_pickup_location;
 580
 581                         # Default to logged-in, if valid
 582                         if ( C4::Context->userenv->{branch} ) {
 583                             ($default_pickup_location) = grep { $_->branchcode eq C4::Context->userenv->{branch} } @pickup_locations;
 584                         }
 585
 586                         $item->{default_pickup_location} = $default_pickup_location;
 587                     }
 588                     else {
 589                         $item->{available} = 0;
 590                         $item->{not_holdable} = "no_valid_pickup_location";
 591                     }
 592
 593                     push( @available_itemtypes, $item->{itype} );
 594                 }
 595                 elsif ( C4::Context->preference('AllowHoldPolicyOverride') ) {
 596                     # If AllowHoldPolicyOverride is set, it should override EVERY restriction, not just branch item rules
 597                     # with the exception of itemAlreadyOnHold because, you know, the item is already on hold
 598                     if ( $can_item_be_reserved ne 'itemAlreadyOnHold' ) {
 599                         # Send the pickup locations count to the UI, the pickup locations will be pulled using the API
 600                         my $pickup_locations = $item_object->pickup_locations({ patron => $patron });
 601                         $item->{pickup_locations_count} = $pickup_locations->count;
 602                         if ( $item->{pickup_locations_count} > 0 ) {
 603                             $item->{override} = 1;
 604                             $num_override++;
 605                             # pass the holding branch for use as default
 606                             my $default_pickup_location = $pickup_locations->search({ branchcode => $item->{holdingbranch} })->next;
 607                             $item->{default_pickup_location} = $default_pickup_location;
 608                         }
 609                         else {
 610                             $item->{available} = 0;
 611                             $item->{not_holdable} = "no_valid_pickup_location";
 612                         }
 613                     } else { $num_alreadyheld++ }
 614
 615                     push( @available_itemtypes, $item->{itype} );
 616                 }
 617
 618                 # If none of the conditions hold true, then neither override nor available is set and the item cannot be checked
 619
 620                 # Show serial enumeration when needed
 621                 if ($item->{enumchron}) {
 622                     $itemdata_enumchron = 1;
 623                 }
 624                 # Show collection when needed
 625                 if ($item->{ccode}) {
 626                     $itemdata_ccode = 1;
 627                 }
 628             }
 629
 630             push @{ $biblioitem->{itemloop} }, $item;
 631         }
 632
 633         # While we can't override an alreay held item, we should be able to override the others
 634         # Unless all items are already held
 635         if ( $num_override > 0 && ($num_override + $num_alreadyheld) == scalar( @{ $biblioitem->{itemloop} } ) ) {
 636         # That is, if all items require an override
 637             $template->param( override_required => 1 );
 638         } elsif ( $num_available == 0 ) {
 639             $template->param( none_available => 1 );
 640             $biblioloopiter{warn} = 1;
 641             $biblioloopiter{none_avail} = 1;
 642         }
 643         $template->param( hiddencount => $hiddencount);
 644
 645         push @bibitemloop, $biblioitem;
 646     }
 647
 648     @available_itemtypes = uniq( @available_itemtypes );
 649     $template->param( available_itemtypes => \@available_itemtypes );
 650
 651     # existingreserves building
 652     my @reserveloop;
 653     my @reserves = Koha::Holds->search( { biblionumber => $biblionumber }, { order_by => 'priority' } );
 654     foreach my $res (
 655         sort {
 656             my $a_found = $a->found() || '';
 657             my $b_found = $a->found() || '';
 658             $a_found cmp $b_found;
 659         } @reserves
 660       )
 661     {
 662         my %reserve;
 663         if ( $res->is_found() ) {
 664             $reserve{'holdingbranch'} = $res->item()->holdingbranch();
 665             $reserve{'biblionumber'}  = $res->item()->biblionumber();
 666             $reserve{'barcodenumber'} = $res->item()->barcode();
 667             $reserve{'wbrcode'}       = $res->branchcode();
 668             $reserve{'itemnumber'}    = $res->itemnumber();
 669             $reserve{'wbrname'}       = $res->branch()->branchname();
 670             $reserve{'atdestination'} = $res->is_at_destination();
 671             $reserve{'desk_name'}     = ( $res->desk() ) ? $res->desk()->desk_name() : '' ;
 672             $reserve{'found'}     = $res->is_found();
 673             $reserve{'inprocessing'} = $res->is_in_processing();
 674             $reserve{'intransit'} = $res->is_in_transit();
 675         }
 676         elsif ( $res->priority() > 0 ) {
 677             if ( my $item = $res->item() )  {
 678                 $reserve{'itemnumber'}      = $item->id();
 679                 $reserve{'barcodenumber'}   = $item->barcode();
 680                 $reserve{'item_level_hold'} = 1;
 681             }
 682         }
 683
 684         $reserve{'expirationdate'} = $res->expirationdate;
 685         $reserve{'date'}           = $res->reservedate;
 686         $reserve{'borrowernumber'} = $res->borrowernumber();
 687         $reserve{'biblionumber'}   = $res->biblionumber();
 688         $reserve{'patron'}         = $res->borrower;
 689         $reserve{'notes'}          = $res->reservenotes();
 690         $reserve{'waiting_date'}   = $res->waitingdate();
 691         $reserve{'ccode'}          = $res->item() ? $res->item()->ccode() : undef;
 692         $reserve{'barcode'}        = $res->item() ? $res->item()->barcode() : undef;
 693         $reserve{'priority'}       = $res->priority();
 694         $reserve{'lowestPriority'} = $res->lowestPriority();
 695         $reserve{'suspend'}        = $res->suspend();
 696         $reserve{'suspend_until'}  = $res->suspend_until();
 697         $reserve{'reserve_id'}     = $res->reserve_id();
 698         $reserve{itemtype}         = $res->itemtype();
 699         $reserve{branchcode}       = $res->branchcode();
 700         $reserve{non_priority}     = $res->non_priority();
 701         $reserve{object}           = $res;
 702
 703         push( @reserveloop, \%reserve );
 704     }
 705
 706     # get the time for the form name...
 707     my $time = time();
 708
 709     $template->param(
 710                      time        => $time,
 711                      fixedRank   => $fixedRank,
 712                     );
 713
 714     # display infos
 715     $template->param(
 716                      bibitemloop       => \@bibitemloop,
 717                      itemdata_enumchron => $itemdata_enumchron,
 718                      itemdata_ccode    => $itemdata_ccode,
 719                      date              => $date,
 720                      biblionumber      => $biblionumber,
 721                      findborrower      => $findborrower,
 722                      biblio            => $biblio,
 723                      holdsview         => 1,
 724                      C4::Search::enabled_staff_search_views,
 725                     );
 726
 727     $biblioloopiter{biblionumber} = $biblionumber;
 728     $biblioloopiter{title} = $biblio->title;
 729     $biblioloopiter{rank} = $fixedRank;
 730     $biblioloopiter{reserveloop} = \@reserveloop;
 731
 732     if (@reserveloop) {
 733         $template->param( reserveloop => \@reserveloop );
 734     }
 735
 736     if ( $patron ) {
 737         # Add the valid pickup locations
 738         my @pickup_locations = $biblio->pickup_locations({ patron => $patron });
 739         $biblioloopiter{pickup_locations} = \@pickup_locations;
 740         $biblioloopiter{pickup_locations_codes} = [ map { $_->branchcode } @pickup_locations ];
 741     }
 742
 743     push @biblioloop, \%biblioloopiter;
 744 }
 745
 746 $template->param( biblioloop => \@biblioloop );
 747 $template->param( no_reserves_allowed => $no_reserves_allowed );
 748 $template->param( biblionumbers => join('/', @biblionumbers) );
 749 $template->param( exceeded_maxreserves => $exceeded_maxreserves );
 750 $template->param( exceeded_holds_per_record => $exceeded_holds_per_record );
 751 $template->param( subscriptionsnumber => CountSubscriptionFromBiblionumber($biblionumber));
 752
 753 # pass the userenv branch if no pickup location selected
 754 $template->param( pickup => $pickup || C4::Context->userenv->{branch} );
 755
 756 if ( C4::Context->preference( 'AllowHoldDateInFuture' ) ) {
 757     $template->param( reserve_in_future => 1 );
 758 }
 759
 760 $template->param(
 761     SuspendHoldsIntranet => C4::Context->preference('SuspendHoldsIntranet'),
 762     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 763 );
 764
 765 # printout the page
 766 output_html_with_http_headers $input, $cookie, $template->output;
 767
 768 sub sort_borrowerlist {
 769     my $borrowerslist = shift;
 770     my $ref           = [];
 771     push @{$ref}, sort {
 772         uc( $a->{surname} . $a->{firstname} ) cmp
 773           uc( $b->{surname} . $b->{firstname} )
 774     } @{$borrowerslist};
 775     return $ref;
 776 }