t/db_dependent/Biblio.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Test::More tests => 6;
  21 use Test::MockModule;
  22
  23 use List::MoreUtils qw( uniq );
  24 use MARC::Record;
  25 use t::lib::Mocks qw( mock_preference );
  26
  27 BEGIN {
  28     use_ok('C4::Biblio');
  29 }
  30
  31 my $dbh = C4::Context->dbh;
  32 # Start transaction
  33 $dbh->{AutoCommit} = 0;
  34 $dbh->{RaiseError} = 1;
  35
  36 subtest 'GetMarcSubfieldStructureFromKohaField' => sub {
  37     plan tests => 23;
  38
  39     my @columns = qw(
  40         tagfield tagsubfield liblibrarian libopac repeatable mandatory kohafield tab
  41         authorised_value authtypecode value_builder isurl hidden frameworkcode
  42         seealso link defaultvalue maxlength
  43     );
  44
  45     # biblio.biblionumber must be mapped so this should return something
  46     my $marc_subfield_structure = GetMarcSubfieldStructureFromKohaField('biblio.biblionumber', '');
  47
  48     ok(defined $marc_subfield_structure, "There is a result");
  49     is(ref $marc_subfield_structure, "HASH", "Result is a hashref");
  50     foreach my $col (@columns) {
  51         ok(exists $marc_subfield_structure->{$col}, "Hashref contains key '$col'");
  52     }
  53     is($marc_subfield_structure->{kohafield}, 'biblio.biblionumber', "Result is the good result");
  54     like($marc_subfield_structure->{tagfield}, qr/^\d{3}$/, "tagfield is a valid tagfield");
  55
  56     # foo.bar does not exist so this should return undef
  57     $marc_subfield_structure = GetMarcSubfieldStructureFromKohaField('foo.bar', '');
  58     is($marc_subfield_structure, undef, "invalid kohafield returns undef");
  59 };
  60
  61
  62 # Mocking variables
  63 my $biblio_module = new Test::MockModule('C4::Biblio');
  64 $biblio_module->mock(
  65     'GetMarcSubfieldStructure',
  66     sub {
  67         my ($self) = shift;
  68
  69         my ( $title_field,            $title_subfield )            = get_title_field();
  70         my ( $isbn_field,             $isbn_subfield )             = get_isbn_field();
  71         my ( $issn_field,             $issn_subfield )             = get_issn_field();
  72         my ( $biblionumber_field,     $biblionumber_subfield )     = ( '999', 'c' );
  73         my ( $biblioitemnumber_field, $biblioitemnumber_subfield ) = ( '999', '9' );
  74         my ( $itemnumber_field,       $itemnumber_subfield )       = get_itemnumber_field();
  75
  76         return {
  77             'biblio.title'                 => { tagfield => $title_field,            tagsubfield => $title_subfield },
  78             'biblio.biblionumber'          => { tagfield => $biblionumber_field,     tagsubfield => $biblionumber_subfield },
  79             'biblioitems.isbn'             => { tagfield => $isbn_field,             tagsubfield => $isbn_subfield },
  80             'biblioitems.issn'             => { tagfield => $issn_field,             tagsubfield => $issn_subfield },
  81             'biblioitems.biblioitemnumber' => { tagfield => $biblioitemnumber_field, tagsubfield => $biblioitemnumber_subfield },
  82             'items.itemnumber'             => { tagfield => $itemnumber_subfield,    tagsubfield => $itemnumber_subfield },
  83         };
  84       }
  85 );
  86
  87 my $currency = new Test::MockModule('Koha::Acquisition::Currencies');
  88 $currency->mock(
  89     'get_active',
  90     sub {
  91         return Koha::Acquisition::Currency->new(
  92             {   symbol   => '$',
  93                 isocode  => 'USD',
  94                 currency => 'USD',
  95                 active   => 1,
  96             }
  97         );
  98     }
  99 );
 100
 101 sub run_tests {
 102
 103     my $marcflavour = shift;
 104     t::lib::Mocks::mock_preference('marcflavour', $marcflavour);
 105
 106     my $isbn = '0590353403';
 107     my $title = 'Foundation';
 108
 109     # Generate a record with just the ISBN
 110     my $marc_record = MARC::Record->new;
 111     $marc_record->append_fields( create_isbn_field( $isbn, $marcflavour ) );
 112
 113     # Add the record to the DB
 114     my( $biblionumber, $biblioitemnumber ) = AddBiblio( $marc_record, '' );
 115     my $data = GetBiblioData( $biblionumber );
 116     is( $data->{ isbn }, $isbn,
 117         '(GetBiblioData) ISBN correctly retireved.');
 118     is( $data->{ title }, undef,
 119         '(GetBiblioData) Title field is empty in fresh biblio.');
 120
 121     my ( $isbn_field, $isbn_subfield ) = get_isbn_field();
 122     my $marc = GetMarcBiblio( $biblionumber );
 123     is( $marc->subfield( $isbn_field, $isbn_subfield ), $isbn, );
 124
 125     # Add title
 126     my $field = create_title_field( $title, $marcflavour );
 127     $marc_record->append_fields( $field );
 128     ModBiblio( $marc_record, $biblionumber ,'' );
 129     $data = GetBiblioData( $biblionumber );
 130     is( $data->{ title }, $title,
 131         'ModBiblio correctly added the title field, and GetBiblioData.');
 132     is( $data->{ isbn }, $isbn, '(ModBiblio) ISBN is still there after ModBiblio.');
 133     $marc = GetMarcBiblio( $biblionumber );
 134     my ( $title_field, $title_subfield ) = get_title_field();
 135     is( $marc->subfield( $title_field, $title_subfield ), $title, );
 136
 137     my $itemdata = GetBiblioItemData( $biblioitemnumber );
 138     is( $itemdata->{ title }, $title,
 139         'First test of GetBiblioItemData to get same result of previous two GetBiblioData tests.');
 140     is( $itemdata->{ isbn }, $isbn,
 141         'Second test checking it returns the correct isbn.');
 142
 143     my $success = 0;
 144     $field = MARC::Field->new(
 145             655, ' ', ' ',
 146             'a' => 'Auction catalogs',
 147             '9' => '1'
 148             );
 149     eval {
 150         $marc_record->append_fields($field);
 151         $success = ModBiblio($marc_record,$biblionumber,'');
 152     } or do {
 153         diag($@);
 154         $success = 0;
 155     };
 156     ok($success, "ModBiblio handles authority-linked 655");
 157
 158     eval {
 159         $field->delete_subfields('a');
 160         $marc_record->append_fields($field);
 161         $success = ModBiblio($marc_record,$biblionumber,'');
 162     } or do {
 163         diag($@);
 164         $success = 0;
 165     };
 166     ok($success, "ModBiblio handles 655 with authority link but no heading");
 167
 168     eval {
 169         $field->delete_subfields('9');
 170         $marc_record->append_fields($field);
 171         $success = ModBiblio($marc_record,$biblionumber,'');
 172     } or do {
 173         diag($@);
 174         $success = 0;
 175     };
 176     ok($success, "ModBiblio handles 655 with no subfields");
 177
 178     ## Testing GetMarcISSN
 179     my $issns;
 180     $issns = GetMarcISSN( $marc_record, $marcflavour );
 181     is( $issns->[0], undef,
 182         'GetMarcISSN handles records without the ISSN field (list is empty)' );
 183     is( scalar @$issns, 0,
 184         'GetMarcISSN handles records without the ISSN field (count is 0)' );
 185     # Add an ISSN field
 186     my $issn = '1234-1234';
 187     $field = create_issn_field( $issn, $marcflavour );
 188     $marc_record->append_fields($field);
 189     $issns = GetMarcISSN( $marc_record, $marcflavour );
 190     is( $issns->[0], $issn,
 191         'GetMarcISSN handles records with a single ISSN field (first element is correct)' );
 192     is( scalar @$issns, 1,
 193         'GetMARCISSN handles records with a single ISSN field (count is 1)');
 194     # Add multiple ISSN field
 195     my @more_issns = qw/1111-1111 2222-2222 3333-3333/;
 196     foreach (@more_issns) {
 197         $field = create_issn_field( $_, $marcflavour );
 198         $marc_record->append_fields($field);
 199     }
 200     $issns = GetMarcISSN( $marc_record, $marcflavour );
 201     is( scalar @$issns, 4,
 202         'GetMARCISSN handles records with multiple ISSN fields (count correct)');
 203     # Create an empty ISSN
 204     $field = create_issn_field( "", $marcflavour );
 205     $marc_record->append_fields($field);
 206     $issns = GetMarcISSN( $marc_record, $marcflavour );
 207     is( scalar @$issns, 4,
 208         'GetMARCISSN skips empty ISSN fields (Bug 12674)');
 209
 210     ## Testing GetMarcControlnumber
 211     my $controlnumber;
 212     $controlnumber = GetMarcControlnumber( $marc_record, $marcflavour );
 213     is( $controlnumber, '', 'GetMarcControlnumber handles records without 001' );
 214
 215     $field = MARC::Field->new( '001', '' );
 216     $marc_record->append_fields($field);
 217     $controlnumber = GetMarcControlnumber( $marc_record, $marcflavour );
 218     is( $controlnumber, '', 'GetMarcControlnumber handles records with empty 001' );
 219
 220     $field = $marc_record->field('001');
 221     $field->update('123456789X');
 222     $controlnumber = GetMarcControlnumber( $marc_record, $marcflavour );
 223     is( $controlnumber, '123456789X', 'GetMarcControlnumber handles records with 001' );
 224
 225     ## Testing GetMarcISBN
 226     my $record_for_isbn = MARC::Record->new();
 227     my $isbns = GetMarcISBN( $record_for_isbn, $marcflavour );
 228     is( scalar @$isbns, 0, '(GetMarcISBN) The record contains no ISBN');
 229
 230     # We add one ISBN
 231     $isbn_field = create_isbn_field( $isbn, $marcflavour );
 232     $record_for_isbn->append_fields( $isbn_field );
 233     $isbns = GetMarcISBN( $record_for_isbn, $marcflavour );
 234     is( scalar @$isbns, 1, '(GetMarcISBN) The record contains one ISBN');
 235     is( $isbns->[0], $isbn, '(GetMarcISBN) The record contains our ISBN');
 236
 237     # We add 3 more ISBNs
 238     $record_for_isbn = MARC::Record->new();
 239     my @more_isbns = qw/1111111111 2222222222 3333333333 444444444/;
 240     foreach (@more_isbns) {
 241         $field = create_isbn_field( $_, $marcflavour );
 242         $record_for_isbn->append_fields($field);
 243     }
 244     $isbns = GetMarcISBN( $record_for_isbn, $marcflavour );
 245     is( scalar @$isbns, 4, '(GetMarcISBN) The record contains 4 ISBNs');
 246     for my $i (0 .. $#more_isbns) {
 247         is( $isbns->[$i], $more_isbns[$i],
 248             "(GetMarcISBN) Corretly retrieves ISBN #". ($i + 1));
 249     }
 250
 251     is( GetMarcPrice( $record_for_isbn, $marcflavour ), 100,
 252         "GetMarcPrice returns the correct value");
 253     my $newincbiblioitemnumber=$biblioitemnumber+1;
 254     $dbh->do("UPDATE biblioitems SET biblioitemnumber = ? WHERE biblionumber = ?;", undef, $newincbiblioitemnumber, $biblionumber );
 255     my $updatedrecord = GetMarcBiblio($biblionumber, 0);
 256     my $frameworkcode = GetFrameworkCode($biblionumber);
 257     my ( $biblioitem_tag, $biblioitem_subfield ) = GetMarcFromKohaField( "biblioitems.biblioitemnumber", $frameworkcode );
 258     die qq{No biblioitemnumber tag for framework "$frameworkcode"} unless $biblioitem_tag;
 259     my $biblioitemnumbertotest;
 260     if ( $biblioitem_tag < 10 ) {
 261         $biblioitemnumbertotest = $updatedrecord->field($biblioitem_tag)->data();
 262     } else {
 263         $biblioitemnumbertotest = $updatedrecord->field($biblioitem_tag)->subfield($biblioitem_subfield);
 264     }
 265     is ($newincbiblioitemnumber, $biblioitemnumbertotest, 'Check newincbiblioitemnumber');
 266
 267     # test for GetMarcNotes
 268     my $a1= GetMarcNotes( $marc_record, $marcflavour );
 269     my $field2 = MARC::Field->new( $marcflavour eq 'UNIMARC'? 300: 555, 0, '', a=> 'Some text', u=> 'http://url-1.com', u=> 'nohttp://something_else' );
 270     $marc_record->append_fields( $field2 );
 271     my $a2= GetMarcNotes( $marc_record, $marcflavour );
 272     is( ( $marcflavour eq 'UNIMARC' && @$a2 == @$a1 + 1 ) ||
 273         ( $marcflavour ne 'UNIMARC' && @$a2 == @$a1 + 3 ), 1,
 274         'Check the number of returned notes of GetMarcNotes' );
 275 }
 276
 277 sub get_title_field {
 278     my $marc_flavour = C4::Context->preference('marcflavour');
 279     return ( $marc_flavour eq 'UNIMARC' ) ? ( '200', 'a' ) : ( '245', 'a' );
 280 }
 281
 282 sub get_isbn_field {
 283     my $marc_flavour = C4::Context->preference('marcflavour');
 284     return ( $marc_flavour eq 'UNIMARC' ) ? ( '010', 'a' ) : ( '020', 'a' );
 285 }
 286
 287 sub get_issn_field {
 288     my $marc_flavour = C4::Context->preference('marcflavour');
 289     return ( $marc_flavour eq 'UNIMARC' ) ? ( '011', 'a' ) : ( '022', 'a' );
 290 }
 291
 292 sub get_itemnumber_field {
 293     my $marc_flavour = C4::Context->preference('marcflavour');
 294     return ( $marc_flavour eq 'UNIMARC' ) ? ( '995', '9' ) : ( '952', '9' );
 295 }
 296
 297 sub create_title_field {
 298     my ( $title, $marcflavour ) = @_;
 299
 300     my ( $title_field, $title_subfield ) = get_title_field();
 301     my $field = MARC::Field->new( $title_field, '', '', $title_subfield => $title );
 302
 303     return $field;
 304 }
 305
 306 sub create_isbn_field {
 307     my ( $isbn, $marcflavour ) = @_;
 308
 309     my ( $isbn_field, $isbn_subfield ) = get_isbn_field();
 310     my $field = MARC::Field->new( $isbn_field, '', '', $isbn_subfield => $isbn );
 311
 312     # Add the price subfield
 313     my $price_subfield = ( $marcflavour eq 'UNIMARC' ) ? 'd' : 'c';
 314     $field->add_subfields( $price_subfield => '$100' );
 315
 316     return $field;
 317 }
 318
 319 sub create_issn_field {
 320     my ( $issn, $marcflavour ) = @_;
 321
 322     my ( $issn_field, $issn_subfield ) = get_issn_field();
 323     my $field = MARC::Field->new( $issn_field, '', '', $issn_subfield => $issn );
 324
 325     return $field;
 326 }
 327
 328 subtest 'MARC21' => sub {
 329     plan tests => 31;
 330     run_tests('MARC21');
 331     $dbh->rollback;
 332 };
 333
 334 subtest 'UNIMARC' => sub {
 335     plan tests => 31;
 336     run_tests('UNIMARC');
 337     $dbh->rollback;
 338 };
 339
 340 subtest 'NORMARC' => sub {
 341     plan tests => 31;
 342     run_tests('NORMARC');
 343     $dbh->rollback;
 344 };
 345
 346 subtest 'IsMarcStructureInternal' => sub {
 347     plan tests => 6;
 348     my $tagslib = GetMarcStructure();
 349     my @internals;
 350     for my $tag ( sort keys %$tagslib ) {
 351         next unless $tag;
 352         for my $subfield ( sort keys %{ $tagslib->{$tag} } ) {
 353             push @internals, $subfield if IsMarcStructureInternal($tagslib->{$tag}{$subfield});
 354         }
 355     }
 356     @internals = uniq @internals;
 357     is( scalar(@internals), 4, 'expect four internals');
 358     is( grep( /^lib$/, @internals ), 1, 'check lib' );
 359     is( grep( /^tab$/, @internals ), 1, 'check tab' );
 360     is( grep( /^mandatory$/, @internals ), 1, 'check mandatory' );
 361     is( grep( /^repeatable$/, @internals ), 1, 'check repeatable' );
 362     is( grep( /^a$/, @internals ), 0, 'no subfield a' );
 363 };
 364
 365 1;