t/db_dependent/Biblio.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Test::More tests => 14;
  21 use Test::MockModule;
  22 use Test::Warn;
  23 use List::MoreUtils qw( uniq );
  24 use MARC::Record;
  25
  26 use t::lib::Mocks qw( mock_preference );
  27 use t::lib::TestBuilder;
  28
  29 use Koha::Database;
  30 use Koha::Caches;
  31 use Koha::MarcSubfieldStructures;
  32
  33 use C4::Linker::Default qw( get_link );
  34
  35 BEGIN {
  36     use_ok('C4::Biblio', qw( AddBiblio GetMarcFromKohaField BiblioAutoLink GetMarcSubfieldStructure GetMarcSubfieldStructureFromKohaField LinkBibHeadingsToAuthorities GetBiblioData GetMarcBiblio ModBiblio GetMarcISSN GetMarcControlnumber GetMarcISBN GetMarcPrice GetFrameworkCode GetMarcUrls IsMarcStructureInternal GetMarcStructure GetXmlBiblio DelBiblio ));
  37 }
  38
  39 my $schema = Koha::Database->new->schema;
  40 $schema->storage->txn_begin;
  41 my $dbh = C4::Context->dbh;
  42 Koha::Caches->get_instance->clear_from_cache( "MarcSubfieldStructure-" );
  43
  44 my $builder = t::lib::TestBuilder->new;
  45
  46 subtest 'AddBiblio' => sub {
  47     plan tests => 5;
  48
  49     my $marcflavour = 'MARC21';
  50     t::lib::Mocks::mock_preference( 'marcflavour', $marcflavour );
  51     my $record = MARC::Record->new();
  52
  53     my ( $f, $sf ) = GetMarcFromKohaField('biblioitems.lccn');
  54     my $lccn_field = MARC::Field->new( $f, ' ', ' ',
  55         $sf => 'ThisisgoingtobetoomanycharactersfortheLCCNfield' );
  56     $record->append_fields($lccn_field);
  57
  58     my $nb_biblios = Koha::Biblios->count;
  59     my ( $biblionumber, $biblioitemnumber );
  60     warnings_like { ( $biblionumber, $biblioitemnumber ) = C4::Biblio::AddBiblio( $record, '' ) }
  61         [ qr/Data too long for column 'lccn'/, qr/Data too long for column 'lccn'/ ],
  62         "expected warnings when adding too long LCCN";
  63     is( $biblionumber, undef,
  64         'AddBiblio returns undef for biblionumber if something went wrong' );
  65     is( $biblioitemnumber, undef,
  66         'AddBiblio returns undef for biblioitemnumber if something went wrong'
  67     );
  68     is( Koha::Biblios->count, $nb_biblios,
  69         'No biblio should have been added if something went wrong' );
  70
  71     t::lib::Mocks::mock_preference( 'BiblioAddsAuthorities', $marcflavour );
  72     t::lib::Mocks::mock_preference( 'AutoCreateAuthorities', $marcflavour );
  73
  74     my $mock_biblio = Test::MockModule->new("C4::Biblio");
  75     $mock_biblio->mock( BiblioAutoLink => sub {
  76         my $record = shift;
  77         my $frameworkcode = shift;
  78         warn "My biblionumber is ".$record->subfield('999','c')." and my frameworkcode is $frameworkcode";
  79     });
  80     warning_like { $builder->build_sample_biblio(); }
  81         qr/My biblionumber is \d+ and my frameworkcode is /, "The biblionumber is correctly passed to BiblioAutoLink";
  82
  83 };
  84
  85 subtest 'GetMarcSubfieldStructureFromKohaField' => sub {
  86     plan tests => 25;
  87
  88     my @columns = qw(
  89         tagfield tagsubfield liblibrarian libopac repeatable mandatory kohafield tab
  90         authorised_value authtypecode value_builder isurl hidden frameworkcode
  91         seealso link defaultvalue maxlength
  92     );
  93
  94     # biblio.biblionumber must be mapped so this should return something
  95     my $marc_subfield_structure = GetMarcSubfieldStructureFromKohaField('biblio.biblionumber');
  96
  97     ok(defined $marc_subfield_structure, "There is a result");
  98     is(ref $marc_subfield_structure, "HASH", "Result is a hashref");
  99     foreach my $col (@columns) {
 100         ok(exists $marc_subfield_structure->{$col}, "Hashref contains key '$col'");
 101     }
 102     is($marc_subfield_structure->{kohafield}, 'biblio.biblionumber', "Result is the good result");
 103     like($marc_subfield_structure->{tagfield}, qr/^\d{3}$/, "tagfield is a valid tagfield");
 104
 105     # Add a test for list context (BZ 10306)
 106     my @results = GetMarcSubfieldStructureFromKohaField('biblio.biblionumber');
 107     is( @results, 1, 'We expect only one mapping' );
 108     is_deeply( $results[0], $marc_subfield_structure,
 109         'The first entry should be the same hashref as we had before' );
 110
 111     # foo.bar does not exist so this should return undef
 112     $marc_subfield_structure = GetMarcSubfieldStructureFromKohaField('foo.bar');
 113     is($marc_subfield_structure, undef, "invalid kohafield returns undef");
 114
 115 };
 116
 117 subtest "GetMarcSubfieldStructure" => sub {
 118     plan tests => 5;
 119
 120     # Add multiple Koha to Marc mappings
 121     Koha::MarcSubfieldStructures->search({ frameworkcode => '', tagfield => '399', tagsubfield => [ 'a', 'b' ] })->delete;
 122     Koha::MarcSubfieldStructure->new({ frameworkcode => '', tagfield => '399', tagsubfield => 'a', kohafield => "mytable.nicepages" })->store;
 123     Koha::MarcSubfieldStructure->new({ frameworkcode => '', tagfield => '399', tagsubfield => 'b', kohafield => "mytable.nicepages" })->store;
 124     Koha::Caches->get_instance->clear_from_cache( "MarcSubfieldStructure-" );
 125     my $structure = C4::Biblio::GetMarcSubfieldStructure('');
 126
 127     is( @{ $structure->{"mytable.nicepages"} }, 2,
 128         'GetMarcSubfieldStructure should return two entries for nicepages' );
 129     is( $structure->{"mytable.nicepages"}->[0]->{tagfield}, '399',
 130         'Check tagfield for first entry' );
 131     is( $structure->{"mytable.nicepages"}->[0]->{tagsubfield}, 'a',
 132         'Check tagsubfield for first entry' );
 133     is( $structure->{"mytable.nicepages"}->[1]->{tagfield}, '399',
 134         'Check tagfield for second entry' );
 135     is( $structure->{"mytable.nicepages"}->[1]->{tagsubfield}, 'b',
 136         'Check tagsubfield for second entry' );
 137 };
 138
 139 subtest "GetMarcFromKohaField" => sub {
 140     plan tests => 8;
 141
 142     #NOTE: We are building on data from the previous subtest
 143     # With: field 399 / mytable.nicepages
 144
 145     # Check call in list context for multiple mappings
 146     my @retval = C4::Biblio::GetMarcFromKohaField('mytable.nicepages');
 147     is( @retval, 4, 'Should return two tags and subfields' );
 148     is( $retval[0], '399', 'Check first tag' );
 149     is( $retval[1], 'a', 'Check first subfield' );
 150     is( $retval[2], '399', 'Check second tag' );
 151     is( $retval[3], 'b', 'Check second subfield' );
 152
 153     # Check same call in scalar context
 154     is( C4::Biblio::GetMarcFromKohaField('mytable.nicepages'), '399',
 155         'GetMarcFromKohaField returns first tag in scalar context' );
 156
 157     # Bug 19096 Default is authoritative
 158     # If we add a new empty framework, we should still get the mappings
 159     # from Default. CAUTION: This test passes intentionally the obsoleted
 160     # framework parameter.
 161     my $new_fw = t::lib::TestBuilder->new->build({source => 'BiblioFramework'});
 162     @retval = C4::Biblio::GetMarcFromKohaField(
 163         'mytable.nicepages', $new_fw->{frameworkcode},
 164     );
 165     is( @retval, 4, 'Still got two pairs of tags/subfields' );
 166     is( $retval[0].$retval[1], '399a', 'Including 399a' );
 167 };
 168
 169 subtest "Authority creation with default linker" => sub {
 170     plan tests => 4;
 171     # Automatic authority creation
 172     t::lib::Mocks::mock_preference('LinkerModule', 'Default');
 173     t::lib::Mocks::mock_preference('BiblioAddsAuthorities', 1);
 174     t::lib::Mocks::mock_preference('AutoCreateAuthorities', 1);
 175     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
 176     my $linker = C4::Linker::Default->new({});
 177     my $authorities_mod = Test::MockModule->new( 'C4::Heading' );
 178     $authorities_mod->mock(
 179         'authorities',
 180         sub {
 181             my $results = [{ authid => 'original' },{ authid => 'duplicate' }];
 182             return $results;
 183         }
 184     );
 185     my $marc_record = MARC::Record->new();
 186     my $field = MARC::Field->new(655, ' ', ' ','a' => 'Magical realism');
 187     $marc_record->append_fields( $field );
 188     my ($num_changed,$results) = LinkBibHeadingsToAuthorities($linker, $marc_record, "",undef);
 189     is( $num_changed, 0, "We shouldn't link or create a new record");
 190     ok( !defined $results->{added}, "If we have multiple matches, we shouldn't create a new record");
 191
 192     ($num_changed,$results) = LinkBibHeadingsToAuthorities($linker, $marc_record, "",undef);
 193     is( $num_changed, 0, "We shouldn't link or create a new record using cached result");
 194     ok( !defined $results->{added}, "If we have multiple matches, we shouldn't create a new record on second instance");
 195 };
 196
 197
 198
 199 # Mocking variables
 200 my $biblio_module = Test::MockModule->new('C4::Biblio');
 201 $biblio_module->mock(
 202     'GetMarcSubfieldStructure',
 203     sub {
 204         my ($self) = shift;
 205
 206         my ( $title_field,            $title_subfield )            = get_title_field();
 207         my ( $subtitle_field,         $subtitle_subfield )         = get_subtitle_field();
 208         my ( $medium_field,           $medium_subfield )           = get_medium_field();
 209         my ( $part_number_field,      $part_number_subfield )      = get_part_number_field();
 210         my ( $part_name_field,        $part_name_subfield )        = get_part_name_field();
 211         my ( $isbn_field,             $isbn_subfield )             = get_isbn_field();
 212         my ( $issn_field,             $issn_subfield )             = get_issn_field();
 213         my ( $biblionumber_field,     $biblionumber_subfield )     = ( '999', 'c' );
 214         my ( $biblioitemnumber_field, $biblioitemnumber_subfield ) = ( '999', '9' );
 215         my ( $itemnumber_field,       $itemnumber_subfield )       = get_itemnumber_field();
 216
 217         return {
 218             'biblio.title'                 => [ { tagfield => $title_field,            tagsubfield => $title_subfield } ],
 219             'biblio.subtitle'              => [ { tagfield => $subtitle_field,         tagsubfield => $subtitle_subfield } ],
 220             'biblio.medium'                => [ { tagfield => $medium_field,           tagsubfield => $medium_subfield } ],
 221             'biblio.part_number'           => [ { tagfield => $part_number_field,      tagsubfield => $part_number_subfield } ],
 222             'biblio.part_name'             => [ { tagfield => $part_name_field,        tagsubfield => $part_name_subfield } ],
 223             'biblio.biblionumber'          => [ { tagfield => $biblionumber_field,     tagsubfield => $biblionumber_subfield } ],
 224             'biblioitems.isbn'             => [ { tagfield => $isbn_field,             tagsubfield => $isbn_subfield } ],
 225             'biblioitems.issn'             => [ { tagfield => $issn_field,             tagsubfield => $issn_subfield } ],
 226             'biblioitems.biblioitemnumber' => [ { tagfield => $biblioitemnumber_field, tagsubfield => $biblioitemnumber_subfield } ],
 227             'items.itemnumber'             => [ { tagfield => $itemnumber_subfield,    tagsubfield => $itemnumber_subfield } ],
 228         };
 229       }
 230 );
 231
 232 my $currency = Test::MockModule->new('Koha::Acquisition::Currencies');
 233 $currency->mock(
 234     'get_active',
 235     sub {
 236         return Koha::Acquisition::Currency->new(
 237             {   symbol   => '$',
 238                 isocode  => 'USD',
 239                 currency => 'USD',
 240                 active   => 1,
 241             }
 242         );
 243     }
 244 );
 245
 246 sub run_tests {
 247
 248     my $marcflavour = shift;
 249     t::lib::Mocks::mock_preference('marcflavour', $marcflavour);
 250     # Authority tests don't interact well with Elasticsearch at the moment due to the fact that there's currently no way to
 251     # roll back ES index changes.
 252     t::lib::Mocks::mock_preference('SearchEngine', 'Zebra');
 253
 254     my $isbn = '0590353403';
 255     my $title = 'Foundation';
 256     my $subtitle1 = 'Research';
 257     my $subtitle2 = 'Conclusions';
 258     my $medium = 'Medium';
 259     my $part_number = '123';
 260     my $part_name = 'First years';
 261
 262     # Generate a record with just the ISBN
 263     my $marc_record = MARC::Record->new;
 264     $marc_record->append_fields( create_isbn_field( $isbn, $marcflavour ) );
 265
 266     # Add the record to the DB
 267     my( $biblionumber, $biblioitemnumber ) = AddBiblio( $marc_record, '' );
 268     my $data = GetBiblioData( $biblionumber );
 269     is( $data->{ isbn }, $isbn,
 270         '(GetBiblioData) ISBN correctly retireved.');
 271     is( $data->{ title }, undef,
 272         '(GetBiblioData) Title field is empty in fresh biblio.');
 273
 274     my ( $isbn_field, $isbn_subfield ) = get_isbn_field();
 275     my $marc = GetMarcBiblio({ biblionumber => $biblionumber });
 276     is( $marc->subfield( $isbn_field, $isbn_subfield ), $isbn, );
 277
 278     # Add title
 279     my $field = create_title_field( $title, $marcflavour );
 280     $marc_record->append_fields( $field );
 281     ModBiblio( $marc_record, $biblionumber ,'' );
 282     $data = GetBiblioData( $biblionumber );
 283     is( $data->{ title }, $title,
 284         'ModBiblio correctly added the title field, and GetBiblioData.');
 285     is( $data->{ isbn }, $isbn, '(ModBiblio) ISBN is still there after ModBiblio.');
 286     $marc = GetMarcBiblio({ biblionumber => $biblionumber });
 287     my ( $title_field, $title_subfield ) = get_title_field();
 288     is( $marc->subfield( $title_field, $title_subfield ), $title, );
 289
 290     # Add other fields
 291     $marc_record->append_fields( create_field( $subtitle1, $marcflavour, get_subtitle_field() ) );
 292     $marc_record->append_fields( create_field( $subtitle2, $marcflavour, get_subtitle_field() ) );
 293     $marc_record->append_fields( create_field( $medium, $marcflavour, get_medium_field() ) );
 294     $marc_record->append_fields( create_field( $part_number, $marcflavour, get_part_number_field() ) );
 295     $marc_record->append_fields( create_field( $part_name, $marcflavour, get_part_name_field() ) );
 296
 297     ModBiblio( $marc_record, $biblionumber ,'' );
 298     $data = GetBiblioData( $biblionumber );
 299     is( $data->{ title }, $title, '(ModBiblio) still there after adding other fields.' );
 300     is( $data->{ isbn }, $isbn, '(ModBiblio) ISBN is still there after adding other fields.' );
 301
 302     is( $data->{ subtitle }, "$subtitle1 | $subtitle2", '(ModBiblio) subtitles correctly added and returned in GetBiblioData.' );
 303     is( $data->{ medium }, $medium, '(ModBiblio) medium correctly added and returned in GetBiblioData.' );
 304     is( $data->{ part_number }, $part_number, '(ModBiblio) part_number correctly added and returned in GetBiblioData.' );
 305     is( $data->{ part_name }, $part_name, '(ModBiblio) part_name correctly added and returned in GetBiblioData.' );
 306
 307     my $biblioitem = Koha::Biblioitems->find( $biblioitemnumber );
 308     is( $biblioitem->_result->biblio->title, $title, # Should be $biblioitem->biblio instead, but not needed elsewhere for now
 309         'Do not know if this makes sense - compare result of previous two GetBiblioData tests.');
 310     is( $biblioitem->isbn, $isbn,
 311         'Second test checking it returns the correct isbn.');
 312
 313     my $success = 0;
 314     $field = MARC::Field->new(
 315             655, ' ', ' ',
 316             'a' => 'Auction catalogs',
 317             '9' => '1'
 318             );
 319     eval {
 320         $marc_record->append_fields($field);
 321         $success = ModBiblio($marc_record,$biblionumber,'');
 322     } or do {
 323         diag($@);
 324         $success = 0;
 325     };
 326     ok($success, "ModBiblio handles authority-linked 655");
 327
 328     eval {
 329         $field->delete_subfields('a');
 330         $marc_record->append_fields($field);
 331         $success = ModBiblio($marc_record,$biblionumber,'');
 332     } or do {
 333         diag($@);
 334         $success = 0;
 335     };
 336     ok($success, "ModBiblio handles 655 with authority link but no heading");
 337
 338     eval {
 339         $field->delete_subfields('9');
 340         $marc_record->append_fields($field);
 341         $success = ModBiblio($marc_record,$biblionumber,'');
 342     } or do {
 343         diag($@);
 344         $success = 0;
 345     };
 346     ok($success, "ModBiblio handles 655 with no subfields");
 347
 348     ## Testing GetMarcISSN
 349     my $issns;
 350     $issns = GetMarcISSN( $marc_record, $marcflavour );
 351     is( $issns->[0], undef,
 352         'GetMarcISSN handles records without the ISSN field (list is empty)' );
 353     is( scalar @$issns, 0,
 354         'GetMarcISSN handles records without the ISSN field (count is 0)' );
 355     # Add an ISSN field
 356     my $issn = '1234-1234';
 357     $field = create_issn_field( $issn, $marcflavour );
 358     $marc_record->append_fields($field);
 359     $issns = GetMarcISSN( $marc_record, $marcflavour );
 360     is( $issns->[0], $issn,
 361         'GetMarcISSN handles records with a single ISSN field (first element is correct)' );
 362     is( scalar @$issns, 1,
 363         'GetMARCISSN handles records with a single ISSN field (count is 1)');
 364     # Add multiple ISSN field
 365     my @more_issns = qw/1111-1111 2222-2222 3333-3333/;
 366     foreach (@more_issns) {
 367         $field = create_issn_field( $_, $marcflavour );
 368         $marc_record->append_fields($field);
 369     }
 370     $issns = GetMarcISSN( $marc_record, $marcflavour );
 371     is( scalar @$issns, 4,
 372         'GetMARCISSN handles records with multiple ISSN fields (count correct)');
 373     # Create an empty ISSN
 374     $field = create_issn_field( "", $marcflavour );
 375     $marc_record->append_fields($field);
 376     $issns = GetMarcISSN( $marc_record, $marcflavour );
 377     is( scalar @$issns, 4,
 378         'GetMARCISSN skips empty ISSN fields (Bug 12674)');
 379
 380     ## Testing GetMarcControlnumber
 381     my $controlnumber;
 382     $controlnumber = GetMarcControlnumber( $marc_record, $marcflavour );
 383     is( $controlnumber, '', 'GetMarcControlnumber handles records without 001' );
 384
 385     $field = MARC::Field->new( '001', '' );
 386     $marc_record->append_fields($field);
 387     $controlnumber = GetMarcControlnumber( $marc_record, $marcflavour );
 388     is( $controlnumber, '', 'GetMarcControlnumber handles records with empty 001' );
 389
 390     $field = $marc_record->field('001');
 391     $field->update('123456789X');
 392     $controlnumber = GetMarcControlnumber( $marc_record, $marcflavour );
 393     is( $controlnumber, '123456789X', 'GetMarcControlnumber handles records with 001' );
 394
 395     ## Testing GetMarcISBN
 396     my $record_for_isbn = MARC::Record->new();
 397     my $isbns = GetMarcISBN( $record_for_isbn, $marcflavour );
 398     is( scalar @$isbns, 0, '(GetMarcISBN) The record contains no ISBN');
 399
 400     # We add one ISBN
 401     $isbn_field = create_isbn_field( $isbn, $marcflavour );
 402     $record_for_isbn->append_fields( $isbn_field );
 403     $isbns = GetMarcISBN( $record_for_isbn, $marcflavour );
 404     is( scalar @$isbns, 1, '(GetMarcISBN) The record contains one ISBN');
 405     is( $isbns->[0], $isbn, '(GetMarcISBN) The record contains our ISBN');
 406
 407     # We add 3 more ISBNs
 408     $record_for_isbn = MARC::Record->new();
 409     my @more_isbns = qw/1111111111 2222222222 3333333333 444444444/;
 410     foreach (@more_isbns) {
 411         $field = create_isbn_field( $_, $marcflavour );
 412         $record_for_isbn->append_fields($field);
 413     }
 414     $isbns = GetMarcISBN( $record_for_isbn, $marcflavour );
 415     is( scalar @$isbns, 4, '(GetMarcISBN) The record contains 4 ISBNs');
 416     for my $i (0 .. $#more_isbns) {
 417         is( $isbns->[$i], $more_isbns[$i],
 418             "(GetMarcISBN) Correctly retrieves ISBN #". ($i + 1));
 419     }
 420
 421     is( GetMarcPrice( $record_for_isbn, $marcflavour ), 100,
 422         "GetMarcPrice returns the correct value");
 423     my $updatedrecord = GetMarcBiblio({
 424         biblionumber => $biblionumber,
 425         embed_items  => 0 });
 426     my $frameworkcode = GetFrameworkCode($biblionumber);
 427     my ( $biblioitem_tag, $biblioitem_subfield ) = GetMarcFromKohaField( "biblioitems.biblioitemnumber" );
 428     die qq{No biblioitemnumber tag for framework "$frameworkcode"} unless $biblioitem_tag;
 429     my $biblioitemnumbertotest;
 430     if ( $biblioitem_tag < 10 ) {
 431         $biblioitemnumbertotest = $updatedrecord->field($biblioitem_tag)->data();
 432     } else {
 433         $biblioitemnumbertotest = $updatedrecord->field($biblioitem_tag)->subfield($biblioitem_subfield);
 434     }
 435
 436     # test for GetMarcUrls
 437     $marc_record->append_fields(
 438         MARC::Field->new( '856', '', '', u => ' https://koha-community.org ' ),
 439         MARC::Field->new( '856', '', '', u => 'koha-community.org' ),
 440     );
 441     my $marcurl = GetMarcUrls( $marc_record, $marcflavour );
 442     is( @$marcurl, 2, 'GetMarcUrls returns two URLs' );
 443     like( $marcurl->[0]->{MARCURL}, qr/^https/, 'GetMarcUrls did not stumble over a preceding space' );
 444     ok( $marcflavour ne 'MARC21' || $marcurl->[1]->{MARCURL} =~ /^http:\/\//,
 445         'GetMarcUrls prefixed a MARC21 URL with http://' );
 446
 447     # Automatic authority creation
 448     t::lib::Mocks::mock_preference('BiblioAddsAuthorities', 1);
 449     t::lib::Mocks::mock_preference('AutoCreateAuthorities', 1);
 450     my $authorities_mod = Test::MockModule->new( 'C4::Heading' );
 451     $authorities_mod->mock(
 452         'authorities',
 453         sub {
 454             my @results;
 455             return \@results;
 456         }
 457     );
 458     $success = 0;
 459     $field = create_author_field('Author Name');
 460     eval {
 461         $marc_record->append_fields($field);
 462         $success = ModBiblio($marc_record,$biblionumber,'');
 463     } or do {
 464         diag($@);
 465         $success = 0;
 466     };
 467     ok($success, "ModBiblio handles authority addition for author");
 468
 469     my ($author_field, $author_subfield, $author_relator_subfield) = get_author_field();
 470     $field = $marc_record->field($author_field);
 471     ok($field->subfield($author_subfield), "ModBiblio keeps $author_field$author_subfield intact");
 472
 473     my $authid = $field->subfield('9');
 474     ok($authid, 'ModBiblio adds authority id');
 475
 476     use_ok('C4::AuthoritiesMarc', qw( GetAuthority ));
 477     my $auth_record = C4::AuthoritiesMarc::GetAuthority($authid);
 478     ok($auth_record, 'Authority record successfully retrieved');
 479
 480
 481     my ($auth_author_field, $auth_author_subfield) = get_auth_author_field();
 482     $field = $auth_record->field($auth_author_field);
 483     ok($field, "Authority record contains field $auth_author_field");
 484     is(
 485         $field->subfield($auth_author_subfield),
 486         'Author Name',
 487         'Authority $auth_author_field$auth_author_subfield contains author name'
 488     );
 489     is($field->subfield($author_relator_subfield), undef, 'Authority does not contain relator subfield');
 490
 491     # Reset settings
 492     t::lib::Mocks::mock_preference('BiblioAddsAuthorities', 0);
 493     t::lib::Mocks::mock_preference('AutoCreateAuthorities', 0);
 494 }
 495
 496 sub get_title_field {
 497     my $marc_flavour = C4::Context->preference('marcflavour');
 498     return ( $marc_flavour eq 'UNIMARC' ) ? ( '200', 'a' ) : ( '245', 'a' );
 499 }
 500
 501 sub get_medium_field {
 502     my $marc_flavour = C4::Context->preference('marcflavour');
 503     return ( $marc_flavour eq 'UNIMARC' ) ? ( '200', 'b' ) : ( '245', 'h' );
 504 }
 505
 506 sub get_subtitle_field {
 507     my $marc_flavour = C4::Context->preference('marcflavour');
 508     return ( $marc_flavour eq 'UNIMARC' ) ? ( '200', 'e' ) : ( '245', 'b' );
 509 }
 510
 511 sub get_part_number_field {
 512     my $marc_flavour = C4::Context->preference('marcflavour');
 513     return ( $marc_flavour eq 'UNIMARC' ) ? ( '200', 'h' ) : ( '245', 'n' );
 514 }
 515
 516 sub get_part_name_field {
 517     my $marc_flavour = C4::Context->preference('marcflavour');
 518     return ( $marc_flavour eq 'UNIMARC' ) ? ( '200', 'i' ) : ( '245', 'p' );
 519 }
 520
 521 sub get_isbn_field {
 522     my $marc_flavour = C4::Context->preference('marcflavour');
 523     return ( $marc_flavour eq 'UNIMARC' ) ? ( '010', 'a' ) : ( '020', 'a' );
 524 }
 525
 526 sub get_issn_field {
 527     my $marc_flavour = C4::Context->preference('marcflavour');
 528     return ( $marc_flavour eq 'UNIMARC' ) ? ( '011', 'a' ) : ( '022', 'a' );
 529 }
 530
 531 sub get_itemnumber_field {
 532     my $marc_flavour = C4::Context->preference('marcflavour');
 533     return ( $marc_flavour eq 'UNIMARC' ) ? ( '995', '9' ) : ( '952', '9' );
 534 }
 535
 536 sub get_author_field {
 537     my $marc_flavour = C4::Context->preference('marcflavour');
 538     return ( $marc_flavour eq 'UNIMARC' ) ? ( '700', 'a', '4' ) : ( '100', 'a', 'e' );
 539 }
 540
 541 sub get_auth_author_field {
 542     my $marc_flavour = C4::Context->preference('marcflavour');
 543     return ( $marc_flavour eq 'UNIMARC' ) ? ( '106', 'a' ) : ( '100', 'a' );
 544 }
 545
 546 sub create_title_field {
 547     my ( $title, $marcflavour ) = @_;
 548
 549     my ( $title_field, $title_subfield ) = get_title_field();
 550     my $field = MARC::Field->new( $title_field, '', '', $title_subfield => $title );
 551
 552     return $field;
 553 }
 554
 555 sub create_field {
 556     my ( $content, $marcflavour, $field, $subfield ) = @_;
 557
 558     return MARC::Field->new( $field, '', '', $subfield => $content );
 559 }
 560
 561 sub create_isbn_field {
 562     my ( $isbn, $marcflavour ) = @_;
 563
 564     my ( $isbn_field, $isbn_subfield ) = get_isbn_field();
 565     my $field = MARC::Field->new( $isbn_field, '', '', $isbn_subfield => $isbn );
 566
 567     # Add the price subfield
 568     my $price_subfield = ( $marcflavour eq 'UNIMARC' ) ? 'd' : 'c';
 569     $field->add_subfields( $price_subfield => '$100' );
 570
 571     return $field;
 572 }
 573
 574 sub create_issn_field {
 575     my ( $issn, $marcflavour ) = @_;
 576
 577     my ( $issn_field, $issn_subfield ) = get_issn_field();
 578     my $field = MARC::Field->new( $issn_field, '', '', $issn_subfield => $issn );
 579
 580     return $field;
 581 }
 582
 583 sub create_author_field {
 584     my ( $author ) = @_;
 585
 586     my ( $author_field, $author_subfield, $author_relator_subfield ) = get_author_field();
 587     my $field = MARC::Field->new(
 588         $author_field, '', '',
 589         $author_subfield => $author,
 590         $author_relator_subfield => 'aut'
 591     );
 592
 593     return $field;
 594 }
 595
 596 subtest 'MARC21' => sub {
 597     plan tests => 46;
 598     run_tests('MARC21');
 599     $schema->storage->txn_rollback;
 600     $schema->storage->txn_begin;
 601 };
 602
 603 subtest 'UNIMARC' => sub {
 604     plan tests => 46;
 605
 606     # Mock the auth type data for UNIMARC
 607     $dbh->do("UPDATE auth_types SET auth_tag_to_report = '106' WHERE auth_tag_to_report = '100'") or die $dbh->errstr;
 608
 609     run_tests('UNIMARC');
 610     $schema->storage->txn_rollback;
 611     $schema->storage->txn_begin;
 612 };
 613
 614 subtest 'IsMarcStructureInternal' => sub {
 615     plan tests => 9;
 616     my $tagslib = GetMarcStructure();
 617     my @internals;
 618     for my $tag ( sort keys %$tagslib ) {
 619         next unless $tag;
 620         for my $subfield ( sort keys %{ $tagslib->{$tag} } ) {
 621             push @internals, $subfield if IsMarcStructureInternal($tagslib->{$tag}{$subfield});
 622         }
 623     }
 624     @internals = uniq @internals;
 625     is( scalar(@internals), 7, 'expect 7 internals');
 626     is( grep( /^lib$/, @internals ), 1, 'check lib' );
 627     is( grep( /^tab$/, @internals ), 1, 'check tab' );
 628     is( grep( /^mandatory$/, @internals ), 1, 'check mandatory' );
 629     is( grep( /^repeatable$/, @internals ), 1, 'check repeatable' );
 630     is( grep( /^important$/, @internals ), 1, 'check important' );
 631     is( grep( /^a$/, @internals ), 0, 'no subfield a' );
 632     is( grep( /^ind1_defaultvalue$/, @internals ), 1, 'check indicator 1 default value' );
 633     is( grep( /^ind2_defaultvalue$/, @internals ), 1, 'check indicator 2 default value' );
 634 };
 635
 636 subtest 'deletedbiblio_metadata' => sub {
 637     plan tests => 2;
 638
 639     my ($biblionumber, $biblioitemnumber) = AddBiblio(MARC::Record->new, '');
 640     my $biblio_metadata = C4::Biblio::GetXmlBiblio( $biblionumber );
 641     C4::Biblio::DelBiblio( $biblionumber );
 642     my ( $moved ) = $dbh->selectrow_array(q|SELECT biblionumber FROM deletedbiblio WHERE biblionumber=?|, undef, $biblionumber);
 643     is( $moved, $biblionumber, 'Found in deletedbiblio' );
 644     ( $moved ) = $dbh->selectrow_array(q|SELECT biblionumber FROM deletedbiblio_metadata WHERE biblionumber=?|, undef, $biblionumber);
 645     is( $moved, $biblionumber, 'Found in deletedbiblio_metadata' );
 646 };
 647
 648 subtest 'DelBiblio' => sub {
 649     plan tests => 5;
 650
 651     my ($biblionumber, $biblioitemnumber) = C4::Biblio::AddBiblio(MARC::Record->new, '');
 652     my $deleted = C4::Biblio::DelBiblio( $biblionumber );
 653     is( $deleted, undef, 'DelBiblio returns undef is the biblio has been deleted correctly - Must be 1 instead'); # FIXME We should return 1 instead!
 654
 655     $deleted = C4::Biblio::DelBiblio( $biblionumber );
 656     is( $deleted, undef, 'DelBiblo should return undef is the record did not exist');
 657
 658     my $biblio       = $builder->build_sample_biblio;
 659     my $subscription = $builder->build_object(
 660         {
 661             class => 'Koha::Subscriptions',
 662             value => { biblionumber => $biblio->biblionumber }
 663         }
 664     );
 665     my $serial = $builder->build_object(
 666         {
 667             class => 'Koha::Serials',
 668             value => {
 669                 biblionumber   => $biblio->biblionumber,
 670                 subscriptionid => $subscription->subscriptionid
 671             }
 672         }
 673     );
 674     my $subscription_history = $builder->build_object(
 675         {
 676             class => 'Koha::Subscription::Histories',
 677             value => {
 678                 biblionumber   => $biblio->biblionumber,
 679                 subscriptionid => $subscription->subscriptionid
 680             }
 681         }
 682     );
 683     C4::Biblio::DelBiblio($biblio->biblionumber); # Or $biblio->delete
 684     is( $subscription->get_from_storage, undef, 'subscription should be deleted on biblio deletion' );
 685     is( $serial->get_from_storage, undef, 'serial should be deleted on biblio deletion' );
 686     is( $subscription_history->get_from_storage, undef, 'subscription history should be deleted on biblio deletion' );
 687 };
 688
 689 subtest 'MarcFieldForCreatorAndModifier' => sub {
 690     plan tests => 8;
 691
 692     t::lib::Mocks::mock_preference('MarcFieldForCreatorId', '998$a');
 693     t::lib::Mocks::mock_preference('MarcFieldForCreatorName', '998$b');
 694     t::lib::Mocks::mock_preference('MarcFieldForModifierId', '998$c');
 695     t::lib::Mocks::mock_preference('MarcFieldForModifierName', '998$d');
 696     my $c4_context = Test::MockModule->new('C4::Context');
 697     $c4_context->mock('userenv', sub { return { number => 123, firstname => 'John', surname => 'Doe'}; });
 698
 699     my $record = MARC::Record->new();
 700     my ($biblionumber) = C4::Biblio::AddBiblio($record, '');
 701
 702     $record = GetMarcBiblio({biblionumber => $biblionumber});
 703     is($record->subfield('998', 'a'), 123, '998$a = 123');
 704     is($record->subfield('998', 'b'), 'John Doe', '998$b = John Doe');
 705     is($record->subfield('998', 'c'), 123, '998$c = 123');
 706     is($record->subfield('998', 'd'), 'John Doe', '998$d = John Doe');
 707
 708     $c4_context->mock('userenv', sub { return { number => 321, firstname => 'Jane', surname => 'Doe'}; });
 709     C4::Biblio::ModBiblio($record, $biblionumber, '');
 710
 711     $record = GetMarcBiblio({biblionumber => $biblionumber});
 712     is($record->subfield('998', 'a'), 123, '998$a = 123');
 713     is($record->subfield('998', 'b'), 'John Doe', '998$b = John Doe');
 714     is($record->subfield('998', 'c'), 321, '998$c = 321');
 715     is($record->subfield('998', 'd'), 'Jane Doe', '998$d = Jane Doe');
 716 };
 717
 718 subtest 'ModBiblio called from linker test' => sub {
 719     plan tests => 2;
 720     my $called = 0;
 721     t::lib::Mocks::mock_preference('BiblioAddsAuthorities', 1);
 722     my $biblio_mod = Test::MockModule->new( 'C4::Biblio' );
 723     $biblio_mod->mock( 'LinkBibHeadingsToAuthorities', sub {
 724         $called = 1;
 725     });
 726     my $record = MARC::Record->new();
 727     my ($biblionumber) = C4::Biblio::AddBiblio($record,'');
 728     C4::Biblio::ModBiblio($record,$biblionumber,'');
 729     is($called,1,"We called to link bibs because not from linker");
 730     $called = 0;
 731     C4::Biblio::ModBiblio($record,$biblionumber,'',{ disable_autolink => 1 });
 732     is($called,0,"We didn't call to link bibs because from linker");
 733 };
 734
 735 subtest "LinkBibHeadingsToAuthorities record generation tests" => sub {
 736     plan tests => 12;
 737
 738     # Set up mocks to ensure authorities are generated
 739     my $biblio_mod = Test::MockModule->new( 'C4::Linker::Default' );
 740     $biblio_mod->mock( 'get_link', sub {
 741         return (undef,undef);
 742     });
 743     # UNIMARC valid headings are built from the marc_subfield_structure for bibs and
 744     # include all subfields as valid, testing with MARC21 should be sufficient for now
 745     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
 746     t::lib::Mocks::mock_preference('AutoCreateAuthorities', '1');
 747
 748     my $linker = C4::Linker::Default->new();
 749     my $biblio = $builder->build_sample_biblio();
 750     my $record = $biblio->metadata->record;
 751
 752     # Generate a record including all valid subfields and an invalid one 'e'
 753     my $field = MARC::Field->new('650','','','a' => 'Beach city', 'b' => 'Weirdness', 'v' => 'Fiction', 'x' => 'Books', 'y' => '21st Century', 'z' => 'Fish Stew Pizza', 'e' => 'Depicted');
 754
 755     $record->append_fields($field);
 756     my ( $num_headings_changed, $results ) = LinkBibHeadingsToAuthorities($linker, $record, "",undef,650);
 757
 758     is( $num_headings_changed, 1, 'We changed the one we passed' );
 759     is_deeply( $results->{added},
 760         {"Beach city Weirdness--Fiction--Books--21st Century--Fish Stew Pizza" => 1 },
 761         "We added an authority record for the heading"
 762     );
 763
 764     # Now we check the authority record itself
 765     my $authority = GetAuthority( $record->subfield('650','9') );
 766     is( $authority->field('150')->as_string(),
 767         "Beach city Weirdness Fiction Books 21st Century Fish Stew Pizza",
 768         "The generated record contains the correct subfields"
 769     );
 770
 771     #Add test for this case using verbose
 772     $record->field('650')->delete_subfield('9');
 773     ( $num_headings_changed, $results ) = LinkBibHeadingsToAuthorities($linker, $record, "",undef, 650, 1);
 774     is( $num_headings_changed, 1, 'We changed the one we passed' );
 775     is( $results->{details}->[0]->{status}, 'CREATED', "We added an authority record for the heading using verbose");
 776
 777     # Now we check the authority record itself
 778     $authority = GetAuthority($results->{details}->[0]->{authid});
 779
 780     is( $authority->field('150')->as_string(),
 781          "Beach city Weirdness Fiction Books 21st Century Fish Stew Pizza",
 782          "The generated record contains the correct subfields when using verbose"
 783     );
 784
 785     # Example series link with volume and punctuation
 786     $field = MARC::Field->new('800','','','a' => 'Tolkien, J. R. R.', 'q' => '(John Ronald Reuel),', 'd' => '1892-1973.', 't' => 'Lord of the rings ;', 'v' => '1');
 787     $record->append_fields($field);
 788
 789     ( $num_headings_changed, $results ) = LinkBibHeadingsToAuthorities($linker, $record, "",undef, 800);
 790
 791     is( $num_headings_changed, 1, 'We changed the one we passed' );
 792     is_deeply( $results->{added},
 793         {"Tolkien, J. R. R. (John Ronald Reuel), 1892-1973. Lord of the rings ;" => 1 },
 794         "We added an authority record for the heading"
 795     );
 796
 797     # Now we check the authority record itself
 798     $authority = GetAuthority( $record->subfield('800','9') );
 799     is( $authority->field('100')->as_string(),
 800         "Tolkien, J. R. R. (John Ronald Reuel), 1892-1973. Lord of the rings",
 801         "The generated record contains the correct subfields"
 802     );
 803
 804     # The same example With verbose
 805     $record->field('800')->delete_subfield('9');
 806     ( $num_headings_changed, $results ) = LinkBibHeadingsToAuthorities($linker, $record, "",undef, 800, 1);
 807     is( $num_headings_changed, 1, 'We changed the one we passed' );
 808     is( $results->{details}->[0]->{status}, 'CREATED', "We added an authority record for the heading using verbose");
 809
 810     # Now we check the authority record itself
 811     $authority = GetAuthority($results->{details}->[0]->{authid});
 812     is( $authority->field('100')->as_string(),
 813          "Tolkien, J. R. R. (John Ronald Reuel), 1892-1973. Lord of the rings",
 814          "The generated record contains the correct subfields"
 815     );
 816 };
 817
 818 # Cleanup
 819 Koha::Caches->get_instance->clear_from_cache( "MarcSubfieldStructure-" );
 820 $schema->storage->txn_rollback;