t/db_dependent/Biblio.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Test::More tests => 14;
  21 use Test::MockModule;
  22 use Test::Warn;
  23 use List::MoreUtils qw( uniq );
  24 use MARC::Record;
  25
  26 use t::lib::Mocks qw( mock_preference );
  27 use t::lib::TestBuilder;
  28
  29 use Koha::Database;
  30 use Koha::Caches;
  31 use Koha::MarcSubfieldStructures;
  32
  33 use C4::Linker::Default qw( get_link );
  34
  35 BEGIN {
  36     use_ok('C4::Biblio', qw( AddBiblio GetMarcFromKohaField BiblioAutoLink GetMarcSubfieldStructure GetMarcSubfieldStructureFromKohaField LinkBibHeadingsToAuthorities GetBiblioData ModBiblio GetMarcISSN GetMarcControlnumber GetMarcISBN GetMarcPrice GetFrameworkCode GetMarcUrls IsMarcStructureInternal GetMarcStructure GetXmlBiblio DelBiblio ));
  37 }
  38
  39 my $schema = Koha::Database->new->schema;
  40 $schema->storage->txn_begin;
  41 my $dbh = C4::Context->dbh;
  42 Koha::Caches->get_instance->clear_from_cache( "MarcSubfieldStructure-" );
  43
  44 my $builder = t::lib::TestBuilder->new;
  45
  46 subtest 'AddBiblio' => sub {
  47     plan tests => 5;
  48
  49     my $marcflavour = 'MARC21';
  50     t::lib::Mocks::mock_preference( 'marcflavour', $marcflavour );
  51     my $record = MARC::Record->new();
  52
  53     my ( $f, $sf ) = GetMarcFromKohaField('biblioitems.lccn');
  54     my $lccn_field = MARC::Field->new( $f, ' ', ' ',
  55         $sf => 'ThisisgoingtobetoomanycharactersfortheLCCNfield' );
  56     $record->append_fields($lccn_field);
  57
  58     my $nb_biblios = Koha::Biblios->count;
  59     my ( $biblionumber, $biblioitemnumber );
  60     warnings_like { ( $biblionumber, $biblioitemnumber ) = C4::Biblio::AddBiblio( $record, '' ) }
  61         [ qr/Data too long for column 'lccn'/, qr/Data too long for column 'lccn'/ ],
  62         "expected warnings when adding too long LCCN";
  63     is( $biblionumber, undef,
  64         'AddBiblio returns undef for biblionumber if something went wrong' );
  65     is( $biblioitemnumber, undef,
  66         'AddBiblio returns undef for biblioitemnumber if something went wrong'
  67     );
  68     is( Koha::Biblios->count, $nb_biblios,
  69         'No biblio should have been added if something went wrong' );
  70
  71     t::lib::Mocks::mock_preference( 'BiblioAddsAuthorities', $marcflavour );
  72     t::lib::Mocks::mock_preference( 'AutoCreateAuthorities', $marcflavour );
  73
  74     my $mock_biblio = Test::MockModule->new("C4::Biblio");
  75     $mock_biblio->mock( BiblioAutoLink => sub {
  76         my $record = shift;
  77         my $frameworkcode = shift;
  78         warn "My biblionumber is ".$record->subfield('999','c')." and my frameworkcode is $frameworkcode";
  79     });
  80     warning_like { $builder->build_sample_biblio(); }
  81         qr/My biblionumber is \d+ and my frameworkcode is /, "The biblionumber is correctly passed to BiblioAutoLink";
  82
  83 };
  84
  85 subtest 'GetMarcSubfieldStructureFromKohaField' => sub {
  86     plan tests => 25;
  87
  88     my @columns = qw(
  89         tagfield tagsubfield liblibrarian libopac repeatable mandatory kohafield tab
  90         authorised_value authtypecode value_builder isurl hidden frameworkcode
  91         seealso link defaultvalue maxlength
  92     );
  93
  94     # biblio.biblionumber must be mapped so this should return something
  95     my $marc_subfield_structure = GetMarcSubfieldStructureFromKohaField('biblio.biblionumber');
  96
  97     ok(defined $marc_subfield_structure, "There is a result");
  98     is(ref $marc_subfield_structure, "HASH", "Result is a hashref");
  99     foreach my $col (@columns) {
 100         ok(exists $marc_subfield_structure->{$col}, "Hashref contains key '$col'");
 101     }
 102     is($marc_subfield_structure->{kohafield}, 'biblio.biblionumber', "Result is the good result");
 103     like($marc_subfield_structure->{tagfield}, qr/^\d{3}$/, "tagfield is a valid tagfield");
 104
 105     # Add a test for list context (BZ 10306)
 106     my @results = GetMarcSubfieldStructureFromKohaField('biblio.biblionumber');
 107     is( @results, 1, 'We expect only one mapping' );
 108     is_deeply( $results[0], $marc_subfield_structure,
 109         'The first entry should be the same hashref as we had before' );
 110
 111     # foo.bar does not exist so this should return undef
 112     $marc_subfield_structure = GetMarcSubfieldStructureFromKohaField('foo.bar');
 113     is($marc_subfield_structure, undef, "invalid kohafield returns undef");
 114
 115 };
 116
 117 subtest "GetMarcSubfieldStructure" => sub {
 118     plan tests => 5;
 119
 120     # Add multiple Koha to Marc mappings
 121     Koha::MarcSubfieldStructures->search({ frameworkcode => '', tagfield => '399', tagsubfield => [ 'a', 'b' ] })->delete;
 122     Koha::MarcSubfieldStructure->new({ frameworkcode => '', tagfield => '399', tagsubfield => 'a', kohafield => "mytable.nicepages" })->store;
 123     Koha::MarcSubfieldStructure->new({ frameworkcode => '', tagfield => '399', tagsubfield => 'b', kohafield => "mytable.nicepages" })->store;
 124     Koha::Caches->get_instance->clear_from_cache( "MarcSubfieldStructure-" );
 125     my $structure = C4::Biblio::GetMarcSubfieldStructure('');
 126
 127     is( @{ $structure->{"mytable.nicepages"} }, 2,
 128         'GetMarcSubfieldStructure should return two entries for nicepages' );
 129     is( $structure->{"mytable.nicepages"}->[0]->{tagfield}, '399',
 130         'Check tagfield for first entry' );
 131     is( $structure->{"mytable.nicepages"}->[0]->{tagsubfield}, 'a',
 132         'Check tagsubfield for first entry' );
 133     is( $structure->{"mytable.nicepages"}->[1]->{tagfield}, '399',
 134         'Check tagfield for second entry' );
 135     is( $structure->{"mytable.nicepages"}->[1]->{tagsubfield}, 'b',
 136         'Check tagsubfield for second entry' );
 137 };
 138
 139 subtest "GetMarcFromKohaField" => sub {
 140     plan tests => 8;
 141
 142     #NOTE: We are building on data from the previous subtest
 143     # With: field 399 / mytable.nicepages
 144
 145     # Check call in list context for multiple mappings
 146     my @retval = C4::Biblio::GetMarcFromKohaField('mytable.nicepages');
 147     is( @retval, 4, 'Should return two tags and subfields' );
 148     is( $retval[0], '399', 'Check first tag' );
 149     is( $retval[1], 'a', 'Check first subfield' );
 150     is( $retval[2], '399', 'Check second tag' );
 151     is( $retval[3], 'b', 'Check second subfield' );
 152
 153     # Check same call in scalar context
 154     is( C4::Biblio::GetMarcFromKohaField('mytable.nicepages'), '399',
 155         'GetMarcFromKohaField returns first tag in scalar context' );
 156
 157     # Bug 19096 Default is authoritative
 158     # If we add a new empty framework, we should still get the mappings
 159     # from Default. CAUTION: This test passes intentionally the obsoleted
 160     # framework parameter.
 161     my $new_fw = t::lib::TestBuilder->new->build({source => 'BiblioFramework'});
 162     @retval = C4::Biblio::GetMarcFromKohaField(
 163         'mytable.nicepages', $new_fw->{frameworkcode},
 164     );
 165     is( @retval, 4, 'Still got two pairs of tags/subfields' );
 166     is( $retval[0].$retval[1], '399a', 'Including 399a' );
 167 };
 168
 169 subtest "Authority creation with default linker" => sub {
 170     plan tests => 4;
 171     # Automatic authority creation
 172     t::lib::Mocks::mock_preference('LinkerModule', 'Default');
 173     t::lib::Mocks::mock_preference('BiblioAddsAuthorities', 1);
 174     t::lib::Mocks::mock_preference('AutoCreateAuthorities', 1);
 175     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
 176     my $linker = C4::Linker::Default->new({});
 177     my $authorities_mod = Test::MockModule->new( 'C4::Heading' );
 178     $authorities_mod->mock(
 179         'authorities',
 180         sub {
 181             my $results = [{ authid => 'original' },{ authid => 'duplicate' }];
 182             return $results;
 183         }
 184     );
 185     my $marc_record = MARC::Record->new();
 186     my $field = MARC::Field->new(655, ' ', ' ','a' => 'Magical realism');
 187     $marc_record->append_fields( $field );
 188     my ($num_changed,$results) = LinkBibHeadingsToAuthorities($linker, $marc_record, "",undef);
 189     is( $num_changed, 0, "We shouldn't link or create a new record");
 190     ok( !defined $results->{added}, "If we have multiple matches, we shouldn't create a new record");
 191
 192     ($num_changed,$results) = LinkBibHeadingsToAuthorities($linker, $marc_record, "",undef);
 193     is( $num_changed, 0, "We shouldn't link or create a new record using cached result");
 194     ok( !defined $results->{added}, "If we have multiple matches, we shouldn't create a new record on second instance");
 195 };
 196
 197
 198
 199 # Mocking variables
 200 my $biblio_module = Test::MockModule->new('C4::Biblio');
 201 $biblio_module->mock(
 202     'GetMarcSubfieldStructure',
 203     sub {
 204         my ($self) = shift;
 205
 206         my ( $title_field,            $title_subfield )            = get_title_field();
 207         my ( $subtitle_field,         $subtitle_subfield )         = get_subtitle_field();
 208         my ( $medium_field,           $medium_subfield )           = get_medium_field();
 209         my ( $part_number_field,      $part_number_subfield )      = get_part_number_field();
 210         my ( $part_name_field,        $part_name_subfield )        = get_part_name_field();
 211         my ( $isbn_field,             $isbn_subfield )             = get_isbn_field();
 212         my ( $issn_field,             $issn_subfield )             = get_issn_field();
 213         my ( $biblionumber_field,     $biblionumber_subfield )     = ( '999', 'c' );
 214         my ( $biblioitemnumber_field, $biblioitemnumber_subfield ) = ( '999', '9' );
 215         my ( $itemnumber_field,       $itemnumber_subfield )       = get_itemnumber_field();
 216
 217         return {
 218             'biblio.title'                 => [ { tagfield => $title_field,            tagsubfield => $title_subfield } ],
 219             'biblio.subtitle'              => [ { tagfield => $subtitle_field,         tagsubfield => $subtitle_subfield } ],
 220             'biblio.medium'                => [ { tagfield => $medium_field,           tagsubfield => $medium_subfield } ],
 221             'biblio.part_number'           => [ { tagfield => $part_number_field,      tagsubfield => $part_number_subfield } ],
 222             'biblio.part_name'             => [ { tagfield => $part_name_field,        tagsubfield => $part_name_subfield } ],
 223             'biblio.biblionumber'          => [ { tagfield => $biblionumber_field,     tagsubfield => $biblionumber_subfield } ],
 224             'biblioitems.isbn'             => [ { tagfield => $isbn_field,             tagsubfield => $isbn_subfield } ],
 225             'biblioitems.issn'             => [ { tagfield => $issn_field,             tagsubfield => $issn_subfield } ],
 226             'biblioitems.biblioitemnumber' => [ { tagfield => $biblioitemnumber_field, tagsubfield => $biblioitemnumber_subfield } ],
 227             'items.itemnumber'             => [ { tagfield => $itemnumber_subfield,    tagsubfield => $itemnumber_subfield } ],
 228         };
 229       }
 230 );
 231
 232 my $currency = Test::MockModule->new('Koha::Acquisition::Currencies');
 233 $currency->mock(
 234     'get_active',
 235     sub {
 236         return Koha::Acquisition::Currency->new(
 237             {   symbol   => '$',
 238                 isocode  => 'USD',
 239                 currency => 'USD',
 240                 active   => 1,
 241             }
 242         );
 243     }
 244 );
 245
 246 sub run_tests {
 247
 248     my $marcflavour = shift;
 249     t::lib::Mocks::mock_preference('marcflavour', $marcflavour);
 250     # Authority tests don't interact well with Elasticsearch at the moment due to the fact that there's currently no way to
 251     # roll back ES index changes.
 252     t::lib::Mocks::mock_preference('SearchEngine', 'Zebra');
 253
 254     t::lib::Mocks::mock_preference( 'RealTimeHoldsQueue', 0 );
 255
 256     my $isbn = '0590353403';
 257     my $title = 'Foundation';
 258     my $subtitle1 = 'Research';
 259     my $subtitle2 = 'Conclusions';
 260     my $medium = 'Medium';
 261     my $part_number = '123';
 262     my $part_name = 'First years';
 263
 264     # Generate a record with just the ISBN
 265     my $marc_record = MARC::Record->new;
 266     $marc_record->append_fields( create_isbn_field( $isbn, $marcflavour ) );
 267
 268     # Add the record to the DB
 269     my( $biblionumber, $biblioitemnumber ) = AddBiblio( $marc_record, '' );
 270     my $data = GetBiblioData( $biblionumber );
 271     is( $data->{ isbn }, $isbn,
 272         '(GetBiblioData) ISBN correctly retireved.');
 273     is( $data->{ title }, undef,
 274         '(GetBiblioData) Title field is empty in fresh biblio.');
 275
 276     my $biblio = Koha::Biblios->find($biblionumber);
 277
 278     my ( $isbn_field, $isbn_subfield ) = get_isbn_field();
 279     my $marc = $biblio->metadata->record;
 280     is( $marc->subfield( $isbn_field, $isbn_subfield ), $isbn, );
 281
 282     # Add title
 283     my $field = create_title_field( $title, $marcflavour );
 284     $marc_record->append_fields( $field );
 285     ModBiblio( $marc_record, $biblionumber ,'' );
 286     $data = GetBiblioData( $biblionumber );
 287     is( $data->{ title }, $title,
 288         'ModBiblio correctly added the title field, and GetBiblioData.');
 289     is( $data->{ isbn }, $isbn, '(ModBiblio) ISBN is still there after ModBiblio.');
 290     $marc = $biblio->metadata->record;
 291     my ( $title_field, $title_subfield ) = get_title_field();
 292     is( $marc->subfield( $title_field, $title_subfield ), $title, );
 293
 294     # Add other fields
 295     $marc_record->append_fields( create_field( $subtitle1, $marcflavour, get_subtitle_field() ) );
 296     $marc_record->append_fields( create_field( $subtitle2, $marcflavour, get_subtitle_field() ) );
 297     $marc_record->append_fields( create_field( $medium, $marcflavour, get_medium_field() ) );
 298     $marc_record->append_fields( create_field( $part_number, $marcflavour, get_part_number_field() ) );
 299     $marc_record->append_fields( create_field( $part_name, $marcflavour, get_part_name_field() ) );
 300
 301     ModBiblio( $marc_record, $biblionumber ,'' );
 302     $data = GetBiblioData( $biblionumber );
 303     is( $data->{ title }, $title, '(ModBiblio) still there after adding other fields.' );
 304     is( $data->{ isbn }, $isbn, '(ModBiblio) ISBN is still there after adding other fields.' );
 305
 306     is( $data->{ subtitle }, "$subtitle1 | $subtitle2", '(ModBiblio) subtitles correctly added and returned in GetBiblioData.' );
 307     is( $data->{ medium }, $medium, '(ModBiblio) medium correctly added and returned in GetBiblioData.' );
 308     is( $data->{ part_number }, $part_number, '(ModBiblio) part_number correctly added and returned in GetBiblioData.' );
 309     is( $data->{ part_name }, $part_name, '(ModBiblio) part_name correctly added and returned in GetBiblioData.' );
 310
 311     my $biblioitem = Koha::Biblioitems->find( $biblioitemnumber );
 312     is( $biblioitem->_result->biblio->title, $title, # Should be $biblioitem->biblio instead, but not needed elsewhere for now
 313         'Do not know if this makes sense - compare result of previous two GetBiblioData tests.');
 314     is( $biblioitem->isbn, $isbn,
 315         'Second test checking it returns the correct isbn.');
 316
 317     my $success = 0;
 318     $field = MARC::Field->new(
 319             655, ' ', ' ',
 320             'a' => 'Auction catalogs',
 321             '9' => '1'
 322             );
 323     eval {
 324         $marc_record->append_fields($field);
 325         $success = ModBiblio($marc_record,$biblionumber,'');
 326     } or do {
 327         diag($@);
 328         $success = 0;
 329     };
 330     ok($success, "ModBiblio handles authority-linked 655");
 331
 332     eval {
 333         $field->delete_subfields('a');
 334         $marc_record->append_fields($field);
 335         $success = ModBiblio($marc_record,$biblionumber,'');
 336     } or do {
 337         diag($@);
 338         $success = 0;
 339     };
 340     ok($success, "ModBiblio handles 655 with authority link but no heading");
 341
 342     eval {
 343         $field->delete_subfields('9');
 344         $marc_record->append_fields($field);
 345         $success = ModBiblio($marc_record,$biblionumber,'');
 346     } or do {
 347         diag($@);
 348         $success = 0;
 349     };
 350     ok($success, "ModBiblio handles 655 with no subfields");
 351
 352     ## Testing GetMarcISSN
 353     my $issns;
 354     $issns = GetMarcISSN( $marc_record, $marcflavour );
 355     is( $issns->[0], undef,
 356         'GetMarcISSN handles records without the ISSN field (list is empty)' );
 357     is( scalar @$issns, 0,
 358         'GetMarcISSN handles records without the ISSN field (count is 0)' );
 359     # Add an ISSN field
 360     my $issn = '1234-1234';
 361     $field = create_issn_field( $issn, $marcflavour );
 362     $marc_record->append_fields($field);
 363     $issns = GetMarcISSN( $marc_record, $marcflavour );
 364     is( $issns->[0], $issn,
 365         'GetMarcISSN handles records with a single ISSN field (first element is correct)' );
 366     is( scalar @$issns, 1,
 367         'GetMARCISSN handles records with a single ISSN field (count is 1)');
 368     # Add multiple ISSN field
 369     my @more_issns = qw/1111-1111 2222-2222 3333-3333/;
 370     foreach (@more_issns) {
 371         $field = create_issn_field( $_, $marcflavour );
 372         $marc_record->append_fields($field);
 373     }
 374     $issns = GetMarcISSN( $marc_record, $marcflavour );
 375     is( scalar @$issns, 4,
 376         'GetMARCISSN handles records with multiple ISSN fields (count correct)');
 377     # Create an empty ISSN
 378     $field = create_issn_field( "", $marcflavour );
 379     $marc_record->append_fields($field);
 380     $issns = GetMarcISSN( $marc_record, $marcflavour );
 381     is( scalar @$issns, 4,
 382         'GetMARCISSN skips empty ISSN fields (Bug 12674)');
 383
 384     ## Testing GetMarcControlnumber
 385     my $controlnumber;
 386     $controlnumber = GetMarcControlnumber( $marc_record, $marcflavour );
 387     is( $controlnumber, '', 'GetMarcControlnumber handles records without 001' );
 388
 389     $field = MARC::Field->new( '001', '' );
 390     $marc_record->append_fields($field);
 391     $controlnumber = GetMarcControlnumber( $marc_record, $marcflavour );
 392     is( $controlnumber, '', 'GetMarcControlnumber handles records with empty 001' );
 393
 394     $field = $marc_record->field('001');
 395     $field->update('123456789X');
 396     $controlnumber = GetMarcControlnumber( $marc_record, $marcflavour );
 397     is( $controlnumber, '123456789X', 'GetMarcControlnumber handles records with 001' );
 398
 399     ## Testing GetMarcISBN
 400     my $record_for_isbn = MARC::Record->new();
 401     my $isbns = GetMarcISBN( $record_for_isbn, $marcflavour );
 402     is( scalar @$isbns, 0, '(GetMarcISBN) The record contains no ISBN');
 403
 404     # We add one ISBN
 405     $isbn_field = create_isbn_field( $isbn, $marcflavour );
 406     $record_for_isbn->append_fields( $isbn_field );
 407     $isbns = GetMarcISBN( $record_for_isbn, $marcflavour );
 408     is( scalar @$isbns, 1, '(GetMarcISBN) The record contains one ISBN');
 409     is( $isbns->[0], $isbn, '(GetMarcISBN) The record contains our ISBN');
 410
 411     # We add 3 more ISBNs
 412     $record_for_isbn = MARC::Record->new();
 413     my @more_isbns = qw/1111111111 2222222222 3333333333 444444444/;
 414     foreach (@more_isbns) {
 415         $field = create_isbn_field( $_, $marcflavour );
 416         $record_for_isbn->append_fields($field);
 417     }
 418     $isbns = GetMarcISBN( $record_for_isbn, $marcflavour );
 419     is( scalar @$isbns, 4, '(GetMarcISBN) The record contains 4 ISBNs');
 420     for my $i (0 .. $#more_isbns) {
 421         is( $isbns->[$i], $more_isbns[$i],
 422             "(GetMarcISBN) Correctly retrieves ISBN #". ($i + 1));
 423     }
 424
 425     is( GetMarcPrice( $record_for_isbn, $marcflavour ), 100,
 426         "GetMarcPrice returns the correct value");
 427     my $updatedrecord = $biblio->metadata->record;
 428     my $frameworkcode = GetFrameworkCode($biblionumber);
 429     my ( $biblioitem_tag, $biblioitem_subfield ) = GetMarcFromKohaField( "biblioitems.biblioitemnumber" );
 430     die qq{No biblioitemnumber tag for framework "$frameworkcode"} unless $biblioitem_tag;
 431     my $biblioitemnumbertotest;
 432     if ( $biblioitem_tag < 10 ) {
 433         $biblioitemnumbertotest = $updatedrecord->field($biblioitem_tag)->data();
 434     } else {
 435         $biblioitemnumbertotest = $updatedrecord->field($biblioitem_tag)->subfield($biblioitem_subfield);
 436     }
 437
 438     # test for GetMarcUrls
 439     $marc_record->append_fields(
 440         MARC::Field->new( '856', '', '', u => ' https://koha-community.org ' ),
 441         MARC::Field->new( '856', '', '', u => 'koha-community.org' ),
 442     );
 443     my $marcurl = GetMarcUrls( $marc_record, $marcflavour );
 444     is( @$marcurl, 2, 'GetMarcUrls returns two URLs' );
 445     like( $marcurl->[0]->{MARCURL}, qr/^https/, 'GetMarcUrls did not stumble over a preceding space' );
 446     ok( $marcflavour ne 'MARC21' || $marcurl->[1]->{MARCURL} =~ /^http:\/\//,
 447         'GetMarcUrls prefixed a MARC21 URL with http://' );
 448
 449     # Automatic authority creation
 450     t::lib::Mocks::mock_preference('BiblioAddsAuthorities', 1);
 451     t::lib::Mocks::mock_preference('AutoCreateAuthorities', 1);
 452     my $authorities_mod = Test::MockModule->new( 'C4::Heading' );
 453     $authorities_mod->mock(
 454         'authorities',
 455         sub {
 456             my @results;
 457             return \@results;
 458         }
 459     );
 460     $success = 0;
 461     $field = create_author_field('Author Name');
 462     eval {
 463         $marc_record->append_fields($field);
 464         $success = ModBiblio($marc_record,$biblionumber,'');
 465     } or do {
 466         diag($@);
 467         $success = 0;
 468     };
 469     ok($success, "ModBiblio handles authority addition for author");
 470
 471     my ($author_field, $author_subfield, $author_relator_subfield) = get_author_field();
 472     $field = $marc_record->field($author_field);
 473     ok($field->subfield($author_subfield), "ModBiblio keeps $author_field$author_subfield intact");
 474
 475     my $authid = $field->subfield('9');
 476     ok($authid, 'ModBiblio adds authority id');
 477
 478     use_ok('C4::AuthoritiesMarc', qw( GetAuthority ));
 479     my $auth_record = C4::AuthoritiesMarc::GetAuthority($authid);
 480     ok($auth_record, 'Authority record successfully retrieved');
 481
 482
 483     my ($auth_author_field, $auth_author_subfield) = get_auth_author_field();
 484     $field = $auth_record->field($auth_author_field);
 485     ok($field, "Authority record contains field $auth_author_field");
 486     is(
 487         $field->subfield($auth_author_subfield),
 488         'Author Name',
 489         'Authority $auth_author_field$auth_author_subfield contains author name'
 490     );
 491     is($field->subfield($author_relator_subfield), undef, 'Authority does not contain relator subfield');
 492
 493     # Reset settings
 494     t::lib::Mocks::mock_preference('BiblioAddsAuthorities', 0);
 495     t::lib::Mocks::mock_preference('AutoCreateAuthorities', 0);
 496 }
 497
 498 sub get_title_field {
 499     my $marc_flavour = C4::Context->preference('marcflavour');
 500     return ( $marc_flavour eq 'UNIMARC' ) ? ( '200', 'a' ) : ( '245', 'a' );
 501 }
 502
 503 sub get_medium_field {
 504     my $marc_flavour = C4::Context->preference('marcflavour');
 505     return ( $marc_flavour eq 'UNIMARC' ) ? ( '200', 'b' ) : ( '245', 'h' );
 506 }
 507
 508 sub get_subtitle_field {
 509     my $marc_flavour = C4::Context->preference('marcflavour');
 510     return ( $marc_flavour eq 'UNIMARC' ) ? ( '200', 'e' ) : ( '245', 'b' );
 511 }
 512
 513 sub get_part_number_field {
 514     my $marc_flavour = C4::Context->preference('marcflavour');
 515     return ( $marc_flavour eq 'UNIMARC' ) ? ( '200', 'h' ) : ( '245', 'n' );
 516 }
 517
 518 sub get_part_name_field {
 519     my $marc_flavour = C4::Context->preference('marcflavour');
 520     return ( $marc_flavour eq 'UNIMARC' ) ? ( '200', 'i' ) : ( '245', 'p' );
 521 }
 522
 523 sub get_isbn_field {
 524     my $marc_flavour = C4::Context->preference('marcflavour');
 525     return ( $marc_flavour eq 'UNIMARC' ) ? ( '010', 'a' ) : ( '020', 'a' );
 526 }
 527
 528 sub get_issn_field {
 529     my $marc_flavour = C4::Context->preference('marcflavour');
 530     return ( $marc_flavour eq 'UNIMARC' ) ? ( '011', 'a' ) : ( '022', 'a' );
 531 }
 532
 533 sub get_itemnumber_field {
 534     my $marc_flavour = C4::Context->preference('marcflavour');
 535     return ( $marc_flavour eq 'UNIMARC' ) ? ( '995', '9' ) : ( '952', '9' );
 536 }
 537
 538 sub get_author_field {
 539     my $marc_flavour = C4::Context->preference('marcflavour');
 540     return ( $marc_flavour eq 'UNIMARC' ) ? ( '700', 'a', '4' ) : ( '100', 'a', 'e' );
 541 }
 542
 543 sub get_auth_author_field {
 544     my $marc_flavour = C4::Context->preference('marcflavour');
 545     return ( $marc_flavour eq 'UNIMARC' ) ? ( '106', 'a' ) : ( '100', 'a' );
 546 }
 547
 548 sub create_title_field {
 549     my ( $title, $marcflavour ) = @_;
 550
 551     my ( $title_field, $title_subfield ) = get_title_field();
 552     my $field = MARC::Field->new( $title_field, '', '', $title_subfield => $title );
 553
 554     return $field;
 555 }
 556
 557 sub create_field {
 558     my ( $content, $marcflavour, $field, $subfield ) = @_;
 559
 560     return MARC::Field->new( $field, '', '', $subfield => $content );
 561 }
 562
 563 sub create_isbn_field {
 564     my ( $isbn, $marcflavour ) = @_;
 565
 566     my ( $isbn_field, $isbn_subfield ) = get_isbn_field();
 567     my $field = MARC::Field->new( $isbn_field, '', '', $isbn_subfield => $isbn );
 568
 569     # Add the price subfield
 570     my $price_subfield = ( $marcflavour eq 'UNIMARC' ) ? 'd' : 'c';
 571     $field->add_subfields( $price_subfield => '$100' );
 572
 573     return $field;
 574 }
 575
 576 sub create_issn_field {
 577     my ( $issn, $marcflavour ) = @_;
 578
 579     my ( $issn_field, $issn_subfield ) = get_issn_field();
 580     my $field = MARC::Field->new( $issn_field, '', '', $issn_subfield => $issn );
 581
 582     return $field;
 583 }
 584
 585 sub create_author_field {
 586     my ( $author ) = @_;
 587
 588     my ( $author_field, $author_subfield, $author_relator_subfield ) = get_author_field();
 589     my $field = MARC::Field->new(
 590         $author_field, '', '',
 591         $author_subfield => $author,
 592         $author_relator_subfield => 'aut'
 593     );
 594
 595     return $field;
 596 }
 597
 598 subtest 'MARC21' => sub {
 599     plan tests => 46;
 600     run_tests('MARC21');
 601     $schema->storage->txn_rollback;
 602     $schema->storage->txn_begin;
 603 };
 604
 605 subtest 'UNIMARC' => sub {
 606     plan tests => 46;
 607
 608     # Mock the auth type data for UNIMARC
 609     $dbh->do("UPDATE auth_types SET auth_tag_to_report = '106' WHERE auth_tag_to_report = '100'") or die $dbh->errstr;
 610
 611     run_tests('UNIMARC');
 612     $schema->storage->txn_rollback;
 613     $schema->storage->txn_begin;
 614 };
 615
 616 subtest 'IsMarcStructureInternal' => sub {
 617     plan tests => 9;
 618     my $tagslib = GetMarcStructure();
 619     my @internals;
 620     for my $tag ( sort keys %$tagslib ) {
 621         next unless $tag;
 622         for my $subfield ( sort keys %{ $tagslib->{$tag} } ) {
 623             push @internals, $subfield if IsMarcStructureInternal($tagslib->{$tag}{$subfield});
 624         }
 625     }
 626     @internals = uniq @internals;
 627     is( scalar(@internals), 7, 'expect 7 internals');
 628     is( grep( /^lib$/, @internals ), 1, 'check lib' );
 629     is( grep( /^tab$/, @internals ), 1, 'check tab' );
 630     is( grep( /^mandatory$/, @internals ), 1, 'check mandatory' );
 631     is( grep( /^repeatable$/, @internals ), 1, 'check repeatable' );
 632     is( grep( /^important$/, @internals ), 1, 'check important' );
 633     is( grep( /^a$/, @internals ), 0, 'no subfield a' );
 634     is( grep( /^ind1_defaultvalue$/, @internals ), 1, 'check indicator 1 default value' );
 635     is( grep( /^ind2_defaultvalue$/, @internals ), 1, 'check indicator 2 default value' );
 636 };
 637
 638 subtest 'deletedbiblio_metadata' => sub {
 639     plan tests => 2;
 640
 641     t::lib::Mocks::mock_preference( 'RealTimeHoldsQueue', 0 );
 642
 643     my ($biblionumber, $biblioitemnumber) = AddBiblio(MARC::Record->new, '');
 644     my $biblio_metadata = C4::Biblio::GetXmlBiblio( $biblionumber );
 645     C4::Biblio::DelBiblio( $biblionumber );
 646     my ( $moved ) = $dbh->selectrow_array(q|SELECT biblionumber FROM deletedbiblio WHERE biblionumber=?|, undef, $biblionumber);
 647     is( $moved, $biblionumber, 'Found in deletedbiblio' );
 648     ( $moved ) = $dbh->selectrow_array(q|SELECT biblionumber FROM deletedbiblio_metadata WHERE biblionumber=?|, undef, $biblionumber);
 649     is( $moved, $biblionumber, 'Found in deletedbiblio_metadata' );
 650 };
 651
 652 subtest 'DelBiblio' => sub {
 653
 654     plan tests => 5;
 655
 656     t::lib::Mocks::mock_preference( 'RealTimeHoldsQueue', 0 );
 657
 658     my ($biblionumber, $biblioitemnumber) = C4::Biblio::AddBiblio(MARC::Record->new, '');
 659     my $deleted = C4::Biblio::DelBiblio( $biblionumber );
 660     is( $deleted, undef, 'DelBiblio returns undef is the biblio has been deleted correctly - Must be 1 instead'); # FIXME We should return 1 instead!
 661
 662     $deleted = C4::Biblio::DelBiblio( $biblionumber );
 663     is( $deleted, undef, 'DelBiblo should return undef is the record did not exist');
 664
 665     my $biblio       = $builder->build_sample_biblio;
 666     my $subscription = $builder->build_object(
 667         {
 668             class => 'Koha::Subscriptions',
 669             value => { biblionumber => $biblio->biblionumber }
 670         }
 671     );
 672     my $serial = $builder->build_object(
 673         {
 674             class => 'Koha::Serials',
 675             value => {
 676                 biblionumber   => $biblio->biblionumber,
 677                 subscriptionid => $subscription->subscriptionid
 678             }
 679         }
 680     );
 681     my $subscription_history = $builder->build_object(
 682         {
 683             class => 'Koha::Subscription::Histories',
 684             value => {
 685                 biblionumber   => $biblio->biblionumber,
 686                 subscriptionid => $subscription->subscriptionid
 687             }
 688         }
 689     );
 690     C4::Biblio::DelBiblio($biblio->biblionumber); # Or $biblio->delete
 691     is( $subscription->get_from_storage, undef, 'subscription should be deleted on biblio deletion' );
 692     is( $serial->get_from_storage, undef, 'serial should be deleted on biblio deletion' );
 693     is( $subscription_history->get_from_storage, undef, 'subscription history should be deleted on biblio deletion' );
 694 };
 695
 696 subtest 'MarcFieldForCreatorAndModifier' => sub {
 697     plan tests => 8;
 698
 699     t::lib::Mocks::mock_preference('MarcFieldForCreatorId', '998$a');
 700     t::lib::Mocks::mock_preference('MarcFieldForCreatorName', '998$b');
 701     t::lib::Mocks::mock_preference('MarcFieldForModifierId', '998$c');
 702     t::lib::Mocks::mock_preference('MarcFieldForModifierName', '998$d');
 703     my $c4_context = Test::MockModule->new('C4::Context');
 704     $c4_context->mock('userenv', sub { return { number => 123, firstname => 'John', surname => 'Doe'}; });
 705
 706     my $record = MARC::Record->new();
 707     my ($biblionumber) = C4::Biblio::AddBiblio($record, '');
 708
 709     my $biblio = Koha::Biblios->find($biblionumber);
 710     $record = $biblio->metadata->record;
 711     is($record->subfield('998', 'a'), 123, '998$a = 123');
 712     is($record->subfield('998', 'b'), 'John Doe', '998$b = John Doe');
 713     is($record->subfield('998', 'c'), 123, '998$c = 123');
 714     is($record->subfield('998', 'd'), 'John Doe', '998$d = John Doe');
 715
 716     $c4_context->mock('userenv', sub { return { number => 321, firstname => 'Jane', surname => 'Doe'}; });
 717     C4::Biblio::ModBiblio($record, $biblionumber, '');
 718
 719     $record = $biblio->metadata->record;
 720     is($record->subfield('998', 'a'), 123, '998$a = 123');
 721     is($record->subfield('998', 'b'), 'John Doe', '998$b = John Doe');
 722     is($record->subfield('998', 'c'), 321, '998$c = 321');
 723     is($record->subfield('998', 'd'), 'Jane Doe', '998$d = Jane Doe');
 724 };
 725
 726 subtest 'ModBiblio called from linker test' => sub {
 727     plan tests => 2;
 728     my $called = 0;
 729     t::lib::Mocks::mock_preference('BiblioAddsAuthorities', 1);
 730     my $biblio_mod = Test::MockModule->new( 'C4::Biblio' );
 731     $biblio_mod->mock( 'LinkBibHeadingsToAuthorities', sub {
 732         $called = 1;
 733     });
 734     my $record = MARC::Record->new();
 735     my ($biblionumber) = C4::Biblio::AddBiblio($record,'');
 736     C4::Biblio::ModBiblio($record,$biblionumber,'');
 737     is($called,1,"We called to link bibs because not from linker");
 738     $called = 0;
 739     C4::Biblio::ModBiblio($record,$biblionumber,'',{ disable_autolink => 1 });
 740     is($called,0,"We didn't call to link bibs because from linker");
 741 };
 742
 743 subtest "LinkBibHeadingsToAuthorities record generation tests" => sub {
 744     plan tests => 12;
 745
 746     # Set up mocks to ensure authorities are generated
 747     my $biblio_mod = Test::MockModule->new( 'C4::Linker::Default' );
 748     $biblio_mod->mock( 'get_link', sub {
 749         return (undef,undef);
 750     });
 751     # UNIMARC valid headings are built from the marc_subfield_structure for bibs and
 752     # include all subfields as valid, testing with MARC21 should be sufficient for now
 753     t::lib::Mocks::mock_preference('marcflavour', 'MARC21');
 754     t::lib::Mocks::mock_preference('AutoCreateAuthorities', '1');
 755
 756     my $linker = C4::Linker::Default->new();
 757     my $biblio = $builder->build_sample_biblio();
 758     my $record = $biblio->metadata->record;
 759
 760     # Generate a record including all valid subfields and an invalid one 'e'
 761     my $field = MARC::Field->new('650','','','a' => 'Beach city', 'b' => 'Weirdness', 'v' => 'Fiction', 'x' => 'Books', 'y' => '21st Century', 'z' => 'Fish Stew Pizza', 'e' => 'Depicted');
 762
 763     $record->append_fields($field);
 764     my ( $num_headings_changed, $results ) = LinkBibHeadingsToAuthorities($linker, $record, "",undef,650);
 765
 766     is( $num_headings_changed, 1, 'We changed the one we passed' );
 767     is_deeply( $results->{added},
 768         {"Beach city Weirdness--Fiction--Books--21st Century--Fish Stew Pizza" => 1 },
 769         "We added an authority record for the heading"
 770     );
 771
 772     # Now we check the authority record itself
 773     my $authority = GetAuthority( $record->subfield('650','9') );
 774     is( $authority->field('150')->as_string(),
 775         "Beach city Weirdness Fiction Books 21st Century Fish Stew Pizza",
 776         "The generated record contains the correct subfields"
 777     );
 778
 779     #Add test for this case using verbose
 780     $record->field('650')->delete_subfield('9');
 781     ( $num_headings_changed, $results ) = LinkBibHeadingsToAuthorities($linker, $record, "",undef, 650, 1);
 782     is( $num_headings_changed, 1, 'We changed the one we passed' );
 783     is( $results->{details}->[0]->{status}, 'CREATED', "We added an authority record for the heading using verbose");
 784
 785     # Now we check the authority record itself
 786     $authority = GetAuthority($results->{details}->[0]->{authid});
 787
 788     is( $authority->field('150')->as_string(),
 789          "Beach city Weirdness Fiction Books 21st Century Fish Stew Pizza",
 790          "The generated record contains the correct subfields when using verbose"
 791     );
 792
 793     # Example series link with volume and punctuation
 794     $field = MARC::Field->new('800','','','a' => 'Tolkien, J. R. R.', 'q' => '(John Ronald Reuel),', 'd' => '1892-1973.', 't' => 'Lord of the rings ;', 'v' => '1');
 795     $record->append_fields($field);
 796
 797     ( $num_headings_changed, $results ) = LinkBibHeadingsToAuthorities($linker, $record, "",undef, 800);
 798
 799     is( $num_headings_changed, 1, 'We changed the one we passed' );
 800     is_deeply( $results->{added},
 801         {"Tolkien, J. R. R. (John Ronald Reuel), 1892-1973. Lord of the rings ;" => 1 },
 802         "We added an authority record for the heading"
 803     );
 804
 805     # Now we check the authority record itself
 806     $authority = GetAuthority( $record->subfield('800','9') );
 807     is( $authority->field('100')->as_string(),
 808         "Tolkien, J. R. R. (John Ronald Reuel), 1892-1973. Lord of the rings",
 809         "The generated record contains the correct subfields"
 810     );
 811
 812     # The same example With verbose
 813     $record->field('800')->delete_subfield('9');
 814     ( $num_headings_changed, $results ) = LinkBibHeadingsToAuthorities($linker, $record, "",undef, 800, 1);
 815     is( $num_headings_changed, 1, 'We changed the one we passed' );
 816     is( $results->{details}->[0]->{status}, 'CREATED', "We added an authority record for the heading using verbose");
 817
 818     # Now we check the authority record itself
 819     $authority = GetAuthority($results->{details}->[0]->{authid});
 820     is( $authority->field('100')->as_string(),
 821          "Tolkien, J. R. R. (John Ronald Reuel), 1892-1973. Lord of the rings",
 822          "The generated record contains the correct subfields"
 823     );
 824 };
 825
 826 # Cleanup
 827 Koha::Caches->get_instance->clear_from_cache( "MarcSubfieldStructure-" );
 828 $schema->storage->txn_rollback;