serials/subscription-renew.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20
  21 =head1 NAME
  22
  23 subscription-renew.pl
  24
  25 =head1 DESCRIPTION
  26
  27 this script renew an existing subscription.
  28
  29 =head1 Parameters
  30
  31 =over 4
  32
  33 =item op
  34 op use to know the operation to do on this template.
  35  * renew : to renew the subscription.
  36
  37 Note that if op = modsubscription there are a lot of other parameters.
  38
  39 =item subscriptionid
  40 Id of the subscription this script has to renew
  41
  42 =back
  43
  44 =cut
  45
  46 use Modern::Perl;
  47
  48 use CGI qw ( -utf8 );
  49 use Carp qw( carp );
  50 use C4::Koha;
  51 use C4::Auth qw( get_template_and_user );
  52 use C4::Context;
  53 use C4::Auth qw( get_template_and_user );
  54 use C4::Output qw( output_and_exit output_html_with_http_headers );
  55 use C4::Serials qw( GetSubscription GetSubscriptionLength NewSubscription ReNewSubscription );
  56 use Koha::DateUtils qw( dt_from_string output_pref );
  57
  58 my $query = CGI->new;
  59 my $dbh   = C4::Context->dbh;
  60
  61 my $mode           = $query->param('mode') || q{};
  62 my $op             = $query->param('op') || 'display';
  63 my @subscriptionids = $query->multi_param('subscriptionid');
  64 my $branchcode     = $query->param('branchcode');
  65 my $sublength = $query->param('sublength');
  66 my $subtype = $query->param('subtype');
  67 my ($numberlength, $weeklength, $monthlength);
  68
  69 my $done = 0;    # for after form has been submitted
  70 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  71     {
  72         template_name   => "serials/subscription-renew.tt",
  73         query           => $query,
  74         type            => "intranet",
  75         flagsrequired   => { serials => 'renew_subscription' },
  76     }
  77 );
  78 if ( $op eq "renew" ) {
  79     # Do not use this script with op=renew and @subscriptionids > 1!
  80     my $subscriptionid = $subscriptionids[0];
  81     # Make sure the subscription exists
  82     my $subscription = GetSubscription( $subscriptionid );
  83     output_and_exit( $query, $cookie, $template, 'unknown_subscription') unless $subscription;
  84     my $startdate = output_pref( { str => scalar $query->param('startdate'), dateonly => 1, dateformat => 'iso' } );
  85     ($numberlength, $weeklength, $monthlength) = GetSubscriptionLength( $subtype, $sublength );
  86     ReNewSubscription(
  87         {
  88             subscriptionid => $subscriptionid,
  89             user           => $loggedinuser,
  90             startdate      => $startdate,
  91             numberlength   => $numberlength,
  92             weeklength     => $weeklength,
  93             monthlength    => $monthlength,
  94             note           => scalar $query->param('note'),
  95             branchcode     => $branchcode
  96         }
  97     );
  98 } elsif ( $op eq 'multi_renew' ) {
  99     for my $subscriptionid ( @subscriptionids ) {
 100         my $subscription = GetSubscription( $subscriptionid );
 101         next unless $subscription;
 102         ReNewSubscription(
 103             {
 104                 subscriptionid => $subscriptionid,
 105                 user           => $loggedinuser,
 106                 startdate      => $subscription->{enddate},
 107                 numberlength   => $subscription->{numberlength},
 108                 weeklength     => $subscription->{weeklength},
 109                 monthlength    => $subscription->{monthlength},
 110             }
 111         );
 112     }
 113 } else {
 114     my $subscriptionid = $subscriptionids[0];
 115     my $subscription = GetSubscription($subscriptionid);
 116     output_and_exit( $query, $cookie, $template, 'unknown_subscription') unless $subscription;
 117     if ($subscription->{'cannotedit'}){
 118       carp "Attempt to renew subscription $subscriptionid by ".C4::Context->userenv->{'id'}." not allowed";
 119       print $query->redirect("/cgi-bin/koha/serials/subscription-detail.pl?subscriptionid=$subscriptionid");
 120     }
 121
 122     my $newstartdate = output_pref( { str => $subscription->{enddate}, dateonly => 1 } )
 123         or output_pref( { dt => dt_from_string, dateonly => 1 } );
 124
 125     $template->param(
 126         startdate      => $newstartdate,
 127         subscription   => $subscription,
 128     );
 129 }
 130
 131 $template->param(
 132     op => $op,
 133 );
 134
 135 output_html_with_http_headers $query, $cookie, $template->output;