svc/bib

   1 #!/usr/bin/perl
   2
   3 # Copyright 2007 LibLime
   4 # Copyright 2012 software.coop and MJ Ray
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20 #
  21
  22 use Modern::Perl;
  23
  24 use CGI qw ( -utf8 );
  25 use C4::Auth qw( check_api_auth );
  26 use C4::Biblio qw( GetFrameworkCode );
  27 use C4::Items;
  28 use XML::Simple;
  29 use Koha::Biblios;
  30
  31 my $query = CGI->new;
  32 binmode STDOUT, ':encoding(UTF-8)';
  33
  34 my ($status, $cookie, $sessionID) = check_api_auth($query, { editcatalogue => 'edit_catalogue'} );
  35 unless ($status eq "ok") {
  36     print $query->header(-type => 'text/xml', -status => '403 Forbidden');
  37     print XMLout({ auth_status => $status }, NoAttr => 1, RootName => 'response', XMLDecl => 1);
  38     exit 0;
  39 }
  40
  41 # do initial validation
  42 my $path_info = $query->path_info();
  43
  44 my $biblionumber = undef;
  45 if ($path_info =~ m!^/(\d+)$!) {
  46     $biblionumber = $1;
  47 } else {
  48     print $query->header(-type => 'text/xml', -status => '400 Bad Request');
  49 }
  50
  51 # are we retrieving, updating or deleting a bib?
  52 if ($query->request_method eq "GET") {
  53     fetch_bib($query, $biblionumber);
  54 } elsif ($query->request_method eq "POST") {
  55     update_bib($query, $biblionumber);
  56 } elsif ($query->request_method eq "DELETE") {
  57     delete_bib($query, $biblionumber);
  58 } else {
  59     print $query->header(-type => 'text/xml', -status => '405 Method not allowed');
  60     print XMLout({ error => 'Method not allowed' }, NoAttr => 1, RootName => 'response', XMLDecl => 1);
  61     exit 0;
  62 }
  63
  64 exit 0;
  65
  66 sub fetch_bib {
  67     my $query = shift;
  68     my $biblionumber = shift;
  69     my $biblio = Koha::Biblios->find( $biblionumber );
  70     my $record = $biblio->metadata->record({ embed_items => scalar $query->param('items') });
  71     if  (defined $record) {
  72         print $query->header(-type => 'text/xml',-charset => 'utf-8',);
  73         print $record->as_xml_record();
  74     } else {
  75         print $query->header(-type => 'text/xml', -status => '404 Not Found');
  76     }
  77 }
  78
  79 sub update_bib {
  80     my $query = shift;
  81     my $biblionumber = shift;
  82     my $biblio = Koha::Biblios->find( $biblionumber );
  83     my $old_record = $biblio->metadata->record;
  84     my $frameworkcode = $query->url_param('frameworkcode') // GetFrameworkCode($biblionumber);
  85     unless  (defined $old_record) {
  86         print $query->header(-type => 'text/xml', -status => '404 Not Found');
  87         return;
  88     }
  89
  90     my $result = {};
  91     my $inxml = $query->param('POSTDATA');
  92     print $query->header(-type => 'text/xml', -charset => 'utf-8');
  93
  94     my $record = eval {MARC::Record::new_from_xml( $inxml, "UTF-8", C4::Context->preference('marcflavour'))};
  95     my $do_not_escape = 0;
  96     if ($@) {
  97         $result->{'status'} = "failed";
  98         $result->{'error'} = $@;
  99     } else {
 100         my $fullrecord = $record->clone();
 101         my ( $itemtag, $itemsubfield ) =
 102           C4::Biblio::GetMarcFromKohaField( "items.itemnumber" );
 103
 104         # delete any item tags
 105         foreach my $field ( $record->field($itemtag) ) {
 106             $record->delete_field($field);
 107         }
 108
 109         if ( $query->url_param('items') ) {
 110             foreach my $field ( $fullrecord->field($itemtag) ) {
 111                 my $one_item_record = $record->clone();
 112                 $one_item_record->add_fields($field);
 113                 C4::Items::ModItemFromMarc( $one_item_record, $biblionumber,
 114                     $field->subfield($itemsubfield) );
 115             }
 116         }
 117
 118         C4::Biblio::ModBiblio( $record, $biblionumber, $frameworkcode );
 119         my $biblio = Koha::Biblios->find( $biblionumber );
 120         my $new_record = $biblio->metadata->record({ embed_items => scalar $query->url_param('items') });
 121
 122         $result->{'status'} = "ok";
 123         $result->{'biblionumber'} = $biblionumber;
 124         my $xml = $new_record->as_xml_record();
 125         $xml =~ s/<\?xml.*?\?>//i;
 126         $result->{'marcxml'} =  $xml;
 127         $do_not_escape = 1;
 128     }
 129
 130     print XMLout($result, NoAttr => 1, RootName => 'response', XMLDecl => 1, NoEscape => $do_not_escape);
 131 }
 132
 133 sub delete_bib {
 134     my $query = shift;
 135     my $biblionumber = shift;
 136     my $error = C4::Biblio::DelBiblio($biblionumber);
 137
 138     if (defined $error) {
 139         print $query->header(-type => 'text/xml', -status => '400 Bad request');
 140         print XMLout({ error => $error }, NoAttr => 1, RootName => 'response', XMLDecl => 1);
 141         exit 0;
 142     }
 143
 144     print $query->header(-type => 'text/xml');
 145     print XMLout({ status => 'OK, biblio deleted' }, NoAttr => 1, RootName => 'response', XMLDecl => 1);
 146 }