serials/serials-edit.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # Parts Copyright 2010 Biblibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 =head1 NAME
  22
  23 serials-edit.pl
  24
  25 =head1 Parameters
  26
  27 =over 4
  28
  29 =item op
  30 op can be :
  31     * modsubscriptionhistory :to modify the subscription history
  32     * serialchangestatus     :to modify the status of this subscription
  33
  34 =item subscriptionid
  35
  36 =item user
  37
  38 =item histstartdate
  39
  40 =item enddate
  41
  42 =item recievedlist
  43
  44 =item missinglist
  45
  46 =item opacnote
  47
  48 =item librariannote
  49
  50 =item serialid
  51
  52 =item serialseq
  53
  54 =item planneddate
  55
  56 =item notes
  57
  58 =item status
  59
  60 =back
  61
  62 =cut
  63
  64 use strict;
  65 use warnings;
  66 use CGI qw ( -utf8 );
  67 use Encode qw( decode is_utf8 );
  68 use C4::Auth;
  69 use C4::Biblio;
  70 use C4::Items;
  71 use C4::Koha;
  72 use C4::Output;
  73 use C4::Context;
  74 use C4::Serials;
  75 use C4::Search qw/enabled_staff_search_views/;
  76 use Koha::DateUtils;
  77
  78 use List::MoreUtils qw/uniq/;
  79
  80 my $query           = CGI->new();
  81 my $dbh             = C4::Context->dbh;
  82 my @serialids       = $query->multi_param('serialid');
  83 my @serialseqs      = $query->multi_param('serialseq');
  84 my @planneddates    = $query->multi_param('planneddate');
  85 my @publisheddates  = $query->multi_param('publisheddate');
  86 my @publisheddatetexts = $query->multi_param('publisheddatetext');
  87 my @status          = $query->multi_param('status');
  88 my @notes           = $query->multi_param('notes');
  89 my @subscriptionids = $query->multi_param('subscriptionid');
  90 my $op              = $query->param('op');
  91 if ( scalar(@subscriptionids) == 1 && index( $subscriptionids[0], q|,| ) > 0 ) {
  92     @subscriptionids = split( /,/, $subscriptionids[0] );
  93 }
  94 my @errors;
  95 my @errseq;
  96 my $dbh   = C4::Context->dbh;
  97
  98 # If user comes from subscription details
  99 unless (@serialids) {
 100     my $serstatus = $query->param('serstatus');
 101     my @statuses = split ',', $serstatus;
 102     if ($serstatus) {
 103         foreach my $subscriptionid (@subscriptionids) {
 104             my @tmpser = GetSerials2( $subscriptionid, \@statuses );
 105             push @serialids, map { $_->{serialid} } @tmpser;
 106         }
 107     }
 108 }
 109
 110 unless ( @serialids ) {
 111     my $string =
 112       'serials-collection.pl?subscriptionid=' . join ',', uniq @subscriptionids;
 113     $string =~ s/,$//;
 114
 115     print $query->redirect($string);
 116 }
 117
 118 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
 119     {
 120         template_name   => 'serials/serials-edit.tt',
 121         query           => $query,
 122         type            => 'intranet',
 123         authnotrequired => 0,
 124         flagsrequired   => { serials => 'receive_serials' },
 125         debug           => 1,
 126     }
 127 );
 128
 129 my @serialdatalist;
 130 my %processedserialid;
 131
 132 my $today = output_pref( { dt => dt_from_string, dateonly => 1 } );
 133
 134 foreach my $serialid (@serialids) {
 135
 136     #filtering serialid for duplication
 137     #NEW serial should appear only once and are created afterwards
 138     if (   $serialid
 139         && $serialid =~ /^[0-9]+$/
 140         && !$processedserialid{$serialid} )
 141     {
 142         my $serinfo = GetSerialInformation($serialid); #TODO duplicates work done by GetSerials2 above
 143
 144         for my $d ( qw( publisheddate planneddate )){
 145             if ( $serinfo->{$d} =~m/^00/ ) {
 146                 $serinfo->{$d} = q{};
 147             }
 148             else {
 149                 $serinfo->{$d} = output_pref( { dt => dt_from_string( $serinfo->{$d} ), dateonly => 1 } );
 150             }
 151         }
 152         $serinfo->{arriveddate} = $today;
 153
 154         $serinfo->{'editdisable'} = (
 155             (
 156                 HasSubscriptionExpired( $serinfo->{subscriptionid} )
 157                 && $serinfo->{'status1'}
 158             )
 159             || $serinfo->{'cannotedit'}
 160         );
 161         $serinfo->{editdisable} = 0 if C4::Auth::haspermission( C4::Context->userenv->{id}, { serials => 'receive_serials' } );
 162         $serinfo->{editdisable} ||= ($serinfo->{status8} and $serinfo->{closed});
 163         push @serialdatalist, $serinfo;
 164         $processedserialid{$serialid} = 1;
 165     }
 166 }
 167 my $biblio = GetBiblioData( $serialdatalist[0]->{'biblionumber'} );
 168
 169 my @newserialloop;
 170 my @subscriptionloop;
 171
 172 # check, for each subscription edited, that we have an empty item line if applicable for the subscription
 173 my %processedsubscriptionid;
 174 foreach my $subscriptionid (@subscriptionids) {
 175
 176     #Do not process subscriptionid twice if it was already processed.
 177     if ( $subscriptionid && !$processedsubscriptionid{$subscriptionid} )
 178     {
 179         my $cell;
 180         if ( $serialdatalist[0]->{'serialsadditems'} ) {
 181
 182             #Create New empty item
 183             $cell =
 184               PrepareItemrecordDisplay( $serialdatalist[0]->{'biblionumber'},
 185                 '', GetSubscription($subscriptionid) );
 186             $cell->{serialsadditems} = 1;
 187         }
 188         $cell->{'subscriptionid'} = $subscriptionid;
 189         $cell->{biblionumber} = $serialdatalist[0]->{'biblionumber'};
 190         $cell->{'itemid'}         = 'NNEW';
 191         $cell->{'serialid'}       = 'NEW';
 192         $cell->{'issuesatonce'}   = 1;
 193         $cell->{arriveddate}      = $today;
 194
 195         push @newserialloop, $cell;
 196         push @subscriptionloop,
 197           {
 198             'subscriptionid'      => $subscriptionid,
 199             'abouttoexpire'       => abouttoexpire($subscriptionid),
 200             'subscriptionexpired' => HasSubscriptionExpired($subscriptionid),
 201           };
 202         $processedsubscriptionid{$subscriptionid} = 1;
 203     }
 204 }
 205 $template->param( newserialloop => \@newserialloop );
 206 $template->param( subscriptions => \@subscriptionloop );
 207
 208 if ( $op and $op eq 'serialchangestatus' ) {
 209
 210     # Convert serialseqs to UTF-8 to prevent encoding problems
 211     foreach my $seq (@serialseqs) {
 212         $seq = Encode::decode('UTF-8', $seq) unless Encode::is_utf8($seq);
 213     }
 214
 215     my $newserial;
 216     for ( my $i = 0 ; $i <= $#serialids ; $i++ ) {
 217         my ($plan_date, $pub_date);
 218
 219         if (defined $planneddates[$i] && $planneddates[$i] ne 'XXX') {
 220             $plan_date = eval { output_pref( { dt => dt_from_string( $planneddates[$i] ), dateonly => 1, dateformat => 'iso' } ); };
 221         }
 222         if (defined $publisheddates[$i] && $publisheddates[$i] ne 'XXX') {
 223             $pub_date = eval { output_pref( { dt => dt_from_string( $publisheddates[$i] ), dateonly => 1, dateformat => 'iso' } ); };
 224         }
 225
 226         if ( $serialids[$i] && $serialids[$i] eq 'NEW' ) {
 227             if ( $serialseqs[$i] ) {
 228
 229             #IF newserial was provided a name Then we have to create a newSerial
 230                 ### FIXME if NewIssue is modified to use subscription biblionumber, then biblionumber would not be useful.
 231                 $newserial = NewIssue(
 232                     $serialseqs[$i],
 233                     $subscriptionids[0],
 234                     $serialdatalist[0]->{'biblionumber'},
 235                     $status[$i],
 236                     $plan_date,
 237                     $pub_date,
 238                     $publisheddatetexts[$i],
 239                     $notes[$i]
 240                 );
 241             }
 242         }
 243         elsif ( $serialids[$i] ) {
 244             ModSerialStatus(
 245                 $serialids[$i],
 246                 $serialseqs[$i],
 247                 $plan_date,
 248                 $pub_date,
 249                 $publisheddatetexts[$i],
 250                 $status[$i],
 251                 $notes[$i]
 252             );
 253         }
 254         my $makePreviousSerialAvailable = C4::Context->preference('makePreviousSerialAvailable');
 255         if ($makePreviousSerialAvailable && $serialids[$i] ne "NEW") {
 256             # We already have created the new expected serial at this point, so we get the second previous serial
 257             my $previous = GetPreviousSerialid($subscriptionids[$i]);
 258             if ($previous) {
 259
 260                 # Getting the itemnumber matching the serialid
 261                 my $query = "SELECT itemnumber FROM serialitems WHERE serialid=?";
 262                 my $sth = $dbh->prepare($query);
 263                 $sth->execute($previous);
 264                 my @row = $sth->fetchrow_array;
 265                 if ($row[0]) {
 266                     my $itemnumber = $row[0];
 267
 268                     # Getting the itemtype to set from the database
 269                     my $subscriptioninfos = GetSubscription($subscriptionids[$i]);
 270
 271                     # Changing the status to "available" and the itemtype according to the previousitemtype db field
 272                     ModItem({notforloan => 0, itype => $subscriptioninfos->{'previousitemtype'} }, undef, $itemnumber);
 273                 }
 274             }
 275         }
 276
 277     }
 278     my @moditems = $query->multi_param('moditem');
 279     if ( scalar(@moditems) ) {
 280         my @tags         = $query->multi_param('tag');
 281         my @subfields    = $query->multi_param('subfield');
 282         my @field_values = $query->multi_param('field_value');
 283         my @serials      = $query->multi_param('serial');
 284         my @bibnums      = $query->multi_param('bibnum');
 285         my @itemid       = $query->multi_param('itemid');
 286         my @ind_tag      = $query->multi_param('ind_tag');
 287         my @indicator    = $query->multi_param('indicator');
 288
 289         #Rebuilding ALL the data for items into a hash
 290         # parting them on $itemid.
 291         my %itemhash;
 292         my $countdistinct;
 293         my $range = scalar(@itemid);
 294         for ( my $i = 0 ; $i < $range ; $i++ ) {
 295             unless ( $itemhash{ $itemid[$i] } ) {
 296                 if (   $serials[$countdistinct]
 297                     && $serials[$countdistinct] ne "NEW" )
 298                 {
 299                     $itemhash{ $itemid[$i] }->{'serial'} =
 300                       $serials[$countdistinct];
 301                 }
 302                 else {
 303                     $itemhash{ $itemid[$i] }->{'serial'} = $newserial;
 304                 }
 305                 $itemhash{ $itemid[$i] }->{'bibnum'} = $bibnums[$countdistinct];
 306                 $countdistinct++;
 307             }
 308             push @{ $itemhash{ $itemid[$i] }->{'tags'} },      $tags[$i];
 309             push @{ $itemhash{ $itemid[$i] }->{'subfields'} }, $subfields[$i];
 310             push @{ $itemhash{ $itemid[$i] }->{'field_values'} },
 311               $field_values[$i];
 312             push @{ $itemhash{ $itemid[$i] }->{'ind_tag'} },   $ind_tag[$i];
 313             push @{ $itemhash{ $itemid[$i] }->{'indicator'} }, $indicator[$i];
 314         }
 315         foreach my $item ( keys %itemhash ) {
 316
 317        # Verify Itemization is "Valid", i.e. serial status is Arrived or Missing
 318             my $index = -1;
 319             for ( my $i = 0 ; $i < scalar(@serialids) ; $i++ ) {
 320                   if (
 321                     $itemhash{$item}->{serial} eq $serialids[$i]
 322                     || (   $itemhash{$item}->{serial} == $newserial
 323                         && $serialids[$i] eq 'NEW' )
 324                 ) {
 325                     $index = $i
 326                   }
 327             }
 328             if ( $index >= 0 && $status[$index] == 2 ) {
 329                 my $xml = TransformHtmlToXml(
 330                     $itemhash{$item}->{'tags'},
 331                     $itemhash{$item}->{'subfields'},
 332                     $itemhash{$item}->{'field_values'},
 333                     $itemhash{$item}->{'indicator'},
 334                     $itemhash{$item}->{'ind_tag'}
 335                 );
 336
 337                 #           warn $xml;
 338                 my $bib_record = MARC::Record::new_from_xml( $xml, 'UTF-8' );
 339                 if ( $item =~ /^N/ ) {
 340
 341                     #New Item
 342
 343                   # if autoBarcode is set to 'incremental', calculate barcode...
 344                     my ( $barcodetagfield, $barcodetagsubfield ) =
 345                       GetMarcFromKohaField(
 346                         'items.barcode',
 347                         GetFrameworkCode(
 348                             $serialdatalist[0]->{'biblionumber'}
 349                         )
 350                       );
 351                     if ( C4::Context->preference('autoBarcode') eq
 352                         'incremental' )
 353                     {
 354                         if (
 355                             !(
 356                                    $bib_record->field($barcodetagfield)
 357                                 && $bib_record->field($barcodetagfield)->subfield($barcodetagsubfield)
 358                             )
 359                           )
 360                         {
 361                             my $sth_barcode = $dbh->prepare(
 362                                 'select max(abs(barcode)) from items');
 363                             $sth_barcode->execute;
 364                             my ($newbarcode) = $sth_barcode->fetchrow;
 365
 366 # OK, we have the new barcode, add the entry in MARC record # FIXME -> should be  using barcode plugin here.
 367                             $bib_record->field($barcodetagfield)
 368                               ->update( $barcodetagsubfield => ++$newbarcode );
 369                         }
 370                     }
 371
 372                     # check for item barcode # being unique
 373                     my $exists;
 374                     if (
 375                         $bib_record->subfield(
 376                             $barcodetagfield, $barcodetagsubfield
 377                         )
 378                       )
 379                     {
 380                         $exists = GetItemnumberFromBarcode(
 381                             $bib_record->subfield(
 382                                 $barcodetagfield, $barcodetagsubfield
 383                             )
 384                         );
 385                     }
 386
 387                     #           push @errors,"barcode_not_unique" if($exists);
 388                     # if barcode exists, don't create, but report The problem.
 389                     if ($exists) {
 390                         push @errors, 'barcode_not_unique';
 391                         push @errseq, { serialseq => $serialseqs[$index] };
 392                     }
 393                     else {
 394                         my ( $biblionumber, $bibitemnum, $itemnumber ) =
 395                           AddItemFromMarc( $bib_record,
 396                             $itemhash{$item}->{bibnum} );
 397                         AddItem2Serial( $itemhash{$item}->{serial},
 398                             $itemnumber );
 399                     }
 400                 }
 401                 else {
 402
 403                     #modify item
 404                     my ( $oldbiblionumber, $oldbibnum, $itemnumber ) =
 405                       ModItemFromMarc( $bib_record,
 406                         $itemhash{$item}->{'bibnum'}, $item );
 407                 }
 408             }
 409         }
 410     }
 411
 412
 413     if ( @errors ) {
 414         $template->param( Errors => 1 );
 415         if ( @errseq ) {
 416             $template->param( barcode_not_unique => 1, errseq => \@errseq );
 417         }
 418     }
 419     else {
 420         my $redirect = 'serials-collection.pl?';
 421         $redirect .= join( '&', map { 'subscriptionid=' . $_ } @subscriptionids );
 422         print $query->redirect($redirect);
 423     }
 424 }
 425 my $location = $serialdatalist[0]->{'location'};
 426 my $default_bib_view = get_default_view();
 427
 428 $template->param(
 429     serialsadditems => $serialdatalist[0]->{'serialsadditems'},
 430     callnumber       => $serialdatalist[0]->{'callnumber'},
 431     internalnotes   => $serialdatalist[0]->{'internalnotes'},
 432     bibliotitle     => $biblio->{'title'},
 433     biblionumber    => $serialdatalist[0]->{'biblionumber'},
 434     serialslist     => \@serialdatalist,
 435     default_bib_view => $default_bib_view,
 436     location         => $location,
 437     (uc(C4::Context->preference("marcflavour"))) => 1
 438
 439 );
 440 output_html_with_http_headers $query, $cookie, $template->output;
 441
 442 sub get_default_view {
 443     my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 444     my %views       = C4::Search::enabled_staff_search_views();
 445     if ( $defaultview eq 'isbd' && $views{can_view_ISBD} ) {
 446         return 'ISBDdetail';
 447     }
 448     elsif ( $defaultview eq 'marc' && $views{can_view_MARC} ) {
 449         return 'MARCdetail';
 450     }
 451     elsif ( $defaultview eq 'labeled_marc' && $views{can_view_labeledMARC} ) {
 452         return 'labeledMARCdetail';
 453     }
 454     return 'detail';
 455 }