t/db_dependent/Koha/Libraries.t

   1 #!/usr/bin/perl
   2
   3 # Copyright 2015 Koha Development team
   4 #
   5 # This file is part of Koha
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Test::More tests => 9;
  23
  24 use C4::Biblio;
  25 use C4::Context;
  26 use C4::Items;
  27
  28 use Koha::Biblios;
  29 use Koha::Item::Transfer::Limits;
  30 use Koha::Items;
  31 use Koha::Library;
  32 use Koha::Libraries;
  33 use Koha::Database;
  34 use Koha::CirculationRules;
  35
  36 use t::lib::Mocks;
  37 use t::lib::TestBuilder;
  38
  39 my $schema = Koha::Database->new->schema;
  40 $schema->storage->txn_begin;
  41
  42 # Cleanup default_branch_item_rules
  43 my $dbh     = C4::Context->dbh;
  44 $dbh->do('DELETE FROM circulation_rules');
  45
  46 my $builder = t::lib::TestBuilder->new;
  47 my $nb_of_libraries = Koha::Libraries->search->count;
  48 my $new_library_1 = Koha::Library->new({
  49     branchcode => 'my_bc_1',
  50     branchname => 'my_branchname_1',
  51     branchnotes => 'my_branchnotes_1',
  52     marcorgcode => 'US-MyLib',
  53 })->store;
  54 my $new_library_2 = Koha::Library->new({
  55     branchcode => 'my_bc_2',
  56     branchname => 'my_branchname_2',
  57     branchnotes => 'my_branchnotes_2',
  58 })->store;
  59
  60 is( Koha::Libraries->search->count,         $nb_of_libraries + 2,  'The 2 libraries should have been added' );
  61
  62 my $retrieved_library_1 = Koha::Libraries->find( $new_library_1->branchcode );
  63 is( $retrieved_library_1->branchname, $new_library_1->branchname, 'Find a library by branchcode should return the correct library' );
  64
  65 $retrieved_library_1->delete;
  66 is( Koha::Libraries->search->count, $nb_of_libraries + 1, 'Delete should have deleted the library' );
  67
  68 # Stockrotation relationship testing
  69
  70 my $new_library_sr = $builder->build({ source => 'Branch' });
  71
  72 $builder->build({
  73     source => 'Stockrotationstage',
  74     value  => { branchcode_id => $new_library_sr->{branchcode} },
  75 });
  76 $builder->build({
  77     source => 'Stockrotationstage',
  78     value  => { branchcode_id => $new_library_sr->{branchcode} },
  79 });
  80 $builder->build({
  81     source => 'Stockrotationstage',
  82     value  => { branchcode_id => $new_library_sr->{branchcode} },
  83 });
  84
  85 my $srstages = Koha::Libraries->find($new_library_sr->{branchcode})
  86     ->stockrotationstages;
  87 is( $srstages->count, 3, 'Correctly fetched stockrotationstages associated with this branch');
  88
  89 isa_ok( $srstages->next, 'Koha::StockRotationStage', "Relationship correctly creates Koha::Objects." );
  90
  91 $schema->storage->txn_rollback;
  92
  93 subtest '->get_effective_marcorgcode' => sub {
  94
  95     plan tests => 4;
  96
  97     $schema->storage->txn_begin;
  98
  99     my $library_1 = $builder->build_object({ class => 'Koha::Libraries',
 100                                              value => { marcorgcode => 'US-MyLib' } });
 101     my $library_2 = $builder->build_object({ class => 'Koha::Libraries',
 102                                              value => { marcorgcode => undef } });
 103
 104     t::lib::Mocks::mock_preference('MARCOrgCode', 'US-Default');
 105
 106     is( $library_1->get_effective_marcorgcode, 'US-MyLib',
 107        'If defined, use library\'s own marc org code');
 108     is( $library_2->get_effective_marcorgcode, 'US-Default',
 109        'If not defined library\' marc org code, use the one from system preferences');
 110
 111     t::lib::Mocks::mock_preference('MARCOrgCode', 'Blah');
 112     is( $library_2->get_effective_marcorgcode, 'Blah',
 113        'Fallback is always MARCOrgCode syspref');
 114
 115     $library_2->marcorgcode('ThisIsACode')->store();
 116     is( $library_2->get_effective_marcorgcode, 'ThisIsACode',
 117        'Pick library_2 code');
 118
 119     $schema->storage->txn_rollback;
 120 };
 121
 122 subtest '->inbound_email_address' => sub {
 123
 124     plan tests => 5;
 125
 126     $schema->storage->txn_begin;
 127
 128     my $library_1 = $builder->build_object(
 129         {
 130             class => 'Koha::Libraries',
 131             value => {
 132                 branchemail   => 'from@mybranc.com',
 133                 branchreplyto => 'reply@mybranch.com'
 134             }
 135         }
 136     );
 137
 138     t::lib::Mocks::mock_preference( 'KohaAdminEmailAddress', 'admin@mylibrary.com' );
 139     t::lib::Mocks::mock_preference( 'ReplytoDefault', 'reply@mylibrary.com' );
 140
 141     is( $library_1->inbound_email_address, $library_1->branchreplyto,
 142        'If defined, use branches replyto address');
 143
 144     $library_1->branchreplyto(undef)->store();
 145     is( $library_1->inbound_email_address, $library_1->branchemail,
 146        'Fallback to branches email address when branchreplyto is undefined');
 147
 148     $library_1->branchemail(undef)->store();
 149     is( $library_1->inbound_email_address, 'reply@mylibrary.com',
 150        'Fallback to ReplytoDefault email address when branchreplyto and branchemail are undefined');
 151
 152     t::lib::Mocks::mock_preference( 'ReplytoDefault', '' );
 153     is( $library_1->inbound_email_address, 'admin@mylibrary.com',
 154        'Fallback to KohaAdminEmailAddress email address when branchreplyto, branchemail and ReplytoDefault are undefined');
 155
 156     t::lib::Mocks::mock_preference( 'KohaAdminEmailAddress', '' );
 157     is( $library_1->inbound_email_address, undef,
 158        'Return undef when  email address when branchreplyto, branchemail, ReplytoDefault and KohaAdminEmailAddress are undefined');
 159     $schema->storage->txn_rollback;
 160 };
 161
 162 subtest 'cash_registers' => sub {
 163     plan tests => 3;
 164
 165     $schema->storage->txn_begin;
 166
 167     my $library = $builder->build_object( { class => 'Koha::Libraries' } );
 168     my $register1 = $builder->build_object(
 169         {
 170             class => 'Koha::Cash::Registers',
 171             value  => { branch => $library->branchcode },
 172         }
 173     );
 174     my $register2 = $builder->build_object(
 175         {
 176             class => 'Koha::Cash::Registers',
 177             value  => { branch => $library->branchcode },
 178         }
 179     );
 180
 181     my $registers = $library->cash_registers;
 182     is( ref($registers), 'Koha::Cash::Registers',
 183 'Koha::Library->cash_registers should return a set of Koha::Cash::Registers'
 184     );
 185     is( $registers->count, 2,
 186         'Koha::Library->cash_registers should return the correct cash registers'
 187     );
 188
 189     $register1->delete;
 190     is( $library->cash_registers->next->id, $register2->id,
 191         'Koha::Library->cash_registers should return the correct cash registers'
 192     );
 193
 194     $schema->storage->txn_rollback;
 195 };
 196
 197 subtest 'get_hold_libraries and validate_hold_sibling' => sub {
 198
 199     plan tests => 5;
 200
 201     $schema->storage->txn_begin;
 202
 203     my $library1 = $builder->build_object( { class => 'Koha::Libraries' } );
 204     my $library2 = $builder->build_object( { class => 'Koha::Libraries' } );
 205     my $library3 = $builder->build_object( { class => 'Koha::Libraries' } );
 206
 207     my $root = $builder->build_object( { class => 'Koha::Library::Groups', value => { ft_local_hold_group => 1 } } );
 208     my $g1 = $builder->build_object( { class => 'Koha::Library::Groups', value => { parent_id => $root->id, branchcode => $library1->branchcode } } );
 209     my $g2 = $builder->build_object( { class => 'Koha::Library::Groups', value => { parent_id => $root->id, branchcode => $library2->branchcode } } );
 210
 211     my @hold_libraries = ($library1, $library2);
 212
 213     my @result = $library1->get_hold_libraries();
 214
 215     ok(scalar(@result) == 2, 'get_hold_libraries returns 2 libraries');
 216
 217     my %map = map {$_->branchcode, 1} @result;
 218
 219     foreach my $hold_library ( @hold_libraries ) {
 220         ok(exists $map{$hold_library->branchcode}, 'library in hold group');
 221     }
 222
 223     ok($library1->validate_hold_sibling( { branchcode => $library2->branchcode } ), 'Library 2 is a valid hold sibling');
 224     ok(!$library1->validate_hold_sibling( { branchcode => $library3->branchcode } ), 'Library 3 is not a valid hold sibling');
 225
 226     $schema->storage->txn_rollback;
 227
 228 };