t/db_dependent/Holidays.t

   1 use strict;
   2 use warnings;
   3 use 5.010;
   4 use DateTime;
   5 use DateTime::TimeZone;
   6 use Test::More tests => 12;
   7
   8 use C4::Context;
   9 use C4::Branch;
  10
  11 use Koha::DateUtils;
  12
  13 BEGIN { use_ok('Koha::Calendar'); }
  14 BEGIN { use_ok('C4::Calendar'); }
  15
  16 my $dbh = C4::Context->dbh();
  17 # Start transaction
  18 $dbh->{AutoCommit} = 0;
  19 $dbh->{RaiseError} = 1;
  20
  21 # Add branches if they don't exist
  22 if (not defined GetBranchDetail('CPL')) {
  23     ModBranch({add => 1, branchcode => 'CPL', branchname => 'Centerville'});
  24 }
  25 if (not defined GetBranchDetail('MPL')) {
  26     ModBranch({add => 1, branchcode => 'MPL', branchname => 'Midway'});
  27 }
  28
  29 # Make the repeatable_holidays table ONLY the default data.
  30 $dbh->do("DELETE FROM repeatable_holidays");
  31 C4::Calendar->new( branchcode => 'MPL' )->insert_week_day_holiday(
  32     weekday     => 0,
  33     title       => '',
  34     description => 'Sundays',
  35 );
  36 my $holiday2add = dt_from_string("2015-01-01");
  37 C4::Calendar->new( branchcode => 'MPL' )->insert_day_month_holiday(
  38     day         => $holiday2add->day(),
  39     month       => $holiday2add->month(),
  40     year        => $holiday2add->year(),
  41     title       => '',
  42     description => "New Year's Day",
  43 );
  44 $holiday2add = dt_from_string("2014-12-25");
  45 C4::Calendar->new( branchcode => 'MPL' )->insert_day_month_holiday(
  46     day         => $holiday2add->day(),
  47     month       => $holiday2add->month(),
  48     year        => $holiday2add->year(),
  49     title       => '',
  50     description => 'Christmas',
  51 );
  52
  53 my $branchcode = 'MPL';
  54
  55 my $koha_calendar = Koha::Calendar->new( branchcode => $branchcode );
  56 my $c4_calendar = C4::Calendar->new( branchcode => $branchcode );
  57
  58 isa_ok( $koha_calendar, 'Koha::Calendar', 'Koha::Calendar class returned' );
  59 isa_ok( $c4_calendar,   'C4::Calendar',   'C4::Calendar class returned' );
  60
  61 my $sunday = DateTime->new(
  62     year  => 2011,
  63     month => 6,
  64     day   => 26,
  65 );
  66 my $monday = DateTime->new(
  67     year  => 2011,
  68     month => 6,
  69     day   => 27,
  70 );
  71 my $christmas = DateTime->new(
  72     year  => 2032,
  73     month => 12,
  74     day   => 25,
  75 );
  76 my $newyear = DateTime->new(
  77     year  => 2035,
  78     month => 1,
  79     day   => 1,
  80 );
  81
  82 is( $koha_calendar->is_holiday($sunday),    1, 'Sunday is a closed day' );
  83 is( $koha_calendar->is_holiday($monday),    0, 'Monday is not a closed day' );
  84 is( $koha_calendar->is_holiday($christmas), 1, 'Christmas is a closed day' );
  85 is( $koha_calendar->is_holiday($newyear), 1, 'New Years day is a closed day' );
  86
  87 $dbh->do("DELETE FROM repeatable_holidays");
  88 $dbh->do("DELETE FROM special_holidays");
  89
  90 my $custom_holiday = DateTime->new(
  91     year  => 2013,
  92     month => 11,
  93     day   => 12,
  94 );
  95
  96 is( $koha_calendar->is_holiday($custom_holiday), 0, '2013-11-10 does not start off as a holiday' );
  97 $koha_calendar->add_dummy_holiday($custom_holiday );
  98 is( $koha_calendar->is_holiday($custom_holiday), 1, 'able to add holiday for testing' );
  99
 100 my $today = dt_from_string();
 101 C4::Calendar->new( branchcode => 'CPL' )->insert_single_holiday(
 102     day         => $today->day(),
 103     month       => $today->month(),
 104     year        => $today->year(),
 105     title       => "$today",
 106     description => "$today",
 107 );
 108
 109 is( Koha::Calendar->new( branchcode => 'CPL' )->is_holiday( $today ), 1, "Today is a holiday for CPL" );
 110 is( Koha::Calendar->new( branchcode => 'MPL' )->is_holiday( $today ), 0, "Today is not a holiday for MPL");
 111
 112 $dbh->rollback;