t/db_dependent/ILSDI_Services.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use CGI qw ( -utf8 );
  21
  22 use Test::More tests => 10;
  23 use Test::MockModule;
  24 use t::lib::Mocks;
  25 use t::lib::TestBuilder;
  26
  27 use C4::Items qw( ModItemTransfer );
  28 use C4::Circulation;
  29
  30 use Koha::AuthUtils;
  31
  32 BEGIN {
  33     use_ok('C4::ILSDI::Services');
  34 }
  35
  36 my $schema  = Koha::Database->schema;
  37 my $dbh     = C4::Context->dbh;
  38 my $builder = t::lib::TestBuilder->new;
  39
  40 subtest 'AuthenticatePatron test' => sub {
  41
  42     plan tests => 14;
  43
  44     $schema->storage->txn_begin;
  45
  46     my $plain_password = 'tomasito';
  47
  48     $builder->build({
  49         source => 'Borrower',
  50         value => {
  51             cardnumber => undef,
  52         }
  53     });
  54
  55     my $borrower = $builder->build({
  56         source => 'Borrower',
  57         value  => {
  58             cardnumber => undef,
  59             password => Koha::AuthUtils::hash_password( $plain_password )
  60         }
  61     });
  62
  63     my $query = new CGI;
  64     $query->param( 'username', $borrower->{userid});
  65     $query->param( 'password', $plain_password);
  66
  67     my $reply = C4::ILSDI::Services::AuthenticatePatron( $query );
  68     is( $reply->{id}, $borrower->{borrowernumber}, "userid and password - Patron authenticated" );
  69     is( $reply->{code}, undef, "Error code undef");
  70
  71     $query->param('password','ilsdi-passworD');
  72     $reply = C4::ILSDI::Services::AuthenticatePatron( $query );
  73     is( $reply->{code}, 'PatronNotFound', "userid and wrong password - PatronNotFound" );
  74     is( $reply->{id}, undef, "id undef");
  75
  76     $query->param( 'password', $plain_password );
  77     $query->param( 'username', 'wrong-ilsdi-useriD' );
  78     $reply = C4::ILSDI::Services::AuthenticatePatron( $query );
  79     is( $reply->{code}, 'PatronNotFound', "non-existing userid - PatronNotFound" );
  80     is( $reply->{id}, undef, "id undef");
  81
  82     $query->param( 'username', uc( $borrower->{userid} ));
  83     $reply = C4::ILSDI::Services::AuthenticatePatron( $query );
  84     is( $reply->{id}, $borrower->{borrowernumber}, "userid is not case sensitive - Patron authenticated" );
  85     is( $reply->{code}, undef, "Error code undef");
  86
  87     $query->param( 'username', $borrower->{cardnumber} );
  88     $reply = C4::ILSDI::Services::AuthenticatePatron( $query );
  89     is( $reply->{id}, $borrower->{borrowernumber}, "cardnumber and password - Patron authenticated" );
  90     is( $reply->{code}, undef, "Error code undef" );
  91
  92     $query->param( 'password', 'ilsdi-passworD' );
  93     $reply = C4::ILSDI::Services::AuthenticatePatron( $query );
  94     is( $reply->{code}, 'PatronNotFound', "cardnumber and wrong password - PatronNotFount" );
  95     is( $reply->{id}, undef, "id undef" );
  96
  97     $query->param( 'username', 'randomcardnumber1234' );
  98     $query->param( 'password', $plain_password );
  99     $reply = C4::ILSDI::Services::AuthenticatePatron($query);
 100     is( $reply->{code}, 'PatronNotFound', "non-existing cardnumer/userid - PatronNotFound" );
 101     is( $reply->{id}, undef, "id undef");
 102
 103     $schema->storage->txn_rollback;
 104 };
 105
 106
 107 subtest 'GetPatronInfo/GetBorrowerAttributes test for extended patron attributes' => sub {
 108
 109     plan tests => 5;
 110
 111     $schema->storage->txn_begin;
 112
 113     $schema->resultset( 'Issue' )->delete_all;
 114     $schema->resultset( 'Borrower' )->delete_all;
 115     $schema->resultset( 'BorrowerAttribute' )->delete_all;
 116     $schema->resultset( 'BorrowerAttributeType' )->delete_all;
 117     $schema->resultset( 'Category' )->delete_all;
 118     $schema->resultset( 'Item' )->delete_all; # 'Branch' deps. on this
 119     $schema->resultset( 'Club' )->delete_all;
 120     $schema->resultset( 'Branch' )->delete_all;
 121
 122     # Configure Koha to enable ILS-DI server and extended attributes:
 123     t::lib::Mocks::mock_preference( 'ILS-DI', 1 );
 124     t::lib::Mocks::mock_preference( 'ExtendedPatronAttributes', 1 );
 125
 126     # Set up a library/branch for our user to belong to:
 127     my $lib = $builder->build( {
 128         source => 'Branch',
 129         value => {
 130             branchcode => 'T_ILSDI',
 131         }
 132     } );
 133
 134     # Create a new category for user to belong to:
 135     my $cat = $builder->build( {
 136         source => 'Category',
 137         value  => {
 138             category_type                 => 'A',
 139             BlockExpiredPatronOpacActions => -1,
 140         }
 141     } );
 142
 143     # Create a new attribute type:
 144     my $attr_type = $builder->build( {
 145         source => 'BorrowerAttributeType',
 146         value  => {
 147             code                      => 'HIDEME',
 148             opac_display              => 0,
 149             authorised_value_category => '',
 150             class                     => '',
 151         }
 152     } );
 153     my $attr_type_visible = $builder->build( {
 154         source => 'BorrowerAttributeType',
 155         value  => {
 156             code                      => 'SHOWME',
 157             opac_display              => 1,
 158             authorised_value_category => '',
 159             class                     => '',
 160         }
 161     } );
 162
 163     # Create a new user:
 164     my $brwr = $builder->build( {
 165         source => 'Borrower',
 166         value  => {
 167             categorycode => $cat->{'categorycode'},
 168             branchcode   => $lib->{'branchcode'},
 169         }
 170     } );
 171
 172     # Authorised value:
 173     my $auth = $builder->build( {
 174         source => 'AuthorisedValue',
 175         value  => {
 176             category => $cat->{'categorycode'}
 177         }
 178     } );
 179
 180     # Set the new attribute for our user:
 181     my $attr_hidden = $builder->build( {
 182         source => 'BorrowerAttribute',
 183         value  => {
 184             borrowernumber => $brwr->{'borrowernumber'},
 185             code           => $attr_type->{'code'},
 186             attribute      => '1337 hidden',
 187         }
 188     } );
 189     my $attr_shown = $builder->build( {
 190         source => 'BorrowerAttribute',
 191         value  => {
 192             borrowernumber => $brwr->{'borrowernumber'},
 193             code           => $attr_type_visible->{'code'},
 194             attribute      => '1337 shown',
 195         }
 196     } );
 197
 198     my $fine = $builder->build(
 199         {
 200             source => 'Accountline',
 201             value  => {
 202                 borrowernumber    => $brwr->{borrowernumber},
 203                 debit_type_code   => 'OVERDUE',
 204                 amountoutstanding => 10
 205             }
 206         }
 207     );
 208
 209     # Prepare and send web request for IL-SDI server:
 210     my $query = new CGI;
 211     $query->param( 'service', 'GetPatronInfo' );
 212     $query->param( 'patron_id', $brwr->{'borrowernumber'} );
 213     $query->param( 'show_attributes', '1' );
 214     $query->param( 'show_fines', '1' );
 215
 216     my $reply = C4::ILSDI::Services::GetPatronInfo( $query );
 217
 218     # Build a structure for comparison:
 219     my $cmp = {
 220         borrowernumber    => $brwr->{borrowernumber},
 221         value             => $attr_shown->{'attribute'},
 222         value_description => $attr_shown->{'attribute'},
 223         %$attr_type_visible,
 224         %$attr_shown,
 225     };
 226
 227     is( $reply->{'charges'}, '10.00',
 228         'The \'charges\' attribute should be correctly filled (bug 17836)' );
 229
 230     is( scalar( @{$reply->{fines}->{fine}}), 1, 'There should be only 1 account line');
 231     is(
 232         $reply->{fines}->{fine}->[0]->{accountlines_id},
 233         $fine->{accountlines_id},
 234         "The accountline should be the correct one"
 235     );
 236
 237     # Check results:
 238     is_deeply( $reply->{'attributes'}, [ $cmp ], 'Test GetPatronInfo - show_attributes parameter' );
 239
 240     ok( exists $reply->{is_expired}, 'There should be the is_expired information');
 241
 242     # Cleanup
 243     $schema->storage->txn_rollback;
 244 };
 245
 246 subtest 'LookupPatron test' => sub {
 247
 248     plan tests => 9;
 249
 250     $schema->storage->txn_begin;
 251
 252     $schema->resultset( 'Issue' )->delete_all;
 253     $schema->resultset( 'Borrower' )->delete_all;
 254     $schema->resultset( 'BorrowerAttribute' )->delete_all;
 255     $schema->resultset( 'BorrowerAttributeType' )->delete_all;
 256     $schema->resultset( 'Category' )->delete_all;
 257     $schema->resultset( 'Item' )->delete_all; # 'Branch' deps. on this
 258     $schema->resultset( 'Branch' )->delete_all;
 259
 260     my $borrower = $builder->build({
 261         source => 'Borrower',
 262     });
 263
 264     my $query = CGI->new();
 265     my $bad_result = C4::ILSDI::Services::LookupPatron($query);
 266     is( $bad_result->{message}, 'PatronNotFound', 'No parameters' );
 267
 268     $query->delete_all();
 269     $query->param( 'id', $borrower->{firstname} );
 270     my $optional_result = C4::ILSDI::Services::LookupPatron($query);
 271     is(
 272         $optional_result->{id},
 273         $borrower->{borrowernumber},
 274         'Valid Firstname only'
 275     );
 276
 277     $query->delete_all();
 278     $query->param( 'id', 'ThereIsNoWayThatThisCouldPossiblyBeValid' );
 279     my $bad_optional_result = C4::ILSDI::Services::LookupPatron($query);
 280     is( $bad_optional_result->{message}, 'PatronNotFound', 'Invalid ID' );
 281
 282     foreach my $id_type (
 283         'cardnumber',
 284         'userid',
 285         'email',
 286         'borrowernumber',
 287         'surname',
 288         'firstname'
 289     ) {
 290         $query->delete_all();
 291         $query->param( 'id_type', $id_type );
 292         $query->param( 'id', $borrower->{$id_type} );
 293         my $result = C4::ILSDI::Services::LookupPatron($query);
 294         is( $result->{'id'}, $borrower->{borrowernumber}, "Checking $id_type" );
 295     }
 296
 297     # Cleanup
 298     $schema->storage->txn_rollback;
 299 };
 300
 301 subtest 'Holds test' => sub {
 302
 303     plan tests => 5;
 304
 305     $schema->storage->txn_begin;
 306
 307     t::lib::Mocks::mock_preference( 'AllowHoldsOnDamagedItems', 0 );
 308
 309     my $patron = $builder->build({
 310         source => 'Borrower',
 311     });
 312
 313     my $item = $builder->build_sample_item(
 314         {
 315             damaged => 1
 316         }
 317     );
 318
 319     my $query = new CGI;
 320     $query->param( 'patron_id', $patron->{borrowernumber});
 321     $query->param( 'bib_id', $item->biblionumber);
 322
 323     my $reply = C4::ILSDI::Services::HoldTitle( $query );
 324     is( $reply->{code}, 'damaged', "Item damaged" );
 325
 326     $item->damaged(0)->store;
 327
 328     my $hold = $builder->build({
 329         source => 'Reserve',
 330         value => {
 331             borrowernumber => $patron->{borrowernumber},
 332             biblionumber => $item->biblionumber,
 333             itemnumber => $item->itemnumber
 334         }
 335     });
 336
 337     $reply = C4::ILSDI::Services::HoldTitle( $query );
 338     is( $reply->{code}, 'itemAlreadyOnHold', "Item already on hold" );
 339
 340     my $biblio_with_no_item = $builder->build_sample_biblio;
 341
 342     $query = new CGI;
 343     $query->param( 'patron_id', $patron->{borrowernumber});
 344     $query->param( 'bib_id', $biblio_with_no_item->biblionumber);
 345
 346     $reply = C4::ILSDI::Services::HoldTitle( $query );
 347     is( $reply->{code}, 'NoItems', 'Biblio has no item' );
 348
 349     my $item2 = $builder->build_sample_item(
 350         {
 351             damaged => 0,
 352         }
 353     );
 354
 355     t::lib::Mocks::mock_preference( 'ReservesControlBranch', 'PatronLibrary' );
 356     Koha::CirculationRules->set_rule(
 357         {
 358             categorycode => $patron->{categorycode},
 359             itemtype     => $item2->{itype},
 360             branchcode   => $patron->{branchcode},
 361             rule_name    => 'reservesallowed',
 362             rule_value   => 0,
 363         }
 364     );
 365
 366     $query = new CGI;
 367     $query->param( 'patron_id', $patron->{borrowernumber});
 368     $query->param( 'bib_id', $item2->biblionumber);
 369     $query->param( 'item_id', $item2->itemnumber);
 370
 371     $reply = C4::ILSDI::Services::HoldItem( $query );
 372     is( $reply->{code}, 'tooManyReserves', "Too many reserves" );
 373
 374     # Adding a holdable item to biblio 3.
 375     my $item3 = $builder->build_sample_item(
 376         {
 377             damaged => 0,
 378         }
 379     );
 380
 381     my $item4 = $builder->build_sample_item(
 382         {
 383             biblionumber => $item3->biblionumber,
 384             damaged      => 1,
 385         }
 386     );
 387
 388     Koha::CirculationRules->set_rule(
 389         {
 390             categorycode => $patron->{categorycode},
 391             itemtype     => $item3->{itype},
 392             branchcode   => $patron->{branchcode},
 393             rule_name    => 'reservesallowed',
 394             rule_value   => 10,
 395         }
 396     );
 397
 398     $query = new CGI;
 399     $query->param( 'patron_id', $patron->{borrowernumber});
 400     $query->param( 'bib_id', $item3->biblionumber);
 401     $query->param( 'item_id', $item4->itemnumber);
 402
 403     $reply = C4::ILSDI::Services::HoldItem( $query );
 404     is( $reply->{code}, 'damaged', "Item is damaged" );
 405
 406     $schema->storage->txn_rollback;
 407 };
 408
 409 subtest 'Holds test for branch transfer limits' => sub {
 410
 411     plan tests => 6;
 412
 413     $schema->storage->txn_begin;
 414
 415     # Test enforement of branch transfer limits
 416     t::lib::Mocks::mock_preference( 'UseBranchTransferLimits', '1' );
 417     t::lib::Mocks::mock_preference( 'BranchTransferLimitsType', 'itemtype' );
 418
 419     my $patron = $builder->build({
 420         source => 'Borrower',
 421     });
 422
 423     my $origin_branch = $builder->build(
 424         {
 425             source => 'Branch',
 426             value  => {
 427                 pickup_location => 1,
 428             }
 429         }
 430     );
 431     my $pickup_branch = $builder->build(
 432         {
 433             source => 'Branch',
 434             value  => {
 435                 pickup_location => 1,
 436             }
 437         }
 438     );
 439
 440     my $item = $builder->build_sample_item(
 441         {
 442             library => $origin_branch->{branchcode},
 443         }
 444     );
 445
 446     Koha::CirculationRules->set_rule(
 447         {
 448             categorycode => undef,
 449             itemtype     => undef,
 450             branchcode   => undef,
 451             rule_name    => 'reservesallowed',
 452             rule_value   => 99,
 453         }
 454     );
 455
 456     my $limit = Koha::Item::Transfer::Limit->new({
 457         toBranch => $pickup_branch->{branchcode},
 458         fromBranch => $item->holdingbranch,
 459         itemtype => $item->effective_itemtype,
 460     })->store();
 461
 462     my $query = new CGI;
 463     $query->param( 'pickup_location', $pickup_branch->{branchcode} );
 464     $query->param( 'patron_id', $patron->{borrowernumber});
 465     $query->param( 'bib_id', $item->biblionumber);
 466     $query->param( 'item_id', $item->itemnumber);
 467
 468     my $reply = C4::ILSDI::Services::HoldItem( $query );
 469     is( $reply->{code}, 'cannotBeTransferred', "Item hold, Item cannot be transferred" );
 470
 471     $reply = C4::ILSDI::Services::HoldTitle( $query );
 472     is( $reply->{code}, 'cannotBeTransferred', "Record hold, Item cannot be transferred" );
 473
 474     t::lib::Mocks::mock_preference( 'UseBranchTransferLimits', '0' );
 475
 476     $reply = C4::ILSDI::Services::HoldItem( $query );
 477     is( $reply->{code}, undef, "Item hold, Item can be transferred" );
 478     my $hold = Koha::Holds->search({ itemnumber => $item->itemnumber, borrowernumber => $patron->{borrowernumber} })->next;
 479     is( $hold->branchcode, $pickup_branch->{branchcode}, 'The library id is correctly set' );
 480
 481     Koha::Holds->search()->delete();
 482
 483     $reply = C4::ILSDI::Services::HoldTitle( $query );
 484     is( $reply->{code}, undef, "Record hold, Item con be transferred" );
 485     $hold = Koha::Holds->search({ biblionumber => $item->biblionumber, borrowernumber => $patron->{borrowernumber} })->next;
 486     is( $hold->branchcode, $pickup_branch->{branchcode}, 'The library id is correctly set' );
 487
 488     $schema->storage->txn_rollback;
 489 };
 490
 491 subtest 'Holds test with start_date and end_date' => sub {
 492
 493     plan tests => 8;
 494
 495     $schema->storage->txn_begin;
 496
 497     my $pickup_library = $builder->build_object(
 498         {
 499             class  => 'Koha::Libraries',
 500             value  => {
 501                 pickup_location => 1,
 502             }
 503         }
 504     );
 505
 506     my $patron = $builder->build_object({
 507         class => 'Koha::Patrons',
 508     });
 509
 510     my $item = $builder->build_sample_item({ library => $pickup_library->branchcode });
 511
 512     Koha::CirculationRules->set_rule(
 513         {
 514             categorycode => undef,
 515             itemtype     => undef,
 516             branchcode   => undef,
 517             rule_name    => 'reservesallowed',
 518             rule_value   => 99,
 519         }
 520     );
 521
 522     my $query = new CGI;
 523     $query->param( 'pickup_location', $pickup_library->branchcode );
 524     $query->param( 'patron_id', $patron->borrowernumber);
 525     $query->param( 'bib_id', $item->biblionumber);
 526     $query->param( 'item_id', $item->itemnumber);
 527     $query->param( 'start_date', '2020-03-20');
 528     $query->param( 'expiry_date', '2020-04-22');
 529
 530     my $reply = C4::ILSDI::Services::HoldItem( $query );
 531     is ($reply->{pickup_location}, $pickup_library->branchname, "Item hold with date parameters was placed");
 532     my $hold = Koha::Holds->search({ biblionumber => $item->biblionumber})->next();
 533     is( $hold->biblionumber, $item->biblionumber, "correct biblionumber");
 534     is( $hold->reservedate, '2020-03-20', "Item hold has correct start date" );
 535     is( $hold->expirationdate, '2020-04-22', "Item hold has correct end date" );
 536
 537     $hold->delete();
 538
 539     $reply = C4::ILSDI::Services::HoldTitle( $query );
 540     is ($reply->{pickup_location}, $pickup_library->branchname, "Record hold with date parameters was placed");
 541     $hold = Koha::Holds->search({ biblionumber => $item->biblionumber})->next();
 542     is( $hold->biblionumber, $item->biblionumber, "correct biblionumber");
 543     is( $hold->reservedate, '2020-03-20', "Record hold has correct start date" );
 544     is( $hold->expirationdate, '2020-04-22', "Record hold has correct end date" );
 545
 546     $schema->storage->txn_rollback;
 547 };
 548
 549 subtest 'GetRecords' => sub {
 550
 551     plan tests => 1;
 552
 553     $schema->storage->txn_begin;
 554
 555     t::lib::Mocks::mock_preference( 'ILS-DI', 1 );
 556
 557     my $branch1 = $builder->build({
 558         source => 'Branch',
 559     });
 560     my $branch2 = $builder->build({
 561         source => 'Branch',
 562     });
 563
 564     my $item = $builder->build_sample_item(
 565         {
 566             library => $branch1->{branchcode},
 567         }
 568     );
 569
 570     ModItemTransfer($item->itemnumber, $branch1->{branchcode}, $branch2->{branchcode});
 571
 572     my $cgi = new CGI;
 573     $cgi->param(service => 'GetRecords');
 574     $cgi->param(id => $item->biblionumber);
 575
 576     my $reply = C4::ILSDI::Services::GetRecords($cgi);
 577
 578     my $transfer = $item->get_transfer;
 579     my $expected = {
 580         datesent => $transfer->datesent,
 581         frombranch => $transfer->frombranch,
 582         tobranch => $transfer->tobranch,
 583     };
 584     is_deeply($reply->{record}->[0]->{items}->{item}->[0]->{transfer}, $expected,
 585         'GetRecords returns transfer informations');
 586
 587     $schema->storage->txn_rollback;
 588 };
 589
 590 subtest 'RenewHold' => sub {
 591     plan tests => 4;
 592
 593     $schema->storage->txn_begin;
 594
 595     my $cgi    = new CGI;
 596     my $patron = $builder->build_object( { class => 'Koha::Patrons' } );
 597     my $item   = $builder->build_sample_item;
 598     $cgi->param( patron_id => $patron->borrowernumber );
 599     $cgi->param( item_id   => $item->itemnumber );
 600
 601     t::lib::Mocks::mock_userenv( { patron => $patron } );    # For AddIssue
 602     my $checkout = C4::Circulation::AddIssue( $patron->unblessed, $item->barcode );
 603
 604     # Everything is ok
 605     my $reply = C4::ILSDI::Services::RenewLoan($cgi);
 606     is( exists $reply->{date_due}, 1, 'If the item is checked out, the date_due key should exist' );
 607
 608     # The item is not checked out
 609     $checkout->delete;
 610     $reply = C4::ILSDI::Services::RenewLoan($cgi);
 611     is( $reply, undef, 'If the item is not checked out, we should not explode.');    # FIXME We should return an error code instead
 612
 613     # The item does not exist
 614     $item->delete;
 615     $reply = C4::ILSDI::Services::RenewLoan($cgi);
 616     is( $reply->{code}, 'RecordNotFound', 'If the item does not exist, RecordNotFound should be returned');
 617
 618     $patron->delete;
 619     $reply = C4::ILSDI::Services::RenewLoan($cgi);
 620     is( $reply->{code}, 'PatronNotFound', 'If the patron does not exist, PatronNotFound should be returned');
 621
 622     $schema->storage->txn_rollback;
 623 };
 624
 625 subtest 'GetPatronInfo paginated loans' => sub {
 626     plan tests => 7;
 627
 628     $schema->storage->txn_begin;
 629
 630     my $library = $builder->build_object({
 631         class => 'Koha::Libraries',
 632     });
 633
 634     my $item1 = $builder->build_sample_item({ library => $library->branchcode });
 635     my $item2 = $builder->build_sample_item({ library => $library->branchcode });
 636     my $item3 = $builder->build_sample_item({ library => $library->branchcode });
 637     my $patron = $builder->build_object({
 638         class => 'Koha::Patrons',
 639         value => {
 640             branchcode => $library->branchcode,
 641         },
 642     });
 643     my $module = new Test::MockModule('C4::Context');
 644     $module->mock('userenv', sub { { branch => $library->branchcode } });
 645     my $date_due = DateTime->now->add(weeks => 2);
 646     my $issue1 = C4::Circulation::AddIssue($patron->unblessed, $item1->barcode, $date_due);
 647     my $date_due1 = Koha::DateUtils::dt_from_string( $issue1->date_due );
 648     my $issue2 = C4::Circulation::AddIssue($patron->unblessed, $item2->barcode, $date_due);
 649     my $date_due2 = Koha::DateUtils::dt_from_string( $issue2->date_due );
 650     my $issue3 = C4::Circulation::AddIssue($patron->unblessed, $item3->barcode, $date_due);
 651     my $date_due3 = Koha::DateUtils::dt_from_string( $issue3->date_due );
 652
 653     my $cgi = new CGI;
 654
 655     $cgi->param( 'service', 'GetPatronInfo' );
 656     $cgi->param( 'patron_id', $patron->borrowernumber );
 657     $cgi->param( 'show_loans', '1' );
 658     $cgi->param( 'loans_per_page', '2' );
 659     $cgi->param( 'loans_page', '1' );
 660     my $reply = C4::ILSDI::Services::GetPatronInfo($cgi);
 661
 662     is($reply->{total_loans}, 3, 'total_loans == 3');
 663     is(scalar @{ $reply->{loans}->{loan} }, 2, 'GetPatronInfo returned only 2 loans');
 664     is($reply->{loans}->{loan}->[0]->{itemnumber}, $item3->itemnumber);
 665     is($reply->{loans}->{loan}->[1]->{itemnumber}, $item2->itemnumber);
 666
 667     $cgi->param( 'loans_page', '2' );
 668     $reply = C4::ILSDI::Services::GetPatronInfo($cgi);
 669
 670     is($reply->{total_loans}, 3, 'total_loans == 3');
 671     is(scalar @{ $reply->{loans}->{loan} }, 1, 'GetPatronInfo returned only 1 loan');
 672     is($reply->{loans}->{loan}->[0]->{itemnumber}, $item1->itemnumber);
 673
 674     $schema->storage->txn_rollback;
 675 };