svc/holds

   1 #!/usr/bin/perl
   2
   3 # Copyright 2014 ByWater Solutions
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 3 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use Modern::Perl;
  21
  22 use CGI;
  23 use JSON qw(to_json);
  24
  25 use C4::Auth qw(check_cookie_auth);
  26 use C4::Biblio qw(GetMarcBiblio GetFrameworkCode GetRecordValue );
  27 use C4::Branch qw(GetBranchName GetBranchesLoop);
  28 use C4::Charset;
  29 use C4::Circulation qw(GetTransfers);
  30 use C4::Context;
  31
  32 use Koha::DateUtils;
  33 use Koha::Holds;
  34 use Koha::Libraries;
  35
  36 my $input = new CGI;
  37
  38 my ( $auth_status, $sessionID ) =
  39   check_cookie_auth( $input->cookie('CGISESSID'),
  40     { circulate => 'circulate_remaining_permissions' } );
  41
  42 if ( $auth_status ne "ok" ) {
  43     exit 0;
  44 }
  45
  46 my $branch = C4::Context->userenv->{'branch'};
  47
  48 my $schema = Koha::Database->new()->schema();
  49
  50 my @sort_columns =
  51   qw/reservedate title itemcallnumber barcode expirationdate priority/;
  52
  53 my $borrowernumber    = $input->param('borrowernumber');
  54 my $offset            = $input->param('iDisplayStart');
  55 my $results_per_page  = $input->param('iDisplayLength');
  56 my $sorting_direction = $input->param('sSortDir_0') || 'desc';
  57 my $sorting_column    = $sort_columns[ $input->param('iSortCol_0') ]
  58   || 'reservedate';
  59
  60 binmode STDOUT, ":encoding(UTF-8)";
  61 print $input->header( -type => 'text/plain', -charset => 'UTF-8' );
  62
  63 my $holds_rs = Koha::Holds->search(
  64     { borrowernumber => $borrowernumber },
  65     {
  66         order_by => { "-$sorting_direction" => $sorting_column }
  67     }
  68 );
  69
  70 my $borrower;
  71 my @holds;
  72 while ( my $h = $holds_rs->next() ) {
  73     my $item = $h->item();
  74
  75     my $biblionumber = $h->biblio()->biblionumber();
  76
  77     my $itemtype_limit;
  78     if ( $h->itemtype ) {
  79         my $itemtype = C4::Koha::getitemtypeinfo( $h->itemtype );
  80         $itemtype_limit = $itemtype->{translated_description};
  81     }
  82
  83     my $hold = {
  84         DT_RowId       => $h->reserve_id(),
  85         biblionumber   => $biblionumber,
  86         title          => $h->biblio()->title(),
  87         author         => $h->biblio()->author(),
  88         reserve_id     => $h->reserve_id(),
  89         branchcode     => $h->branch()->branchname(),
  90         branches       => GetBranchesLoop($h->branch()->branchcode()),
  91         reservedate    => $h->reservedate(),
  92         expirationdate => $h->expirationdate(),
  93         suspend        => $h->suspend(),
  94         suspend_until  => $h->suspend_until(),
  95         found          => $h->found(),
  96         waiting        => $h->is_waiting(),
  97         waiting_at     => $h->branch()->branchname(),
  98         waiting_here   => $h->branch()->branchcode() eq $branch,
  99         priority       => $h->priority(),
 100         itemtype_limit => $itemtype_limit,
 101         subtitle       => GetRecordValue(
 102             'subtitle', GetMarcBiblio($biblionumber),
 103             GetFrameworkCode($biblionumber)
 104         ),
 105         reservedate_formatted => $h->reservedate() ? output_pref(
 106             { dt => dt_from_string( $h->reservedate() ), dateonly => 1 }
 107           )
 108         : q{},
 109         suspend_until_formatted => $h->suspend_until() ? output_pref(
 110             { dt => dt_from_string( $h->suspend_until() ), dateonly => 1 }
 111           )
 112         : q{},
 113         expirationdate_formatted => $h->expirationdate() ? output_pref(
 114             { dt => dt_from_string( $h->expirationdate() ), dateonly => 1 }
 115           )
 116         : q{},
 117     };
 118
 119     if ( my $e = $h->waiting_expires_on() ) {
 120         $hold->{expirationdate} = $e->ymd();
 121         $hold->{expirationdate_formatted} = output_pref( { dt => $e, dateonly => 1 });
 122     }
 123
 124     $hold->{transfered}     = 0;
 125     $hold->{not_transfered} = 0;
 126
 127     if ($item) {
 128         $hold->{itemnumber}     = $item->itemnumber();
 129         $hold->{barcode}        = $item->barcode();
 130         $hold->{itemtype}       = $item->effective_itemtype();
 131         $hold->{itemcallnumber} = $item->itemcallnumber() || q{};
 132
 133         my ( $transferred_when, $transferred_from, $transferred_to ) =
 134           GetTransfers( $item->itemnumber() );
 135         if ($transferred_when) {
 136             $hold->{color}       = 'transferred';
 137             $hold->{transferred} = 1;
 138             $hold->{date_sent} = output_pref( dt_from_string($transferred_when) );
 139             $hold->{from_branch} = Koha::Libraries->find($transferred_from)->branchname;
 140         }
 141         elsif ( $item->holding_branch() && $item->holding_branch()->branchcode() ne
 142             $h->branch()->branchcode() )
 143         {
 144             $hold->{not_transferred}    = 1;
 145             $hold->{not_transferred_by} = $h->item()->holding_branch()->branchname();
 146         }
 147     }
 148
 149     push( @holds, $hold );
 150 }
 151
 152 my $data;
 153 $data->{'iTotalRecords'}        = scalar @holds;
 154 $data->{'iTotalDisplayRecords'} = scalar @holds;
 155 $data->{'sEcho'}                = $input->param('sEcho') || undef;
 156 $data->{'aaData'}               = \@holds;
 157
 158 print to_json($data);