t/db_dependent/Circulation/IssuingRules/maxsuspensiondays.t

   1 use Modern::Perl;
   2 use Test::More tests => 2;
   3
   4 use MARC::Record;
   5 use MARC::Field;
   6 use Test::MockModule;
   7 use C4::Context;
   8
   9 use C4::Biblio qw( AddBiblio );
  10 use C4::Circulation qw( AddIssue AddReturn );
  11 use C4::Items qw( AddItem );
  12 use C4::Members qw( AddMember GetMember );
  13 use Koha::Database;
  14 use Koha::DateUtils;
  15 use Koha::Patron::Debarments qw( GetDebarments DelDebarment );
  16
  17 use t::lib::TestBuilder;
  18
  19 my $schema = Koha::Database->schema;
  20 $schema->storage->txn_begin;
  21 my $builder = t::lib::TestBuilder->new;
  22 my $dbh = C4::Context->dbh;
  23 $dbh->{RaiseError} = 1;
  24
  25 my $branchcode = $builder->build({ source => 'Branch' })->{branchcode};
  26 my $itemtype   = $builder->build({ source => 'Itemtype' })->{itemtype};
  27
  28 local $SIG{__WARN__} = sub { warn $_[0] unless $_[0] =~ /redefined/ };
  29 my $userenv->{branch} = $branchcode;
  30 *C4::Context::userenv = \&Mock_userenv;
  31
  32 my $circulation_module = Test::MockModule->new('C4::Circulation');
  33
  34 # Test without maxsuspensiondays set
  35 $circulation_module->mock('GetIssuingRule', sub {
  36         return {
  37             firstremind => 0,
  38             finedays => 2,
  39             lengthunit => 'days',
  40         }
  41 });
  42
  43 my $borrowernumber = AddMember(
  44     firstname =>  'my firstname',
  45     surname => 'my surname',
  46     categorycode => 'S',
  47     branchcode => $branchcode,
  48 );
  49 my $borrower = GetMember( borrowernumber => $borrowernumber );
  50
  51 my $record = MARC::Record->new();
  52 $record->append_fields(
  53     MARC::Field->new('100', ' ', ' ', a => 'My author'),
  54     MARC::Field->new('245', ' ', ' ', a => 'My title'),
  55 );
  56
  57 my $barcode = 'bc_maxsuspensiondays';
  58 my ($biblionumber, $biblioitemnumber) = AddBiblio($record, '');
  59 my (undef, undef, $itemnumber) = AddItem({
  60         homebranch => $branchcode,
  61         holdingbranch => $branchcode,
  62         barcode => $barcode,
  63         itype => $itemtype
  64     } , $biblionumber);
  65
  66 # clear any holidays to avoid throwing off the suspension day
  67 # calculations
  68 $dbh->do('DELETE FROM special_holidays');
  69 $dbh->do('DELETE FROM repeatable_holidays');
  70
  71 my $daysago20 = dt_from_string->add_duration(DateTime::Duration->new(days => -20));
  72 my $daysafter40 = dt_from_string->add_duration(DateTime::Duration->new(days => 40));
  73
  74 AddIssue( $borrower, $barcode, $daysago20 );
  75 AddReturn( $barcode, $branchcode );
  76 my $debarments = GetDebarments({borrowernumber => $borrower->{borrowernumber}});
  77 is(
  78     $debarments->[0]->{expiration},
  79     output_pref({ dt => $daysafter40, dateformat => 'iso', dateonly => 1 }),
  80     'calculate suspension with no maximum set'
  81 );
  82 DelDebarment( $debarments->[0]->{borrower_debarment_id} );
  83
  84 # Test with maxsuspensiondays = 10 days
  85 $circulation_module->mock('GetIssuingRule', sub {
  86         return {
  87             firstremind => 0,
  88             finedays => 2,
  89             maxsuspensiondays => 10,
  90             lengthunit => 'days',
  91         }
  92 });
  93 my $daysafter10 = dt_from_string->add_duration(DateTime::Duration->new(days => 10));
  94 AddIssue( $borrower, $barcode, $daysago20 );
  95 AddReturn( $barcode, $branchcode );
  96 $debarments = GetDebarments({borrowernumber => $borrower->{borrowernumber}});
  97 is(
  98     $debarments->[0]->{expiration},
  99     output_pref({ dt => $daysafter10, dateformat => 'iso', dateonly => 1 }),
 100     'calculate suspension with a maximum set'
 101 );
 102 DelDebarment( $debarments->[0]->{borrower_debarment_id} );
 103
 104 $schema->storage->txn_rollback;
 105
 106 # C4::Context->userenv
 107 sub Mock_userenv {
 108     return $userenv;
 109 }