t/db_dependent/Holds.t

   1 #!/usr/bin/perl
   2
   3 use Modern::Perl;
   4
   5 use t::lib::Mocks;
   6 use t::lib::TestBuilder;
   7
   8 use C4::Context;
   9 use C4::Branch;
  10
  11 use Test::More tests => 60;
  12 use MARC::Record;
  13 use C4::Biblio;
  14 use C4::Items;
  15 use C4::Members;
  16 use C4::Calendar;
  17 use Koha::Database;
  18 use Koha::DateUtils qw( dt_from_string output_pref );
  19 use Koha::Holds;
  20
  21 BEGIN {
  22     use FindBin;
  23     use lib $FindBin::Bin;
  24     use_ok('C4::Reserves');
  25 }
  26
  27 my $schema  = Koha::Database->new->schema;
  28 $schema->storage->txn_begin;
  29
  30 my $builder = t::lib::TestBuilder->new();
  31 my $dbh     = C4::Context->dbh;
  32
  33 # Create two random branches
  34 my $branch_1 = $builder->build({ source => 'Branch' })->{ branchcode };
  35 my $branch_2 = $builder->build({ source => 'Branch' })->{ branchcode };
  36
  37 # This test assumes we have a category S. This statement helps.
  38 $builder->build({
  39     source => 'Category',
  40     value  => { categorycode => 'S', category_type => 'S' },
  41 });
  42
  43 my $borrowers_count = 5;
  44
  45 $dbh->do('DELETE FROM itemtypes');
  46 $dbh->do('DELETE FROM reserves');
  47 my $insert_sth = $dbh->prepare('INSERT INTO itemtypes (itemtype) VALUES (?)');
  48 $insert_sth->execute('CAN');
  49 $insert_sth->execute('CANNOT');
  50 $insert_sth->execute('DUMMY');
  51 $insert_sth->execute('ONLY1');
  52
  53 # Setup Test------------------------
  54 # Create a biblio instance for testing
  55 my ($bibnum, $title, $bibitemnum) = create_helper_biblio('DUMMY');
  56
  57 # Create item instance for testing.
  58 my ($item_bibnum, $item_bibitemnum, $itemnumber)
  59     = AddItem({ homebranch => $branch_1, holdingbranch => $branch_1 } , $bibnum);
  60
  61 # Create some borrowers
  62 my @borrowernumbers;
  63 foreach (1..$borrowers_count) {
  64     my $borrowernumber = AddMember(
  65         firstname =>  'my firstname',
  66         surname => 'my surname ' . $_,
  67         categorycode => 'S',
  68         branchcode => $branch_1,
  69     );
  70     push @borrowernumbers, $borrowernumber;
  71 }
  72
  73 my $biblionumber = $bibnum;
  74
  75 # Create five item level holds
  76 foreach my $borrowernumber ( @borrowernumbers ) {
  77     AddReserve(
  78         $branch_1,
  79         $borrowernumber,
  80         $biblionumber,
  81         my $bibitems = q{},
  82         my $priority = C4::Reserves::CalculatePriority( $biblionumber ),
  83         my $resdate,
  84         my $expdate,
  85         my $notes = q{},
  86         $title,
  87         my $checkitem = $itemnumber,
  88         my $found,
  89     );
  90 }
  91
  92 my $reserves = GetReservesFromBiblionumber({ biblionumber => $biblionumber });
  93 is( scalar(@$reserves), $borrowers_count, "Test GetReserves()" );
  94
  95 is( $reserves->[0]->{priority}, 1, "Reserve 1 has a priority of 1" );
  96 is( $reserves->[1]->{priority}, 2, "Reserve 2 has a priority of 2" );
  97 is( $reserves->[2]->{priority}, 3, "Reserve 3 has a priority of 3" );
  98 is( $reserves->[3]->{priority}, 4, "Reserve 4 has a priority of 4" );
  99 is( $reserves->[4]->{priority}, 5, "Reserve 5 has a priority of 5" );
 100
 101 my ( $reservedate, $borrowernumber, $branch_1code, $reserve_id ) = GetReservesFromItemnumber($itemnumber);
 102 is( $reservedate, output_pref({ dt => dt_from_string, dateformat => 'iso', dateonly => 1 }), "GetReservesFromItemnumber should return a valid reserve date");
 103 is( $borrowernumber, $borrowernumbers[0], "GetReservesFromItemnumber should return a valid borrowernumber");
 104 is( $branch_1code, $branch_1, "GetReservesFromItemnumber should return a valid branchcode");
 105 ok($reserve_id, "Test GetReservesFromItemnumber()");
 106
 107 my $hold = Koha::Holds->find( $reserve_id );
 108 ok( $hold, "Koha::Holds found the hold" );
 109 my $hold_biblio = $hold->biblio();
 110 ok( $hold_biblio, "Got biblio using biblio() method" );
 111 ok( $hold_biblio == $hold->biblio(), "biblio method returns stashed biblio" );
 112 my $hold_item = $hold->item();
 113 ok( $hold_item, "Got item using item() method" );
 114 ok( $hold_item == $hold->item(), "item method returns stashed item" );
 115 my $hold_branch = $hold->branch();
 116 ok( $hold_branch, "Got branch using branch() method" );
 117 ok( $hold_branch == $hold->branch(), "branch method returns stashed branch" );
 118 my $hold_found = $hold->found();
 119 $hold->set({ found => 'W'})->store();
 120 is( Koha::Holds->waiting()->count(), 1, "Koha::Holds->waiting returns waiting holds" );
 121
 122 my ( $reserve ) = GetReservesFromBorrowernumber($borrowernumbers[0]);
 123 ok( $reserve->{'borrowernumber'} eq $borrowernumbers[0], "Test GetReservesFromBorrowernumber()");
 124
 125
 126 ok( GetReserveCount( $borrowernumbers[0] ), "Test GetReserveCount()" );
 127
 128
 129 CancelReserve({ 'reserve_id' => $reserve_id });
 130 $reserves = GetReservesFromBiblionumber({ biblionumber => $biblionumber });
 131 is( scalar(@$reserves), $borrowers_count - 1, "Test CancelReserve()" );
 132
 133
 134 ( $reservedate, $borrowernumber, $branch_1code, $reserve_id ) = GetReservesFromItemnumber($itemnumber);
 135 ModReserve({
 136     reserve_id    => $reserve_id,
 137     rank          => '4',
 138     branchcode    => $branch_1,
 139     itemnumber    => $itemnumber,
 140     suspend_until => output_pref( { dt => dt_from_string( "2013-01-01", "iso" ), dateonly => 1 } ),
 141 });
 142
 143 $reserve = GetReserve( $reserve_id );
 144 ok( $reserve->{'priority'} eq '4', "Test GetReserve(), priority changed correctly" );
 145 ok( $reserve->{'suspend'}, "Test GetReserve(), suspend hold" );
 146 is( $reserve->{'suspend_until'}, '2013-01-01 00:00:00', "Test GetReserve(), suspend until date" );
 147
 148 ToggleSuspend( $reserve_id );
 149 $reserve = GetReserve( $reserve_id );
 150 ok( !$reserve->{'suspend'}, "Test ToggleSuspend(), no date" );
 151
 152 ToggleSuspend( $reserve_id, '2012-01-01' );
 153 $reserve = GetReserve( $reserve_id );
 154 is( $reserve->{'suspend_until'}, '2012-01-01 00:00:00', "Test ToggleSuspend(), with date" );
 155
 156 AutoUnsuspendReserves();
 157 $reserve = GetReserve( $reserve_id );
 158 ok( !$reserve->{'suspend'}, "Test AutoUnsuspendReserves()" );
 159
 160 SuspendAll(
 161     borrowernumber => $borrowernumber,
 162     biblionumber   => $biblionumber,
 163     suspend => 1,
 164     suspend_until => '2012-01-01',
 165 );
 166 $reserve = GetReserve( $reserve_id );
 167 is( $reserve->{'suspend'}, 1, "Test SuspendAll()" );
 168 is( $reserve->{'suspend_until'}, '2012-01-01 00:00:00', "Test SuspendAll(), with date" );
 169
 170 SuspendAll(
 171     borrowernumber => $borrowernumber,
 172     biblionumber   => $biblionumber,
 173     suspend => 0,
 174 );
 175 $reserve = GetReserve( $reserve_id );
 176 is( $reserve->{'suspend'}, 0, "Test resuming with SuspendAll()" );
 177 is( $reserve->{'suspend_until'}, undef, "Test resuming with SuspendAll(), should have no suspend until date" );
 178
 179 # Add a new hold for the borrower whose hold we canceled earlier, this time at the bib level
 180 AddReserve(
 181     $branch_1,
 182     $borrowernumbers[0],
 183     $biblionumber,
 184     my $bibitems = q{},
 185     my $priority,
 186     my $resdate,
 187     my $expdate,
 188     my $notes = q{},
 189     $title,
 190     my $checkitem,
 191     my $found,
 192 );
 193 ( $reserve ) = GetReservesFromBorrowernumber($borrowernumber);
 194 my $reserveid = C4::Reserves::GetReserveId(
 195     {
 196         biblionumber => $biblionumber,
 197         borrowernumber => $borrowernumber
 198     }
 199 );
 200 is( $reserveid, $reserve->{reserve_id}, "Test GetReserveId" );
 201 ModReserveMinusPriority( $itemnumber, $reserve->{'reserve_id'} );
 202 ( $reserve ) = GetReservesFromBorrowernumber($borrowernumber);
 203 ok( $reserve->{'itemnumber'} eq $itemnumber, "Test ModReserveMinusPriority()" );
 204
 205
 206 my $reserve2 = GetReserveInfo( $reserve->{'reserve_id'} );
 207 ok( $reserve->{'reserve_id'} eq $reserve2->{'reserve_id'}, "Test GetReserveInfo()" );
 208
 209
 210 $reserves = GetReservesFromBiblionumber({ biblionumber => $biblionumber, all_dates => 1 });
 211 $reserve = $reserves->[1];
 212 AlterPriority( 'top', $reserve->{'reserve_id'} );
 213 $reserve = GetReserve( $reserve->{'reserve_id'} );
 214 is( $reserve->{'priority'}, '1', "Test AlterPriority(), move to top" );
 215
 216 AlterPriority( 'down', $reserve->{'reserve_id'} );
 217 $reserve = GetReserve( $reserve->{'reserve_id'} );
 218 is( $reserve->{'priority'}, '2', "Test AlterPriority(), move down" );
 219
 220 AlterPriority( 'up', $reserve->{'reserve_id'} );
 221 $reserve = GetReserve( $reserve->{'reserve_id'} );
 222 is( $reserve->{'priority'}, '1', "Test AlterPriority(), move up" );
 223
 224 AlterPriority( 'bottom', $reserve->{'reserve_id'} );
 225 $reserve = GetReserve( $reserve->{'reserve_id'} );
 226 is( $reserve->{'priority'}, '5', "Test AlterPriority(), move to bottom" );
 227
 228 # Regression test for bug 2394
 229 #
 230 # If IndependentBranches is ON and canreservefromotherbranches is OFF,
 231 # a patron is not permittedo to request an item whose homebranch (i.e.,
 232 # owner of the item) is different from the patron's own library.
 233 # However, if canreservefromotherbranches is turned ON, the patron can
 234 # create such hold requests.
 235 #
 236 # Note that canreservefromotherbranches has no effect if
 237 # IndependentBranches is OFF.
 238
 239 my ($foreign_bibnum, $foreign_title, $foreign_bibitemnum) = create_helper_biblio('DUMMY');
 240 my ($foreign_item_bibnum, $foreign_item_bibitemnum, $foreign_itemnumber)
 241   = AddItem({ homebranch => $branch_2, holdingbranch => $branch_2 } , $foreign_bibnum);
 242 $dbh->do('DELETE FROM issuingrules');
 243 $dbh->do(
 244     q{INSERT INTO issuingrules (categorycode, branchcode, itemtype, reservesallowed)
 245       VALUES (?, ?, ?, ?)},
 246     {},
 247     '*', '*', '*', 25
 248 );
 249 $dbh->do(
 250     q{INSERT INTO issuingrules (categorycode, branchcode, itemtype, reservesallowed)
 251       VALUES (?, ?, ?, ?)},
 252     {},
 253     '*', '*', 'CANNOT', 0
 254 );
 255
 256 # make sure some basic sysprefs are set
 257 t::lib::Mocks::mock_preference('ReservesControlBranch', 'ItemHomeLibrary');
 258 t::lib::Mocks::mock_preference('item-level_itypes', 1);
 259
 260 # if IndependentBranches is OFF, a $branch_1 patron can reserve an $branch_2 item
 261 t::lib::Mocks::mock_preference('IndependentBranches', 0);
 262 ok(
 263     CanItemBeReserved($borrowernumbers[0], $foreign_itemnumber) eq 'OK',
 264     '$branch_1 patron allowed to reserve $branch_2 item with IndependentBranches OFF (bug 2394)'
 265 );
 266
 267 # if IndependentBranches is OFF, a $branch_1 patron cannot reserve an $branch_2 item
 268 t::lib::Mocks::mock_preference('IndependentBranches', 1);
 269 t::lib::Mocks::mock_preference('canreservefromotherbranches', 0);
 270 ok(
 271     CanItemBeReserved($borrowernumbers[0], $foreign_itemnumber) eq 'cannotReserveFromOtherBranches',
 272     '$branch_1 patron NOT allowed to reserve $branch_2 item with IndependentBranches ON ... (bug 2394)'
 273 );
 274
 275 # ... unless canreservefromotherbranches is ON
 276 t::lib::Mocks::mock_preference('canreservefromotherbranches', 1);
 277 ok(
 278     CanItemBeReserved($borrowernumbers[0], $foreign_itemnumber) eq 'OK',
 279     '... unless canreservefromotherbranches is ON (bug 2394)'
 280 );
 281
 282 # Regression test for bug 11336
 283 ($bibnum, $title, $bibitemnum) = create_helper_biblio('DUMMY');
 284 ($item_bibnum, $item_bibitemnum, $itemnumber) = AddItem({ homebranch => $branch_1, holdingbranch => $branch_1 } , $bibnum);
 285 AddReserve(
 286     $branch_1,
 287     $borrowernumbers[0],
 288     $bibnum,
 289     '',
 290     1,
 291 );
 292
 293 my $reserveid1 = C4::Reserves::GetReserveId(
 294     {
 295         biblionumber => $bibnum,
 296         borrowernumber => $borrowernumbers[0]
 297     }
 298 );
 299
 300 ($item_bibnum, $item_bibitemnum, $itemnumber) = AddItem({ homebranch => $branch_1, holdingbranch => $branch_1 } , $bibnum);
 301 AddReserve(
 302     $branch_1,
 303     $borrowernumbers[1],
 304     $bibnum,
 305     '',
 306     2,
 307 );
 308 my $reserveid2 = C4::Reserves::GetReserveId(
 309     {
 310         biblionumber => $bibnum,
 311         borrowernumber => $borrowernumbers[1]
 312     }
 313 );
 314
 315 CancelReserve({ reserve_id => $reserveid1 });
 316
 317 $reserve2 = GetReserve( $reserveid2 );
 318 is( $reserve2->{priority}, 1, "After cancelreserve, the 2nd reserve becomes the first on the waiting list" );
 319
 320 ($item_bibnum, $item_bibitemnum, $itemnumber) = AddItem({ homebranch => $branch_1, holdingbranch => $branch_1 } , $bibnum);
 321 AddReserve(
 322     $branch_1,
 323     $borrowernumbers[0],
 324     $bibnum,
 325     '',
 326     2,
 327 );
 328 my $reserveid3 = C4::Reserves::GetReserveId(
 329     {
 330         biblionumber => $bibnum,
 331         borrowernumber => $borrowernumbers[0]
 332     }
 333 );
 334
 335 my $reserve3 = GetReserve( $reserveid3 );
 336 is( $reserve3->{priority}, 2, "New reserve for patron 0, the reserve has a priority = 2" );
 337
 338 ModReserve({ reserve_id => $reserveid2, rank => 'del' });
 339 $reserve3 = GetReserve( $reserveid3 );
 340 is( $reserve3->{priority}, 1, "After ModReserve, the 3rd reserve becomes the first on the waiting list" );
 341
 342 ModItem({ damaged => 1 }, $item_bibnum, $itemnumber);
 343 t::lib::Mocks::mock_preference( 'AllowHoldsOnDamagedItems', 1 );
 344 ok( CanItemBeReserved( $borrowernumbers[0], $itemnumber) eq 'OK', "Patron can reserve damaged item with AllowHoldsOnDamagedItems enabled" );
 345 ok( defined( ( CheckReserves($itemnumber) )[1] ), "Hold can be trapped for damaged item with AllowHoldsOnDamagedItems enabled" );
 346 t::lib::Mocks::mock_preference( 'AllowHoldsOnDamagedItems', 0 );
 347 ok( CanItemBeReserved( $borrowernumbers[0], $itemnumber) eq 'damaged', "Patron cannot reserve damaged item with AllowHoldsOnDamagedItems disabled" );
 348 ok( !defined( ( CheckReserves($itemnumber) )[1] ), "Hold cannot be trapped for damaged item with AllowHoldsOnDamagedItems disabled" );
 349
 350 # Regression test for bug 9532
 351 ($bibnum, $title, $bibitemnum) = create_helper_biblio('CANNOT');
 352 ($item_bibnum, $item_bibitemnum, $itemnumber) = AddItem({ homebranch => $branch_1, holdingbranch => $branch_1, itype => 'CANNOT' } , $bibnum);
 353 AddReserve(
 354     $branch_1,
 355     $borrowernumbers[0],
 356     $bibnum,
 357     '',
 358     1,
 359 );
 360 ok(
 361     CanItemBeReserved( $borrowernumbers[0], $itemnumber) eq 'tooManyReserves',
 362     "cannot request item if policy that matches on item-level item type forbids it"
 363 );
 364 ModItem({ itype => 'CAN' }, $item_bibnum, $itemnumber);
 365 ok(
 366     CanItemBeReserved( $borrowernumbers[0], $itemnumber) eq 'OK',
 367     "can request item if policy that matches on item type allows it"
 368 );
 369
 370 t::lib::Mocks::mock_preference('item-level_itypes', 0);
 371 ModItem({ itype => undef }, $item_bibnum, $itemnumber);
 372 ok(
 373     CanItemBeReserved( $borrowernumbers[0], $itemnumber) eq 'tooManyReserves',
 374     "cannot request item if policy that matches on bib-level item type forbids it (bug 9532)"
 375 );
 376
 377
 378 # Test branch item rules
 379
 380 $dbh->do('DELETE FROM issuingrules');
 381 $dbh->do(
 382     q{INSERT INTO issuingrules (categorycode, branchcode, itemtype, reservesallowed)
 383       VALUES (?, ?, ?, ?)},
 384     {},
 385     '*', '*', '*', 25
 386 );
 387 $dbh->do('DELETE FROM branch_item_rules');
 388 $dbh->do('DELETE FROM default_branch_circ_rules');
 389 $dbh->do('DELETE FROM default_branch_item_rules');
 390 $dbh->do('DELETE FROM default_circ_rules');
 391 $dbh->do(q{
 392     INSERT INTO branch_item_rules (branchcode, itemtype, holdallowed, returnbranch)
 393     VALUES (?, ?, ?, ?)
 394 }, {}, $branch_1, 'CANNOT', 0, 'homebranch');
 395 $dbh->do(q{
 396     INSERT INTO branch_item_rules (branchcode, itemtype, holdallowed, returnbranch)
 397     VALUES (?, ?, ?, ?)
 398 }, {}, $branch_1, 'CAN', 1, 'homebranch');
 399 ($bibnum, $title, $bibitemnum) = create_helper_biblio('CANNOT');
 400 ($item_bibnum, $item_bibitemnum, $itemnumber) = AddItem(
 401     { homebranch => $branch_1, holdingbranch => $branch_1, itype => 'CANNOT' } , $bibnum);
 402 is(CanItemBeReserved($borrowernumbers[0], $itemnumber), 'notReservable',
 403     "CanItemBeReserved should returns 'notReservable'");
 404
 405 ($item_bibnum, $item_bibitemnum, $itemnumber) = AddItem(
 406     { homebranch => $branch_2, holdingbranch => $branch_1, itype => 'CAN' } , $bibnum);
 407 is(CanItemBeReserved($borrowernumbers[0], $itemnumber),
 408     'cannotReserveFromOtherBranches',
 409     "CanItemBeReserved should returns 'cannotReserveFromOtherBranches'");
 410
 411 ($item_bibnum, $item_bibitemnum, $itemnumber) = AddItem(
 412     { homebranch => $branch_1, holdingbranch => $branch_1, itype => 'CAN' } , $bibnum);
 413 is(CanItemBeReserved($borrowernumbers[0], $itemnumber), 'OK',
 414     "CanItemBeReserved should returns 'OK'");
 415
 416
 417 # Test CancelExpiredReserves
 418 t::lib::Mocks::mock_preference('ExpireReservesMaxPickUpDelay', 1);
 419 t::lib::Mocks::mock_preference('ReservesMaxPickUpDelay', 1);
 420
 421 my ( $sec, $min, $hour, $mday, $mon, $year, $wday, $yday, $isdst ) = localtime(time);
 422 $year += 1900;
 423 $mon += 1;
 424 $reserves = $dbh->selectall_arrayref('SELECT * FROM reserves', { Slice => {} });
 425 $reserve = $reserves->[0];
 426 my $calendar = C4::Calendar->new(branchcode => $reserve->{branchcode});
 427 $calendar->insert_single_holiday(
 428     day         => $mday,
 429     month       => $mon,
 430     year        => $year,
 431     title       => 'Test',
 432     description => 'Test',
 433 );
 434 $reserve_id = $reserve->{reserve_id};
 435 $dbh->do("UPDATE reserves SET waitingdate = DATE_SUB( NOW(), INTERVAL 5 DAY ), found = 'W', priority = 0 WHERE reserve_id = ?", undef, $reserve_id );
 436 t::lib::Mocks::mock_preference('ExpireReservesOnHolidays', 0);
 437 CancelExpiredReserves();
 438 my $count = $dbh->selectrow_array("SELECT COUNT(*) FROM reserves WHERE reserve_id = ?", undef, $reserve_id );
 439 is( $count, 1, "Waiting reserve beyond max pickup delay *not* canceled on holiday" );
 440 t::lib::Mocks::mock_preference('ExpireReservesOnHolidays', 1);
 441 CancelExpiredReserves();
 442 $count = $dbh->selectrow_array("SELECT COUNT(*) FROM reserves WHERE reserve_id = ?", undef, $reserve_id );
 443 is( $count, 0, "Waiting reserve beyond max pickup delay canceled on holiday" );
 444
 445 # Test expirationdate
 446 $reserve = $reserves->[1];
 447 $reserve_id = $reserve->{reserve_id};
 448 $dbh->do("UPDATE reserves SET expirationdate = DATE_SUB( NOW(), INTERVAL 1 DAY ) WHERE reserve_id = ?", undef, $reserve_id );
 449 CancelExpiredReserves();
 450 $count = $dbh->selectrow_array("SELECT COUNT(*) FROM reserves WHERE reserve_id = ?", undef, $reserve_id );
 451 is( $count, 0, "Reserve with manual expiration date canceled correctly" );
 452
 453 # Bug 12632
 454 t::lib::Mocks::mock_preference( 'item-level_itypes',     1 );
 455 t::lib::Mocks::mock_preference( 'ReservesControlBranch', 'PatronLibrary' );
 456
 457 $dbh->do('DELETE FROM reserves');
 458 $dbh->do('DELETE FROM issues');
 459 $dbh->do('DELETE FROM items');
 460 $dbh->do('DELETE FROM biblio');
 461
 462 ( $bibnum, $title, $bibitemnum ) = create_helper_biblio('ONLY1');
 463 ( $item_bibnum, $item_bibitemnum, $itemnumber )
 464     = AddItem( { homebranch => $branch_1, holdingbranch => $branch_1 }, $bibnum );
 465
 466 $dbh->do(
 467     q{INSERT INTO issuingrules (categorycode, branchcode, itemtype, reservesallowed)
 468       VALUES (?, ?, ?, ?)},
 469     {},
 470     '*', '*', 'ONLY1', 1
 471 );
 472 is( CanItemBeReserved( $borrowernumbers[0], $itemnumber ),
 473     'OK', 'Patron can reserve item with hold limit of 1, no holds placed' );
 474
 475 my $res_id = AddReserve( $branch_1, $borrowernumbers[0], $bibnum, '', 1, );
 476
 477 is( CanItemBeReserved( $borrowernumbers[0], $itemnumber ),
 478     'tooManyReserves', 'Patron cannot reserve item with hold limit of 1, 1 bib level hold placed' );
 479
 480
 481 # Helper method to set up a Biblio.
 482 sub create_helper_biblio {
 483     my $itemtype = shift;
 484     my $bib = MARC::Record->new();
 485     my $title = 'Silence in the library';
 486     $bib->append_fields(
 487         MARC::Field->new('100', ' ', ' ', a => 'Moffat, Steven'),
 488         MARC::Field->new('245', ' ', ' ', a => $title),
 489         MARC::Field->new('942', ' ', ' ', c => $itemtype),
 490     );
 491     return ($bibnum, $title, $bibitemnum) = AddBiblio($bib, '');
 492 }