t/db_dependent/ILSDI_Services.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use CGI qw ( -utf8 );
  21
  22 use Test::More tests => 10;
  23 use Test::MockModule;
  24 use t::lib::Mocks;
  25 use t::lib::TestBuilder;
  26
  27 use C4::Items qw( ModItemTransfer );
  28 use C4::Circulation;
  29
  30 use Koha::AuthUtils;
  31
  32 BEGIN {
  33     use_ok('C4::ILSDI::Services');
  34 }
  35
  36 my $schema  = Koha::Database->schema;
  37 my $dbh     = C4::Context->dbh;
  38 my $builder = t::lib::TestBuilder->new;
  39
  40 subtest 'AuthenticatePatron test' => sub {
  41
  42     plan tests => 14;
  43
  44     $schema->storage->txn_begin;
  45
  46     my $plain_password = 'tomasito';
  47
  48     $builder->build({
  49         source => 'Borrower',
  50         value => {
  51             cardnumber => undef,
  52         }
  53     });
  54
  55     my $borrower = $builder->build({
  56         source => 'Borrower',
  57         value  => {
  58             cardnumber => undef,
  59             password => Koha::AuthUtils::hash_password( $plain_password )
  60         }
  61     });
  62
  63     my $query = new CGI;
  64     $query->param( 'username', $borrower->{userid});
  65     $query->param( 'password', $plain_password);
  66
  67     my $reply = C4::ILSDI::Services::AuthenticatePatron( $query );
  68     is( $reply->{id}, $borrower->{borrowernumber}, "userid and password - Patron authenticated" );
  69     is( $reply->{code}, undef, "Error code undef");
  70
  71     $query->param('password','ilsdi-passworD');
  72     $reply = C4::ILSDI::Services::AuthenticatePatron( $query );
  73     is( $reply->{code}, 'PatronNotFound', "userid and wrong password - PatronNotFound" );
  74     is( $reply->{id}, undef, "id undef");
  75
  76     $query->param( 'password', $plain_password );
  77     $query->param( 'username', 'wrong-ilsdi-useriD' );
  78     $reply = C4::ILSDI::Services::AuthenticatePatron( $query );
  79     is( $reply->{code}, 'PatronNotFound', "non-existing userid - PatronNotFound" );
  80     is( $reply->{id}, undef, "id undef");
  81
  82     $query->param( 'username', uc( $borrower->{userid} ));
  83     $reply = C4::ILSDI::Services::AuthenticatePatron( $query );
  84     is( $reply->{id}, $borrower->{borrowernumber}, "userid is not case sensitive - Patron authenticated" );
  85     is( $reply->{code}, undef, "Error code undef");
  86
  87     $query->param( 'username', $borrower->{cardnumber} );
  88     $reply = C4::ILSDI::Services::AuthenticatePatron( $query );
  89     is( $reply->{id}, $borrower->{borrowernumber}, "cardnumber and password - Patron authenticated" );
  90     is( $reply->{code}, undef, "Error code undef" );
  91
  92     $query->param( 'password', 'ilsdi-passworD' );
  93     $reply = C4::ILSDI::Services::AuthenticatePatron( $query );
  94     is( $reply->{code}, 'PatronNotFound', "cardnumber and wrong password - PatronNotFount" );
  95     is( $reply->{id}, undef, "id undef" );
  96
  97     $query->param( 'username', 'randomcardnumber1234' );
  98     $query->param( 'password', $plain_password );
  99     $reply = C4::ILSDI::Services::AuthenticatePatron($query);
 100     is( $reply->{code}, 'PatronNotFound', "non-existing cardnumer/userid - PatronNotFound" );
 101     is( $reply->{id}, undef, "id undef");
 102
 103     $schema->storage->txn_rollback;
 104 };
 105
 106
 107 subtest 'GetPatronInfo/GetBorrowerAttributes test for extended patron attributes' => sub {
 108
 109     plan tests => 5;
 110
 111     $schema->storage->txn_begin;
 112
 113     $schema->resultset( 'Issue' )->delete_all;
 114     $schema->resultset( 'Borrower' )->delete_all;
 115     $schema->resultset( 'BorrowerAttribute' )->delete_all;
 116     $schema->resultset( 'BorrowerAttributeType' )->delete_all;
 117     $schema->resultset( 'Category' )->delete_all;
 118     $schema->resultset( 'Item' )->delete_all; # 'Branch' deps. on this
 119     $schema->resultset( 'Club' )->delete_all;
 120     $schema->resultset( 'Branch' )->delete_all;
 121
 122     # Configure Koha to enable ILS-DI server and extended attributes:
 123     t::lib::Mocks::mock_preference( 'ILS-DI', 1 );
 124     t::lib::Mocks::mock_preference( 'ExtendedPatronAttributes', 1 );
 125
 126     # Set up a library/branch for our user to belong to:
 127     my $lib = $builder->build( {
 128         source => 'Branch',
 129         value => {
 130             branchcode => 'T_ILSDI',
 131         }
 132     } );
 133
 134     # Create a new category for user to belong to:
 135     my $cat = $builder->build( {
 136         source => 'Category',
 137         value  => {
 138             category_type                 => 'A',
 139             BlockExpiredPatronOpacActions => -1,
 140         }
 141     } );
 142
 143     # Create a new attribute type:
 144     my $attr_type = $builder->build( {
 145         source => 'BorrowerAttributeType',
 146         value  => {
 147             code                      => 'HIDEME',
 148             opac_display              => 0,
 149             authorised_value_category => '',
 150             class                     => '',
 151         }
 152     } );
 153     my $attr_type_visible = $builder->build( {
 154         source => 'BorrowerAttributeType',
 155         value  => {
 156             code                      => 'SHOWME',
 157             opac_display              => 1,
 158             authorised_value_category => '',
 159             class                     => '',
 160         }
 161     } );
 162
 163     # Create a new user:
 164     my $brwr = $builder->build( {
 165         source => 'Borrower',
 166         value  => {
 167             categorycode => $cat->{'categorycode'},
 168             branchcode   => $lib->{'branchcode'},
 169         }
 170     } );
 171
 172     # Authorised value:
 173     my $auth = $builder->build( {
 174         source => 'AuthorisedValue',
 175         value  => {
 176             category => $cat->{'categorycode'}
 177         }
 178     } );
 179
 180     # Set the new attribute for our user:
 181     my $attr_hidden = $builder->build( {
 182         source => 'BorrowerAttribute',
 183         value  => {
 184             borrowernumber => $brwr->{'borrowernumber'},
 185             code           => $attr_type->{'code'},
 186             attribute      => '1337 hidden',
 187         }
 188     } );
 189     my $attr_shown = $builder->build( {
 190         source => 'BorrowerAttribute',
 191         value  => {
 192             borrowernumber => $brwr->{'borrowernumber'},
 193             code           => $attr_type_visible->{'code'},
 194             attribute      => '1337 shown',
 195         }
 196     } );
 197
 198     my $fine = $builder->build(
 199         {
 200             source => 'Accountline',
 201             value  => {
 202                 borrowernumber    => $brwr->{borrowernumber},
 203                 debit_type_code   => 'OVERDUE',
 204                 amountoutstanding => 10
 205             }
 206         }
 207     );
 208
 209     # Prepare and send web request for IL-SDI server:
 210     my $query = new CGI;
 211     $query->param( 'service', 'GetPatronInfo' );
 212     $query->param( 'patron_id', $brwr->{'borrowernumber'} );
 213     $query->param( 'show_attributes', '1' );
 214     $query->param( 'show_fines', '1' );
 215
 216     my $reply = C4::ILSDI::Services::GetPatronInfo( $query );
 217
 218     # Build a structure for comparison:
 219     my $cmp = {
 220         borrowernumber    => $brwr->{borrowernumber},
 221         value             => $attr_shown->{'attribute'},
 222         value_description => $attr_shown->{'attribute'},
 223         %$attr_type_visible,
 224         %$attr_shown,
 225     };
 226
 227     is( $reply->{'charges'}, '10.00',
 228         'The \'charges\' attribute should be correctly filled (bug 17836)' );
 229
 230     is( scalar( @{$reply->{fines}->{fine}}), 1, 'There should be only 1 account line');
 231     is(
 232         $reply->{fines}->{fine}->[0]->{accountlines_id},
 233         $fine->{accountlines_id},
 234         "The accountline should be the correct one"
 235     );
 236
 237     # Check results:
 238     is_deeply( $reply->{'attributes'}, [ $cmp ], 'Test GetPatronInfo - show_attributes parameter' );
 239
 240     ok( exists $reply->{is_expired}, 'There should be the is_expired information');
 241
 242     # Cleanup
 243     $schema->storage->txn_rollback;
 244 };
 245
 246 subtest 'LookupPatron test' => sub {
 247
 248     plan tests => 9;
 249
 250     $schema->storage->txn_begin;
 251
 252     $schema->resultset( 'Issue' )->delete_all;
 253     $schema->resultset( 'Borrower' )->delete_all;
 254     $schema->resultset( 'BorrowerAttribute' )->delete_all;
 255     $schema->resultset( 'BorrowerAttributeType' )->delete_all;
 256     $schema->resultset( 'Category' )->delete_all;
 257     $schema->resultset( 'Item' )->delete_all; # 'Branch' deps. on this
 258     $schema->resultset( 'Branch' )->delete_all;
 259
 260     my $borrower = $builder->build({
 261         source => 'Borrower',
 262     });
 263
 264     my $query = CGI->new();
 265     my $bad_result = C4::ILSDI::Services::LookupPatron($query);
 266     is( $bad_result->{message}, 'PatronNotFound', 'No parameters' );
 267
 268     $query->delete_all();
 269     $query->param( 'id', $borrower->{firstname} );
 270     my $optional_result = C4::ILSDI::Services::LookupPatron($query);
 271     is(
 272         $optional_result->{id},
 273         $borrower->{borrowernumber},
 274         'Valid Firstname only'
 275     );
 276
 277     $query->delete_all();
 278     $query->param( 'id', 'ThereIsNoWayThatThisCouldPossiblyBeValid' );
 279     my $bad_optional_result = C4::ILSDI::Services::LookupPatron($query);
 280     is( $bad_optional_result->{message}, 'PatronNotFound', 'Invalid ID' );
 281
 282     foreach my $id_type (
 283         'cardnumber',
 284         'userid',
 285         'email',
 286         'borrowernumber',
 287         'surname',
 288         'firstname'
 289     ) {
 290         $query->delete_all();
 291         $query->param( 'id_type', $id_type );
 292         $query->param( 'id', $borrower->{$id_type} );
 293         my $result = C4::ILSDI::Services::LookupPatron($query);
 294         is( $result->{'id'}, $borrower->{borrowernumber}, "Checking $id_type" );
 295     }
 296
 297     # Cleanup
 298     $schema->storage->txn_rollback;
 299 };
 300
 301 subtest 'Holds test' => sub {
 302
 303     plan tests => 5;
 304
 305     $schema->storage->txn_begin;
 306
 307     t::lib::Mocks::mock_preference( 'AllowHoldsOnDamagedItems', 0 );
 308
 309     my $patron = $builder->build({
 310         source => 'Borrower',
 311     });
 312
 313     my $biblio = $builder->build({
 314         source => 'Biblio',
 315     });
 316
 317     my $biblioitems = $builder->build({
 318         source => 'Biblioitem',
 319         value => {
 320             biblionumber => $biblio->{biblionumber},
 321         }
 322     });
 323
 324     my $item = $builder->build({
 325         source => 'Item',
 326         value => {
 327             biblionumber => $biblio->{biblionumber},
 328             damaged => 1
 329         }
 330     });
 331
 332     my $query = new CGI;
 333     $query->param( 'patron_id', $patron->{borrowernumber});
 334     $query->param( 'bib_id', $biblio->{biblionumber});
 335
 336     my $reply = C4::ILSDI::Services::HoldTitle( $query );
 337     is( $reply->{code}, 'damaged', "Item damaged" );
 338
 339     my $item_o = Koha::Items->find($item->{itemnumber});
 340     $item_o->damaged(0)->store;
 341
 342     my $hold = $builder->build({
 343         source => 'Reserve',
 344         value => {
 345             borrowernumber => $patron->{borrowernumber},
 346             biblionumber => $biblio->{biblionumber},
 347             itemnumber => $item->{itemnumber}
 348         }
 349     });
 350
 351     $reply = C4::ILSDI::Services::HoldTitle( $query );
 352     is( $reply->{code}, 'itemAlreadyOnHold', "Item already on hold" );
 353
 354     my $biblio_with_no_item = $builder->build({
 355         source => 'Biblio',
 356     });
 357
 358     $query = new CGI;
 359     $query->param( 'patron_id', $patron->{borrowernumber});
 360     $query->param( 'bib_id', $biblio_with_no_item->{biblionumber});
 361
 362     $reply = C4::ILSDI::Services::HoldTitle( $query );
 363     is( $reply->{code}, 'NoItems', 'Biblio has no item' );
 364
 365     my $biblio2 = $builder->build({
 366         source => 'Biblio',
 367     });
 368
 369     my $biblioitems2 = $builder->build({
 370         source => 'Biblioitem',
 371         value => {
 372             biblionumber => $biblio2->{biblionumber},
 373         }
 374     });
 375
 376     my $item2 = $builder->build({
 377         source => 'Item',
 378         value => {
 379             biblionumber => $biblio2->{biblionumber},
 380             damaged => 0,
 381             itype => $builder->build_object({ class => 'Koha::ItemTypes' })->itemtype,
 382         }
 383     });
 384
 385     t::lib::Mocks::mock_preference( 'ReservesControlBranch', 'PatronLibrary' );
 386     Koha::CirculationRules->set_rule(
 387         {
 388             categorycode => $patron->{categorycode},
 389             itemtype     => $item2->{itype},
 390             branchcode   => $patron->{branchcode},
 391             rule_name    => 'reservesallowed',
 392             rule_value   => 0,
 393         }
 394     );
 395
 396     $query = new CGI;
 397     $query->param( 'patron_id', $patron->{borrowernumber});
 398     $query->param( 'bib_id', $biblio2->{biblionumber});
 399     $query->param( 'item_id', $item2->{itemnumber});
 400
 401     $reply = C4::ILSDI::Services::HoldItem( $query );
 402     is( $reply->{code}, 'tooManyReserves', "Too many reserves" );
 403
 404     my $biblio3 = $builder->build({
 405         source => 'Biblio',
 406     });
 407
 408     my $biblioitems3 = $builder->build({
 409         source => 'Biblioitem',
 410         value => {
 411             biblionumber => $biblio3->{biblionumber},
 412         }
 413     });
 414
 415     # Adding a holdable item to biblio 3.
 416     my $item3 = $builder->build({
 417         source => 'Item',
 418         value => {
 419             biblionumber => $biblio3->{biblionumber},
 420             damaged => 0,
 421             itype => $builder->build_object({ class => 'Koha::ItemTypes' })->itemtype,
 422         }
 423     });
 424
 425     my $item4 = $builder->build({
 426         source => 'Item',
 427         value => {
 428             biblionumber => $biblio3->{biblionumber},
 429             damaged => 1,
 430             itype => $builder->build_object({ class => 'Koha::ItemTypes' })->itemtype,
 431         }
 432     });
 433
 434     Koha::CirculationRules->set_rule(
 435         {
 436             categorycode => $patron->{categorycode},
 437             itemtype     => $item3->{itype},
 438             branchcode   => $patron->{branchcode},
 439             rule_name    => 'reservesallowed',
 440             rule_value   => 10,
 441         }
 442     );
 443
 444     $query = new CGI;
 445     $query->param( 'patron_id', $patron->{borrowernumber});
 446     $query->param( 'bib_id', $biblio3->{biblionumber});
 447     $query->param( 'item_id', $item4->{itemnumber});
 448
 449     $reply = C4::ILSDI::Services::HoldItem( $query );
 450     is( $reply->{code}, 'damaged', "Item is damaged" );
 451
 452     $schema->storage->txn_rollback;
 453 };
 454
 455 subtest 'Holds test for branch transfer limits' => sub {
 456
 457     plan tests => 6;
 458
 459     $schema->storage->txn_begin;
 460
 461     # Test enforement of branch transfer limits
 462     t::lib::Mocks::mock_preference( 'UseBranchTransferLimits', '1' );
 463     t::lib::Mocks::mock_preference( 'BranchTransferLimitsType', 'itemtype' );
 464
 465     my $patron = $builder->build({
 466         source => 'Borrower',
 467     });
 468
 469     my $origin_branch = $builder->build(
 470         {
 471             source => 'Branch',
 472             value  => {
 473                 pickup_location => 1,
 474             }
 475         }
 476     );
 477     my $pickup_branch = $builder->build(
 478         {
 479             source => 'Branch',
 480             value  => {
 481                 pickup_location => 1,
 482             }
 483         }
 484     );
 485
 486     my $biblio = $builder->build({
 487         source => 'Biblio',
 488     });
 489     my $biblioitem = $builder->build({
 490         source => 'Biblioitem',
 491         value => {
 492             biblionumber => $biblio->{biblionumber},
 493         }
 494     });
 495     my $item = $builder->build({
 496         source => 'Item',
 497         value => {
 498             homebranch => $origin_branch->{branchcode},
 499             holdingbranch => $origin_branch->{branchcode},
 500             biblionumber => $biblio->{biblionumber},
 501             damaged => 0,
 502             itemlost => 0,
 503             itype => $builder->build_object({ class => 'Koha::ItemTypes' })->itemtype,
 504         }
 505     });
 506
 507     Koha::CirculationRules->set_rule(
 508         {
 509             categorycode => undef,
 510             itemtype     => undef,
 511             branchcode   => undef,
 512             rule_name    => 'reservesallowed',
 513             rule_value   => 99,
 514         }
 515     );
 516
 517     my $limit = Koha::Item::Transfer::Limit->new({
 518         toBranch => $pickup_branch->{branchcode},
 519         fromBranch => $item->{holdingbranch},
 520         itemtype => $item->{itype},
 521     })->store();
 522
 523     my $query = new CGI;
 524     $query->param( 'pickup_location', $pickup_branch->{branchcode} );
 525     $query->param( 'patron_id', $patron->{borrowernumber});
 526     $query->param( 'bib_id', $biblio->{biblionumber});
 527     $query->param( 'item_id', $item->{itemnumber});
 528
 529     my $reply = C4::ILSDI::Services::HoldItem( $query );
 530     is( $reply->{code}, 'cannotBeTransferred', "Item hold, Item cannot be transferred" );
 531
 532     $reply = C4::ILSDI::Services::HoldTitle( $query );
 533     is( $reply->{code}, 'cannotBeTransferred', "Record hold, Item cannot be transferred" );
 534
 535     t::lib::Mocks::mock_preference( 'UseBranchTransferLimits', '0' );
 536
 537     $reply = C4::ILSDI::Services::HoldItem( $query );
 538     is( $reply->{code}, undef, "Item hold, Item can be transferred" );
 539     my $hold = Koha::Holds->search({ itemnumber => $item->{itemnumber}, borrowernumber => $patron->{borrowernumber} })->next;
 540     is( $hold->branchcode, $pickup_branch->{branchcode}, 'The library id is correctly set' );
 541
 542     Koha::Holds->search()->delete();
 543
 544     $reply = C4::ILSDI::Services::HoldTitle( $query );
 545     is( $reply->{code}, undef, "Record hold, Item con be transferred" );
 546     $hold = Koha::Holds->search({ biblionumber => $biblio->{biblionumber}, borrowernumber => $patron->{borrowernumber} })->next;
 547     is( $hold->branchcode, $pickup_branch->{branchcode}, 'The library id is correctly set' );
 548
 549     $schema->storage->txn_rollback;
 550 };
 551
 552 subtest 'Holds test with start_date and end_date' => sub {
 553
 554     plan tests => 8;
 555
 556     $schema->storage->txn_begin;
 557
 558     my $pickup_library = $builder->build_object(
 559         {
 560             class  => 'Koha::Libraries',
 561             value  => {
 562                 pickup_location => 1,
 563             }
 564         }
 565     );
 566
 567     my $patron = $builder->build_object({
 568         class => 'Koha::Patrons',
 569     });
 570
 571     my $item = $builder->build_sample_item({ library => $pickup_library->branchcode });
 572
 573     Koha::CirculationRules->set_rule(
 574         {
 575             categorycode => undef,
 576             itemtype     => undef,
 577             branchcode   => undef,
 578             rule_name    => 'reservesallowed',
 579             rule_value   => 99,
 580         }
 581     );
 582
 583     my $query = new CGI;
 584     $query->param( 'pickup_location', $pickup_library->branchcode );
 585     $query->param( 'patron_id', $patron->borrowernumber);
 586     $query->param( 'bib_id', $item->biblionumber);
 587     $query->param( 'item_id', $item->itemnumber);
 588     $query->param( 'start_date', '2020-03-20');
 589     $query->param( 'expiry_date', '2020-04-22');
 590
 591     my $reply = C4::ILSDI::Services::HoldItem( $query );
 592     is ($reply->{pickup_location}, $pickup_library->branchname, "Item hold with date parameters was placed");
 593     my $hold = Koha::Holds->search({ biblionumber => $item->biblionumber})->next();
 594     is( $hold->biblionumber, $item->biblionumber, "correct biblionumber");
 595     is( $hold->reservedate, '2020-03-20', "Item hold has correct start date" );
 596     is( $hold->expirationdate, '2020-04-22', "Item hold has correct end date" );
 597
 598     $hold->delete();
 599
 600     $reply = C4::ILSDI::Services::HoldTitle( $query );
 601     is ($reply->{pickup_location}, $pickup_library->branchname, "Record hold with date parameters was placed");
 602     $hold = Koha::Holds->search({ biblionumber => $item->biblionumber})->next();
 603     is( $hold->biblionumber, $item->biblionumber, "correct biblionumber");
 604     is( $hold->reservedate, '2020-03-20', "Record hold has correct start date" );
 605     is( $hold->expirationdate, '2020-04-22', "Record hold has correct end date" );
 606
 607     $schema->storage->txn_rollback;
 608 };
 609
 610 subtest 'GetRecords' => sub {
 611
 612     plan tests => 1;
 613
 614     $schema->storage->txn_begin;
 615
 616     t::lib::Mocks::mock_preference( 'ILS-DI', 1 );
 617
 618     my $branch1 = $builder->build({
 619         source => 'Branch',
 620     });
 621     my $branch2 = $builder->build({
 622         source => 'Branch',
 623     });
 624
 625     my $biblio = $builder->build({
 626         source => 'Biblio',
 627     });
 628     my $biblioitem = $builder->build({
 629         source => 'Biblioitem',
 630         value => {
 631             biblionumber => $biblio->{biblionumber},
 632         },
 633     });
 634     my $item = $builder->build_object({
 635         class => 'Koha::Items',
 636         value => {
 637             biblionumber => $biblio->{biblionumber},
 638             biblioitemnumber => $biblioitem->{biblioitemnumber},
 639             homebranch => $branch1->{branchcode},
 640             holdingbranch => $branch1->{branchcode},
 641         },
 642     });
 643
 644     ModItemTransfer($item->itemnumber, $branch1->{branchcode}, $branch2->{branchcode});
 645
 646     my $cgi = new CGI;
 647     $cgi->param(service => 'GetRecords');
 648     $cgi->param(id => $biblio->{biblionumber});
 649
 650     my $reply = C4::ILSDI::Services::GetRecords($cgi);
 651
 652     my $transfer = $item->get_transfer;
 653     my $expected = {
 654         datesent => $transfer->datesent,
 655         frombranch => $transfer->frombranch,
 656         tobranch => $transfer->tobranch,
 657     };
 658     is_deeply($reply->{record}->[0]->{items}->{item}->[0]->{transfer}, $expected,
 659         'GetRecords returns transfer informations');
 660
 661     $schema->storage->txn_rollback;
 662 };
 663
 664 subtest 'RenewHold' => sub {
 665     plan tests => 4;
 666
 667     $schema->storage->txn_begin;
 668
 669     my $cgi    = new CGI;
 670     my $patron = $builder->build_object( { class => 'Koha::Patrons' } );
 671     my $item   = $builder->build_object( { class => 'Koha::Items' } );
 672     $cgi->param( patron_id => $patron->borrowernumber );
 673     $cgi->param( item_id   => $item->itemnumber );
 674
 675     t::lib::Mocks::mock_userenv( { patron => $patron } );    # For AddIssue
 676     my $checkout = C4::Circulation::AddIssue( $patron->unblessed, $item->barcode );
 677
 678     # Everything is ok
 679     my $reply = C4::ILSDI::Services::RenewLoan($cgi);
 680     is( exists $reply->{date_due}, 1, 'If the item is checked out, the date_due key should exist' );
 681
 682     # The item is not checked out
 683     $checkout->delete;
 684     $reply = C4::ILSDI::Services::RenewLoan($cgi);
 685     is( $reply, undef, 'If the item is not checked out, we should not explode.');    # FIXME We should return an error code instead
 686
 687     # The item does not exist
 688     $item->delete;
 689     $reply = C4::ILSDI::Services::RenewLoan($cgi);
 690     is( $reply->{code}, 'RecordNotFound', 'If the item does not exist, RecordNotFound should be returned');
 691
 692     $patron->delete;
 693     $reply = C4::ILSDI::Services::RenewLoan($cgi);
 694     is( $reply->{code}, 'PatronNotFound', 'If the patron does not exist, PatronNotFound should be returned');
 695
 696     $schema->storage->txn_rollback;
 697 };
 698
 699 subtest 'GetPatronInfo paginated loans' => sub {
 700     plan tests => 7;
 701
 702     $schema->storage->txn_begin;
 703
 704     my $library = $builder->build_object({
 705         class => 'Koha::Libraries',
 706     });
 707
 708     my $item1 = $builder->build_sample_item({ library => $library->branchcode });
 709     my $item2 = $builder->build_sample_item({ library => $library->branchcode });
 710     my $item3 = $builder->build_sample_item({ library => $library->branchcode });
 711     my $patron = $builder->build_object({
 712         class => 'Koha::Patrons',
 713         value => {
 714             branchcode => $library->branchcode,
 715         },
 716     });
 717     my $module = new Test::MockModule('C4::Context');
 718     $module->mock('userenv', sub { { branch => $library->branchcode } });
 719     my $date_due = DateTime->now->add(weeks => 2);
 720     my $issue1 = C4::Circulation::AddIssue($patron->unblessed, $item1->barcode, $date_due);
 721     my $date_due1 = Koha::DateUtils::dt_from_string( $issue1->date_due );
 722     my $issue2 = C4::Circulation::AddIssue($patron->unblessed, $item2->barcode, $date_due);
 723     my $date_due2 = Koha::DateUtils::dt_from_string( $issue2->date_due );
 724     my $issue3 = C4::Circulation::AddIssue($patron->unblessed, $item3->barcode, $date_due);
 725     my $date_due3 = Koha::DateUtils::dt_from_string( $issue3->date_due );
 726
 727     my $cgi = new CGI;
 728
 729     $cgi->param( 'service', 'GetPatronInfo' );
 730     $cgi->param( 'patron_id', $patron->borrowernumber );
 731     $cgi->param( 'show_loans', '1' );
 732     $cgi->param( 'loans_per_page', '2' );
 733     $cgi->param( 'loans_page', '1' );
 734     my $reply = C4::ILSDI::Services::GetPatronInfo($cgi);
 735
 736     is($reply->{total_loans}, 3, 'total_loans == 3');
 737     is(scalar @{ $reply->{loans}->{loan} }, 2, 'GetPatronInfo returned only 2 loans');
 738     is($reply->{loans}->{loan}->[0]->{itemnumber}, $item3->itemnumber);
 739     is($reply->{loans}->{loan}->[1]->{itemnumber}, $item2->itemnumber);
 740
 741     $cgi->param( 'loans_page', '2' );
 742     $reply = C4::ILSDI::Services::GetPatronInfo($cgi);
 743
 744     is($reply->{total_loans}, 3, 'total_loans == 3');
 745     is(scalar @{ $reply->{loans}->{loan} }, 1, 'GetPatronInfo returned only 1 loan');
 746     is($reply->{loans}->{loan}->[0]->{itemnumber}, $item1->itemnumber);
 747
 748     $schema->storage->txn_rollback;
 749 };