t/db_dependent/AuthoritiesMarc.t

   1 #!/usr/bin/perl
   2 #
   3 # This Koha test module is a stub!
   4 # Add more tests here!!!
   5
   6 use Modern::Perl;
   7
   8 use Test::More tests => 12;
   9 use Test::MockModule;
  10 use Test::Warn;
  11 use MARC::Field;
  12 use MARC::Record;
  13
  14 use t::lib::Mocks;
  15 use t::lib::TestBuilder;
  16 use Koha::Database;
  17 use Koha::Authority::Types;
  18
  19 BEGIN {
  20         use_ok('C4::AuthoritiesMarc', qw( GetHeaderAuthority AddAuthority AddAuthorityTrees GetAuthority BuildAuthHierarchies GenerateHierarchy BuildSummary DelAuthority CompareFieldWithAuthority ModAuthority merge ));
  21 }
  22
  23 # We are now going to be testing the authorities hierarchy code, and
  24 # therefore need to pretend that we have consistent data in our database
  25 my $module = Test::MockModule->new('C4::AuthoritiesMarc');
  26 $module->mock('GetHeaderAuthority', sub {
  27     return {'authtrees' => ''};
  28 });
  29 $module->mock('AddAuthorityTrees', sub {
  30     return;
  31 });
  32 $module->mock('GetAuthority', sub {
  33     my ($authid) = @_;
  34     my $record = MARC::Record->new();
  35     if ($authid eq '1') {
  36         $record->add_fields(
  37             [ '001', '1' ],
  38             [ '151', ' ', ' ', a => 'United States' ]
  39             );
  40     } elsif ($authid eq '2') {
  41         $record->add_fields(
  42             [ '001', '2' ],
  43             [ '151', ' ', ' ', a => 'New York (State)' ],
  44             [ '551', ' ', ' ', a => 'United States', w => 'g', 9 => '1' ]
  45             );
  46     } elsif ($authid eq '3') {
  47         $record->add_fields(
  48             [ '001', '3' ],
  49             [ '151', ' ', ' ', a => 'New York (City)' ],
  50             [ '551', ' ', ' ', a => 'New York (State)', w => 'g', 9 => '2' ]
  51             );
  52     } elsif ($authid eq '4') {
  53         $record->add_fields(
  54             [ '001', '4' ],
  55             [ '151', ' ', ' ', a => 'New York (City)' ],
  56             [ '551', ' ', ' ', a => 'New York (State)', w => 'g' ]
  57             );
  58     } elsif ($authid eq '5') {
  59         $record->add_fields(
  60             [ '001', '5' ],
  61             [ '100', ' ', ' ', a => 'Lastname, Firstname', b => 'b', c => 'c', i => 'i' ]
  62             );
  63     } else {
  64         undef $record;
  65     }
  66     return $record;
  67 });
  68
  69 my $schema  = Koha::Database->new->schema;
  70 $schema->storage->txn_begin;
  71 my $dbh = C4::Context->dbh;
  72 my $builder = t::lib::TestBuilder->new;
  73
  74 t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
  75
  76 # Authority type GEOGR_NAME is hardcoded here
  77 if( ! Koha::Authority::Types->find('GEOGR_NAME') ) {
  78     $builder->build({ source => 'AuthType', value => { authtypecode => 'GEOGR_NAME' }});
  79 };
  80
  81 is(BuildAuthHierarchies(3, 1), '1,2,3', "Built linked authtrees hierarchy string");
  82
  83 my $expectedhierarchy = [ [ {
  84         'authid' => '1',
  85         'value' => 'United States',
  86         'class' => 'child0',
  87         'children' => [ {
  88             'authid' => '2',
  89             'value' => 'New York (State)',
  90             'class' => 'child1',
  91             'children' => [ {
  92                 'authid' => '3',
  93                 'current_value' => 1,
  94                 'value' => 'New York (City)',
  95                 'class' => 'child2',
  96                 'children' => [],
  97                 'parents' => [ {
  98                     'authid' => '2',
  99                     'value' => 'New York (State)'
 100                 } ]
 101             } ],
 102             'parents' => [ {
 103                 'authid' => '1',
 104                 'value' => 'United States'
 105             } ]
 106         } ],
 107         'parents' => []
 108 } ] ];
 109
 110 is_deeply(GenerateHierarchy(3), $expectedhierarchy, "Generated hierarchy data structure for linked hierarchy");
 111
 112 is(BuildAuthHierarchies(4, 1), '4', "Built unlinked authtrees hierarchy string");
 113 $expectedhierarchy = [ [ {
 114     'authid' => '4',
 115     'current_value' => 1,
 116     'value' => 'New York (City)',
 117     'class' => 'child0',
 118     'children' => [],
 119     'parents' => []
 120 } ] ];
 121 is_deeply(GenerateHierarchy(4), $expectedhierarchy, "Generated hierarchy data structure for unlinked hierarchy");
 122
 123 # set up auth_types for next tests
 124 $dbh->do('DELETE FROM auth_types');
 125 $dbh->do(q{
 126     INSERT INTO auth_types (authtypecode, authtypetext, auth_tag_to_report, summary)
 127     VALUES ('GEOGR_NAME', 'Geographic Name', '151', 'Geographic Name')
 128 });
 129
 130 t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
 131 my $expected_marc21_summary = {
 132     'authorized' => [
 133                       {
 134                         'field' => '151',
 135                         'heading' => 'New York (State)',
 136                         'hemain' => 'New York (State)'
 137                       }
 138                     ],
 139     'authtypecode' => 'GEOGR_NAME',
 140     'mainentry' => 'New York (State)',
 141     'mainmainentry' => 'New York (State)',
 142     'notes' => [],
 143     'otherscript' => [],
 144     'seealso' => [
 145                    {
 146                      'authid' => '1',
 147                      'field' => '551',
 148                      'heading' => 'United States',
 149                      'hemain' => 'United States',
 150                      'search' => 'United States',
 151                      'type' => 'broader'
 152                    }
 153                  ],
 154     'seefrom' => [],
 155     'label' => 'Geographic Name',
 156     'type' => 'Geographic Name'
 157 };
 158 is_deeply(
 159     BuildSummary(C4::AuthoritiesMarc::GetAuthority(2), 2, 'GEOGR_NAME'),
 160     $expected_marc21_summary,
 161     'test BuildSummary for MARC21'
 162 );
 163
 164 my $marc21_subdiv = MARC::Record->new();
 165 $marc21_subdiv->add_fields(
 166     [ '181', ' ', ' ', x => 'Political aspects' ]
 167 );
 168 warning_is { BuildSummary($marc21_subdiv, 99999, 'GEN_SUBDIV') } [],
 169     'BuildSummary does not generate warning if main heading subfield not present';
 170
 171 t::lib::Mocks::mock_preference('marcflavour', 'UNIMARC');
 172 $dbh->do(q{
 173     INSERT INTO auth_types (authtypecode, authtypetext, auth_tag_to_report, summary)
 174     VALUES ('NP', 'Auteur', '200', '[200a][, 200b][ 200d][ ; 200c][ (200f)]')
 175 });
 176
 177 my $unimarc_name_auth = MARC::Record->new();
 178 $unimarc_name_auth->add_fields(
 179     ['100', ' ', ' ',  a => '20121025              frey50       '],
 180     ['200', ' ', ' ',  a => 'Fossey', b => 'Brigitte' ],
 181     ['152', ' ', ' ',  a => 'NP'],
 182 );
 183 my $expected_unimarc_name_summary = {
 184     'authorized' => [
 185                       {
 186                         'field' => '200',
 187                         'heading' => 'Fossey Brigitte',
 188                         'hemain' => 'Fossey'
 189                       }
 190                     ],
 191     'authtypecode' => 'NP',
 192     'mainentry' => 'Fossey Brigitte',
 193     'mainmainentry' => 'Fossey',
 194     'notes' => [],
 195     'otherscript' => [],
 196     'seealso' => [],
 197     'seefrom' => [],
 198     'summary' => 'Fossey, Brigitte',
 199     'type' => 'Auteur'
 200 };
 201
 202 is_deeply(
 203     BuildSummary($unimarc_name_auth, 99999, 'NP'),
 204     $expected_unimarc_name_summary,
 205     'test BuildSummary for UNIMARC'
 206 );
 207
 208 subtest 'AddAuthority should respect AUTO_INCREMENT (BZ 18104)' => sub {
 209     plan tests => 3;
 210
 211     t::lib::Mocks::mock_preference( 'marcflavour', 'MARC21' );
 212     my $record = C4::AuthoritiesMarc::GetAuthority(1);
 213     my $id1 = AddAuthority( $record, undef, 'GEOGR_NAME' );
 214     DelAuthority({ authid => $id1 });
 215     my $id2 = AddAuthority( $record, undef, 'GEOGR_NAME' );
 216     isnt( $id1, $id2, 'Do not return the same id again' );
 217     t::lib::Mocks::mock_preference( 'marcflavour', 'UNIMARC' );
 218     my $id3 = AddAuthority( $record, undef, 'GEOGR_NAME' );
 219     ok( $id3 > 0, 'Tested AddAuthority with UNIMARC' );
 220     is( $record->field('001')->data, $id3, 'Check updated 001' );
 221 };
 222
 223 subtest 'CompareFieldWithAuthority tests' => sub {
 224     plan tests => 3;
 225
 226     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
 227
 228     $builder->build({ source => 'AuthType', value => { authtypecode => 'PERSO_NAME' }});
 229
 230     my $field = MARC::Field->new('100', 0, 0, a => 'Lastname, Firstname', b => 'b', c => 'c');
 231
 232     ok(C4::AuthoritiesMarc::CompareFieldWithAuthority({'field' => $field, 'authid' => 5}), 'Authority matches');
 233
 234     $field->add_subfields(i => 'X');
 235
 236     ok(C4::AuthoritiesMarc::CompareFieldWithAuthority({'field' => $field, 'authid' => 5}), 'Compare ignores unlisted subfields');
 237
 238     $field->add_subfields(d => 'd');
 239
 240     ok(!C4::AuthoritiesMarc::CompareFieldWithAuthority({'field' => $field, 'authid' => 5}), 'Authority does not match');
 241 };
 242
 243 $schema->storage->txn_rollback;
 244
 245 $module->unmock('GetAuthority');
 246
 247 subtest 'ModAuthority() tests' => sub {
 248
 249     plan tests => 2;
 250
 251     $schema->storage->txn_begin;
 252
 253     my $auth_type = 'GEOGR_NAME';
 254     my $record  = MARC::Record->new;
 255     $record->add_fields(
 256             [ '001', '1' ],
 257             [ '151', ' ', ' ', a => 'United States' ]
 258             );
 259 ;
 260     my $auth_id = AddAuthority( $record, undef, $auth_type );
 261
 262     my $mocked_authorities_marc = Test::MockModule->new('C4::AuthoritiesMarc');
 263     $mocked_authorities_marc->mock( 'merge', sub { warn 'merge called'; } );
 264
 265     warning_is
 266         { ModAuthority( $auth_id, $record, $auth_type ); }
 267         'merge called',
 268         'No param, merge called';
 269
 270     warning_is
 271         { ModAuthority( $auth_id, $record, $auth_type, { skip_merge => 1 } ); }
 272         undef,
 273         'skip_merge passed, merge not called';
 274
 275     $schema->storage->txn_rollback;
 276 };
 277
 278 subtest 'DelAuthority() tests' => sub {
 279
 280     plan tests => 2;
 281
 282     $schema->storage->txn_begin;
 283
 284     my $auth_type = 'GEOGR_NAME';
 285     my $record  = MARC::Record->new;
 286     $record->add_fields(
 287             [ '001', '1' ],
 288             [ '151', ' ', ' ', a => 'United States' ]
 289             );
 290 ;
 291     my $auth_id = AddAuthority( $record, undef, $auth_type );
 292
 293     my $mocked_authorities_marc = Test::MockModule->new('C4::AuthoritiesMarc');
 294     $mocked_authorities_marc->mock( 'merge', sub { warn 'merge called'; } );
 295
 296     warning_is
 297         { DelAuthority({ authid => $auth_id }); }
 298         'merge called',
 299         'No param, merge called';
 300
 301     $auth_id = AddAuthority( $record, undef, $auth_type );
 302
 303     warning_is
 304         { DelAuthority({ authid => $auth_id, skip_merge => 1 }); }
 305         undef,
 306         'skip_merge passed, merge not called';
 307
 308     $schema->storage->txn_rollback;
 309 };