t/db_dependent/Hold.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use t::lib::Mocks;
  21 use C4::Context;
  22 use C4::Biblio qw( AddBiblio );
  23 use Koha::Database;
  24 use Koha::Libraries;
  25 use C4::Calendar;
  26 use Koha::Patrons;
  27 use Koha::Holds;
  28 use Koha::Item;
  29 use Koha::DateUtils;
  30 use t::lib::TestBuilder;
  31
  32 use Test::More tests => 33;
  33 use Test::Exception;
  34 use Test::Warn;
  35
  36 use_ok('Koha::Hold');
  37
  38 my $schema = Koha::Database->new()->schema();
  39 $schema->storage->txn_begin();
  40
  41 # add two branches and a borrower
  42 my $builder = t::lib::TestBuilder->new;
  43 my @branches;
  44 foreach( 1..2 ) {
  45     push @branches, $builder->build({ source => 'Branch' });
  46 }
  47 my $borrower = $builder->build({ source => 'Borrower' });
  48
  49 my $biblio = MARC::Record->new();
  50 my $title  = 'Silence in the library';
  51 $biblio->append_fields(
  52     MARC::Field->new( '100', ' ', ' ', a => 'Moffat, Steven' ),
  53     MARC::Field->new( '245', ' ', ' ', a => $title ),
  54 );
  55 my ( $biblionumber, $biblioitemnumber ) = AddBiblio( $biblio, '' );
  56
  57 my $item = Koha::Item->new(
  58     {
  59         biblionumber     => $biblionumber,
  60         biblioitemnumber => $biblioitemnumber,
  61         holdingbranch    => $branches[0]->{branchcode},
  62         homebranch       => $branches[0]->{branchcode},
  63     }
  64 );
  65 $item->store();
  66
  67 my $hold = Koha::Hold->new(
  68     {
  69         biblionumber   => $biblionumber,
  70         itemnumber     => $item->id(),
  71         reservedate    => '2017-01-01',
  72         waitingdate    => '2000-01-01',
  73         borrowernumber => $borrower->{borrowernumber},
  74         branchcode     => $branches[1]->{branchcode},
  75         suspend        => 0,
  76     }
  77 );
  78 $hold->store();
  79
  80 my $b1_cal = C4::Calendar->new( branchcode => $branches[1]->{branchcode} );
  81 $b1_cal->insert_single_holiday( day => 2, month => 1, year => 2017, title => "Morty Day", description => "Rick" ); #Add a holiday
  82 my $today = dt_from_string;
  83 is( $hold->age(), $today->delta_days( dt_from_string( '2017-01-01' ) )->in_units( 'days')  , "Age of hold is days from reservedate to now if calendar ignored");
  84 is( $hold->age(1), $today->delta_days( dt_from_string( '2017-01-01' ) )->in_units( 'days' ) - 1 , "Age of hold is days from reservedate to now minus 1 if calendar used");
  85
  86 is( $hold->suspend, 0, "Hold is not suspended" );
  87 $hold->suspend_hold();
  88 is( $hold->suspend, 1, "Hold is suspended" );
  89 $hold->resume();
  90 is( $hold->suspend, 0, "Hold is not suspended" );
  91 my $dt = dt_from_string();
  92 $hold->suspend_hold( $dt );
  93 $dt->truncate( to => 'day' );
  94 is( $hold->suspend, 1, "Hold is suspended" );
  95 is( $hold->suspend_until, "$dt", "Hold is suspended with a date, truncation takes place automatically" );
  96 $hold->suspend_hold;
  97 is( $hold->suspend, 1, "Hold is suspended" );
  98 is( $hold->suspend_until, undef, "Hold is suspended without a date" );
  99 $hold->resume();
 100 is( $hold->suspend, 0, "Hold is not suspended" );
 101 is( $hold->suspend_until, undef, "Hold no longer has suspend_until date" );
 102
 103 $item = $hold->item();
 104
 105 my $hold_borrower = $hold->borrower();
 106 ok( $hold_borrower, 'Got hold borrower' );
 107 is( $hold_borrower->borrowernumber(), $borrower->{borrowernumber}, 'Hold borrower matches correct borrower' );
 108
 109 t::lib::Mocks::mock_preference( 'ReservesMaxPickUpDelay', '5' );
 110 $hold->found('T');
 111 isnt( $hold->is_waiting, 1, 'The hold is not waiting (T)' );
 112 is( $hold->is_found, 1, 'The hold is found');
 113 is( $hold->is_in_transit, 1, 'The hold is in transit' );
 114
 115 $hold->found('P');
 116 is( $hold->is_found, 1, 'The hold is found');
 117 is( $hold->is_in_processing, 1, 'The hold is in processing' );
 118
 119 $hold->found(q{});
 120 isnt( $hold->is_waiting, 1, 'The hold is not waiting (W)' );
 121 is( $hold->is_found, 0, 'The hold is not found' );
 122 ok( !$hold->is_in_transit, 'The hold is not in transit' );
 123 ok( !$hold->is_in_processing, 'The hold is not in processing' );
 124
 125 # Test method is_cancelable_from_opac
 126 $hold->found(undef);
 127 is( $hold->is_cancelable_from_opac, 1, "Unfound hold is cancelable" );
 128 $hold->found('W');
 129 is( $hold->is_cancelable_from_opac, 0, "Waiting hold is not cancelable" );
 130 $hold->found('T');
 131 is( $hold->is_cancelable_from_opac, 0, "In transit hold is not cancelable" );
 132 $hold->found('P');
 133 is( $hold->is_cancelable_from_opac, 0, "In processing hold is not cancelable" );
 134
 135 # Test method is_at_destination
 136 $hold->found(undef);
 137 ok( !$hold->is_at_destination(), "Unfound hold cannot be at destination" );
 138 $hold->found('T');
 139 ok( !$hold->is_at_destination(), "In transit hold cannot be at destination" );
 140 $hold->found('W');
 141 ok( !$hold->is_at_destination(), "Waiting hold where hold branchcode is not the same as the item's holdingbranch is not at destination" );
 142 $item->holdingbranch( $branches[1]->{branchcode} );
 143 ok( $hold->is_at_destination(), "Waiting hold where hold branchcode is the same as the item's holdingbranch is at destination" );
 144
 145 $schema->storage->txn_rollback();
 146
 147 subtest "delete() tests" => sub {
 148
 149     plan tests => 6;
 150
 151     $schema->storage->txn_begin();
 152
 153     # Disable logging
 154     t::lib::Mocks::mock_preference( 'HoldsLog', 0 );
 155
 156     my $hold = $builder->build({ source => 'Reserve' });
 157
 158     my $hold_object = Koha::Holds->find( $hold->{ reserve_id } );
 159     my $deleted = $hold_object->delete;
 160     is( ref($deleted), 'Koha::Hold', 'Koha::Hold->delete should return the Koha::Hold object if the hold has been correctly deleted' );
 161     is( Koha::Holds->search({ reserve_id => $hold->{ reserve_id } })->count, 0,
 162         "Koha::Hold->delete should have deleted the hold" );
 163
 164     my $number_of_logs = $schema->resultset('ActionLog')->search(
 165             { module => 'HOLDS', action => 'DELETE', object => $hold->{ reserve_id } } )->count;
 166     is( $number_of_logs, 0, 'With HoldsLogs, Koha::Hold->delete shouldn\'t have been logged' );
 167
 168     # Enable logging
 169     t::lib::Mocks::mock_preference( 'HoldsLog', 1 );
 170
 171     $hold = $builder->build({ source => 'Reserve' });
 172
 173     $hold_object = Koha::Holds->find( $hold->{ reserve_id } );
 174     $deleted = $hold_object->delete;
 175     is( ref($deleted), 'Koha::Hold', 'Koha::Hold->delete should return a Koha::Hold object if the hold has been correctly deleted' );
 176     is( Koha::Holds->search({ reserve_id => $hold->{ reserve_id } })->count, 0,
 177         "Koha::Hold->delete should have deleted the hold" );
 178
 179     $number_of_logs = $schema->resultset('ActionLog')->search(
 180             { module => 'HOLDS', action => 'DELETE', object => $hold->{ reserve_id } } )->count;
 181     is( $number_of_logs, 1, 'With HoldsLogs, Koha::Hold->delete should have been logged' );
 182
 183     $schema->storage->txn_rollback();
 184  };
 185
 186 subtest 'suspend() tests' => sub {
 187
 188     plan tests => 18;
 189
 190     $schema->storage->txn_begin;
 191
 192     # Disable logging
 193     t::lib::Mocks::mock_preference( 'HoldsLog', 0 );
 194
 195     my $hold = $builder->build_object(
 196         {   class => 'Koha::Holds',
 197             value => { found => undef, suspend => 0, suspend_until => undef, waitingdate => undef }
 198         }
 199     );
 200
 201     ok( !$hold->is_suspended, 'Hold is not suspended' );
 202     my $suspended = $hold->suspend_hold;
 203     is( ref($suspended) , 'Koha::Hold', 'suspend returns the Koha::Hold object' );
 204     is( $suspended->id, $hold->id, 'suspend returns the same object' );
 205     ok( $suspended->is_suspended, 'The hold is suspended' );
 206     is( $suspended->suspend_until, undef, 'It is an indefinite suspension' );
 207
 208     # resume the hold
 209     $suspended->resume;
 210     $hold->discard_changes;
 211
 212     # create a DT
 213     my $date = dt_from_string()->add( days => 1 );
 214     $suspended = $hold->suspend_hold( $date );
 215     is( ref($suspended) , 'Koha::Hold', 'suspend returns the Koha::Hold object' );
 216     is( $suspended->id, $hold->id, 'suspend returns the same object' );
 217     ok( $suspended->is_suspended, 'The hold is suspended' );
 218     is( $suspended->suspend_until, $date->truncate( to => 'day' ), 'It is an indefinite suspension' );
 219
 220     # resume the hold
 221     $suspended->resume;
 222     $hold->discard_changes;
 223
 224     # set hold found=W
 225     $hold->set_waiting;
 226     throws_ok
 227         { $hold->suspend_hold; }
 228         'Koha::Exceptions::Hold::CannotSuspendFound',
 229         'Exception is thrown when a found hold is tried to suspend';
 230
 231     is( $@->status, 'W', 'Exception gets the \'status\' parameter set correctly' );
 232
 233     # set hold found=T
 234     $hold->set_transfer;
 235     throws_ok
 236         { $hold->suspend_hold; }
 237         'Koha::Exceptions::Hold::CannotSuspendFound',
 238         'Exception is thrown when a found hold is tried to suspend';
 239
 240     is( $@->status, 'T', 'Exception gets the \'status\' parameter set correctly' );
 241
 242     # set hold found=T
 243     $hold->set_processing();
 244     throws_ok
 245         { $hold->suspend_hold; }
 246         'Koha::Exceptions::Hold::CannotSuspendFound',
 247         'Exception is thrown when a found hold is tried to suspend';
 248
 249     is( $@->status, 'P', 'Exception gets the \'status\' parameter set correctly' );
 250
 251     my $holds_module = Test::MockModule->new('Koha::Hold');
 252     $holds_module->mock( 'is_found', 1 );
 253
 254     # bad data case
 255     $hold->found('X');
 256     throws_ok
 257         { $hold->suspend_hold }
 258         'Koha::Exceptions::Hold::CannotSuspendFound',
 259         'Exception is thrown when a found hold is tried to suspend';
 260
 261     is( $@->error, 'Unhandled data exception on found hold (id='
 262                     . $hold->id
 263                     . ', found='
 264                     . $hold->found
 265                     . ')' , 'Exception gets the \'status\' parameter set correctly' );
 266
 267     $holds_module->unmock( 'is_found' );
 268
 269     # Enable logging
 270     t::lib::Mocks::mock_preference( 'HoldsLog', 1 );
 271
 272     my $logs_count = $schema->resultset('ActionLog')->search(
 273             { module => 'HOLDS', action => 'SUSPEND', object => $hold->id } )->count;
 274
 275     $hold = $builder->build_object(
 276         {   class => 'Koha::Holds',
 277             value => { suspend => 0, suspend_until => undef, waitingdate => undef, found => undef }
 278         }
 279     );
 280
 281     $hold->suspend_hold;
 282     my $new_logs_count = $schema->resultset('ActionLog')->search(
 283             { module => 'HOLDS', action => 'SUSPEND', object => $hold->id } )->count;
 284
 285     is( $new_logs_count, $logs_count + 1, 'If logging is enabled, suspending a hold gets logged' );
 286
 287     $schema->storage->txn_rollback;
 288 };