t/db_dependent/Koha/Checkouts.t

   1 #!/usr/bin/perl
   2
   3 # Copyright 2015 Koha Development team
   4 #
   5 # This file is part of Koha
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Test::More tests => 8;
  23
  24 use C4::Circulation;
  25 use Koha::Checkouts;
  26 use Koha::Database;
  27 use Koha::DateUtils qw( dt_from_string );
  28
  29 use t::lib::TestBuilder;
  30
  31 my $schema = Koha::Database->new->schema;
  32 $schema->storage->txn_begin;
  33
  34 my $builder         = t::lib::TestBuilder->new;
  35 my $library         = $builder->build( { source => 'Branch' } );
  36 my $patron          = $builder->build( { source => 'Borrower', value => { branchcode => $library->{branchcode} } } );
  37 my $item_1          = $builder->build_sample_item;
  38 my $item_2          = $builder->build_sample_item;
  39 my $nb_of_checkouts = Koha::Checkouts->search->count;
  40 my $new_checkout_1  = Koha::Checkout->new(
  41     {   borrowernumber => $patron->{borrowernumber},
  42         itemnumber     => $item_1->itemnumber,
  43         branchcode     => $library->{branchcode},
  44     }
  45 )->store;
  46 my $new_checkout_2 = Koha::Checkout->new(
  47     {   borrowernumber => $patron->{borrowernumber},
  48         itemnumber     => $item_2->itemnumber,
  49         branchcode     => $library->{branchcode},
  50     }
  51 )->store;
  52
  53 like( $new_checkout_1->issue_id, qr|^\d+$|, 'Adding a new checkout should have set the issue_id' );
  54 is( Koha::Checkouts->search->count, $nb_of_checkouts + 2, 'The 2 checkouts should have been added' );
  55
  56 my $retrieved_checkout_1 = Koha::Checkouts->find( $new_checkout_1->issue_id );
  57 is( $retrieved_checkout_1->itemnumber, $new_checkout_1->itemnumber, 'Find a checkout by id should return the correct checkout' );
  58
  59 subtest 'is_overdue' => sub {
  60     plan tests => 6;
  61     my $ten_days_ago   = dt_from_string->add( days => -10 );
  62     my $ten_days_later = dt_from_string->add( days => 10 );
  63     my $yesterday      = dt_from_string->add( days => -1 );
  64     my $tomorrow       = dt_from_string->add( days => 1 );
  65
  66     $retrieved_checkout_1->date_due($ten_days_ago)->store;
  67     is( $retrieved_checkout_1->is_overdue,
  68         1, 'The item should have been returned 10 days ago' );
  69
  70     $retrieved_checkout_1->date_due($ten_days_later)->store;
  71     is( $retrieved_checkout_1->is_overdue, 0, 'The item is due in 10 days' );
  72
  73     $retrieved_checkout_1->date_due($tomorrow)->store;
  74     is( $retrieved_checkout_1->is_overdue($ten_days_later),
  75         1, 'The item should have been returned yesterday' );
  76
  77     $retrieved_checkout_1->date_due($yesterday)->store;
  78     is( $retrieved_checkout_1->is_overdue($ten_days_ago),
  79         0, 'Ten days ago the item due yesterday was not late' );
  80
  81     $retrieved_checkout_1->date_due($tomorrow)->store;
  82     is( $retrieved_checkout_1->is_overdue($ten_days_later),
  83         1, 'In Ten days, the item due tomorrow will be late' );
  84
  85     $retrieved_checkout_1->date_due($yesterday)->store;
  86     is( $retrieved_checkout_1->is_overdue($ten_days_ago),
  87         0, 'In Ten days, the item due yesterday will still be late' );
  88 };
  89
  90 subtest 'item' => sub {
  91     plan tests => 2;
  92     my $item = $retrieved_checkout_1->item;
  93     is( ref( $item ), 'Koha::Item', 'Koha::Checkout->item should return a Koha::Item' );
  94     is( $item->itemnumber, $item_1->itemnumber, 'Koha::Checkout->item should return the correct item' );
  95 };
  96
  97 $retrieved_checkout_1->delete;
  98 is( Koha::Checkouts->search->count, $nb_of_checkouts + 1, 'Delete should have deleted the checkout' );
  99
 100 subtest 'patron' => sub {
 101     plan tests => 3;
 102     my $patron = $builder->build_object({class=>'Koha::Patrons', value => {branchcode => $library->{branchcode}}});
 103
 104     my $item = $builder->build_sample_item;
 105     my $checkout = Koha::Checkout->new(
 106         {   borrowernumber => $patron->borrowernumber,
 107             itemnumber     => $item->itemnumber,
 108             branchcode     => $library->{branchcode},
 109         }
 110     )->store;
 111
 112     my $p = $checkout->patron;
 113     is( ref($p), 'Koha::Patron',
 114         'Koha::Checkout->patron should return a Koha::Patron' );
 115     is( $p->borrowernumber, $patron->borrowernumber,
 116         'Koha::Checkout->patron should return the correct patron' );
 117
 118     # Testing Koha::Old::Checkout->patron now
 119     my $issue_id = $checkout->issue_id;
 120     C4::Circulation::MarkIssueReturned( $p->borrowernumber, $checkout->itemnumber );
 121     $p->delete;
 122     my $old_issue = Koha::Old::Checkouts->find($issue_id);
 123     is( $old_issue->patron, undef,
 124         'Koha::Checkout->patron should return undef if the patron record has been deleted'
 125     );
 126 };
 127
 128 subtest 'issuer' => sub {
 129     plan tests => 3;
 130     my $patron = $builder->build_object({class=>'Koha::Patrons', value => {branchcode => $library->{branchcode}}});
 131     my $issuer = $builder->build_object({class=>'Koha::Patrons', value => {branchcode => $library->{branchcode}}});
 132
 133     my $item = $builder->build_sample_item;
 134     my $checkout = Koha::Checkout->new({
 135         borrowernumber => $patron->borrowernumber,
 136         issuer         => $issuer->borrowernumber,
 137         itemnumber     => $item->itemnumber,
 138         branchcode     => $library->{branchcode},
 139     })->store;
 140
 141     my $i = $checkout->issued_by;
 142     is( ref($i), 'Koha::Patron',
 143         'Koha::Checkout->issued_by should return a Koha::Patron' );
 144     is( $i->borrowernumber, $issuer->borrowernumber,
 145         'Koha::Checkout->issued_by should return the correct patron' );
 146
 147     # Testing Koha::Old::Checkout->patron now
 148     my $issue_id = $checkout->issue_id;
 149     C4::Circulation::MarkIssueReturned( $patron->borrowernumber, $checkout->itemnumber );
 150     $i->delete;
 151     my $old_issue = Koha::Old::Checkouts->find($issue_id);
 152     is( $old_issue->issuer, undef,
 153         'Koha::Checkout->issuer should return undef if the patron record has been deleted'
 154     );
 155
 156 };
 157
 158 $schema->storage->txn_rollback;
 159