t/db_dependent/Acquisition.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use POSIX qw(strftime);
  21
  22 use Test::More tests => 70;
  23 use t::lib::Mocks;
  24 use Koha::Database;
  25 use Koha::DateUtils qw(dt_from_string output_pref);
  26 use Koha::Acquisition::Basket;
  27
  28 use MARC::File::XML ( BinaryEncoding => 'utf8', RecordFormat => 'MARC21' );
  29
  30 BEGIN {
  31     use_ok('C4::Acquisition', qw( NewBasket GetBasket AddInvoice GetInvoice ModReceiveOrder SearchOrders GetOrder GetHistory ModOrder get_rounding_sql get_rounded_price ReopenBasket ModBasket ModBasketHeader ModBasketUsers ));
  32     use_ok('C4::Biblio', qw( AddBiblio GetMarcSubfieldStructure ));
  33     use_ok('C4::Budgets', qw( AddBudgetPeriod AddBudget GetBudget GetBudgetByOrderNumber GetBudgetsReport GetBudgets GetBudgetReport ));
  34     use_ok('Koha::Acquisition::Orders');
  35     use_ok('Koha::Acquisition::Booksellers');
  36     use_ok('t::lib::TestBuilder');
  37 }
  38
  39 # Sub used for testing C4::Acquisition subs returning order(s):
  40 #    GetOrdersByStatus, GetOrders, GetDeletedOrders, GetOrder etc.
  41 # (\@test_missing_fields,\@test_extra_fields,\@test_different_fields,$test_nbr_fields) =
  42 #  _check_fields_of_order ($exp_fields, $original_order_content, $order_to_check);
  43 # params :
  44 # $exp_fields             : arrayref whose elements are the keys we expect to find
  45 # $original_order_content : hashref whose 2 keys str and num contains hashrefs
  46 #                           containing content fields of the order created with Koha::Acquisition::Order
  47 # $order_to_check         : hashref whose keys/values are the content of an order
  48 #                           returned by the C4::Acquisition sub we are testing
  49 # returns :
  50 # \@test_missing_fields   : arrayref void if ok ; otherwise contains the list of
  51 #                           fields missing in $order_to_check
  52 # \@test_extra_fields     : arrayref void if ok ; otherwise contains the list of
  53 #                           fields unexpected in $order_to_check
  54 # \@test_different_fields : arrayref void if ok ; otherwise contains the list of
  55 #                           fields which value is not the same in between $order_to_check and
  56 # $test_nbr_fields        : contains the number of fields of $order_to_check
  57
  58 sub _check_fields_of_order {
  59     my ( $exp_fields, $original_order_content, $order_to_check ) = @_;
  60     my @test_missing_fields   = ();
  61     my @test_extra_fields     = ();
  62     my @test_different_fields = ();
  63     my $test_nbr_fields       = scalar( keys %$order_to_check );
  64     foreach my $field (@$exp_fields) {
  65         push @test_missing_fields, $field
  66           unless exists( $order_to_check->{$field} );
  67     }
  68     foreach my $field ( keys %$order_to_check ) {
  69         push @test_extra_fields, $field
  70           unless grep ( /^$field$/, @$exp_fields );
  71     }
  72     foreach my $field ( keys %{ $original_order_content->{str} } ) {
  73         push @test_different_fields, $field
  74           unless ( !exists $order_to_check->{$field} )
  75           or ( $original_order_content->{str}->{$field} eq
  76             $order_to_check->{$field} );
  77     }
  78     foreach my $field ( keys %{ $original_order_content->{num} } ) {
  79         push @test_different_fields, $field
  80           unless ( !exists $order_to_check->{$field} )
  81           or ( $original_order_content->{num}->{$field} ==
  82             $order_to_check->{$field} );
  83     }
  84     return (
  85         \@test_missing_fields,   \@test_extra_fields,
  86         \@test_different_fields, $test_nbr_fields
  87     );
  88 }
  89
  90 # Sub used for testing C4::Acquisition subs returning several orders
  91 # (\@test_missing_fields,\@test_extra_fields,\@test_different_fields,\@test_nbr_fields) =
  92 #   _check_fields_of_orders ($exp_fields, $original_orders_content, $orders_to_check)
  93 sub _check_fields_of_orders {
  94     my ( $exp_fields, $original_orders_content, $orders_to_check ) = @_;
  95     my @test_missing_fields   = ();
  96     my @test_extra_fields     = ();
  97     my @test_different_fields = ();
  98     my @test_nbr_fields       = ();
  99     foreach my $order_to_check (@$orders_to_check) {
 100         my $original_order_content =
 101           ( grep { $_->{str}->{ordernumber} eq $order_to_check->{ordernumber} }
 102               @$original_orders_content )[0];
 103         my (
 104             $t_missing_fields,   $t_extra_fields,
 105             $t_different_fields, $t_nbr_fields
 106           )
 107           = _check_fields_of_order( $exp_fields, $original_order_content,
 108             $order_to_check );
 109         push @test_missing_fields,   @$t_missing_fields;
 110         push @test_extra_fields,     @$t_extra_fields;
 111         push @test_different_fields, @$t_different_fields;
 112         push @test_nbr_fields,       $t_nbr_fields;
 113     }
 114     @test_missing_fields = keys %{ { map { $_ => 1 } @test_missing_fields } };
 115     @test_extra_fields   = keys %{ { map { $_ => 1 } @test_extra_fields } };
 116     @test_different_fields =
 117       keys %{ { map { $_ => 1 } @test_different_fields } };
 118     return (
 119         \@test_missing_fields,   \@test_extra_fields,
 120         \@test_different_fields, \@test_nbr_fields
 121     );
 122 }
 123
 124
 125 my $schema = Koha::Database->new()->schema();
 126 $schema->storage->txn_begin();
 127
 128 # Creating some orders
 129 my $bookseller = Koha::Acquisition::Bookseller->new(
 130     {
 131         name         => "my vendor",
 132         address1     => "bookseller's address",
 133         phone        => "0123456",
 134         active       => 1,
 135         deliverytime => 5,
 136     }
 137 )->store;
 138 my $booksellerid = $bookseller->id;
 139
 140 my $booksellerinfo = Koha::Acquisition::Booksellers->find( $booksellerid );
 141 is( $booksellerinfo->deliverytime,
 142     5, 'set deliverytime when creating vendor (Bug 10556)' );
 143
 144 my ( $basket, $basketno );
 145 ok(
 146     $basketno = NewBasket( $booksellerid, 1 ),
 147     "NewBasket(  $booksellerid , 1  ) returns $basketno"
 148 );
 149 ok( $basket = GetBasket($basketno), "GetBasket($basketno) returns $basket" );
 150
 151 my $bpid=AddBudgetPeriod({
 152         budget_period_startdate => '2008-01-01'
 153         , budget_period_enddate => '2008-12-31'
 154         , budget_period_active  => 1
 155         , budget_period_description    => "MAPERI"
 156 });
 157
 158 my $budgetid = C4::Budgets::AddBudget(
 159     {
 160         budget_code => "budget_code_test_1",
 161         budget_name => "budget_name_test_1",
 162         budget_period_id => $bpid,
 163     }
 164 );
 165 my $budget = C4::Budgets::GetBudget($budgetid);
 166
 167 my @ordernumbers;
 168 my ( $biblionumber1, $biblioitemnumber1 ) = AddBiblio( MARC::Record->new, '' );
 169 my ( $biblionumber2, $biblioitemnumber2 ) = AddBiblio( MARC::Record->new, '' );
 170 my ( $biblionumber3, $biblioitemnumber3 ) = AddBiblio( MARC::Record->new, '' );
 171 my ( $biblionumber4, $biblioitemnumber4 ) = AddBiblio( MARC::Record->new, '' );
 172 my ( $biblionumber5, $biblioitemnumber5 ) = AddBiblio( MARC::Record->new, '' );
 173
 174
 175
 176 # Prepare 6 orders, and make distinction beween fields to be tested with eq and with ==
 177 # Ex : a price of 50.1 will be stored internally as 5.100000
 178
 179 my @order_content = (
 180     {
 181         str => {
 182             basketno       => $basketno,
 183             biblionumber   => $biblionumber1,
 184             budget_id      => $budget->{budget_id},
 185             uncertainprice => 0,
 186             order_internalnote => "internal note foo",
 187             order_vendornote   => "vendor note bar",
 188             ordernumber => '',
 189         },
 190         num => {
 191             quantity  => 24,
 192             listprice => 50.121111,
 193             ecost     => 38.15,
 194             rrp       => 40.15,
 195             discount  => 5.1111,
 196         }
 197     },
 198     {
 199         str => {
 200             basketno     => $basketno,
 201             biblionumber => $biblionumber2,
 202             budget_id    => $budget->{budget_id}
 203         },
 204         num => { quantity => 42 }
 205     },
 206     {
 207         str => {
 208             basketno       => $basketno,
 209             biblionumber   => $biblionumber2,
 210             budget_id      => $budget->{budget_id},
 211             uncertainprice => 0,
 212             order_internalnote => "internal note foo",
 213             order_vendornote   => "vendor note bar"
 214         },
 215         num => {
 216             quantity  => 4,
 217             ecost     => 42.1,
 218             rrp       => 42.1,
 219             listprice => 10.1,
 220             ecost     => 38.1,
 221             rrp       => 11.0,
 222             discount  => 5.1,
 223         }
 224     },
 225     {
 226         str => {
 227             basketno     => $basketno,
 228             biblionumber => $biblionumber3,
 229             budget_id    => $budget->{budget_id},
 230             order_internalnote => "internal note",
 231             order_vendornote   => "vendor note"
 232         },
 233         num => {
 234             quantity       => 4,
 235             ecost          => 40,
 236             rrp            => 42,
 237             listprice      => 10,
 238             ecost          => 38.15,
 239             rrp            => 11.00,
 240             discount       => 0,
 241             uncertainprice => 0,
 242         }
 243     },
 244     {
 245         str => {
 246             basketno     => $basketno,
 247             biblionumber => $biblionumber4,
 248             budget_id    => $budget->{budget_id},
 249             order_internalnote => "internal note bar",
 250             order_vendornote   => "vendor note foo"
 251         },
 252         num => {
 253             quantity       => 1,
 254             ecost          => 10,
 255             rrp            => 10,
 256             listprice      => 10,
 257             ecost          => 10,
 258             rrp            => 10,
 259             discount       => 0,
 260             uncertainprice => 0,
 261         }
 262     },
 263     {
 264         str => {
 265             basketno     => $basketno,
 266             biblionumber => $biblionumber5,
 267             budget_id    => $budget->{budget_id},
 268             order_internalnote => "internal note",
 269             order_vendornote   => "vendor note"
 270         },
 271         num => {
 272             quantity       => 1,
 273             ecost          => 10,
 274             rrp            => 10,
 275             listprice      => 10,
 276             ecost          => 10,
 277             rrp            => 10,
 278             discount       => 0,
 279             uncertainprice => 0,
 280         }
 281     }
 282 );
 283
 284 # Create 6 orders in database
 285 for ( 0 .. 5 ) {
 286     my %ocontent;
 287     @ocontent{ keys %{ $order_content[$_]->{num} } } =
 288       values %{ $order_content[$_]->{num} };
 289     @ocontent{ keys %{ $order_content[$_]->{str} } } =
 290       values %{ $order_content[$_]->{str} };
 291     $ordernumbers[$_] = Koha::Acquisition::Order->new( \%ocontent )->store->ordernumber;
 292     $order_content[$_]->{str}->{ordernumber} = $ordernumbers[$_];
 293 }
 294
 295 Koha::Acquisition::Orders->find($ordernumbers[3])->cancel;
 296
 297 my $invoiceid = AddInvoice(
 298     invoicenumber => 'invoice',
 299     booksellerid  => $booksellerid,
 300     unknown       => "unknown"
 301 );
 302
 303 my $invoice = GetInvoice( $invoiceid );
 304
 305 my $reception_date = output_pref(
 306     {
 307             dt => dt_from_string->add( days => 1 ),
 308             dateformat => 'iso',
 309             dateonly => 1,
 310     }
 311 );
 312 my ($datereceived, $new_ordernumber) = ModReceiveOrder(
 313     {
 314         biblionumber      => $biblionumber4,
 315         order             => Koha::Acquisition::Orders->find( $ordernumbers[4] )->unblessed,
 316         quantityreceived  => 1,
 317         invoice           => $invoice,
 318         budget_id         => $order_content[4]->{str}->{budget_id},
 319         datereceived      => $reception_date,
 320     }
 321 );
 322
 323 is(
 324     output_pref(
 325         {
 326             dt         => dt_from_string($datereceived),
 327             dateformat => 'iso',
 328             dateonly   => 1
 329         }
 330     ),
 331     $reception_date,
 332     'ModReceiveOrder sets the passed date'
 333 );
 334
 335 my $search_orders = SearchOrders({
 336     booksellerid => $booksellerid,
 337     basketno     => $basketno
 338 });
 339 isa_ok( $search_orders, 'ARRAY' );
 340 ok(
 341     (
 342         ( scalar @$search_orders == 5 )
 343           and !grep ( $_->{ordernumber} eq $ordernumbers[3], @$search_orders )
 344     ),
 345     "SearchOrders only gets non-cancelled orders"
 346 );
 347
 348 $search_orders = SearchOrders({
 349     booksellerid => $booksellerid,
 350     basketno     => $basketno,
 351     pending      => 1
 352 });
 353 ok(
 354     (
 355         ( scalar @$search_orders == 4 ) and !grep ( (
 356                      ( $_->{ordernumber} eq $ordernumbers[3] )
 357                   or ( $_->{ordernumber} eq $ordernumbers[4] )
 358             ),
 359             @$search_orders )
 360     ),
 361     "SearchOrders with pending params gets only pending orders (bug 10723)"
 362 );
 363
 364 $search_orders = SearchOrders({
 365     booksellerid => $booksellerid,
 366     basketno     => $basketno,
 367     pending      => 1,
 368     ordered      => 1,
 369 });
 370 is( scalar (@$search_orders), 0, "SearchOrders with pending and ordered params gets only pending ordered orders (bug 11170)" );
 371
 372 $search_orders = SearchOrders({
 373     ordernumber => $ordernumbers[4]
 374 });
 375 is( scalar (@$search_orders), 1, "SearchOrders takes into account the ordernumber filter" );
 376
 377 $search_orders = SearchOrders({
 378     biblionumber => $biblionumber4
 379 });
 380 is( scalar (@$search_orders), 1, "SearchOrders takes into account the biblionumber filter" );
 381
 382 $search_orders = SearchOrders({
 383     biblionumber => $biblionumber4,
 384     pending      => 1
 385 });
 386 is( scalar (@$search_orders), 0, "SearchOrders takes into account the biblionumber and pending filters" );
 387
 388 #
 389 # Test GetBudgetByOrderNumber
 390 #
 391 ok( GetBudgetByOrderNumber( $ordernumbers[0] )->{'budget_id'} eq $budgetid,
 392     "GetBudgetByOrderNumber returns expected budget" );
 393
 394 my $lateorders = Koha::Acquisition::Orders->filter_by_lates({ delay => 0 });
 395 is( $lateorders->search({ 'me.basketno' => $basketno })->count,
 396     0, "GetLateOrders does not get orders from opened baskets" );
 397 Koha::Acquisition::Baskets->find($basketno)->close;
 398 $lateorders = Koha::Acquisition::Orders->filter_by_lates({ delay => 0 });
 399 isnt( $lateorders->search({ 'me.basketno' => $basketno })->count,
 400     0, "GetLateOrders gets orders from closed baskets" );
 401 is( $lateorders->search({ ordernumber => $ordernumbers[3] })->count, 0,
 402     "GetLateOrders does not get cancelled orders" );
 403 is( $lateorders->search({ ordernumber => $ordernumbers[4] })->count, 0,
 404     "GetLateOrders does not get received orders" );
 405
 406 $search_orders = SearchOrders({
 407     booksellerid => $booksellerid,
 408     basketno     => $basketno,
 409     pending      => 1,
 410     ordered      => 1,
 411 });
 412 is( scalar (@$search_orders), 4, "SearchOrders with pending and ordered params gets only pending ordered orders. After closing the basket, orders are marked as 'ordered' (bug 11170)" );
 413
 414 #
 415 # Test AddClaim
 416 #
 417
 418 my $order = $lateorders->next;
 419 $order->claim();
 420 is(
 421     output_pref({ str => $order->claimed_date, dateformat => 'iso', dateonly => 1 }),
 422     strftime( "%Y-%m-%d", localtime(time) ),
 423     "Koha::Acquisition::Order->claim: Check claimed_date"
 424 );
 425
 426 my $order2 = Koha::Acquisition::Orders->find( $ordernumbers[1] )->unblessed;
 427 $order2->{order_internalnote} = "my notes";
 428 ( $datereceived, $new_ordernumber ) = ModReceiveOrder(
 429     {
 430         biblionumber     => $biblionumber2,
 431         order            => $order2,
 432         quantityreceived => 2,
 433         invoice          => $invoice,
 434     }
 435 );
 436 $order2 = GetOrder( $ordernumbers[1] );
 437 is( $order2->{'quantityreceived'},
 438     0, 'Splitting up order did not receive any on original order' );
 439 is( $order2->{'quantity'}, 40, '40 items on original order' );
 440 is( $order2->{'budget_id'}, $budgetid,
 441     'Budget on original order is unchanged' );
 442 is( $order2->{order_internalnote}, "my notes",
 443     'ModReceiveOrder and GetOrder deal with internal notes' );
 444 my $order1 = GetOrder( $ordernumbers[0] );
 445 is(
 446     $order1->{order_internalnote},
 447     "internal note foo",
 448     "ModReceiveOrder only changes the supplied orders internal notes"
 449 );
 450
 451 my $neworder = GetOrder($new_ordernumber);
 452 is( $neworder->{'quantity'}, 2, '2 items on new order' );
 453 is( $neworder->{'quantityreceived'},
 454     2, 'Splitting up order received items on new order' );
 455 is( $neworder->{'budget_id'}, $budgetid, 'Budget on new order is unchanged' );
 456
 457 is( $neworder->{ordernumber}, $new_ordernumber, 'Split: test ordernumber' );
 458 is( $neworder->{parent_ordernumber}, $ordernumbers[1], 'Split: test parent_ordernumber' );
 459
 460 my $orders = GetHistory( ordernumber => $ordernumbers[1] );
 461 is( scalar( @$orders ), 1, 'GetHistory with a given ordernumber returns 1 order' );
 462 $orders = GetHistory( ordernumber => $ordernumbers[1], search_children_too => 1 );
 463 is( scalar( @$orders ), 2, 'GetHistory with a given ordernumber and search_children_too set returns 2 orders' );
 464 $orders = GetHistory( ordernumbers => [$ordernumbers[1]] );
 465 is( scalar( @$orders ), 1, 'GetHistory with a given ordernumbers returns 1 order' );
 466 $orders = GetHistory( ordernumbers => \@ordernumbers );
 467 is( scalar( @$orders ), scalar( @ordernumbers ) - 1, 'GetHistory with a list of ordernumbers returns N-1 orders (was has been deleted [3])' );
 468
 469 $orders = GetHistory( internalnote => 'internal note foo' );
 470 is( scalar( @$orders ), 2, 'GetHistory returns correctly a search for internalnote' );
 471 $orders = GetHistory( vendornote => 'vendor note bar' );
 472 is( scalar( @$orders ), 2, 'GetHistory returns correctly a search for vendornote' );
 473 $orders = GetHistory( internalnote => 'internal note bar' );
 474 is( scalar( @$orders ), 1, 'GetHistory returns correctly a search for internalnote' );
 475 $orders = GetHistory( vendornote => 'vendor note foo' );
 476 is( scalar( @$orders ), 1, 'GetHistory returns correctly a search for vendornote' );
 477
 478
 479 # Test GetHistory() with and without SearchWithISBNVariations
 480 # The ISBN passed as a param is the ISBN-10 version of the 13-digit ISBN in the sample record declared in $marcxml
 481
 482 my $budgetid2 = C4::Budgets::AddBudget(
 483     {
 484         budget_code => "budget_code_test_modrecv",
 485         budget_name => "budget_name_test_modrecv",
 486     }
 487 );
 488
 489 my $order3 = Koha::Acquisition::Orders->find( $ordernumbers[2] )->unblessed;
 490 $order3->{order_internalnote} = "my other notes";
 491 ( $datereceived, $new_ordernumber ) = ModReceiveOrder(
 492     {
 493         biblionumber     => $biblionumber2,
 494         order            => $order3,
 495         quantityreceived => 2,
 496         invoice          => $invoice,
 497         budget_id        => $budgetid2,
 498     }
 499 );
 500
 501 $order3 = GetOrder( $ordernumbers[2] );
 502 is( $order3->{'quantityreceived'},
 503     0, 'Splitting up order did not receive any on original order' );
 504 is( $order3->{'quantity'}, 2, '2 items on original order' );
 505 is( $order3->{'budget_id'}, $budgetid,
 506     'Budget on original order is unchanged' );
 507 is( $order3->{order_internalnote}, "my other notes",
 508     'ModReceiveOrder and GetOrder deal with notes' );
 509
 510 $neworder = GetOrder($new_ordernumber);
 511 is( $neworder->{'quantity'}, 2, '2 items on new order' );
 512 is( $neworder->{'quantityreceived'},
 513     2, 'Splitting up order received items on new order' );
 514 is( $neworder->{'budget_id'}, $budgetid2, 'Budget on new order is changed' );
 515
 516 $order3 = Koha::Acquisition::Orders->find( $ordernumbers[2] )->unblessed;
 517 $order3->{order_internalnote} = "my third notes";
 518 ( $datereceived, $new_ordernumber ) = ModReceiveOrder(
 519     {
 520         biblionumber     => $biblionumber2,
 521         order            => $order3,
 522         quantityreceived => 2,
 523         invoice          => $invoice,
 524         budget_id        => $budgetid2,
 525     }
 526 );
 527
 528 $order3 = GetOrder( $ordernumbers[2] );
 529 is( $order3->{'quantityreceived'}, 2,          'Order not split up' );
 530 is( $order3->{'quantity'},         2,          '2 items on order' );
 531 is( $order3->{'budget_id'},        $budgetid2, 'Budget has changed' );
 532 is( $order3->{order_internalnote}, "my third notes", 'ModReceiveOrder and GetOrder deal with notes' );
 533
 534 my $nonexistent_order = GetOrder();
 535 is( $nonexistent_order, undef, 'GetOrder returns undef if no ordernumber is given' );
 536 $nonexistent_order = GetOrder( 424242424242 );
 537 is( $nonexistent_order, undef, 'GetOrder returns undef if a nonexistent ordernumber is given' );
 538
 539 subtest 'ModOrder' => sub {
 540     plan tests => 1;
 541     ModOrder( { ordernumber => $order1->{ordernumber}, unitprice => 42 } );
 542     my $order = GetOrder( $order1->{ordernumber} );
 543     is( int($order->{unitprice}), 42, 'ModOrder should work even if biblionumber if not passed');
 544 };
 545
 546 # Budget reports
 547 my $all_count = scalar GetBudgetsReport();
 548 ok($all_count >= 1, "GetBudgetReport OK");
 549
 550 my $active_count = scalar GetBudgetsReport(1);
 551 ok($active_count >= 1 , "GetBudgetsReport(1) OK");
 552
 553 is($all_count, scalar GetBudgetsReport(), "GetBudgetReport returns inactive budget period acquisitions.");
 554 ok($active_count >= scalar GetBudgetsReport(1), "GetBudgetReport doesn't return inactive budget period acquisitions.");
 555
 556 # "Flavoured" tests (tests that required a run for each marc flavour)
 557 # Tests should be added to the run_flavoured_tests sub below
 558 my $biblio_module = Test::MockModule->new('C4::Biblio');
 559 $biblio_module->mock(
 560     'GetMarcSubfieldStructure',
 561     sub {
 562         my ($self) = shift;
 563
 564         my ( $title_field,            $title_subfield )            = get_title_field();
 565         my ( $isbn_field,             $isbn_subfield )             = get_isbn_field();
 566         my ( $issn_field,             $issn_subfield )             = get_issn_field();
 567         my ( $biblionumber_field,     $biblionumber_subfield )     = ( '999', 'c' );
 568         my ( $biblioitemnumber_field, $biblioitemnumber_subfield ) = ( '999', '9' );
 569         my ( $itemnumber_field,       $itemnumber_subfield )       = get_itemnumber_field();
 570
 571         return {
 572             'biblio.title'                 => [ { tagfield => $title_field,            tagsubfield => $title_subfield } ],
 573             'biblio.biblionumber'          => [ { tagfield => $biblionumber_field,     tagsubfield => $biblionumber_subfield } ],
 574             'biblioitems.isbn'             => [ { tagfield => $isbn_field,             tagsubfield => $isbn_subfield } ],
 575             'biblioitems.issn'             => [ { tagfield => $issn_field,             tagsubfield => $issn_subfield } ],
 576             'biblioitems.biblioitemnumber' => [ { tagfield => $biblioitemnumber_field, tagsubfield => $biblioitemnumber_subfield } ],
 577             'items.itemnumber'             => [ { tagfield => $itemnumber_subfield,    tagsubfield => $itemnumber_subfield } ],
 578         };
 579       }
 580 );
 581
 582 sub run_flavoured_tests {
 583     my $marcflavour = shift;
 584     t::lib::Mocks::mock_preference('marcflavour', $marcflavour);
 585
 586     #
 587     # Test SearchWithISBNVariations syspref
 588     #
 589     my $marc_record = MARC::Record->new;
 590     $marc_record->append_fields( create_isbn_field( '9780136019701', $marcflavour ) );
 591     my ( $biblionumber6, $biblioitemnumber6 ) = AddBiblio( $marc_record, '' );
 592
 593     # Create order
 594     my $ordernumber = Koha::Acquisition::Order->new( {
 595             basketno     => $basketno,
 596             biblionumber => $biblionumber6,
 597             budget_id    => $budget->{budget_id},
 598             order_internalnote => "internal note",
 599             order_vendornote   => "vendor note",
 600             quantity       => 1,
 601             ecost          => 10,
 602             rrp            => 10,
 603             listprice      => 10,
 604             ecost          => 10,
 605             rrp            => 10,
 606             discount       => 0,
 607             uncertainprice => 0,
 608     } )->store->ordernumber;
 609
 610     t::lib::Mocks::mock_preference('SearchWithISBNVariations', 0);
 611     $orders = GetHistory( isbn => '0136019706' );
 612     is( scalar(@$orders), 0, "GetHistory searches correctly by ISBN" );
 613
 614     t::lib::Mocks::mock_preference('SearchWithISBNVariations', 1);
 615     $orders = GetHistory( isbn => '0136019706' );
 616     is( scalar(@$orders), 1, "GetHistory searches correctly by ISBN" );
 617
 618     Koha::Acquisition::Orders->find($ordernumber)->cancel;
 619 }
 620
 621 # Do "flavoured" tests
 622 subtest 'MARC21' => sub {
 623     plan tests => 2;
 624     run_flavoured_tests('MARC21');
 625 };
 626
 627 subtest 'UNIMARC' => sub {
 628     plan tests => 2;
 629     run_flavoured_tests('UNIMARC');
 630 };
 631
 632 ### Functions required for "flavoured" tests
 633 sub get_title_field {
 634     my $marc_flavour = C4::Context->preference('marcflavour');
 635     return ( $marc_flavour eq 'UNIMARC' ) ? ( '200', 'a' ) : ( '245', 'a' );
 636 }
 637
 638 sub get_isbn_field {
 639     my $marc_flavour = C4::Context->preference('marcflavour');
 640     return ( $marc_flavour eq 'UNIMARC' ) ? ( '010', 'a' ) : ( '020', 'a' );
 641 }
 642
 643 sub get_issn_field {
 644     my $marc_flavour = C4::Context->preference('marcflavour');
 645     return ( $marc_flavour eq 'UNIMARC' ) ? ( '011', 'a' ) : ( '022', 'a' );
 646 }
 647
 648 sub get_itemnumber_field {
 649     my $marc_flavour = C4::Context->preference('marcflavour');
 650     return ( $marc_flavour eq 'UNIMARC' ) ? ( '995', '9' ) : ( '952', '9' );
 651 }
 652
 653 sub create_isbn_field {
 654     my ( $isbn, $marcflavour ) = @_;
 655
 656     my ( $isbn_field, $isbn_subfield ) = get_isbn_field();
 657     my $field = MARC::Field->new( $isbn_field, '', '', $isbn_subfield => $isbn );
 658
 659     # Add the price subfield
 660     my $price_subfield = ( $marcflavour eq 'UNIMARC' ) ? 'd' : 'c';
 661     $field->add_subfields( $price_subfield => '$100' );
 662
 663     return $field;
 664 }
 665
 666 subtest 'ModReceiveOrder replacementprice tests' => sub {
 667     plan tests => 2;
 668     #Let's build an order, we need a couple things though
 669     my $builder = t::lib::TestBuilder->new;
 670     my $order_biblio = $builder->build_sample_biblio;
 671     my $order_basket = $builder->build({ source => 'Aqbasket', value => { is_standing => 0 } });
 672     my $order_invoice = $builder->build({ source => 'Aqinvoice'});
 673     my $order_currency = $builder->build({ source => 'Currency', value => { active => 1, archived => 0, symbol => 'F', rate => 2, isocode => undef, currency => 'FOO' }  });
 674     my $order_vendor = $builder->build({ source => 'Aqbookseller',value => { listincgst => 0, listprice => $order_currency->{currency}, invoiceprice => $order_currency->{currency} } });
 675     my $orderinfo ={
 676         basketno => $order_basket->{basketno},
 677         booksellerid => $order_vendor->{id},
 678         rrp => 19.99,
 679         replacementprice => undef,
 680         quantity => 1,
 681         quantityreceived => 0,
 682         datereceived => undef,
 683         datecancellationprinted => undef,
 684     };
 685     my $receive_order = $builder->build({ source => 'Aqorder', value => $orderinfo });
 686     (undef, my $received_ordernumber) = ModReceiveOrder({
 687             biblionumber => $order_biblio->biblionumber,
 688             order        => $receive_order,
 689             invoice      => $order_invoice,
 690             quantityreceived => $receive_order->{quantity},
 691             budget_id    => $order->{budget_id},
 692     });
 693     my $received_order = GetOrder($received_ordernumber);
 694     is ($received_order->{replacementprice},undef,"No price set if none passed in");
 695     $orderinfo->{replacementprice} = 16.12;
 696     $receive_order = $builder->build({ source => 'Aqorder', value => $orderinfo });
 697     (undef, $received_ordernumber) = ModReceiveOrder({
 698             biblionumber => $order_biblio->biblionumber,
 699             order        => $receive_order,
 700             invoice      => $order_invoice,
 701             quantityreceived => $receive_order->{quantity},
 702             budget_id    => $order->{budget_id},
 703     });
 704     $received_order = GetOrder($received_ordernumber);
 705     is ($received_order->{replacementprice},'16.120000',"Replacement price set if none passed in");
 706 };
 707
 708 subtest 'ModReceiveOrder and subscription' => sub {
 709     plan tests => 2;
 710
 711     my $builder     = t::lib::TestBuilder->new;
 712     my $first_note  = 'first note';
 713     my $second_note = 'second note';
 714     my $subscription = $builder->build_object( { class => 'Koha::Subscriptions' } );
 715     my $order = $builder->build_object(
 716         {
 717             class => 'Koha::Acquisition::Orders',
 718             value => {
 719                 subscriptionid     => $subscription->subscriptionid,
 720                 order_internalnote => $first_note,
 721                 quantity           => 5,
 722                 quantityreceived   => 0,
 723                 ecost_tax_excluded => 42,
 724                 unitprice_tax_excluded => 42,
 725             }
 726         }
 727     );
 728     my $order_info = $order->unblessed;
 729     # We do not want the note from the original note to be modified
 730     # Keeping it will permit to display it for future receptions
 731     $order_info->{order_internalnote} = $second_note;
 732     my ( undef, $received_ordernumber ) = ModReceiveOrder(
 733         {
 734             biblionumber     => $order->biblionumber,
 735             order            => $order_info,
 736             invoice          => $order->{invoiceid},
 737             quantityreceived => 1,
 738             budget_id        => $order->budget_id,
 739         }
 740     );
 741     my $received_order = Koha::Acquisition::Orders->find($received_ordernumber);
 742     is( $received_order->order_internalnote,
 743         $second_note, "No price set if none passed in" );
 744
 745     $order->get_from_storage;
 746     is( $order->get_from_storage->order_internalnote, $first_note );
 747 };
 748
 749 subtest 'GetHistory with additional fields' => sub {
 750     plan tests => 3;
 751     my $builder = t::lib::TestBuilder->new;
 752     my $order_basket = $builder->build({ source => 'Aqbasket', value => { is_standing => 0 } });
 753     my $orderinfo ={
 754         basketno => $order_basket->{basketno},
 755         rrp => 19.99,
 756         replacementprice => undef,
 757         quantity => 1,
 758         quantityreceived => 0,
 759         datereceived => undef,
 760         datecancellationprinted => undef,
 761     };
 762     my $order =        $builder->build({ source => 'Aqorder', value => $orderinfo });
 763     my $history = GetHistory(ordernumber => $order->{ordernumber});
 764     is( scalar( @$history ), 1, 'GetHistory returns the one order');
 765
 766     my $additional_field = $builder->build({source => 'AdditionalField', value => {
 767             tablename => 'aqbasket',
 768             name => 'snakeoil',
 769             authorised_value_category => "",
 770         }
 771     });
 772     $history = GetHistory( ordernumber => $order->{ordernumber}, additional_fields => [{ id => $additional_field->{id}, value=>'delicious'}]);
 773     is( scalar ( @$history ), 0, 'GetHistory returns no order for an unused additional field');
 774     my $basket = Koha::Acquisition::Baskets->find({ basketno => $order_basket->{basketno} });
 775     $basket->set_additional_fields([{
 776         id => $additional_field->{id},
 777         value => 'delicious',
 778     }]);
 779
 780     $history = GetHistory( ordernumber => $order->{ordernumber}, additional_fields => [{ id => $additional_field->{id}, value=>'delicious'}]);
 781     is( scalar( @$history ), 1, 'GetHistory returns the order when additional field is set');
 782 };
 783
 784 subtest 'Tests for get_rounding_sql' => sub {
 785
 786     plan tests => 2;
 787
 788     my $value = '3.141592';
 789
 790     t::lib::Mocks::mock_preference( 'OrderPriceRounding', q{} );
 791     my $no_rounding_result = C4::Acquisition::get_rounding_sql($value);
 792     t::lib::Mocks::mock_preference( 'OrderPriceRounding', q{nearest_cent} );
 793     my $rounding_result = C4::Acquisition::get_rounding_sql($value);
 794
 795     ok( $no_rounding_result eq $value, "Value ($value) not to be rounded" );
 796     ok( $rounding_result =~ /CAST/,    "Value ($value) will be rounded" );
 797
 798 };
 799
 800 subtest 'Test for get_rounded_price' => sub {
 801
 802     plan tests => 6;
 803
 804     my $exact_price      = 3.14;
 805     my $up_price         = 3.145592;
 806     my $down_price       = 3.141592;
 807     my $round_up_price   = sprintf( '%0.2f', $up_price );
 808     my $round_down_price = sprintf( '%0.2f', $down_price );
 809
 810     t::lib::Mocks::mock_preference( 'OrderPriceRounding', q{} );
 811     my $not_rounded_result1 = C4::Acquisition::get_rounded_price($exact_price);
 812     my $not_rounded_result2 = C4::Acquisition::get_rounded_price($up_price);
 813     my $not_rounded_result3 = C4::Acquisition::get_rounded_price($down_price);
 814     t::lib::Mocks::mock_preference( 'OrderPriceRounding', q{nearest_cent} );
 815     my $rounded_result1 = C4::Acquisition::get_rounded_price($exact_price);
 816     my $rounded_result2 = C4::Acquisition::get_rounded_price($up_price);
 817     my $rounded_result3 = C4::Acquisition::get_rounded_price($down_price);
 818
 819     is( $not_rounded_result1, $exact_price,      "Price ($exact_price) was correctly not rounded ($not_rounded_result1)" );
 820     is( $not_rounded_result2, $up_price,         "Price ($up_price) was correctly not rounded ($not_rounded_result2)" );
 821     is( $not_rounded_result3, $down_price,       "Price ($down_price) was correctly not rounded ($not_rounded_result3)" );
 822     is( $rounded_result1,     $exact_price,      "Price ($exact_price) was correctly rounded ($rounded_result1)" );
 823     is( $rounded_result2,     $round_up_price,   "Price ($up_price) was correctly rounded ($rounded_result2)" );
 824     is( $rounded_result3,     $round_down_price, "Price ($down_price) was correctly rounded ($rounded_result3)" );
 825
 826 };
 827
 828 subtest 'GetHistory - managing library' => sub {
 829
 830     plan tests => 1;
 831
 832     my $orders = GetHistory(managing_library => 'CPL');
 833
 834     my $builder = t::lib::TestBuilder->new;
 835
 836     my $order_basket1 = $builder->build({ source => 'Aqbasket', value => { branch => 'CPL' } });
 837     my $orderinfo1 ={
 838         basketno => $order_basket1->{basketno},
 839         rrp => 19.99,
 840         replacementprice => undef,
 841         quantity => 1,
 842         quantityreceived => 0,
 843         datereceived => undef,
 844         datecancellationprinted => undef,
 845     };
 846     my $order1 = $builder->build({ source => 'Aqorder', value => $orderinfo1 });
 847
 848     my $order_basket2 = $builder->build({ source => 'Aqbasket', value => { branch => 'LIB' } });
 849     my $orderinfo2 ={
 850         basketno => $order_basket2->{basketno},
 851         rrp => 19.99,
 852         replacementprice => undef,
 853         quantity => 1,
 854         quantityreceived => 0,
 855         datereceived => undef,
 856         datecancellationprinted => undef,
 857     };
 858     my $order2 = $builder->build({ source => 'Aqorder', value => $orderinfo2 });
 859
 860     my $history = GetHistory(managing_library => 'CPL');
 861     is( scalar( @$history), scalar ( @$orders ) +1, "GetHistory returns number of orders");
 862
 863 };
 864
 865 subtest 'GetHistory - is_standing' => sub {
 866
 867     plan tests => 1;
 868
 869     my $orders = GetHistory( is_standing => '1' );
 870
 871     my $builder = t::lib::TestBuilder->new;
 872
 873     my $order_basket1 = $builder->build( { source => 'Aqbasket', value => { is_standing => 0 } } );
 874     my $orderinfo1 = {
 875         basketno                => $order_basket1->{basketno},
 876         rrp                     => 19.99,
 877         replacementprice        => undef,
 878         quantity                => 1,
 879         quantityreceived        => 0,
 880         datereceived            => undef,
 881         datecancellationprinted => undef,
 882     };
 883     my $order1 = $builder->build( { source => 'Aqorder', value => $orderinfo1 } );
 884
 885     my $order_basket2 = $builder->build( { source => 'Aqbasket', value => { is_standing => 1 } } );
 886     my $orderinfo2 = {
 887         basketno                => $order_basket2->{basketno},
 888         rrp                     => 19.99,
 889         replacementprice        => undef,
 890         quantity                => 1,
 891         quantityreceived        => 0,
 892         datereceived            => undef,
 893         datecancellationprinted => undef,
 894     };
 895     my $order2 = $builder->build( { source => 'Aqorder', value => $orderinfo2 } );
 896
 897     my $history = GetHistory( is_standing => 1 );
 898     is(
 899         scalar(@$history),
 900         scalar(@$orders) + 1,
 901         "GetHistory returns number of standing orders"
 902     );
 903
 904 };
 905
 906 subtest 'Acquisition logging' => sub {
 907
 908     plan tests => 5;
 909
 910     t::lib::Mocks::mock_preference('AcquisitionLog', 1);
 911
 912     Koha::ActionLogs->delete;
 913     my $basketno = NewBasket( $booksellerid, 1 );
 914     my @create_logs = Koha::ActionLogs->search({ module =>'ACQUISITIONS', action => 'ADD_BASKET', object => $basketno })->as_list;
 915     is (scalar @create_logs, 1, 'Basket creation is logged');
 916
 917     Koha::ActionLogs->delete;
 918     C4::Acquisition::ReopenBasket($basketno);
 919     my @reopen_logs = Koha::ActionLogs->search({ module =>'ACQUISITIONS', action => 'REOPEN_BASKET', object => $basketno })->as_list;
 920     is (scalar @reopen_logs, 1, 'Basket reopen is logged');
 921
 922     Koha::ActionLogs->delete;
 923     C4::Acquisition::ModBasket({
 924         basketno => $basketno,
 925         booksellerid => $booksellerid
 926     });
 927     my @mod_logs = Koha::ActionLogs->search({ module =>'ACQUISITIONS', action => 'MODIFY_BASKET', object => $basketno })->as_list;
 928     is (scalar @mod_logs, 1, 'Basket modify is logged');
 929
 930     Koha::ActionLogs->delete;
 931     C4::Acquisition::ModBasketHeader($basketno,"Test","","","",$booksellerid);
 932     my @mod_header_logs = Koha::ActionLogs->search({ module =>'ACQUISITIONS', action => 'MODIFY_BASKET_HEADER', object => $basketno })->as_list;
 933     is (scalar @mod_header_logs, 1, 'Basket header modify is logged');
 934
 935     Koha::ActionLogs->delete;
 936     C4::Acquisition::ModBasketUsers($basketno,(1));
 937     my @mod_users_logs = Koha::ActionLogs->search({ module =>'ACQUISITIONS', action => 'MODIFY_BASKET_USERS', object => $basketno })->as_list;
 938     is (scalar @mod_users_logs, 1, 'Basket users modify is logged');
 939
 940     t::lib::Mocks::mock_preference('AcquisitionLog', 0);
 941 };
 942
 943 $schema->storage->txn_rollback();