t/db_dependent/Acquisition.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use POSIX qw(strftime);
  21
  22 use Test::More tests => 79;
  23 use t::lib::Mocks;
  24 use Koha::Database;
  25 use Koha::DateUtils qw(dt_from_string output_pref);
  26 use Koha::Acquisition::Basket;
  27
  28 use MARC::File::XML ( BinaryEncoding => 'utf8', RecordFormat => 'MARC21' );
  29
  30 BEGIN {
  31     use_ok('C4::Acquisition');
  32     use_ok('C4::Biblio');
  33     use_ok('C4::Budgets');
  34     use_ok('Koha::Acquisition::Orders');
  35     use_ok('Koha::Acquisition::Booksellers');
  36     use_ok('t::lib::TestBuilder');
  37 }
  38
  39 # Sub used for testing C4::Acquisition subs returning order(s):
  40 #    GetOrdersByStatus, GetOrders, GetDeletedOrders, GetOrder etc.
  41 # (\@test_missing_fields,\@test_extra_fields,\@test_different_fields,$test_nbr_fields) =
  42 #  _check_fields_of_order ($exp_fields, $original_order_content, $order_to_check);
  43 # params :
  44 # $exp_fields             : arrayref whose elements are the keys we expect to find
  45 # $original_order_content : hashref whose 2 keys str and num contains hashrefs
  46 #                           containing content fields of the order created with Koha::Acquisition::Order
  47 # $order_to_check         : hashref whose keys/values are the content of an order
  48 #                           returned by the C4::Acquisition sub we are testing
  49 # returns :
  50 # \@test_missing_fields   : arrayref void if ok ; otherwise contains the list of
  51 #                           fields missing in $order_to_check
  52 # \@test_extra_fields     : arrayref void if ok ; otherwise contains the list of
  53 #                           fields unexpected in $order_to_check
  54 # \@test_different_fields : arrayref void if ok ; otherwise contains the list of
  55 #                           fields which value is not the same in between $order_to_check and
  56 # $test_nbr_fields        : contains the number of fields of $order_to_check
  57
  58 sub _check_fields_of_order {
  59     my ( $exp_fields, $original_order_content, $order_to_check ) = @_;
  60     my @test_missing_fields   = ();
  61     my @test_extra_fields     = ();
  62     my @test_different_fields = ();
  63     my $test_nbr_fields       = scalar( keys %$order_to_check );
  64     foreach my $field (@$exp_fields) {
  65         push @test_missing_fields, $field
  66           unless exists( $order_to_check->{$field} );
  67     }
  68     foreach my $field ( keys %$order_to_check ) {
  69         push @test_extra_fields, $field
  70           unless grep ( /^$field$/, @$exp_fields );
  71     }
  72     foreach my $field ( keys %{ $original_order_content->{str} } ) {
  73         push @test_different_fields, $field
  74           unless ( !exists $order_to_check->{$field} )
  75           or ( $original_order_content->{str}->{$field} eq
  76             $order_to_check->{$field} );
  77     }
  78     foreach my $field ( keys %{ $original_order_content->{num} } ) {
  79         push @test_different_fields, $field
  80           unless ( !exists $order_to_check->{$field} )
  81           or ( $original_order_content->{num}->{$field} ==
  82             $order_to_check->{$field} );
  83     }
  84     return (
  85         \@test_missing_fields,   \@test_extra_fields,
  86         \@test_different_fields, $test_nbr_fields
  87     );
  88 }
  89
  90 # Sub used for testing C4::Acquisition subs returning several orders
  91 # (\@test_missing_fields,\@test_extra_fields,\@test_different_fields,\@test_nbr_fields) =
  92 #   _check_fields_of_orders ($exp_fields, $original_orders_content, $orders_to_check)
  93 sub _check_fields_of_orders {
  94     my ( $exp_fields, $original_orders_content, $orders_to_check ) = @_;
  95     my @test_missing_fields   = ();
  96     my @test_extra_fields     = ();
  97     my @test_different_fields = ();
  98     my @test_nbr_fields       = ();
  99     foreach my $order_to_check (@$orders_to_check) {
 100         my $original_order_content =
 101           ( grep { $_->{str}->{ordernumber} eq $order_to_check->{ordernumber} }
 102               @$original_orders_content )[0];
 103         my (
 104             $t_missing_fields,   $t_extra_fields,
 105             $t_different_fields, $t_nbr_fields
 106           )
 107           = _check_fields_of_order( $exp_fields, $original_order_content,
 108             $order_to_check );
 109         push @test_missing_fields,   @$t_missing_fields;
 110         push @test_extra_fields,     @$t_extra_fields;
 111         push @test_different_fields, @$t_different_fields;
 112         push @test_nbr_fields,       $t_nbr_fields;
 113     }
 114     @test_missing_fields = keys %{ { map { $_ => 1 } @test_missing_fields } };
 115     @test_extra_fields   = keys %{ { map { $_ => 1 } @test_extra_fields } };
 116     @test_different_fields =
 117       keys %{ { map { $_ => 1 } @test_different_fields } };
 118     return (
 119         \@test_missing_fields,   \@test_extra_fields,
 120         \@test_different_fields, \@test_nbr_fields
 121     );
 122 }
 123
 124
 125 my $schema = Koha::Database->new()->schema();
 126 $schema->storage->txn_begin();
 127
 128 # Creating some orders
 129 my $bookseller = Koha::Acquisition::Bookseller->new(
 130     {
 131         name         => "my vendor",
 132         address1     => "bookseller's address",
 133         phone        => "0123456",
 134         active       => 1,
 135         deliverytime => 5,
 136     }
 137 )->store;
 138 my $booksellerid = $bookseller->id;
 139
 140 my $booksellerinfo = Koha::Acquisition::Booksellers->find( $booksellerid );
 141 is( $booksellerinfo->deliverytime,
 142     5, 'set deliverytime when creating vendor (Bug 10556)' );
 143
 144 my ( $basket, $basketno );
 145 ok(
 146     $basketno = NewBasket( $booksellerid, 1 ),
 147     "NewBasket(  $booksellerid , 1  ) returns $basketno"
 148 );
 149 ok( $basket = GetBasket($basketno), "GetBasket($basketno) returns $basket" );
 150
 151 my $bpid=AddBudgetPeriod({
 152         budget_period_startdate => '2008-01-01'
 153         , budget_period_enddate => '2008-12-31'
 154         , budget_period_active  => 1
 155         , budget_period_description    => "MAPERI"
 156 });
 157
 158 my $budgetid = C4::Budgets::AddBudget(
 159     {
 160         budget_code => "budget_code_test_1",
 161         budget_name => "budget_name_test_1",
 162         budget_period_id => $bpid,
 163     }
 164 );
 165 my $budget = C4::Budgets::GetBudget($budgetid);
 166
 167 my @ordernumbers;
 168 my ( $biblionumber1, $biblioitemnumber1 ) = AddBiblio( MARC::Record->new, '' );
 169 my ( $biblionumber2, $biblioitemnumber2 ) = AddBiblio( MARC::Record->new, '' );
 170 my ( $biblionumber3, $biblioitemnumber3 ) = AddBiblio( MARC::Record->new, '' );
 171 my ( $biblionumber4, $biblioitemnumber4 ) = AddBiblio( MARC::Record->new, '' );
 172 my ( $biblionumber5, $biblioitemnumber5 ) = AddBiblio( MARC::Record->new, '' );
 173
 174
 175
 176 # Prepare 5 orders, and make distinction beween fields to be tested with eq and with ==
 177 # Ex : a price of 50.1 will be stored internally as 5.100000
 178
 179 my @order_content = (
 180     {
 181         str => {
 182             basketno       => $basketno,
 183             biblionumber   => $biblionumber1,
 184             budget_id      => $budget->{budget_id},
 185             uncertainprice => 0,
 186             order_internalnote => "internal note",
 187             order_vendornote   => "vendor note",
 188             ordernumber => '',
 189         },
 190         num => {
 191             quantity  => 24,
 192             listprice => 50.121111,
 193             ecost     => 38.15,
 194             rrp       => 40.15,
 195             discount  => 5.1111,
 196         }
 197     },
 198     {
 199         str => {
 200             basketno     => $basketno,
 201             biblionumber => $biblionumber2,
 202             budget_id    => $budget->{budget_id}
 203         },
 204         num => { quantity => 42 }
 205     },
 206     {
 207         str => {
 208             basketno       => $basketno,
 209             biblionumber   => $biblionumber2,
 210             budget_id      => $budget->{budget_id},
 211             uncertainprice => 0,
 212             order_internalnote => "internal note",
 213             order_vendornote   => "vendor note"
 214         },
 215         num => {
 216             quantity  => 4,
 217             ecost     => 42.1,
 218             rrp       => 42.1,
 219             listprice => 10.1,
 220             ecost     => 38.1,
 221             rrp       => 11.0,
 222             discount  => 5.1,
 223         }
 224     },
 225     {
 226         str => {
 227             basketno     => $basketno,
 228             biblionumber => $biblionumber3,
 229             budget_id    => $budget->{budget_id},
 230             order_internalnote => "internal note",
 231             order_vendornote   => "vendor note"
 232         },
 233         num => {
 234             quantity       => 4,
 235             ecost          => 40,
 236             rrp            => 42,
 237             listprice      => 10,
 238             ecost          => 38.15,
 239             rrp            => 11.00,
 240             discount       => 0,
 241             uncertainprice => 0,
 242         }
 243     },
 244     {
 245         str => {
 246             basketno     => $basketno,
 247             biblionumber => $biblionumber4,
 248             budget_id    => $budget->{budget_id},
 249             order_internalnote => "internal note",
 250             order_vendornote   => "vendor note"
 251         },
 252         num => {
 253             quantity       => 1,
 254             ecost          => 10,
 255             rrp            => 10,
 256             listprice      => 10,
 257             ecost          => 10,
 258             rrp            => 10,
 259             discount       => 0,
 260             uncertainprice => 0,
 261         }
 262     },
 263     {
 264         str => {
 265             basketno     => $basketno,
 266             biblionumber => $biblionumber5,
 267             budget_id    => $budget->{budget_id},
 268             order_internalnote => "internal note",
 269             order_vendornote   => "vendor note"
 270         },
 271         num => {
 272             quantity       => 1,
 273             ecost          => 10,
 274             rrp            => 10,
 275             listprice      => 10,
 276             ecost          => 10,
 277             rrp            => 10,
 278             discount       => 0,
 279             uncertainprice => 0,
 280         }
 281     }
 282 );
 283
 284 # Create 5 orders in database
 285 for ( 0 .. 5 ) {
 286     my %ocontent;
 287     @ocontent{ keys %{ $order_content[$_]->{num} } } =
 288       values %{ $order_content[$_]->{num} };
 289     @ocontent{ keys %{ $order_content[$_]->{str} } } =
 290       values %{ $order_content[$_]->{str} };
 291     $ordernumbers[$_] = Koha::Acquisition::Order->new( \%ocontent )->store->ordernumber;
 292     $order_content[$_]->{str}->{ordernumber} = $ordernumbers[$_];
 293 }
 294
 295 DelOrder( $order_content[3]->{str}->{biblionumber}, $ordernumbers[3] );
 296
 297 my $invoiceid = AddInvoice(
 298     invoicenumber => 'invoice',
 299     booksellerid  => $booksellerid,
 300     unknown       => "unknown"
 301 );
 302
 303 my $invoice = GetInvoice( $invoiceid );
 304
 305 my $reception_date = output_pref(
 306     {
 307             dt => dt_from_string->add( days => 1 ),
 308             dateformat => 'iso',
 309             dateonly => 1,
 310     }
 311 );
 312 my ($datereceived, $new_ordernumber) = ModReceiveOrder(
 313     {
 314         biblionumber      => $biblionumber4,
 315         order             => Koha::Acquisition::Orders->find( $ordernumbers[4] )->unblessed,
 316         quantityreceived  => 1,
 317         invoice           => $invoice,
 318         budget_id         => $order_content[4]->{str}->{budget_id},
 319         datereceived      => $reception_date,
 320     }
 321 );
 322
 323 is(
 324     output_pref(
 325         {
 326             dt         => dt_from_string($datereceived),
 327             dateformat => 'iso',
 328             dateonly   => 1
 329         }
 330     ),
 331     $reception_date,
 332     'ModReceiveOrder sets the passed date'
 333 );
 334
 335 my $search_orders = SearchOrders({
 336     booksellerid => $booksellerid,
 337     basketno     => $basketno
 338 });
 339 isa_ok( $search_orders, 'ARRAY' );
 340 ok(
 341     (
 342         ( scalar @$search_orders == 5 )
 343           and !grep ( $_->{ordernumber} eq $ordernumbers[3], @$search_orders )
 344     ),
 345     "SearchOrders only gets non-cancelled orders"
 346 );
 347
 348 $search_orders = SearchOrders({
 349     booksellerid => $booksellerid,
 350     basketno     => $basketno,
 351     pending      => 1
 352 });
 353 ok(
 354     (
 355         ( scalar @$search_orders == 4 ) and !grep ( (
 356                      ( $_->{ordernumber} eq $ordernumbers[3] )
 357                   or ( $_->{ordernumber} eq $ordernumbers[4] )
 358             ),
 359             @$search_orders )
 360     ),
 361     "SearchOrders with pending params gets only pending orders (bug 10723)"
 362 );
 363
 364 $search_orders = SearchOrders({
 365     booksellerid => $booksellerid,
 366     basketno     => $basketno,
 367     pending      => 1,
 368     ordered      => 1,
 369 });
 370 is( scalar (@$search_orders), 0, "SearchOrders with pending and ordered params gets only pending ordered orders (bug 11170)" );
 371
 372 $search_orders = SearchOrders({
 373     ordernumber => $ordernumbers[4]
 374 });
 375 is( scalar (@$search_orders), 1, "SearchOrders takes into account the ordernumber filter" );
 376
 377 $search_orders = SearchOrders({
 378     biblionumber => $biblionumber4
 379 });
 380 is( scalar (@$search_orders), 1, "SearchOrders takes into account the biblionumber filter" );
 381
 382 $search_orders = SearchOrders({
 383     biblionumber => $biblionumber4,
 384     pending      => 1
 385 });
 386 is( scalar (@$search_orders), 0, "SearchOrders takes into account the biblionumber and pending filters" );
 387
 388 #
 389 # Test GetBudgetByOrderNumber
 390 #
 391 ok( GetBudgetByOrderNumber( $ordernumbers[0] )->{'budget_id'} eq $budgetid,
 392     "GetBudgetByOrderNumber returns expected budget" );
 393
 394 my @lateorders = GetLateOrders(0);
 395 is( scalar grep ( $_->{basketno} eq $basketno, @lateorders ),
 396     0, "GetLateOrders does not get orders from opened baskets" );
 397 C4::Acquisition::CloseBasket($basketno);
 398 @lateorders = GetLateOrders(0);
 399 isnt( scalar grep ( $_->{basketno} eq $basketno, @lateorders ),
 400     0, "GetLateOrders gets orders from closed baskets" );
 401 ok( !grep ( $_->{ordernumber} eq $ordernumbers[3], @lateorders ),
 402     "GetLateOrders does not get cancelled orders" );
 403 ok( !grep ( $_->{ordernumber} eq $ordernumbers[4], @lateorders ),
 404     "GetLateOrders does not get received orders" );
 405
 406 $search_orders = SearchOrders({
 407     booksellerid => $booksellerid,
 408     basketno     => $basketno,
 409     pending      => 1,
 410     ordered      => 1,
 411 });
 412 is( scalar (@$search_orders), 4, "SearchOrders with pending and ordered params gets only pending ordered orders. After closing the basket, orders are marked as 'ordered' (bug 11170)" );
 413
 414 #
 415 # Test AddClaim
 416 #
 417
 418 my $order = $lateorders[0];
 419 AddClaim( $order->{ordernumber} );
 420 my $neworder = GetOrder( $order->{ordernumber} );
 421 is(
 422     $neworder->{claimed_date},
 423     strftime( "%Y-%m-%d", localtime(time) ),
 424     "AddClaim : Check claimed_date"
 425 );
 426
 427 my $order2 = Koha::Acquisition::Orders->find( $ordernumbers[1] )->unblessed;
 428 $order2->{order_internalnote} = "my notes";
 429 ( $datereceived, $new_ordernumber ) = ModReceiveOrder(
 430     {
 431         biblionumber     => $biblionumber2,
 432         order            => $order2,
 433         quantityreceived => 2,
 434         invoice          => $invoice,
 435     }
 436 );
 437 $order2 = GetOrder( $ordernumbers[1] );
 438 is( $order2->{'quantityreceived'},
 439     0, 'Splitting up order did not receive any on original order' );
 440 is( $order2->{'quantity'}, 40, '40 items on original order' );
 441 is( $order2->{'budget_id'}, $budgetid,
 442     'Budget on original order is unchanged' );
 443 is( $order2->{order_internalnote}, "my notes",
 444     'ModReceiveOrder and GetOrder deal with internal notes' );
 445 my $order1 = GetOrder( $ordernumbers[0] );
 446 is(
 447     $order1->{order_internalnote},
 448     "internal note",
 449     "ModReceiveOrder only changes the supplied orders internal notes"
 450 );
 451
 452 $neworder = GetOrder($new_ordernumber);
 453 is( $neworder->{'quantity'}, 2, '2 items on new order' );
 454 is( $neworder->{'quantityreceived'},
 455     2, 'Splitting up order received items on new order' );
 456 is( $neworder->{'budget_id'}, $budgetid, 'Budget on new order is unchanged' );
 457
 458 is( $neworder->{ordernumber}, $new_ordernumber, 'Split: test ordernumber' );
 459 is( $neworder->{parent_ordernumber}, $ordernumbers[1], 'Split: test parent_ordernumber' );
 460
 461 my $orders = GetHistory( ordernumber => $ordernumbers[1] );
 462 is( scalar( @$orders ), 1, 'GetHistory with a given ordernumber returns 1 order' );
 463 $orders = GetHistory( ordernumber => $ordernumbers[1], search_children_too => 1 );
 464 is( scalar( @$orders ), 2, 'GetHistory with a given ordernumber and search_children_too set returns 2 orders' );
 465 $orders = GetHistory( ordernumbers => [$ordernumbers[1]] );
 466 is( scalar( @$orders ), 1, 'GetHistory with a given ordernumbers returns 1 order' );
 467 $orders = GetHistory( ordernumbers => \@ordernumbers );
 468 is( scalar( @$orders ), scalar( @ordernumbers ) - 1, 'GetHistory with a list of ordernumbers returns N-1 orders (was has been deleted [3])' );
 469
 470
 471 # Test GetHistory() with and without SearchWithISBNVariations
 472 # The ISBN passed as a param is the ISBN-10 version of the 13-digit ISBN in the sample record declared in $marcxml
 473
 474 my $budgetid2 = C4::Budgets::AddBudget(
 475     {
 476         budget_code => "budget_code_test_modrecv",
 477         budget_name => "budget_name_test_modrecv",
 478     }
 479 );
 480
 481 my $order3 = Koha::Acquisition::Orders->find( $ordernumbers[2] )->unblessed;
 482 $order3->{order_internalnote} = "my other notes";
 483 ( $datereceived, $new_ordernumber ) = ModReceiveOrder(
 484     {
 485         biblionumber     => $biblionumber2,
 486         order            => $order3,
 487         quantityreceived => 2,
 488         invoice          => $invoice,
 489         budget_id        => $budgetid2,
 490     }
 491 );
 492
 493 $order3 = GetOrder( $ordernumbers[2] );
 494 is( $order3->{'quantityreceived'},
 495     0, 'Splitting up order did not receive any on original order' );
 496 is( $order3->{'quantity'}, 2, '2 items on original order' );
 497 is( $order3->{'budget_id'}, $budgetid,
 498     'Budget on original order is unchanged' );
 499 is( $order3->{order_internalnote}, "my other notes",
 500     'ModReceiveOrder and GetOrder deal with notes' );
 501
 502 $neworder = GetOrder($new_ordernumber);
 503 is( $neworder->{'quantity'}, 2, '2 items on new order' );
 504 is( $neworder->{'quantityreceived'},
 505     2, 'Splitting up order received items on new order' );
 506 is( $neworder->{'budget_id'}, $budgetid2, 'Budget on new order is changed' );
 507
 508 $order3 = Koha::Acquisition::Orders->find( $ordernumbers[2] )->unblessed;
 509 $order3->{order_internalnote} = "my third notes";
 510 ( $datereceived, $new_ordernumber ) = ModReceiveOrder(
 511     {
 512         biblionumber     => $biblionumber2,
 513         order            => $order3,
 514         quantityreceived => 2,
 515         invoice          => $invoice,
 516         budget_id        => $budgetid2,
 517     }
 518 );
 519
 520 $order3 = GetOrder( $ordernumbers[2] );
 521 is( $order3->{'quantityreceived'}, 2,          'Order not split up' );
 522 is( $order3->{'quantity'},         2,          '2 items on order' );
 523 is( $order3->{'budget_id'},        $budgetid2, 'Budget has changed' );
 524 is( $order3->{order_internalnote}, "my third notes", 'ModReceiveOrder and GetOrder deal with notes' );
 525
 526 my $nonexistent_order = GetOrder();
 527 is( $nonexistent_order, undef, 'GetOrder returns undef if no ordernumber is given' );
 528 $nonexistent_order = GetOrder( 424242424242 );
 529 is( $nonexistent_order, undef, 'GetOrder returns undef if a nonexistent ordernumber is given' );
 530
 531 # Tests for DelOrder
 532 $order1 = GetOrder($ordernumbers[0]);
 533 my $error = DelOrder($order1->{biblionumber}, $order1->{ordernumber});
 534 ok((not defined $error), "DelOrder does not fail");
 535 $order1 = GetOrder($order1->{ordernumber});
 536 ok((defined $order1->{datecancellationprinted}), "order is cancelled");
 537 ok((not defined $order1->{cancellationreason}), "order has no cancellation reason");
 538 ok((defined Koha::Biblios->find( $order1->{biblionumber} )), "biblio still exists");
 539
 540 $order2 = GetOrder($ordernumbers[1]);
 541 $error = DelOrder($order2->{biblionumber}, $order2->{ordernumber}, 1);
 542 ok((not defined $error), "DelOrder does not fail");
 543 $order2 = GetOrder($order2->{ordernumber});
 544 ok((defined $order2->{datecancellationprinted}), "order is cancelled");
 545 ok((not defined $order2->{cancellationreason}), "order has no cancellation reason");
 546 ok((not defined Koha::Biblios->find( $order2->{biblionumber} )), "biblio does not exist anymore");
 547
 548 my $order4 = GetOrder($ordernumbers[3]);
 549 $error = DelOrder($order4->{biblionumber}, $order4->{ordernumber}, 1, "foobar");
 550 ok((not defined $error), "DelOrder does not fail");
 551 $order4 = GetOrder($order4->{ordernumber});
 552 ok((defined $order4->{datecancellationprinted}), "order is cancelled");
 553 ok(($order4->{cancellationreason} eq "foobar"), "order has cancellation reason \"foobar\"");
 554 ok((not defined Koha::Biblios->find( $order4->{biblionumber} )), "biblio does not exist anymore");
 555
 556 my $order5 = GetOrder($ordernumbers[4]);
 557 Koha::Item->new({ barcode => '0102030405', biblionumber => $order5->{biblionumber} })->store;
 558 $error = DelOrder($order5->{biblionumber}, $order5->{ordernumber}, 1);
 559 $order5 = GetOrder($order5->{ordernumber});
 560 ok((defined $order5->{datecancellationprinted}), "order is cancelled");
 561 ok((defined Koha::Biblios->find( $order5->{biblionumber} )), "biblio still exists");
 562
 563 # End of tests for DelOrder
 564
 565 subtest 'ModOrder' => sub {
 566     plan tests => 1;
 567     ModOrder( { ordernumber => $order1->{ordernumber}, unitprice => 42 } );
 568     my $order = GetOrder( $order1->{ordernumber} );
 569     is( int($order->{unitprice}), 42, 'ModOrder should work even if biblionumber if not passed');
 570 };
 571
 572 # Budget reports
 573 my $all_count = scalar GetBudgetsReport();
 574 ok($all_count >= 1, "GetBudgetReport OK");
 575
 576 my $active_count = scalar GetBudgetsReport(1);
 577 ok($active_count >= 1 , "GetBudgetsReport(1) OK");
 578
 579 is($all_count, scalar GetBudgetsReport(), "GetBudgetReport returns inactive budget period acquisitions.");
 580 ok($active_count >= scalar GetBudgetsReport(1), "GetBudgetReport doesn't return inactive budget period acquisitions.");
 581
 582 # "Flavoured" tests (tests that required a run for each marc flavour)
 583 # Tests should be added to the run_flavoured_tests sub below
 584 my $biblio_module = new Test::MockModule('C4::Biblio');
 585 $biblio_module->mock(
 586     'GetMarcSubfieldStructure',
 587     sub {
 588         my ($self) = shift;
 589
 590         my ( $title_field,            $title_subfield )            = get_title_field();
 591         my ( $isbn_field,             $isbn_subfield )             = get_isbn_field();
 592         my ( $issn_field,             $issn_subfield )             = get_issn_field();
 593         my ( $biblionumber_field,     $biblionumber_subfield )     = ( '999', 'c' );
 594         my ( $biblioitemnumber_field, $biblioitemnumber_subfield ) = ( '999', '9' );
 595         my ( $itemnumber_field,       $itemnumber_subfield )       = get_itemnumber_field();
 596
 597         return {
 598             'biblio.title'                 => [ { tagfield => $title_field,            tagsubfield => $title_subfield } ],
 599             'biblio.biblionumber'          => [ { tagfield => $biblionumber_field,     tagsubfield => $biblionumber_subfield } ],
 600             'biblioitems.isbn'             => [ { tagfield => $isbn_field,             tagsubfield => $isbn_subfield } ],
 601             'biblioitems.issn'             => [ { tagfield => $issn_field,             tagsubfield => $issn_subfield } ],
 602             'biblioitems.biblioitemnumber' => [ { tagfield => $biblioitemnumber_field, tagsubfield => $biblioitemnumber_subfield } ],
 603             'items.itemnumber'             => [ { tagfield => $itemnumber_subfield,    tagsubfield => $itemnumber_subfield } ],
 604         };
 605       }
 606 );
 607
 608 sub run_flavoured_tests {
 609     my $marcflavour = shift;
 610     t::lib::Mocks::mock_preference('marcflavour', $marcflavour);
 611
 612     #
 613     # Test SearchWithISBNVariations syspref
 614     #
 615     my $marc_record = MARC::Record->new;
 616     $marc_record->append_fields( create_isbn_field( '9780136019701', $marcflavour ) );
 617     my ( $biblionumber6, $biblioitemnumber6 ) = AddBiblio( $marc_record, '' );
 618
 619     # Create order
 620     my $ordernumber = Koha::Acquisition::Order->new( {
 621             basketno     => $basketno,
 622             biblionumber => $biblionumber6,
 623             budget_id    => $budget->{budget_id},
 624             order_internalnote => "internal note",
 625             order_vendornote   => "vendor note",
 626             quantity       => 1,
 627             ecost          => 10,
 628             rrp            => 10,
 629             listprice      => 10,
 630             ecost          => 10,
 631             rrp            => 10,
 632             discount       => 0,
 633             uncertainprice => 0,
 634     } )->store->ordernumber;
 635
 636     t::lib::Mocks::mock_preference('SearchWithISBNVariations', 0);
 637     $orders = GetHistory( isbn => '0136019706' );
 638     is( scalar(@$orders), 0, "GetHistory searches correctly by ISBN" );
 639
 640     t::lib::Mocks::mock_preference('SearchWithISBNVariations', 1);
 641     $orders = GetHistory( isbn => '0136019706' );
 642     is( scalar(@$orders), 1, "GetHistory searches correctly by ISBN" );
 643
 644     my $order = GetOrder($ordernumber);
 645     DelOrder($order->{biblionumber}, $order->{ordernumber}, 1);
 646 }
 647
 648 # Do "flavoured" tests
 649 subtest 'MARC21' => sub {
 650     plan tests => 2;
 651     run_flavoured_tests('MARC21');
 652 };
 653
 654 subtest 'UNIMARC' => sub {
 655     plan tests => 2;
 656     run_flavoured_tests('UNIMARC');
 657 };
 658
 659 subtest 'NORMARC' => sub {
 660     plan tests => 2;
 661     run_flavoured_tests('NORMARC');
 662 };
 663
 664 ### Functions required for "flavoured" tests
 665 sub get_title_field {
 666     my $marc_flavour = C4::Context->preference('marcflavour');
 667     return ( $marc_flavour eq 'UNIMARC' ) ? ( '200', 'a' ) : ( '245', 'a' );
 668 }
 669
 670 sub get_isbn_field {
 671     my $marc_flavour = C4::Context->preference('marcflavour');
 672     return ( $marc_flavour eq 'UNIMARC' ) ? ( '010', 'a' ) : ( '020', 'a' );
 673 }
 674
 675 sub get_issn_field {
 676     my $marc_flavour = C4::Context->preference('marcflavour');
 677     return ( $marc_flavour eq 'UNIMARC' ) ? ( '011', 'a' ) : ( '022', 'a' );
 678 }
 679
 680 sub get_itemnumber_field {
 681     my $marc_flavour = C4::Context->preference('marcflavour');
 682     return ( $marc_flavour eq 'UNIMARC' ) ? ( '995', '9' ) : ( '952', '9' );
 683 }
 684
 685 sub create_isbn_field {
 686     my ( $isbn, $marcflavour ) = @_;
 687
 688     my ( $isbn_field, $isbn_subfield ) = get_isbn_field();
 689     my $field = MARC::Field->new( $isbn_field, '', '', $isbn_subfield => $isbn );
 690
 691     # Add the price subfield
 692     my $price_subfield = ( $marcflavour eq 'UNIMARC' ) ? 'd' : 'c';
 693     $field->add_subfields( $price_subfield => '$100' );
 694
 695     return $field;
 696 }
 697
 698 subtest 'ModReceiveOrder replacementprice tests' => sub {
 699     plan tests => 2;
 700     #Let's build an order, we need a couple things though
 701     my $builder = t::lib::TestBuilder->new;
 702     my $order_biblio = $builder->build({ source => 'Biblio' });
 703     my $order_basket = $builder->build({ source => 'Aqbasket', value => { is_standing => 0 } });
 704     my $order_invoice = $builder->build({ source => 'Aqinvoice'});
 705     my $order_currency = $builder->build({ source => 'Currency', value => { active => 1, archived => 0, symbol => 'F', rate => 2, isocode => undef, currency => 'FOO' }  });
 706     my $order_vendor = $builder->build({ source => 'Aqbookseller',value => { listincgst => 0, listprice => $order_currency->{currency}, invoiceprice => $order_currency->{currency} } });
 707     my $orderinfo ={
 708         basketno => $order_basket->{basketno},
 709         booksellerid => $order_vendor->{id},
 710         rrp => 19.99,
 711         replacementprice => undef,
 712         quantity => 1,
 713         quantityreceived => 0,
 714         datereceived => undef,
 715         datecancellationprinted => undef,
 716     };
 717     my $receive_order = $builder->build({ source => 'Aqorder', value => $orderinfo });
 718     (undef, my $received_ordernumber) = ModReceiveOrder({
 719             biblionumber => $order_biblio->{biblionumber},
 720             order        => $receive_order,
 721             invoice      => $order_invoice,
 722             quantityreceived => $receive_order->{quantity},
 723             budget_id    => $order->{budget_id},
 724     });
 725     my $received_order = GetOrder($received_ordernumber);
 726     is ($received_order->{replacementprice},undef,"No price set if none passed in");
 727     $orderinfo->{replacementprice} = 16.12;
 728     $receive_order = $builder->build({ source => 'Aqorder', value => $orderinfo });
 729     (undef, $received_ordernumber) = ModReceiveOrder({
 730             biblionumber => $order_biblio->{biblionumber},
 731             order        => $receive_order,
 732             invoice      => $order_invoice,
 733             quantityreceived => $receive_order->{quantity},
 734             budget_id    => $order->{budget_id},
 735     });
 736     $received_order = GetOrder($received_ordernumber);
 737     is ($received_order->{replacementprice},'16.120000',"Replacement price set if none passed in");
 738 };
 739
 740 subtest 'ModReceiveOrder and subscription' => sub {
 741     plan tests => 2;
 742
 743     my $builder     = t::lib::TestBuilder->new;
 744     my $first_note  = 'first note';
 745     my $second_note = 'second note';
 746     my $subscription = $builder->build_object( { class => 'Koha::Subscriptions' } );
 747     my $order = $builder->build_object(
 748         {
 749             class => 'Koha::Acquisition::Orders',
 750             value => {
 751                 subscriptionid     => $subscription->subscriptionid,
 752                 order_internalnote => $first_note,
 753                 quantity           => 5,
 754                 quantityreceived   => 0,
 755                 ecost_tax_excluded => 42,
 756                 unitprice_tax_excluded => 42,
 757             }
 758         }
 759     );
 760     my $order_info = $order->unblessed;
 761     # We do not want the note from the original note to be modified
 762     # Keeping it will permit to display it for future receptions
 763     $order_info->{order_internalnote} = $second_note;
 764     my ( undef, $received_ordernumber ) = ModReceiveOrder(
 765         {
 766             biblionumber     => $order->biblionumber,
 767             order            => $order_info,
 768             invoice          => $order->{invoiceid},
 769             quantityreceived => 1,
 770             budget_id        => $order->budget_id,
 771         }
 772     );
 773     my $received_order = Koha::Acquisition::Orders->find($received_ordernumber);
 774     is( $received_order->order_internalnote,
 775         $second_note, "No price set if none passed in" );
 776
 777     $order->get_from_storage;
 778     is( $order->get_from_storage->order_internalnote, $first_note );
 779 };
 780
 781 subtest 'GetHistory with additional fields' => sub {
 782     plan tests => 3;
 783     my $builder = t::lib::TestBuilder->new;
 784     my $order_basket = $builder->build({ source => 'Aqbasket', value => { is_standing => 0 } });
 785     my $orderinfo ={
 786         basketno => $order_basket->{basketno},
 787         rrp => 19.99,
 788         replacementprice => undef,
 789         quantity => 1,
 790         quantityreceived => 0,
 791         datereceived => undef,
 792         datecancellationprinted => undef,
 793     };
 794     my $order =        $builder->build({ source => 'Aqorder', value => $orderinfo });
 795     my $history = GetHistory(ordernumber => $order->{ordernumber});
 796     is( scalar( @$history ), 1, 'GetHistory returns the one order');
 797
 798     my $additional_field = $builder->build({source => 'AdditionalField', value => {
 799             tablename => 'aqbasket',
 800             name => 'snakeoil',
 801             authorised_value_category => "",
 802         }
 803     });
 804     $history = GetHistory( ordernumber => $order->{ordernumber}, additional_fields => [{ id => $additional_field->{id}, value=>'delicious'}]);
 805     is( scalar ( @$history ), 0, 'GetHistory returns no order for an unused additional field');
 806     my $basket = Koha::Acquisition::Baskets->find({ basketno => $order_basket->{basketno} });
 807     $basket->set_additional_fields([{
 808         id => $additional_field->{id},
 809         value => 'delicious',
 810     }]);
 811
 812     $history = GetHistory( ordernumber => $order->{ordernumber}, additional_fields => [{ id => $additional_field->{id}, value=>'delicious'}]);
 813     is( scalar( @$history ), 1, 'GetHistory returns the order when additional field is set');
 814 };
 815
 816 subtest 'Tests for get_rounding_sql' => sub {
 817
 818     plan tests => 2;
 819
 820     my $value = '3.141592';
 821
 822     t::lib::Mocks::mock_preference( 'OrderPriceRounding', q{} );
 823     my $no_rounding_result = C4::Acquisition::get_rounding_sql($value);
 824     t::lib::Mocks::mock_preference( 'OrderPriceRounding', q{nearest_cent} );
 825     my $rounding_result = C4::Acquisition::get_rounding_sql($value);
 826
 827     ok( $no_rounding_result eq $value, "Value ($value) not to be rounded" );
 828     ok( $rounding_result =~ /CAST/,    "Value ($value) will be rounded" );
 829
 830 };
 831
 832 subtest 'Test for get_rounded_price' => sub {
 833
 834     plan tests => 6;
 835
 836     my $exact_price      = 3.14;
 837     my $up_price         = 3.145592;
 838     my $down_price       = 3.141592;
 839     my $round_up_price   = sprintf( '%0.2f', $up_price );
 840     my $round_down_price = sprintf( '%0.2f', $down_price );
 841
 842     t::lib::Mocks::mock_preference( 'OrderPriceRounding', q{} );
 843     my $not_rounded_result1 = C4::Acquisition::get_rounded_price($exact_price);
 844     my $not_rounded_result2 = C4::Acquisition::get_rounded_price($up_price);
 845     my $not_rounded_result3 = C4::Acquisition::get_rounded_price($down_price);
 846     t::lib::Mocks::mock_preference( 'OrderPriceRounding', q{nearest_cent} );
 847     my $rounded_result1 = C4::Acquisition::get_rounded_price($exact_price);
 848     my $rounded_result2 = C4::Acquisition::get_rounded_price($up_price);
 849     my $rounded_result3 = C4::Acquisition::get_rounded_price($down_price);
 850
 851     is( $not_rounded_result1, $exact_price,      "Price ($exact_price) was correctly not rounded ($not_rounded_result1)" );
 852     is( $not_rounded_result2, $up_price,         "Price ($up_price) was correctly not rounded ($not_rounded_result2)" );
 853     is( $not_rounded_result3, $down_price,       "Price ($down_price) was correctly not rounded ($not_rounded_result3)" );
 854     is( $rounded_result1,     $exact_price,      "Price ($exact_price) was correctly rounded ($rounded_result1)" );
 855     is( $rounded_result2,     $round_up_price,   "Price ($up_price) was correctly rounded ($rounded_result2)" );
 856     is( $rounded_result3,     $round_down_price, "Price ($down_price) was correctly rounded ($rounded_result3)" );
 857
 858 };
 859
 860 subtest 'GetHistory - managing library' => sub {
 861
 862     plan tests => 1;
 863
 864     my $orders = GetHistory(managing_library => 'CPL');
 865
 866     my $builder = t::lib::TestBuilder->new;
 867
 868     my $order_basket1 = $builder->build({ source => 'Aqbasket', value => { branch => 'CPL' } });
 869     my $orderinfo1 ={
 870         basketno => $order_basket1->{basketno},
 871         rrp => 19.99,
 872         replacementprice => undef,
 873         quantity => 1,
 874         quantityreceived => 0,
 875         datereceived => undef,
 876         datecancellationprinted => undef,
 877     };
 878     my $order1 = $builder->build({ source => 'Aqorder', value => $orderinfo1 });
 879
 880     my $order_basket2 = $builder->build({ source => 'Aqbasket', value => { branch => 'LIB' } });
 881     my $orderinfo2 ={
 882         basketno => $order_basket2->{basketno},
 883         rrp => 19.99,
 884         replacementprice => undef,
 885         quantity => 1,
 886         quantityreceived => 0,
 887         datereceived => undef,
 888         datecancellationprinted => undef,
 889     };
 890     my $order2 = $builder->build({ source => 'Aqorder', value => $orderinfo2 });
 891
 892     my $history = GetHistory(managing_library => 'CPL');
 893     is( scalar( @$history), scalar ( @$orders ) +1, "GetHistory returns number of orders");
 894
 895 };
 896
 897 $schema->storage->txn_rollback();